lib/DBIx/Class/_Util.pm

   1 package # hide from PAUSE
   2   DBIx::Class::_Util;
   3
   4 use warnings;
   5 use strict;
   6
   7 use constant SPURIOUS_VERSION_CHECK_WARNINGS => ( "$]" < 5.010 ? 1 : 0);
   8
   9 BEGIN {
  10   package # hide from pause
  11     DBIx::Class::_ENV_;
  12
  13   use Config;
  14
  15   use constant {
  16
  17     # but of course
  18     BROKEN_FORK => ($^O eq 'MSWin32') ? 1 : 0,
  19
  20     BROKEN_GOTO => ( "$]" < 5.008003 ) ? 1 : 0,
  21
  22     HAS_ITHREADS => $Config{useithreads} ? 1 : 0,
  23
  24     UNSTABLE_DOLLARAT => ( "$]" < 5.013002 ) ? 1 : 0,
  25
  26     ( map
  27       #
  28       # the "DBIC_" prefix below is crucial - this is what makes CI pick up
  29       # all envvars without further adjusting its scripts
  30       # DO NOT CHANGE to the more logical { $_ => !!( $ENV{"DBIC_$_"} ) }
  31       #
  32       { substr($_, 5) => !!( $ENV{$_} ) }
  33       qw(
  34         DBIC_SHUFFLE_UNORDERED_RESULTSETS
  35         DBIC_ASSERT_NO_INTERNAL_WANTARRAY
  36         DBIC_ASSERT_NO_INTERNAL_INDIRECT_CALLS
  37         DBIC_STRESSTEST_UTF8_UPGRADE_GENERATED_COLLAPSER_SOURCE
  38         DBIC_STRESSTEST_COLUMN_INFO_UNAWARE_STORAGE
  39       )
  40     ),
  41
  42     IV_SIZE => $Config{ivsize},
  43
  44     OS_NAME => $^O,
  45   };
  46
  47   if ( "$]" < 5.009_005) {
  48     require MRO::Compat;
  49     constant->import( OLD_MRO => 1 );
  50   }
  51   else {
  52     require mro;
  53     constant->import( OLD_MRO => 0 );
  54   }
  55 }
  56
  57 # FIXME - this is not supposed to be here
  58 # Carp::Skip to the rescue soon
  59 use DBIx::Class::Carp '^DBIx::Class|^DBICTest';
  60
  61 use B ();
  62 use Carp 'croak';
  63 use Storable 'nfreeze';
  64 use Scalar::Util qw(weaken blessed reftype refaddr);
  65 use List::Util qw(first);
  66 use Sub::Quote qw(qsub quote_sub);
  67
  68 # Already correctly prototyped: perlbrew exec perl -MStorable -e 'warn prototype \&Storable::dclone'
  69 BEGIN { *deep_clone = \&Storable::dclone }
  70
  71 use base 'Exporter';
  72 our @EXPORT_OK = qw(
  73   sigwarn_silencer modver_gt_or_eq modver_gt_or_eq_and_lt
  74   fail_on_internal_wantarray fail_on_internal_call
  75   refdesc refcount hrefaddr
  76   scope_guard detected_reinvoked_destructor
  77   is_exception dbic_internal_try
  78   quote_sub qsub perlstring serialize deep_clone dump_value
  79   parent_dir mkdir_p
  80   UNRESOLVABLE_CONDITION
  81 );
  82
  83 use constant UNRESOLVABLE_CONDITION => \ '1 = 0';
  84
  85 sub sigwarn_silencer ($) {
  86   my $pattern = shift;
  87
  88   croak "Expecting a regexp" if ref $pattern ne 'Regexp';
  89
  90   my $orig_sig_warn = $SIG{__WARN__} || sub { CORE::warn(@_) };
  91
  92   return sub { &$orig_sig_warn unless $_[0] =~ $pattern };
  93 }
  94
  95 sub perlstring ($) { q{"}. quotemeta( shift ). q{"} };
  96
  97 sub hrefaddr ($) { sprintf '0x%x', &refaddr||0 }
  98
  99 sub refdesc ($) {
 100   croak "Expecting a reference" if ! length ref $_[0];
 101
 102   # be careful not to trigger stringification,
 103   # reuse @_ as a scratch-pad
 104   sprintf '%s%s(0x%x)',
 105     ( defined( $_[1] = blessed $_[0]) ? "$_[1]=" : '' ),
 106     reftype $_[0],
 107     refaddr($_[0]),
 108   ;
 109 }
 110
 111 sub refcount ($) {
 112   croak "Expecting a reference" if ! length ref $_[0];
 113
 114   # No tempvars - must operate on $_[0], otherwise the pad
 115   # will count as an extra ref
 116   B::svref_2object($_[0])->REFCNT;
 117 }
 118
 119 sub serialize ($) {
 120   local $Storable::canonical = 1;
 121   nfreeze($_[0]);
 122 }
 123
 124 my $dd_obj;
 125 sub dump_value ($) {
 126   local $Data::Dumper::Indent = 1
 127     unless defined $Data::Dumper::Indent;
 128
 129   my $dump_str = (
 130     $dd_obj
 131       ||=
 132     do {
 133       require Data::Dumper;
 134       my $d = Data::Dumper->new([])
 135         ->Purity(0)
 136         ->Pad('')
 137         ->Useqq(1)
 138         ->Terse(1)
 139         ->Freezer('')
 140         ->Quotekeys(0)
 141         ->Bless('bless')
 142         ->Pair(' => ')
 143         ->Sortkeys(1)
 144         ->Deparse(1)
 145       ;
 146
 147       $d->Sparseseen(1) if modver_gt_or_eq (
 148         'Data::Dumper', '2.136'
 149       );
 150
 151       $d;
 152     }
 153   )->Values([$_[0]])->Dump;
 154
 155   $dd_obj->Reset->Values([]);
 156
 157   $dump_str;
 158 }
 159
 160 sub scope_guard (&) {
 161   croak 'Calling scope_guard() in void context makes no sense'
 162     if ! defined wantarray;
 163
 164   # no direct blessing of coderefs - DESTROY is buggy on those
 165   bless [ $_[0] ], 'DBIx::Class::_Util::ScopeGuard';
 166 }
 167 {
 168   package #
 169     DBIx::Class::_Util::ScopeGuard;
 170
 171   sub DESTROY {
 172     &DBIx::Class::_Util::detected_reinvoked_destructor;
 173
 174     local $@ if DBIx::Class::_ENV_::UNSTABLE_DOLLARAT;
 175
 176     eval {
 177       $_[0]->[0]->();
 178       1;
 179     }
 180       or
 181     Carp::cluck(
 182       "Execution of scope guard $_[0] resulted in the non-trappable exception:\n\n$@"
 183     );
 184   }
 185 }
 186
 187
 188 sub is_exception ($) {
 189   my $e = $_[0];
 190
 191   # FIXME
 192   # this is not strictly correct - an eval setting $@ to undef
 193   # is *not* the same as an eval setting $@ to ''
 194   # but for the sake of simplicity assume the following for
 195   # the time being
 196   return 0 unless defined $e;
 197
 198   my ($not_blank, $suberror);
 199   {
 200     local $SIG{__DIE__} if $SIG{__DIE__};
 201     local $@;
 202     eval {
 203       # The ne() here is deliberate - a plain length($e), or worse "$e" ne
 204       # will entirely obviate the need for the encolsing eval{}, as the
 205       # condition we guard against is a missing fallback overload
 206       $not_blank = ( $e ne '' );
 207       1;
 208     } or $suberror = $@;
 209   }
 210
 211   if (defined $suberror) {
 212     if (length (my $class = blessed($e) )) {
 213       carp_unique( sprintf(
 214         'External exception class %s implements partial (broken) overloading '
 215       . 'preventing its instances from being used in simple ($x eq $y) '
 216       . 'comparisons. Given Perl\'s "globally cooperative" exception '
 217       . 'handling this type of brokenness is extremely dangerous on '
 218       . 'exception objects, as it may (and often does) result in silent '
 219       . '"exception substitution". DBIx::Class tries to work around this '
 220       . 'as much as possible, but other parts of your software stack may '
 221       . 'not be even aware of this. Please submit a bugreport against the '
 222       . 'distribution containing %s and in the meantime apply a fix similar '
 223       . 'to the one shown at %s, in order to ensure your exception handling '
 224       . 'is saner application-wide. What follows is the actual error text '
 225       . "as generated by Perl itself:\n\n%s\n ",
 226         $class,
 227         $class,
 228         'http://v.gd/DBIC_overload_tempfix/',
 229         $suberror,
 230       ));
 231
 232       # workaround, keeps spice flowing
 233       $not_blank = !!( length $e );
 234     }
 235     else {
 236       # not blessed yet failed the 'ne'... this makes 0 sense...
 237       # just throw further
 238       die $suberror
 239     }
 240   }
 241   elsif (
 242     # a ref evaluating to '' is definitively a "null object"
 243     ( not $not_blank )
 244       and
 245     length( my $class = ref $e )
 246   ) {
 247     carp_unique( sprintf(
 248       "Objects of external exception class '%s' stringify to '' (the "
 249     . 'empty string), implementing the so called null-object-pattern. '
 250     . 'Given Perl\'s "globally cooperative" exception handling using this '
 251     . 'class of exceptions is extremely dangerous, as it may (and often '
 252     . 'does) result in silent discarding of errors. DBIx::Class tries to '
 253     . 'work around this as much as possible, but other parts of your '
 254     . 'software stack may not be even aware of the problem. Please submit '
 255     . 'a bugreport against the distribution containing %s',
 256
 257       ($class) x 2,
 258     ));
 259
 260     $not_blank = 1;
 261   }
 262
 263   return $not_blank;
 264 }
 265
 266 {
 267   my $callstack_state;
 268
 269   # Recreate the logic of try(), while reusing the catch()/finally() as-is
 270   #
 271   # FIXME: We need to move away from Try::Tiny entirely (way too heavy and
 272   # yes, shows up ON TOP of profiles) but this is a batle for another maint
 273   sub dbic_internal_try (&;@) {
 274
 275     my $try_cref = shift;
 276     my $catch_cref = undef;  # apparently this is a thing... https://rt.perl.org/Public/Bug/Display.html?id=119311
 277
 278     for my $arg (@_) {
 279
 280       if( ref($arg) eq 'Try::Tiny::Catch' ) {
 281
 282         croak 'dbic_internal_try() may not be followed by multiple catch() blocks'
 283           if $catch_cref;
 284
 285         $catch_cref = $$arg;
 286       }
 287       elsif ( ref($arg) eq 'Try::Tiny::Finally' ) {
 288         croak 'dbic_internal_try() does not support finally{}';
 289       }
 290       else {
 291         croak(
 292           'dbic_internal_try() encountered an unexpected argument '
 293         . "'@{[ defined $arg ? $arg : 'UNDEF' ]}' - perhaps "
 294         . 'a missing semi-colon before or ' # trailing space important
 295         );
 296       }
 297     }
 298
 299     my $wantarray = wantarray;
 300     my $preexisting_exception = $@;
 301
 302     my @ret;
 303     my $all_good = eval {
 304       $@ = $preexisting_exception;
 305
 306       local $callstack_state->{in_internal_try} = 1
 307         unless $callstack_state->{in_internal_try};
 308
 309       # always unset - someone may have snuck it in
 310       local $SIG{__DIE__} if $SIG{__DIE__};
 311
 312       if( $wantarray ) {
 313         @ret = $try_cref->();
 314       }
 315       elsif( defined $wantarray ) {
 316         $ret[0] = $try_cref->();
 317       }
 318       else {
 319         $try_cref->();
 320       }
 321
 322       1;
 323     };
 324
 325     my $exception = $@;
 326     $@ = $preexisting_exception;
 327
 328     if ( $all_good ) {
 329       return $wantarray ? @ret : $ret[0]
 330     }
 331     elsif ( $catch_cref ) {
 332       for ( $exception ) {
 333         return $catch_cref->($exception);
 334       }
 335     }
 336
 337     return;
 338   }
 339
 340   sub in_internal_try { !! $callstack_state->{in_internal_try} }
 341 }
 342
 343 {
 344   my $destruction_registry = {};
 345
 346   sub CLONE {
 347     $destruction_registry = { map
 348       { defined $_ ? ( refaddr($_) => $_ ) : () }
 349       values %$destruction_registry
 350     };
 351
 352     # Dummy NEXTSTATE ensuring the all temporaries on the stack are garbage
 353     # collected before leaving this scope. Depending on the code above, this
 354     # may very well be just a preventive measure guarding future modifications
 355     undef;
 356   }
 357
 358   # This is almost invariably invoked from within DESTROY
 359   # throwing exceptions won't work
 360   sub detected_reinvoked_destructor {
 361
 362     # quick "garbage collection" pass - prevents the registry
 363     # from slowly growing with a bunch of undef-valued keys
 364     defined $destruction_registry->{$_} or delete $destruction_registry->{$_}
 365       for keys %$destruction_registry;
 366
 367     if (! length ref $_[0]) {
 368       printf STDERR '%s() expects a blessed reference %s',
 369         (caller(0))[3],
 370         Carp::longmess,
 371       ;
 372       return undef; # don't know wtf to do
 373     }
 374     elsif (! defined $destruction_registry->{ my $addr = refaddr($_[0]) } ) {
 375       weaken( $destruction_registry->{$addr} = $_[0] );
 376       return 0;
 377     }
 378     else {
 379       carp_unique ( sprintf (
 380         'Preventing *MULTIPLE* DESTROY() invocations on %s - an *EXTREMELY '
 381       . 'DANGEROUS* condition which is *ALMOST CERTAINLY GLOBAL* within your '
 382       . 'application, affecting *ALL* classes without active protection against '
 383       . 'this. Diagnose and fix the root cause ASAP!!!%s',
 384       refdesc $_[0],
 385         ( ( $INC{'Devel/StackTrace.pm'} and ! do { local $@; eval { Devel::StackTrace->VERSION(2) } } )
 386           ? " (likely culprit Devel::StackTrace\@@{[ Devel::StackTrace->VERSION ]} found in %INC, http://is.gd/D_ST_refcap)"
 387           : ''
 388         )
 389       ));
 390
 391       return 1;
 392     }
 393   }
 394 }
 395
 396 my $module_name_rx = qr/ \A [A-Z_a-z] [0-9A-Z_a-z]* (?: :: [0-9A-Z_a-z]+ )* \z /x;
 397 my $ver_rx =         qr/ \A [0-9]+ (?: \. [0-9]+ )* (?: \_ [0-9]+ )*        \z /x;
 398
 399 sub modver_gt_or_eq ($$) {
 400   my ($mod, $ver) = @_;
 401
 402   croak "Nonsensical module name supplied"
 403     if ! defined $mod or $mod !~ $module_name_rx;
 404
 405   croak "Nonsensical minimum version supplied"
 406     if ! defined $ver or $ver !~ $ver_rx;
 407
 408   no strict 'refs';
 409   my $ver_cache = ${"${mod}::__DBIC_MODULE_VERSION_CHECKS__"} ||= ( $mod->VERSION
 410     ? {}
 411     : croak "$mod does not seem to provide a version (perhaps it never loaded)"
 412   );
 413
 414   ! defined $ver_cache->{$ver}
 415     and
 416   $ver_cache->{$ver} = do {
 417
 418     local $SIG{__WARN__} = sigwarn_silencer( qr/\Qisn't numeric in subroutine entry/ )
 419       if SPURIOUS_VERSION_CHECK_WARNINGS;
 420
 421     local $SIG{__DIE__} if $SIG{__DIE__};
 422     local $@;
 423     eval { $mod->VERSION($ver) } ? 1 : 0;
 424   };
 425
 426   $ver_cache->{$ver};
 427 }
 428
 429 sub modver_gt_or_eq_and_lt ($$$) {
 430   my ($mod, $v_ge, $v_lt) = @_;
 431
 432   croak "Nonsensical maximum version supplied"
 433     if ! defined $v_lt or $v_lt !~ $ver_rx;
 434
 435   return (
 436     modver_gt_or_eq($mod, $v_ge)
 437       and
 438     ! modver_gt_or_eq($mod, $v_lt)
 439   ) ? 1 : 0;
 440 }
 441
 442
 443 #
 444 # Why not just use some higher-level module or at least File::Spec here?
 445 # Because:
 446 # 1)  This is a *very* rarely used function, and the deptree is large
 447 #     enough already as it is
 448 #
 449 # 2)  (more importantly) Our tooling is utter shit in this area. There
 450 #     is no comprehensive support for UNC paths in PathTools and there
 451 #     are also various small bugs in representation across different
 452 #     path-manipulation CPAN offerings.
 453 #
 454 # Since this routine is strictly used for logical path processing (it
 455 # *must* be able to work with not-yet-existing paths), use this seemingly
 456 # simple but I *think* complete implementation to feed to other consumers
 457 #
 458 # If bugs are ever uncovered in this routine, *YOU ARE URGED TO RESIST*
 459 # the impulse to bring in an external dependency. During runtime there
 460 # is exactly one spot that could potentially maybe once in a blue moon
 461 # use this function. Keep it lean.
 462 #
 463 sub parent_dir ($) {
 464   ( $_[0] =~ m{  [\/\\]  ( \.{0,2} ) ( [\/\\]* ) \z }x )
 465     ? (
 466       $_[0]
 467         .
 468       ( ( length($1) and ! length($2) ) ? '/' : '' )
 469         .
 470       '../'
 471     )
 472     : (
 473       require File::Spec
 474         and
 475       File::Spec->catpath (
 476         ( File::Spec->splitpath( "$_[0]" ) )[0,1],
 477         '/',
 478       )
 479     )
 480   ;
 481 }
 482
 483 sub mkdir_p ($) {
 484   require File::Path;
 485   # do not ask for a recent version, use 1.x API calls
 486   File::Path::mkpath([ "$_[0]" ]);  # File::Path does not like objects
 487 }
 488
 489
 490 {
 491   my $list_ctx_ok_stack_marker;
 492
 493   sub fail_on_internal_wantarray () {
 494     return if $list_ctx_ok_stack_marker;
 495
 496     if (! defined wantarray) {
 497       croak('fail_on_internal_wantarray() needs a tempvar to save the stack marker guard');
 498     }
 499
 500     my $cf = 1;
 501     while ( ( (CORE::caller($cf+1))[3] || '' ) =~ / :: (?:
 502
 503       # these are public API parts that alter behavior on wantarray
 504       search | search_related | slice | search_literal
 505
 506         |
 507
 508       # these are explicitly prefixed, since we only recognize them as valid
 509       # escapes when they come from the guts of CDBICompat
 510       CDBICompat .*? :: (?: search_where | retrieve_from_sql | retrieve_all )
 511
 512     ) $/x ) {
 513       $cf++;
 514     }
 515
 516     my ($fr, $want, $argdesc);
 517     {
 518       package DB;
 519       $fr = [ CORE::caller($cf) ];
 520       $want = ( CORE::caller($cf-1) )[5];
 521       $argdesc = ref $DB::args[0]
 522         ? DBIx::Class::_Util::refdesc($DB::args[0])
 523         : 'non '
 524       ;
 525     };
 526
 527     if (
 528       $want and $fr->[0] =~ /^(?:DBIx::Class|DBICx::)/
 529     ) {
 530       DBIx::Class::Exception->throw( sprintf (
 531         "Improper use of %s instance in list context at %s line %d\n\n    Stacktrace starts",
 532         $argdesc, @{$fr}[1,2]
 533       ), 'with_stacktrace');
 534     }
 535
 536     my $mark = [];
 537     weaken ( $list_ctx_ok_stack_marker = $mark );
 538     $mark;
 539   }
 540 }
 541
 542 sub fail_on_internal_call {
 543   my ($fr, $argdesc);
 544   {
 545     package DB;
 546     $fr = [ CORE::caller(1) ];
 547     $argdesc = ref $DB::args[0]
 548       ? DBIx::Class::_Util::refdesc($DB::args[0])
 549       : undef
 550     ;
 551   };
 552
 553   if (
 554     $argdesc
 555       and
 556     $fr->[0] =~ /^(?:DBIx::Class|DBICx::)/
 557       and
 558     $fr->[1] !~ /\b(?:CDBICompat|ResultSetProxy)\b/  # no point touching there
 559   ) {
 560     DBIx::Class::Exception->throw( sprintf (
 561       "Illegal internal call of indirect proxy-method %s() with argument %s: examine the last lines of the proxy method deparse below to determine what to call directly instead at %s on line %d\n\n%s\n\n    Stacktrace starts",
 562       $fr->[3], $argdesc, @{$fr}[1,2], ( $fr->[6] || do {
 563         require B::Deparse;
 564         no strict 'refs';
 565         B::Deparse->new->coderef2text(\&{$fr->[3]})
 566       }),
 567     ), 'with_stacktrace');
 568   }
 569 }
 570
 571 1;