lib/DBIx/Class/_Util.pm

   1 package # hide from PAUSE
   2   DBIx::Class::_Util;
   3
   4 use DBIx::Class::StartupCheck;  # load es early as we can, usually a noop
   5
   6 use warnings;
   7 use strict;
   8
   9 use constant SPURIOUS_VERSION_CHECK_WARNINGS => ( "$]" < 5.010 ? 1 : 0);
  10
  11 my $mro_recursor_stack;
  12
  13 BEGIN {
  14   package # hide from pause
  15     DBIx::Class::_ENV_;
  16
  17   use Config;
  18
  19   use constant {
  20
  21     # but of course
  22     BROKEN_FORK => ($^O eq 'MSWin32') ? 1 : 0,
  23
  24     BROKEN_GOTO => ( "$]" < 5.008003 ) ? 1 : 0,
  25
  26     # perl -MScalar::Util=weaken -e 'weaken( $hash{key} = \"value" )'
  27     BROKEN_WEAK_SCALARREF_VALUES => ( "$]" < 5.008003 ) ? 1 : 0,
  28
  29     HAS_ITHREADS => $Config{useithreads} ? 1 : 0,
  30
  31     UNSTABLE_DOLLARAT => ( "$]" < 5.013002 ) ? 1 : 0,
  32
  33     ( map
  34       #
  35       # the "DBIC_" prefix below is crucial - this is what makes CI pick up
  36       # all envvars without further adjusting its scripts
  37       # DO NOT CHANGE to the more logical { $_ => !!( $ENV{"DBIC_$_"} ) }
  38       #
  39       { substr($_, 5) => !!( $ENV{$_} ) }
  40       qw(
  41         DBIC_SHUFFLE_UNORDERED_RESULTSETS
  42         DBIC_ASSERT_NO_INTERNAL_WANTARRAY
  43         DBIC_ASSERT_NO_INTERNAL_INDIRECT_CALLS
  44         DBIC_STRESSTEST_UTF8_UPGRADE_GENERATED_COLLAPSER_SOURCE
  45         DBIC_STRESSTEST_COLUMN_INFO_UNAWARE_STORAGE
  46       )
  47     ),
  48
  49     IV_SIZE => $Config{ivsize},
  50
  51     OS_NAME => $^O,
  52   };
  53
  54   if ( "$]" < 5.009_005) {
  55     require MRO::Compat;
  56     constant->import( OLD_MRO => 1 );
  57
  58     #
  59     # Yes, I know this is a rather PHP-ish name, but please first read
  60     # https://metacpan.org/source/BOBTFISH/MRO-Compat-0.12/lib/MRO/Compat.pm#L363-368
  61     #
  62     # Even if we are using Class::C3::XS it still won't work, as doing
  63     #   defined( *{ "SubClass::"->{$_} }{CODE} )
  64     # will set pkg_gen to the same value for SubClass and *ALL PARENTS*
  65     #
  66     *DBIx::Class::_Util::get_real_pkg_gen = sub ($) {
  67       require Digest::MD5;
  68       require Math::BigInt;
  69
  70       # the non-assign-unless-there-is-a-hash is deliberate
  71       ( $mro_recursor_stack->{cache} || {} )->{$_[0]}{gen} ||= (
  72         Math::BigInt->new( '0x' . ( Digest::MD5::md5_hex( join "\0", map {
  73
  74           ( $mro_recursor_stack->{cache} || {} )->{$_}{methlist} ||= do {
  75
  76             my $class = $_;
  77             no strict 'refs';
  78
  79             # RV to be hashed up and turned into a number
  80             join "\0", (
  81               $class,
  82               map
  83                 {(
  84                   # stringification should be sufficient, ignore names/refaddr entirely
  85                   $_,
  86                   attributes::get( $_ ),
  87                 )}
  88                 map
  89                   {(
  90                     # skip dummy C::C3 helper crefs
  91                     ! ( ( $Class::C3::MRO{$class} || {} )->{methods}{$_} )
  92                       and
  93                     (
  94                       ref(\ "${class}::"->{$_} ) ne 'GLOB'
  95                         or
  96                       defined( *{ "${class}::"->{$_} }{CODE} )
  97                     )
  98                   )
  99                     ? ( \&{"${class}::$_"} )
 100                     : ()
 101                   }
 102                   keys %{ "${class}::" }
 103             );
 104           }
 105         } (
 106
 107           @{
 108             ( $mro_recursor_stack->{cache} || {} )->{$_[0]}{linear_isa}
 109               ||=
 110             mro::get_linear_isa($_[0])
 111           },
 112
 113           ((
 114             ( $mro_recursor_stack->{cache} || {} )->{$_[0]}{is_universal}
 115               ||=
 116             mro::is_universal($_[0])
 117           ) ? () : @{
 118             ( $mro_recursor_stack->{cache} || {} )->{UNIVERSAL}{linear_isa}
 119               ||=
 120             mro::get_linear_isa("UNIVERSAL")
 121           } ),
 122
 123         ) ) ) )
 124       );
 125     };
 126   }
 127   else {
 128     require mro;
 129     constant->import( OLD_MRO => 0 );
 130     *DBIx::Class::_Util::get_real_pkg_gen = \&mro::get_pkg_gen;
 131   }
 132
 133   # Both of these are no longer used for anything. However bring
 134   # them back after they were purged in 08a8d8f1, as there appear
 135   # to be outfits with *COPY PASTED* pieces of lib/DBIx/Class/Storage/*
 136   # in their production codebases. There is no point in breaking these
 137   # if whatever they used actually continues to work
 138   my $warned;
 139   my $sigh = sub {
 140
 141     require Carp;
 142     my $cluck = "The @{[ (caller(1))[3] ]} constant is no more - adjust your code" . Carp::longmess();
 143
 144     warn $cluck unless $warned->{$cluck}++;
 145
 146     0;
 147   };
 148   sub DBICTEST () { &$sigh }
 149   sub PEEPEENESS () { &$sigh }
 150 }
 151
 152 # FIXME - this is not supposed to be here
 153 # Carp::Skip to the rescue soon
 154 use DBIx::Class::Carp '^DBIx::Class|^DBICTest';
 155
 156 use B ();
 157 use Carp 'croak';
 158 use Storable 'nfreeze';
 159 use Scalar::Util qw(weaken blessed reftype refaddr);
 160 use Sub::Quote qw(qsub);
 161 use Sub::Name ();
 162 use attributes ();
 163
 164 # Already correctly prototyped: perlbrew exec perl -MStorable -e 'warn prototype \&Storable::dclone'
 165 BEGIN { *deep_clone = \&Storable::dclone }
 166
 167 use base 'Exporter';
 168 our @EXPORT_OK = qw(
 169   sigwarn_silencer modver_gt_or_eq modver_gt_or_eq_and_lt
 170   fail_on_internal_wantarray fail_on_internal_call
 171   refdesc refcount hrefaddr set_subname describe_class_methods
 172   scope_guard detected_reinvoked_destructor
 173   is_exception dbic_internal_try visit_namespaces
 174   quote_sub qsub perlstring serialize deep_clone dump_value uniq
 175   parent_dir mkdir_p
 176   UNRESOLVABLE_CONDITION
 177 );
 178
 179 use constant UNRESOLVABLE_CONDITION => \ '1 = 0';
 180
 181 # Override forcing no_defer, and adding naming consistency checks
 182 our %refs_closed_over_by_quote_sub_installed_crefs;
 183 sub quote_sub {
 184   Carp::confess( "Anonymous quoting not supported by the DBIC quote_sub override - supply a sub name" ) if
 185     @_ < 2
 186       or
 187     ! defined $_[1]
 188       or
 189     length ref $_[1]
 190   ;
 191
 192   Carp::confess( "The DBIC quote_sub override expects sub name '$_[0]' to be fully qualified" )
 193     unless (my $stash) = $_[0] =~ /^(.+)::/;
 194
 195   Carp::confess(
 196     "The DBIC sub_quote override does not support 'no_install'"
 197   ) if (
 198     $_[3]
 199       and
 200     $_[3]->{no_install}
 201   );
 202
 203   Carp::confess(
 204     'The DBIC quote_sub override expects the namespace-part of sub name '
 205   . "'$_[0]' to match the supplied package argument '$_[3]->{package}'"
 206   ) if (
 207     $_[3]
 208       and
 209     defined $_[3]->{package}
 210       and
 211     $stash ne $_[3]->{package}
 212   );
 213
 214   my @caller = caller(0);
 215   my $sq_opts = {
 216     package => $caller[0],
 217     hints => $caller[8],
 218     warning_bits => $caller[9],
 219     hintshash => $caller[10],
 220     %{ $_[3] || {} },
 221
 222     # explicitly forced for everything
 223     no_defer => 1,
 224   };
 225
 226   weaken (
 227     # just use a growing counter, no need to perform neither compaction
 228     # nor any special ithread-level handling
 229     $refs_closed_over_by_quote_sub_installed_crefs
 230      { scalar keys %refs_closed_over_by_quote_sub_installed_crefs }
 231       = $_
 232   ) for grep {
 233     length ref $_
 234       and
 235     (
 236       ! DBIx::Class::_ENV_::BROKEN_WEAK_SCALARREF_VALUES
 237         or
 238       ref $_ ne 'SCALAR'
 239     )
 240   } values %{ $_[2] || {} };
 241
 242   Sub::Quote::quote_sub( $_[0], $_[1], $_[2]||{}, $sq_opts );
 243 }
 244
 245 sub sigwarn_silencer ($) {
 246   my $pattern = shift;
 247
 248   croak "Expecting a regexp" if ref $pattern ne 'Regexp';
 249
 250   my $orig_sig_warn = $SIG{__WARN__} || sub { CORE::warn(@_) };
 251
 252   return sub { &$orig_sig_warn unless $_[0] =~ $pattern };
 253 }
 254
 255 sub perlstring ($) { q{"}. quotemeta( shift ). q{"} };
 256
 257 sub hrefaddr ($) { sprintf '0x%x', &refaddr||0 }
 258
 259 sub refdesc ($) {
 260   croak "Expecting a reference" if ! length ref $_[0];
 261
 262   # be careful not to trigger stringification,
 263   # reuse @_ as a scratch-pad
 264   sprintf '%s%s(0x%x)',
 265     ( defined( $_[1] = blessed $_[0]) ? "$_[1]=" : '' ),
 266     reftype $_[0],
 267     refaddr($_[0]),
 268   ;
 269 }
 270
 271 sub refcount ($) {
 272   croak "Expecting a reference" if ! length ref $_[0];
 273
 274   # No tempvars - must operate on $_[0], otherwise the pad
 275   # will count as an extra ref
 276   B::svref_2object($_[0])->REFCNT;
 277 }
 278
 279 sub visit_namespaces {
 280   my $args = { (ref $_[0]) ? %{$_[0]} : @_ };
 281
 282   my $visited_count = 1;
 283
 284   # A package and a namespace are subtly different things
 285   $args->{package} ||= 'main';
 286   $args->{package} = 'main' if $args->{package} =~ /^ :: (?: main )? $/x;
 287   $args->{package} =~ s/^:://;
 288
 289   if ( $args->{action}->($args->{package}) ) {
 290     my $ns =
 291       ( ($args->{package} eq 'main') ? '' :  $args->{package} )
 292         .
 293       '::'
 294     ;
 295
 296     $visited_count += visit_namespaces( %$args, package => $_ ) for
 297       grep
 298         # this happens sometimes on %:: traversal
 299         { $_ ne '::main' }
 300         map
 301           { $_ =~ /^(.+?)::$/ ? "$ns$1" : () }
 302           do { no strict 'refs'; keys %$ns }
 303     ;
 304   }
 305
 306   $visited_count;
 307 }
 308
 309 # FIXME In another life switch this to a polyfill like the one in namespace::clean
 310 sub set_subname ($$) {
 311
 312   # fully qualify name
 313   splice @_, 0, 1, caller(0) . "::$_[0]"
 314     if $_[0] !~ /::|'/;
 315
 316   &Sub::Name::subname;
 317 }
 318
 319 sub serialize ($) {
 320   local $Storable::canonical = 1;
 321   nfreeze($_[0]);
 322 }
 323
 324 sub uniq {
 325   my( %seen, $seen_undef, $numeric_preserving_copy );
 326   grep { not (
 327     defined $_
 328       ? $seen{ $numeric_preserving_copy = $_ }++
 329       : $seen_undef++
 330   ) } @_;
 331 }
 332
 333 my $dd_obj;
 334 sub dump_value ($) {
 335   local $Data::Dumper::Indent = 1
 336     unless defined $Data::Dumper::Indent;
 337
 338   my $dump_str = (
 339     $dd_obj
 340       ||=
 341     do {
 342       require Data::Dumper;
 343       my $d = Data::Dumper->new([])
 344         ->Purity(0)
 345         ->Pad('')
 346         ->Useqq(1)
 347         ->Terse(1)
 348         ->Freezer('')
 349         ->Quotekeys(0)
 350         ->Bless('bless')
 351         ->Pair(' => ')
 352         ->Sortkeys(1)
 353         ->Deparse(1)
 354       ;
 355
 356       $d->Sparseseen(1) if modver_gt_or_eq (
 357         'Data::Dumper', '2.136'
 358       );
 359
 360       $d;
 361     }
 362   )->Values([$_[0]])->Dump;
 363
 364   $dd_obj->Reset->Values([]);
 365
 366   $dump_str;
 367 }
 368
 369 sub scope_guard (&) {
 370   croak 'Calling scope_guard() in void context makes no sense'
 371     if ! defined wantarray;
 372
 373   # no direct blessing of coderefs - DESTROY is buggy on those
 374   bless [ $_[0] ], 'DBIx::Class::_Util::ScopeGuard';
 375 }
 376 {
 377   package #
 378     DBIx::Class::_Util::ScopeGuard;
 379
 380   sub DESTROY {
 381     &DBIx::Class::_Util::detected_reinvoked_destructor;
 382
 383     local $@ if DBIx::Class::_ENV_::UNSTABLE_DOLLARAT;
 384
 385     eval {
 386       $_[0]->[0]->();
 387       1;
 388     }
 389       or
 390     Carp::cluck(
 391       "Execution of scope guard $_[0] resulted in the non-trappable exception:\n\n$@"
 392     );
 393   }
 394 }
 395
 396
 397 sub is_exception ($) {
 398   my $e = $_[0];
 399
 400   # FIXME
 401   # this is not strictly correct - an eval setting $@ to undef
 402   # is *not* the same as an eval setting $@ to ''
 403   # but for the sake of simplicity assume the following for
 404   # the time being
 405   return 0 unless defined $e;
 406
 407   my ($not_blank, $suberror);
 408   {
 409     local $SIG{__DIE__} if $SIG{__DIE__};
 410     local $@;
 411     eval {
 412       # The ne() here is deliberate - a plain length($e), or worse "$e" ne
 413       # will entirely obviate the need for the encolsing eval{}, as the
 414       # condition we guard against is a missing fallback overload
 415       $not_blank = ( $e ne '' );
 416       1;
 417     } or $suberror = $@;
 418   }
 419
 420   if (defined $suberror) {
 421     if (length (my $class = blessed($e) )) {
 422       carp_unique( sprintf(
 423         'External exception class %s implements partial (broken) overloading '
 424       . 'preventing its instances from being used in simple ($x eq $y) '
 425       . 'comparisons. Given Perl\'s "globally cooperative" exception '
 426       . 'handling this type of brokenness is extremely dangerous on '
 427       . 'exception objects, as it may (and often does) result in silent '
 428       . '"exception substitution". DBIx::Class tries to work around this '
 429       . 'as much as possible, but other parts of your software stack may '
 430       . 'not be even aware of this. Please submit a bugreport against the '
 431       . 'distribution containing %s and in the meantime apply a fix similar '
 432       . 'to the one shown at %s, in order to ensure your exception handling '
 433       . 'is saner application-wide. What follows is the actual error text '
 434       . "as generated by Perl itself:\n\n%s\n ",
 435         $class,
 436         $class,
 437         'http://v.gd/DBIC_overload_tempfix/',
 438         $suberror,
 439       ));
 440
 441       # workaround, keeps spice flowing
 442       $not_blank = !!( length $e );
 443     }
 444     else {
 445       # not blessed yet failed the 'ne'... this makes 0 sense...
 446       # just throw further
 447       die $suberror
 448     }
 449   }
 450   elsif (
 451     # a ref evaluating to '' is definitively a "null object"
 452     ( not $not_blank )
 453       and
 454     length( my $class = ref $e )
 455   ) {
 456     carp_unique( sprintf(
 457       "Objects of external exception class '%s' stringify to '' (the "
 458     . 'empty string), implementing the so called null-object-pattern. '
 459     . 'Given Perl\'s "globally cooperative" exception handling using this '
 460     . 'class of exceptions is extremely dangerous, as it may (and often '
 461     . 'does) result in silent discarding of errors. DBIx::Class tries to '
 462     . 'work around this as much as possible, but other parts of your '
 463     . 'software stack may not be even aware of the problem. Please submit '
 464     . 'a bugreport against the distribution containing %s',
 465
 466       ($class) x 2,
 467     ));
 468
 469     $not_blank = 1;
 470   }
 471
 472   return $not_blank;
 473 }
 474
 475 {
 476   my $callstack_state;
 477
 478   # Recreate the logic of try(), while reusing the catch()/finally() as-is
 479   #
 480   # FIXME: We need to move away from Try::Tiny entirely (way too heavy and
 481   # yes, shows up ON TOP of profiles) but this is a batle for another maint
 482   sub dbic_internal_try (&;@) {
 483
 484     my $try_cref = shift;
 485     my $catch_cref = undef;  # apparently this is a thing... https://rt.perl.org/Public/Bug/Display.html?id=119311
 486
 487     for my $arg (@_) {
 488
 489       if( ref($arg) eq 'Try::Tiny::Catch' ) {
 490
 491         croak 'dbic_internal_try() may not be followed by multiple catch() blocks'
 492           if $catch_cref;
 493
 494         $catch_cref = $$arg;
 495       }
 496       elsif ( ref($arg) eq 'Try::Tiny::Finally' ) {
 497         croak 'dbic_internal_try() does not support finally{}';
 498       }
 499       else {
 500         croak(
 501           'dbic_internal_try() encountered an unexpected argument '
 502         . "'@{[ defined $arg ? $arg : 'UNDEF' ]}' - perhaps "
 503         . 'a missing semi-colon before or ' # trailing space important
 504         );
 505       }
 506     }
 507
 508     my $wantarray = wantarray;
 509     my $preexisting_exception = $@;
 510
 511     my @ret;
 512     my $all_good = eval {
 513       $@ = $preexisting_exception;
 514
 515       local $callstack_state->{in_internal_try} = 1
 516         unless $callstack_state->{in_internal_try};
 517
 518       # always unset - someone may have snuck it in
 519       local $SIG{__DIE__} if $SIG{__DIE__};
 520
 521       if( $wantarray ) {
 522         @ret = $try_cref->();
 523       }
 524       elsif( defined $wantarray ) {
 525         $ret[0] = $try_cref->();
 526       }
 527       else {
 528         $try_cref->();
 529       }
 530
 531       1;
 532     };
 533
 534     my $exception = $@;
 535     $@ = $preexisting_exception;
 536
 537     if ( $all_good ) {
 538       return $wantarray ? @ret : $ret[0]
 539     }
 540     elsif ( $catch_cref ) {
 541       for ( $exception ) {
 542         return $catch_cref->($exception);
 543       }
 544     }
 545
 546     return;
 547   }
 548
 549   sub in_internal_try { !! $callstack_state->{in_internal_try} }
 550 }
 551
 552 {
 553   my $destruction_registry = {};
 554
 555   sub DBIx::Class::__Util_iThreads_handler__::CLONE {
 556     %$destruction_registry = map {
 557       (defined $_)
 558         ? ( refaddr($_) => $_ )
 559         : ()
 560     } values %$destruction_registry;
 561
 562     weaken($_) for values %$destruction_registry;
 563
 564     # Dummy NEXTSTATE ensuring the all temporaries on the stack are garbage
 565     # collected before leaving this scope. Depending on the code above, this
 566     # may very well be just a preventive measure guarding future modifications
 567     undef;
 568   }
 569
 570   # This is almost invariably invoked from within DESTROY
 571   # throwing exceptions won't work
 572   sub detected_reinvoked_destructor {
 573
 574     # quick "garbage collection" pass - prevents the registry
 575     # from slowly growing with a bunch of undef-valued keys
 576     defined $destruction_registry->{$_} or delete $destruction_registry->{$_}
 577       for keys %$destruction_registry;
 578
 579     if (! length ref $_[0]) {
 580       printf STDERR '%s() expects a blessed reference %s',
 581         (caller(0))[3],
 582         Carp::longmess,
 583       ;
 584       return undef; # don't know wtf to do
 585     }
 586     elsif (! defined $destruction_registry->{ my $addr = refaddr($_[0]) } ) {
 587       weaken( $destruction_registry->{$addr} = $_[0] );
 588       return 0;
 589     }
 590     else {
 591       carp_unique ( sprintf (
 592         'Preventing *MULTIPLE* DESTROY() invocations on %s - an *EXTREMELY '
 593       . 'DANGEROUS* condition which is *ALMOST CERTAINLY GLOBAL* within your '
 594       . 'application, affecting *ALL* classes without active protection against '
 595       . 'this. Diagnose and fix the root cause ASAP!!!%s',
 596       refdesc $_[0],
 597         ( ( $INC{'Devel/StackTrace.pm'} and ! do { local $@; eval { Devel::StackTrace->VERSION(2) } } )
 598           ? " (likely culprit Devel::StackTrace\@@{[ Devel::StackTrace->VERSION ]} found in %INC, http://is.gd/D_ST_refcap)"
 599           : ''
 600         )
 601       ));
 602
 603       return 1;
 604     }
 605   }
 606 }
 607
 608 my $module_name_rx = qr/ \A [A-Z_a-z] [0-9A-Z_a-z]* (?: :: [0-9A-Z_a-z]+ )* \z /x;
 609 my $ver_rx =         qr/ \A [0-9]+ (?: \. [0-9]+ )* (?: \_ [0-9]+ )*        \z /x;
 610
 611 sub modver_gt_or_eq ($$) {
 612   my ($mod, $ver) = @_;
 613
 614   croak "Nonsensical module name supplied"
 615     if ! defined $mod or $mod !~ $module_name_rx;
 616
 617   croak "Nonsensical minimum version supplied"
 618     if ! defined $ver or $ver !~ $ver_rx;
 619
 620   no strict 'refs';
 621   my $ver_cache = ${"${mod}::__DBIC_MODULE_VERSION_CHECKS__"} ||= ( $mod->VERSION
 622     ? {}
 623     : croak "$mod does not seem to provide a version (perhaps it never loaded)"
 624   );
 625
 626   ! defined $ver_cache->{$ver}
 627     and
 628   $ver_cache->{$ver} = do {
 629
 630     local $SIG{__WARN__} = sigwarn_silencer( qr/\Qisn't numeric in subroutine entry/ )
 631       if SPURIOUS_VERSION_CHECK_WARNINGS;
 632
 633     local $SIG{__DIE__} if $SIG{__DIE__};
 634     local $@;
 635     eval { $mod->VERSION($ver) } ? 1 : 0;
 636   };
 637
 638   $ver_cache->{$ver};
 639 }
 640
 641 sub modver_gt_or_eq_and_lt ($$$) {
 642   my ($mod, $v_ge, $v_lt) = @_;
 643
 644   croak "Nonsensical maximum version supplied"
 645     if ! defined $v_lt or $v_lt !~ $ver_rx;
 646
 647   return (
 648     modver_gt_or_eq($mod, $v_ge)
 649       and
 650     ! modver_gt_or_eq($mod, $v_lt)
 651   ) ? 1 : 0;
 652 }
 653
 654 {
 655   # FIXME - should be a private my(), but I'm too uncertain whether
 656   # all bases are covered
 657   our $describe_class_query_cache;
 658
 659   sub describe_class_methods {
 660     my ($class, $requested_mro) = @_;
 661
 662     croak "Expecting a class name"
 663       if not defined $class or $class !~ $module_name_rx;
 664
 665     $requested_mro ||= mro::get_mro($class);
 666
 667     # mro::set_mro() does not bump pkg_gen - WHAT THE FUCK?!
 668     my $query_cache_key = "$class|$requested_mro";
 669
 670     my $stack_cache_key =
 671       ( mro::get_mro($class) eq $requested_mro )
 672         ? $class
 673         : $query_cache_key
 674     ;
 675
 676     # use a cache on old MRO, since while we are recursing in this function
 677     # nothing can possibly change (the speedup is immense)
 678     # (yes, people could be tie()ing the stash and adding methods on access
 679     # but there is a limit to how much crazy can be supported here)
 680     #
 681     # we use the cache for linear_isa lookups on new MRO as well - it adds
 682     # a *tiny* speedup, and simplifies the code a lot
 683     #
 684     local $mro_recursor_stack->{cache} = {}
 685       unless $mro_recursor_stack->{cache};
 686
 687     my $my_gen = 0;
 688
 689     $my_gen += get_real_pkg_gen($_) for ( my @full_ISA = (
 690
 691       @{
 692         $mro_recursor_stack->{cache}{$stack_cache_key}{linear_isa}
 693           ||=
 694         mro::get_linear_isa($class, $requested_mro)
 695       },
 696
 697       ((
 698         $mro_recursor_stack->{cache}{$class}{is_universal}
 699           ||=
 700         mro::is_universal($class)
 701       ) ? () : @{
 702         $mro_recursor_stack->{cache}{UNIVERSAL}{linear_isa}
 703           ||=
 704         mro::get_linear_isa("UNIVERSAL")
 705       }),
 706
 707     ));
 708
 709     my $slot = $describe_class_query_cache->{$query_cache_key} ||= {};
 710
 711     unless ( ($slot->{cumulative_gen}||0) == $my_gen ) {
 712
 713       # remove ourselves from ISA
 714       shift @full_ISA;
 715
 716       # reset
 717       %$slot = (
 718         class => $class,
 719         isa => [
 720           @{ $mro_recursor_stack->{cache}{$stack_cache_key}{linear_isa} }
 721             [ 1 .. $#{$mro_recursor_stack->{cache}{$stack_cache_key}{linear_isa}} ]
 722         ],
 723         mro => {
 724           type => $requested_mro,
 725           is_c3 => ( ($requested_mro eq 'c3') ? 1 : 0 ),
 726         },
 727         cumulative_gen => $my_gen,
 728       );
 729
 730       # ensure the cache is populated for the parents, code below can then
 731       # efficiently operate over the query_cache directly
 732       describe_class_methods($_) for reverse @full_ISA;
 733
 734       no strict 'refs';
 735
 736       # combine full ISA-order inherited and local method list into a
 737       # "shadowing stack"
 738
 739       (
 740         unshift @{ $slot->{methods}{$_->{name}} }, $_
 741
 742           and
 743
 744         (
 745           $_->{via_class} ne $class
 746             or
 747           $slot->{methods_defined_in_class}{$_->{name}} = $_
 748         )
 749
 750           and
 751
 752         @{ $slot->{methods}{$_->{name}} } > 1
 753
 754           and
 755
 756         $slot->{methods_with_supers}{$_->{name}} = $slot->{methods}{$_->{name}}
 757
 758       ) for (
 759
 760         # what describe_class_methods for @full_ISA produced above
 761         ( map { values %{
 762           $describe_class_query_cache->{$_}{methods_defined_in_class} || {}
 763         } } map { "$_|" . mro::get_mro($_) } reverse @full_ISA ),
 764
 765         # our own non-cleaned subs + their attributes
 766         ( map {
 767           (
 768             # need to account for dummy helper crefs under OLD_MRO
 769             (
 770               ! DBIx::Class::_ENV_::OLD_MRO
 771                 or
 772               ! ( ( $Class::C3::MRO{$class} || {} )->{methods}{$_} )
 773             )
 774               and
 775             # these 2 OR-ed checks are sufficient for 5.10+
 776             (
 777               ref(\ "${class}::"->{$_} ) ne 'GLOB'
 778                 or
 779               defined( *{ "${class}::"->{$_} }{CODE} )
 780             )
 781           ) ? {
 782               via_class => $class,
 783               name => $_,
 784               attributes => {
 785                 map { $_ => 1 } attributes::get( \&{"${class}::${_}"} )
 786               },
 787             }
 788             : ()
 789         } keys %{"${class}::"} )
 790       );
 791
 792
 793       # recalculate the pkg_gen on newer perls under Taint mode,
 794       # because of shit like:
 795       # perl -T -Mmro -e 'package Foo; sub bar {}; defined( *{ "Foo::"->{bar}}{CODE} ) and warn mro::get_pkg_gen("Foo") for (1,2,3)'
 796       #
 797       if (
 798         ! DBIx::Class::_ENV_::OLD_MRO
 799           and
 800         ${^TAINT}
 801       ) {
 802
 803         $slot->{cumulative_gen} = 0;
 804         $slot->{cumulative_gen} += get_real_pkg_gen($_)
 805           for $class, @full_ISA;
 806       }
 807     }
 808
 809     # RV
 810     +{ %$slot };
 811   }
 812 }
 813
 814
 815 #
 816 # Why not just use some higher-level module or at least File::Spec here?
 817 # Because:
 818 # 1)  This is a *very* rarely used function, and the deptree is large
 819 #     enough already as it is
 820 #
 821 # 2)  (more importantly) Our tooling is utter shit in this area. There
 822 #     is no comprehensive support for UNC paths in PathTools and there
 823 #     are also various small bugs in representation across different
 824 #     path-manipulation CPAN offerings.
 825 #
 826 # Since this routine is strictly used for logical path processing (it
 827 # *must* be able to work with not-yet-existing paths), use this seemingly
 828 # simple but I *think* complete implementation to feed to other consumers
 829 #
 830 # If bugs are ever uncovered in this routine, *YOU ARE URGED TO RESIST*
 831 # the impulse to bring in an external dependency. During runtime there
 832 # is exactly one spot that could potentially maybe once in a blue moon
 833 # use this function. Keep it lean.
 834 #
 835 sub parent_dir ($) {
 836   ( $_[0] =~ m{  [\/\\]  ( \.{0,2} ) ( [\/\\]* ) \z }x )
 837     ? (
 838       $_[0]
 839         .
 840       ( ( length($1) and ! length($2) ) ? '/' : '' )
 841         .
 842       '../'
 843     )
 844     : (
 845       require File::Spec
 846         and
 847       File::Spec->catpath (
 848         ( File::Spec->splitpath( "$_[0]" ) )[0,1],
 849         '/',
 850       )
 851     )
 852   ;
 853 }
 854
 855 sub mkdir_p ($) {
 856   require File::Path;
 857   # do not ask for a recent version, use 1.x API calls
 858   File::Path::mkpath([ "$_[0]" ]);  # File::Path does not like objects
 859 }
 860
 861
 862 {
 863   my $list_ctx_ok_stack_marker;
 864
 865   sub fail_on_internal_wantarray () {
 866     return if $list_ctx_ok_stack_marker;
 867
 868     if (! defined wantarray) {
 869       croak('fail_on_internal_wantarray() needs a tempvar to save the stack marker guard');
 870     }
 871
 872     my $cf = 1;
 873     while ( ( (CORE::caller($cf+1))[3] || '' ) =~ / :: (?:
 874
 875       # these are public API parts that alter behavior on wantarray
 876       search | search_related | slice | search_literal
 877
 878         |
 879
 880       # these are explicitly prefixed, since we only recognize them as valid
 881       # escapes when they come from the guts of CDBICompat
 882       CDBICompat .*? :: (?: search_where | retrieve_from_sql | retrieve_all )
 883
 884     ) $/x ) {
 885       $cf++;
 886     }
 887
 888     my ($fr, $want, $argdesc);
 889     {
 890       package DB;
 891       $fr = [ CORE::caller($cf) ];
 892       $want = ( CORE::caller($cf-1) )[5];
 893       $argdesc = ref $DB::args[0]
 894         ? DBIx::Class::_Util::refdesc($DB::args[0])
 895         : 'non '
 896       ;
 897     };
 898
 899     if (
 900       $want and $fr->[0] =~ /^(?:DBIx::Class|DBICx::)/
 901     ) {
 902       DBIx::Class::Exception->throw( sprintf (
 903         "Improper use of %s instance in list context at %s line %d\n\n    Stacktrace starts",
 904         $argdesc, @{$fr}[1,2]
 905       ), 'with_stacktrace');
 906     }
 907
 908     weaken( $list_ctx_ok_stack_marker = my $mark = [] );
 909
 910     $mark;
 911   }
 912 }
 913
 914 sub fail_on_internal_call {
 915   my ($fr, $argdesc);
 916   {
 917     package DB;
 918     $fr = [ CORE::caller(1) ];
 919     $argdesc = ref $DB::args[0]
 920       ? DBIx::Class::_Util::refdesc($DB::args[0])
 921       : ( $DB::args[0] . '' )
 922     ;
 923   };
 924
 925   my @fr2;
 926   # need to make allowance for a proxy-yet-direct call
 927   my $check_fr = (
 928     $fr->[0] eq 'DBIx::Class::ResultSourceProxy'
 929       and
 930     @fr2 = (CORE::caller(2))
 931       and
 932     (
 933       ( $fr->[3] =~ /([^:])+$/ )[0]
 934         eq
 935       ( $fr2[3] =~ /([^:])+$/ )[0]
 936     )
 937   )
 938     ? \@fr2
 939     : $fr
 940   ;
 941
 942   if (
 943     $argdesc
 944       and
 945     $check_fr->[0] =~ /^(?:DBIx::Class|DBICx::)/
 946       and
 947     $check_fr->[1] !~ /\b(?:CDBICompat|ResultSetProxy)\b/  # no point touching there
 948   ) {
 949     DBIx::Class::Exception->throw( sprintf (
 950       "Illegal internal call of indirect proxy-method %s() with argument '%s': examine the last lines of the proxy method deparse below to determine what to call directly instead at %s on line %d\n\n%s\n\n    Stacktrace starts",
 951       $fr->[3], $argdesc, @{$fr}[1,2], ( $fr->[6] || do {
 952         require B::Deparse;
 953         no strict 'refs';
 954         B::Deparse->new->coderef2text(\&{$fr->[3]})
 955       }),
 956     ), 'with_stacktrace');
 957   }
 958 }
 959
 960 1;