lib/DBIx/Class/_Util.pm

   1 package # hide from PAUSE
   2   DBIx::Class::_Util;
   3
   4 use warnings;
   5 use strict;
   6
   7 use constant SPURIOUS_VERSION_CHECK_WARNINGS => ($] < 5.010 ? 1 : 0);
   8
   9 BEGIN {
  10   package # hide from pause
  11     DBIx::Class::_ENV_;
  12
  13   use Config;
  14
  15   use constant {
  16
  17     # but of course
  18     BROKEN_FORK => ($^O eq 'MSWin32') ? 1 : 0,
  19
  20     BROKEN_GOTO => ($] < '5.008003') ? 1 : 0,
  21
  22     HAS_ITHREADS => $Config{useithreads} ? 1 : 0,
  23
  24     # ::Runmode would only be loaded by DBICTest, which in turn implies t/
  25     DBICTEST => eval { DBICTest::RunMode->is_author } ? 1 : 0,
  26
  27     # During 5.13 dev cycle HELEMs started to leak on copy
  28     # add an escape for these perls ON SMOKERS - a user will still get death
  29     PEEPEENESS => ( eval { DBICTest::RunMode->is_smoker } && ($] >= 5.013005 and $] <= 5.013006) ),
  30
  31     SHUFFLE_UNORDERED_RESULTSETS => $ENV{DBIC_SHUFFLE_UNORDERED_RESULTSETS} ? 1 : 0,
  32
  33     ASSERT_NO_INTERNAL_WANTARRAY => $ENV{DBIC_ASSERT_NO_INTERNAL_WANTARRAY} ? 1 : 0,
  34
  35     ASSERT_NO_INTERNAL_INDIRECT_CALLS => $ENV{DBIC_ASSERT_NO_INTERNAL_INDIRECT_CALLS} ? 1 : 0,
  36
  37     STRESSTEST_UTF8_UPGRADE_GENERATED_COLLAPSER_SOURCE => $ENV{DBIC_STRESSTEST_UTF8_UPGRADE_GENERATED_COLLAPSER_SOURCE} ? 1 : 0,
  38
  39     IV_SIZE => $Config{ivsize},
  40
  41     OS_NAME => $^O,
  42   };
  43
  44   if ($] < 5.009_005) {
  45     require MRO::Compat;
  46     constant->import( OLD_MRO => 1 );
  47   }
  48   else {
  49     require mro;
  50     constant->import( OLD_MRO => 0 );
  51   }
  52 }
  53
  54 # FIXME - this is not supposed to be here
  55 # Carp::Skip to the rescue soon
  56 use DBIx::Class::Carp '^DBIx::Class|^DBICTest';
  57
  58 use B ();
  59 use Carp 'croak';
  60 use Storable 'nfreeze';
  61 use Scalar::Util qw(weaken blessed reftype);
  62 use List::Util qw(first);
  63 use Sub::Quote qw(qsub quote_sub);
  64
  65 use base 'Exporter';
  66 our @EXPORT_OK = qw(
  67   sigwarn_silencer modver_gt_or_eq modver_gt_or_eq_and_lt
  68   fail_on_internal_wantarray fail_on_internal_call
  69   refdesc refcount hrefaddr is_exception
  70   quote_sub qsub perlstring serialize
  71   UNRESOLVABLE_CONDITION
  72 );
  73
  74 use constant UNRESOLVABLE_CONDITION => \ '1 = 0';
  75
  76 sub sigwarn_silencer ($) {
  77   my $pattern = shift;
  78
  79   croak "Expecting a regexp" if ref $pattern ne 'Regexp';
  80
  81   my $orig_sig_warn = $SIG{__WARN__} || sub { CORE::warn(@_) };
  82
  83   return sub { &$orig_sig_warn unless $_[0] =~ $pattern };
  84 }
  85
  86 sub perlstring ($) { q{"}. quotemeta( shift ). q{"} };
  87
  88 sub hrefaddr ($) { sprintf '0x%x', &Scalar::Util::refaddr||0 }
  89
  90 sub refdesc ($) {
  91   croak "Expecting a reference" if ! length ref $_[0];
  92
  93   # be careful not to trigger stringification,
  94   # reuse @_ as a scratch-pad
  95   sprintf '%s%s(0x%x)',
  96     ( defined( $_[1] = blessed $_[0]) ? "$_[1]=" : '' ),
  97     reftype $_[0],
  98     Scalar::Util::refaddr($_[0]),
  99   ;
 100 }
 101
 102 sub refcount ($) {
 103   croak "Expecting a reference" if ! length ref $_[0];
 104
 105   # No tempvars - must operate on $_[0], otherwise the pad
 106   # will count as an extra ref
 107   B::svref_2object($_[0])->REFCNT;
 108 }
 109
 110 sub serialize ($) {
 111   local $Storable::canonical = 1;
 112   nfreeze($_[0]);
 113 }
 114
 115 sub is_exception ($) {
 116   my $e = $_[0];
 117
 118   # this is not strictly correct - an eval setting $@ to undef
 119   # is *not* the same as an eval setting $@ to ''
 120   # but for the sake of simplicity assume the following for
 121   # the time being
 122   return 0 unless defined $e;
 123
 124   my ($not_blank, $suberror);
 125   {
 126     local $@;
 127     eval {
 128       $not_blank = ($e ne '') ? 1 : 0;
 129       1;
 130     } or $suberror = $@;
 131   }
 132
 133   if (defined $suberror) {
 134     if (length (my $class = blessed($e) )) {
 135       carp_unique( sprintf(
 136         'External exception class %s implements partial (broken) overloading '
 137       . 'preventing its instances from being used in simple ($x eq $y) '
 138       . 'comparisons. Given Perl\'s "globally cooperative" exception '
 139       . 'handling this type of brokenness is extremely dangerous on '
 140       . 'exception objects, as it may (and often does) result in silent '
 141       . '"exception substitution". DBIx::Class tries to work around this '
 142       . 'as much as possible, but other parts of your software stack may '
 143       . 'not be even aware of this. Please submit a bugreport against the '
 144       . 'distribution containing %s and in the meantime apply a fix similar '
 145       . 'to the one shown at %s, in order to ensure your exception handling '
 146       . 'is saner application-wide. What follows is the actual error text '
 147       . "as generated by Perl itself:\n\n%s\n ",
 148         $class,
 149         $class,
 150         'http://v.gd/DBIC_overload_tempfix/',
 151         $suberror,
 152       ));
 153
 154       # workaround, keeps spice flowing
 155       $not_blank = ("$e" ne '') ? 1 : 0;
 156     }
 157     else {
 158       # not blessed yet failed the 'ne'... this makes 0 sense...
 159       # just throw further
 160       die $suberror
 161     }
 162   }
 163
 164   return $not_blank;
 165 }
 166
 167 sub modver_gt_or_eq ($$) {
 168   my ($mod, $ver) = @_;
 169
 170   croak "Nonsensical module name supplied"
 171     if ! defined $mod or ! length $mod;
 172
 173   croak "Nonsensical minimum version supplied"
 174     if ! defined $ver or $ver =~ /[^0-9\.\_]/;
 175
 176   local $SIG{__WARN__} = sigwarn_silencer( qr/\Qisn't numeric in subroutine entry/ )
 177     if SPURIOUS_VERSION_CHECK_WARNINGS;
 178
 179   croak "$mod does not seem to provide a version (perhaps it never loaded)"
 180     unless $mod->VERSION;
 181
 182   local $@;
 183   eval { $mod->VERSION($ver) } ? 1 : 0;
 184 }
 185
 186 sub modver_gt_or_eq_and_lt ($$$) {
 187   my ($mod, $v_ge, $v_lt) = @_;
 188
 189   croak "Nonsensical maximum version supplied"
 190     if ! defined $v_lt or $v_lt =~ /[^0-9\.\_]/;
 191
 192   return (
 193     modver_gt_or_eq($mod, $v_ge)
 194       and
 195     ! modver_gt_or_eq($mod, $v_lt)
 196   ) ? 1 : 0;
 197 }
 198
 199 {
 200   my $list_ctx_ok_stack_marker;
 201
 202   sub fail_on_internal_wantarray () {
 203     return if $list_ctx_ok_stack_marker;
 204
 205     if (! defined wantarray) {
 206       croak('fail_on_internal_wantarray() needs a tempvar to save the stack marker guard');
 207     }
 208
 209     my $cf = 1;
 210     while ( ( (caller($cf+1))[3] || '' ) =~ / :: (?:
 211
 212       # these are public API parts that alter behavior on wantarray
 213       search | search_related | slice | search_literal
 214
 215         |
 216
 217       # these are explicitly prefixed, since we only recognize them as valid
 218       # escapes when they come from the guts of CDBICompat
 219       CDBICompat .*? :: (?: search_where | retrieve_from_sql | retrieve_all )
 220
 221     ) $/x ) {
 222       $cf++;
 223     }
 224
 225     my ($fr, $want, $argdesc);
 226     {
 227       package DB;
 228       $fr = [ caller($cf) ];
 229       $want = ( caller($cf-1) )[5];
 230       $argdesc = ref $DB::args[0]
 231         ? DBIx::Class::_Util::refdesc($DB::args[0])
 232         : 'non '
 233       ;
 234     };
 235
 236     if (
 237       $want and $fr->[0] =~ /^(?:DBIx::Class|DBICx::)/
 238     ) {
 239       DBIx::Class::Exception->throw( sprintf (
 240         "Improper use of %s instance in list context at %s line %d\n\n    Stacktrace starts",
 241         $argdesc, @{$fr}[1,2]
 242       ), 'with_stacktrace');
 243     }
 244
 245     my $mark = [];
 246     weaken ( $list_ctx_ok_stack_marker = $mark );
 247     $mark;
 248   }
 249 }
 250
 251 sub fail_on_internal_call {
 252   my ($fr, $argdesc);
 253   {
 254     package DB;
 255     $fr = [ caller(1) ];
 256     $argdesc = ref $DB::args[0]
 257       ? DBIx::Class::_Util::refdesc($DB::args[0])
 258       : undef
 259     ;
 260   };
 261
 262   if (
 263     $argdesc
 264       and
 265     $fr->[0] =~ /^(?:DBIx::Class|DBICx::)/
 266       and
 267     $fr->[1] !~ /\b(?:CDBICompat|ResultSetProxy)\b/  # no point touching there
 268   ) {
 269     DBIx::Class::Exception->throw( sprintf (
 270       "Illegal internal call of indirect proxy-method %s() with argument %s: examine the last lines of the proxy method deparse below to determine what to call directly instead at %s on line %d\n\n%s\n\n    Stacktrace starts",
 271       $fr->[3], $argdesc, @{$fr}[1,2], ( $fr->[6] || do {
 272         require B::Deparse;
 273         no strict 'refs';
 274         B::Deparse->new->coderef2text(\&{$fr->[3]})
 275       }),
 276     ), 'with_stacktrace');
 277   }
 278 }
 279
 280 1;