lib/DBIx/Class/_Util.pm

   1 package # hide from PAUSE
   2   DBIx::Class::_Util;
   3
   4 use warnings;
   5 use strict;
   6
   7 # Temporary - tempextlib
   8 use namespace::clean;
   9 BEGIN {
  10   require Module::Runtime;
  11   require File::Spec;
  12
  13   # There can be only one of these, make sure we get the bundled part and
  14   # *not* something off the site lib
  15   for (qw(
  16     DBIx::Class::SQLMaker
  17     SQL::Abstract
  18     SQL::Abstract::Test
  19   )) {
  20     if ($INC{Module::Runtime::module_notional_filename($_)}) {
  21       die "\nUnable to continue - a part of the bundled templib contents "
  22         . "was already loaded (likely an older version from CPAN). "
  23         . "Make sure that @{[ __PACKAGE__ ]} is loaded before $_\n\n"
  24       ;
  25     }
  26   }
  27
  28   our ($HERE) = File::Spec->rel2abs(
  29     File::Spec->catdir( (File::Spec->splitpath(__FILE__))[1], '_TempExtlib' )
  30   ) =~ /^(.*)$/; # screw you, taint mode
  31
  32   die "TempExtlib $HERE does not seem to exist - perhaps you need to run `perl Makefile.PL` in the DBIC checkout?\n"
  33     unless -d $HERE;
  34
  35   unshift @INC, $HERE;
  36 }
  37
  38 use constant SPURIOUS_VERSION_CHECK_WARNINGS => ($] < 5.010 ? 1 : 0);
  39
  40 BEGIN {
  41   package # hide from pause
  42     DBIx::Class::_ENV_;
  43
  44   use Config;
  45
  46   use constant {
  47
  48     # but of course
  49     BROKEN_FORK => ($^O eq 'MSWin32') ? 1 : 0,
  50
  51     BROKEN_GOTO => ($] < '5.008003') ? 1 : 0,
  52
  53     HAS_ITHREADS => $Config{useithreads} ? 1 : 0,
  54
  55     # ::Runmode would only be loaded by DBICTest, which in turn implies t/
  56     DBICTEST => eval { DBICTest::RunMode->is_author } ? 1 : 0,
  57
  58     # During 5.13 dev cycle HELEMs started to leak on copy
  59     # add an escape for these perls ON SMOKERS - a user will still get death
  60     PEEPEENESS => ( eval { DBICTest::RunMode->is_smoker } && ($] >= 5.013005 and $] <= 5.013006) ),
  61
  62     SHUFFLE_UNORDERED_RESULTSETS => $ENV{DBIC_SHUFFLE_UNORDERED_RESULTSETS} ? 1 : 0,
  63
  64     ASSERT_NO_INTERNAL_WANTARRAY => $ENV{DBIC_ASSERT_NO_INTERNAL_WANTARRAY} ? 1 : 0,
  65
  66     ASSERT_NO_INTERNAL_INDIRECT_CALLS => $ENV{DBIC_ASSERT_NO_INTERNAL_INDIRECT_CALLS} ? 1 : 0,
  67
  68     IV_SIZE => $Config{ivsize},
  69
  70     OS_NAME => $^O,
  71   };
  72
  73   if ($] < 5.009_005) {
  74     require MRO::Compat;
  75     constant->import( OLD_MRO => 1 );
  76   }
  77   else {
  78     require mro;
  79     constant->import( OLD_MRO => 0 );
  80   }
  81 }
  82
  83 # FIXME - this is not supposed to be here
  84 # Carp::Skip to the rescue soon
  85 use DBIx::Class::Carp '^DBIx::Class|^DBICTest';
  86
  87 use Carp 'croak';
  88 use Scalar::Util qw(weaken blessed reftype);
  89 use List::Util qw(first);
  90
  91 # DO NOT edit away without talking to riba first, he will just put it back
  92 # BEGIN pre-Moo2 import block
  93 BEGIN {
  94   my $initial_fatal_bits = (${^WARNING_BITS}||'') & $warnings::DeadBits{all};
  95
  96   local $ENV{PERL_STRICTURES_EXTRA} = 0;
  97   # load all of these now, so that lazy-loading does not escape
  98   # the current PERL_STRICTURES_EXTRA setting
  99   require Sub::Quote;
 100   require Sub::Defer;
 101
 102   Sub::Quote->import('quote_sub');
 103   ${^WARNING_BITS} &= ( $initial_fatal_bits | ~ $warnings::DeadBits{all} );
 104 }
 105 sub qsub ($) { goto &quote_sub }  # no point depping on new Moo just for this
 106 # END pre-Moo2 import block
 107
 108 use base 'Exporter';
 109 our @EXPORT_OK = qw(
 110   sigwarn_silencer modver_gt_or_eq
 111   fail_on_internal_wantarray fail_on_internal_call
 112   refdesc refcount hrefaddr is_exception
 113   quote_sub qsub perlstring serialize
 114   UNRESOLVABLE_CONDITION
 115 );
 116
 117 use constant UNRESOLVABLE_CONDITION => \ '1 = 0';
 118
 119 sub sigwarn_silencer ($) {
 120   my $pattern = shift;
 121
 122   croak "Expecting a regexp" if ref $pattern ne 'Regexp';
 123
 124   my $orig_sig_warn = $SIG{__WARN__} || sub { CORE::warn(@_) };
 125
 126   return sub { &$orig_sig_warn unless $_[0] =~ $pattern };
 127 }
 128
 129 sub perlstring ($) { q{"}. quotemeta( shift ). q{"} };
 130
 131 sub hrefaddr ($) { sprintf '0x%x', &Scalar::Util::refaddr||0 }
 132
 133 sub refdesc ($) {
 134   croak "Expecting a reference" if ! length ref $_[0];
 135
 136   # be careful not to trigger stringification,
 137   # reuse @_ as a scratch-pad
 138   sprintf '%s%s(0x%x)',
 139     ( defined( $_[1] = blessed $_[0]) ? "$_[1]=" : '' ),
 140     reftype $_[0],
 141     Scalar::Util::refaddr($_[0]),
 142   ;
 143 }
 144
 145 sub refcount ($) {
 146   croak "Expecting a reference" if ! length ref $_[0];
 147
 148   require B;
 149   # No tempvars - must operate on $_[0], otherwise the pad
 150   # will count as an extra ref
 151   B::svref_2object($_[0])->REFCNT;
 152 }
 153
 154 sub serialize ($) {
 155   require Storable;
 156   local $Storable::canonical = 1;
 157   Storable::nfreeze($_[0]);
 158 }
 159
 160 sub is_exception ($) {
 161   my $e = $_[0];
 162
 163   # this is not strictly correct - an eval setting $@ to undef
 164   # is *not* the same as an eval setting $@ to ''
 165   # but for the sake of simplicity assume the following for
 166   # the time being
 167   return 0 unless defined $e;
 168
 169   my ($not_blank, $suberror);
 170   {
 171     local $@;
 172     eval {
 173       $not_blank = ($e ne '') ? 1 : 0;
 174       1;
 175     } or $suberror = $@;
 176   }
 177
 178   if (defined $suberror) {
 179     if (length (my $class = blessed($e) )) {
 180       carp_unique( sprintf(
 181         'External exception class %s implements partial (broken) overloading '
 182       . 'preventing its instances from being used in simple ($x eq $y) '
 183       . 'comparisons. Given Perl\'s "globally cooperative" exception '
 184       . 'handling this type of brokenness is extremely dangerous on '
 185       . 'exception objects, as it may (and often does) result in silent '
 186       . '"exception substitution". DBIx::Class tries to work around this '
 187       . 'as much as possible, but other parts of your software stack may '
 188       . 'not be even aware of this. Please submit a bugreport against the '
 189       . 'distribution containing %s and in the meantime apply a fix similar '
 190       . 'to the one shown at %s, in order to ensure your exception handling '
 191       . 'is saner application-wide. What follows is the actual error text '
 192       . "as generated by Perl itself:\n\n%s\n ",
 193         $class,
 194         $class,
 195         'http://v.gd/DBIC_overload_tempfix/',
 196         $suberror,
 197       ));
 198
 199       # workaround, keeps spice flowing
 200       $not_blank = ("$e" ne '') ? 1 : 0;
 201     }
 202     else {
 203       # not blessed yet failed the 'ne'... this makes 0 sense...
 204       # just throw further
 205       die $suberror
 206     }
 207   }
 208
 209   return $not_blank;
 210 }
 211
 212 sub modver_gt_or_eq ($$) {
 213   my ($mod, $ver) = @_;
 214
 215   croak "Nonsensical module name supplied"
 216     if ! defined $mod or ! length $mod;
 217
 218   croak "Nonsensical minimum version supplied"
 219     if ! defined $ver or $ver =~ /[^0-9\.\_]/;
 220
 221   local $SIG{__WARN__} = sigwarn_silencer( qr/\Qisn't numeric in subroutine entry/ )
 222     if SPURIOUS_VERSION_CHECK_WARNINGS;
 223
 224   croak "$mod does not seem to provide a version (perhaps it never loaded)"
 225     unless $mod->VERSION;
 226
 227   local $@;
 228   eval { $mod->VERSION($ver) } ? 1 : 0;
 229 }
 230
 231 {
 232   my $list_ctx_ok_stack_marker;
 233
 234   sub fail_on_internal_wantarray () {
 235     return if $list_ctx_ok_stack_marker;
 236
 237     if (! defined wantarray) {
 238       croak('fail_on_internal_wantarray() needs a tempvar to save the stack marker guard');
 239     }
 240
 241     my $cf = 1;
 242     while ( ( (caller($cf+1))[3] || '' ) =~ / :: (?:
 243
 244       # these are public API parts that alter behavior on wantarray
 245       search | search_related | slice | search_literal
 246
 247         |
 248
 249       # these are explicitly prefixed, since we only recognize them as valid
 250       # escapes when they come from the guts of CDBICompat
 251       CDBICompat .*? :: (?: search_where | retrieve_from_sql | retrieve_all )
 252
 253     ) $/x ) {
 254       $cf++;
 255     }
 256
 257     my ($fr, $want, $argdesc);
 258     {
 259       package DB;
 260       $fr = [ caller($cf) ];
 261       $want = ( caller($cf-1) )[5];
 262       $argdesc = ref $DB::args[0]
 263         ? DBIx::Class::_Util::refdesc($DB::args[0])
 264         : 'non '
 265       ;
 266     };
 267
 268     if (
 269       $want and $fr->[0] =~ /^(?:DBIx::Class|DBICx::)/
 270     ) {
 271       DBIx::Class::Exception->throw( sprintf (
 272         "Improper use of %s instance in list context at %s line %d\n\n    Stacktrace starts",
 273         $argdesc, @{$fr}[1,2]
 274       ), 'with_stacktrace');
 275     }
 276
 277     my $mark = [];
 278     weaken ( $list_ctx_ok_stack_marker = $mark );
 279     $mark;
 280   }
 281 }
 282
 283 sub fail_on_internal_call {
 284   my ($fr, $argdesc);
 285   {
 286     package DB;
 287     $fr = [ caller(1) ];
 288     $argdesc = ref $DB::args[0]
 289       ? DBIx::Class::_Util::refdesc($DB::args[0])
 290       : undef
 291     ;
 292   };
 293
 294   if (
 295     $argdesc
 296       and
 297     $fr->[0] =~ /^(?:DBIx::Class|DBICx::)/
 298       and
 299     $fr->[1] !~ /\b(?:CDBICompat|ResultSetProxy)\b/  # no point touching there
 300   ) {
 301     DBIx::Class::Exception->throw( sprintf (
 302       "Illegal internal call of indirect proxy-method %s() with argument %s: examine the last lines of the proxy method deparse below to determine what to call directly instead at %s on line %d\n\n%s\n\n    Stacktrace starts",
 303       $fr->[3], $argdesc, @{$fr}[1,2], ( $fr->[6] || do {
 304         require B::Deparse;
 305         no strict 'refs';
 306         B::Deparse->new->coderef2text(\&{$fr->[3]})
 307       }),
 308     ), 'with_stacktrace');
 309   }
 310 }
 311
 312 1;