lib/DBIx/Class/_Util.pm

   1 package # hide from PAUSE
   2   DBIx::Class::_Util;
   3
   4 use DBIx::Class::StartupCheck;  # load es early as we can, usually a noop
   5
   6 use warnings;
   7 use strict;
   8
   9 # For the love of everything that is crab-like: DO NOT reach into this
  10 # The entire thing is really fragile and should not be screwed with
  11 # unless absolutely and unavoidably necessary
  12 our $__describe_class_query_cache;
  13
  14 BEGIN {
  15   package # hide from pause
  16     DBIx::Class::_ENV_;
  17
  18   use Config;
  19
  20   use constant {
  21     PERL_VERSION => "$]",
  22     OS_NAME => "$^O",
  23   };
  24
  25   use constant {
  26
  27     # but of course
  28     BROKEN_FORK => (OS_NAME eq 'MSWin32') ? 1 : 0,
  29
  30     BROKEN_GOTO => ( PERL_VERSION < 5.008003 ) ? 1 : 0,
  31
  32     # perl -MScalar::Util=weaken -e 'weaken( $hash{key} = \"value" )'
  33     BROKEN_WEAK_SCALARREF_VALUES => ( PERL_VERSION < 5.008003 ) ? 1 : 0,
  34
  35     HAS_ITHREADS => $Config{useithreads} ? 1 : 0,
  36
  37     TAINT_MODE => 0 + ${^TAINT}, # tri-state: 0, 1, -1
  38
  39     UNSTABLE_DOLLARAT => ( PERL_VERSION < 5.013002 ) ? 1 : 0,
  40
  41     ( map
  42       #
  43       # the "DBIC_" prefix below is crucial - this is what makes CI pick up
  44       # all envvars without further adjusting its scripts
  45       # DO NOT CHANGE to the more logical { $_ => !!( $ENV{"DBIC_$_"} ) }
  46       #
  47       { substr($_, 5) => !!( $ENV{$_} ) }
  48       qw(
  49         DBIC_SHUFFLE_UNORDERED_RESULTSETS
  50         DBIC_ASSERT_NO_INTERNAL_WANTARRAY
  51         DBIC_ASSERT_NO_INTERNAL_INDIRECT_CALLS
  52         DBIC_ASSERT_NO_ERRONEOUS_METAINSTANCE_USE
  53         DBIC_ASSERT_NO_FAILING_SANITY_CHECKS
  54         DBIC_STRESSTEST_UTF8_UPGRADE_GENERATED_COLLAPSER_SOURCE
  55         DBIC_STRESSTEST_COLUMN_INFO_UNAWARE_STORAGE
  56       )
  57     ),
  58
  59     IV_SIZE => $Config{ivsize},
  60   };
  61
  62   if ( PERL_VERSION < 5.009_005) {
  63     require MRO::Compat;
  64     constant->import( OLD_MRO => 1 );
  65
  66     #
  67     # Yes, I know this is a rather PHP-ish name, but please first read
  68     # https://metacpan.org/source/BOBTFISH/MRO-Compat-0.12/lib/MRO/Compat.pm#L363-368
  69     #
  70     # Even if we are using Class::C3::XS it still won't work, as doing
  71     #   defined( *{ "SubClass::"->{$_} }{CODE} )
  72     # will set pkg_gen to the same value for SubClass and *ALL PARENTS*
  73     #
  74     *DBIx::Class::_Util::get_real_pkg_gen = sub ($) {
  75       require Digest::MD5;
  76       require Math::BigInt;
  77
  78       my $cur_class;
  79       no strict 'refs';
  80
  81       # the non-assign-unless-there-is-a-hash is deliberate
  82       ( $__describe_class_query_cache->{'!internal!'} || {} )->{$_[0]}{gen} ||= (
  83         Math::BigInt->new( '0x' . ( Digest::MD5::md5_hex( join "\0", map {
  84
  85           ( $__describe_class_query_cache->{'!internal!'} || {} )->{$_}{methlist} ||= (
  86
  87             $cur_class = $_
  88
  89               and
  90
  91             # RV to be hashed up and turned into a number
  92             join "\0", (
  93               $cur_class,
  94               map
  95                 {(
  96                   # stringification should be sufficient, ignore names/refaddr entirely
  97                   $_,
  98                   do {
  99                     my @attrs;
 100                     local $@;
 101                     local $SIG{__DIE__} if $SIG{__DIE__};
 102                     # attributes::get may throw on blessed-false crefs :/
 103                     eval { @attrs = attributes::get( $_ ); 1 }
 104                       or warn "Unable to determine attributes of coderef $_ due to the following error: $@";
 105                     @attrs;
 106                   },
 107                 )}
 108                 map
 109                   {(
 110                     # skip dummy C::C3 helper crefs
 111                     ! ( ( $Class::C3::MRO{$cur_class} || {} )->{methods}{$_} )
 112                       and
 113                     (
 114                       ref(\ "${cur_class}::"->{$_} ) ne 'GLOB'
 115                         or
 116                       defined( *{ "${cur_class}::"->{$_} }{CODE} )
 117                     )
 118                   )
 119                     ? ( \&{"${cur_class}::$_"} )
 120                     : ()
 121                   }
 122                   keys %{ "${cur_class}::" }
 123             )
 124           )
 125         } (
 126
 127           @{
 128             ( $__describe_class_query_cache->{'!internal!'} || {} )->{$_[0]}{linear_isa}
 129               ||=
 130             mro::get_linear_isa($_[0])
 131           },
 132
 133           ((
 134             ( $__describe_class_query_cache->{'!internal!'} || {} )->{$_[0]}{is_universal}
 135               ||=
 136             mro::is_universal($_[0])
 137           ) ? () : @{
 138             ( $__describe_class_query_cache->{'!internal!'} || {} )->{UNIVERSAL}{linear_isa}
 139               ||=
 140             mro::get_linear_isa("UNIVERSAL")
 141           } ),
 142
 143         ) ) ) )
 144       );
 145     };
 146   }
 147   else {
 148     require mro;
 149     constant->import( OLD_MRO => 0 );
 150     *DBIx::Class::_Util::get_real_pkg_gen = \&mro::get_pkg_gen;
 151   }
 152
 153   # Both of these are no longer used for anything. However bring
 154   # them back after they were purged in 08a8d8f1, as there appear
 155   # to be outfits with *COPY PASTED* pieces of lib/DBIx/Class/Storage/*
 156   # in their production codebases. There is no point in breaking these
 157   # if whatever they used actually continues to work
 158   my $sigh = sub {
 159     DBIx::Class::_Util::emit_loud_diag(
 160       skip_frames => 1,
 161       msg => "The @{[ (caller(1))[3] ]} constant is no more - adjust your code"
 162     );
 163
 164     0;
 165   };
 166   sub DBICTEST () { &$sigh }
 167   sub PEEPEENESS () { &$sigh }
 168 }
 169
 170 use constant SPURIOUS_VERSION_CHECK_WARNINGS => ( DBIx::Class::_ENV_::PERL_VERSION < 5.010 ? 1 : 0);
 171
 172 # FIXME - this is not supposed to be here
 173 # Carp::Skip to the rescue soon
 174 use DBIx::Class::Carp '^DBIx::Class|^DBICTest';
 175
 176 use B ();
 177 use Carp 'croak';
 178 use Storable 'nfreeze';
 179 use Scalar::Util qw(weaken blessed reftype refaddr);
 180 use Sub::Name ();
 181 use attributes ();
 182
 183 # Usually versions are not specified anywhere aside the Makefile.PL
 184 # (writing them out in-code is extremely obnoxious)
 185 # However without a recent enough Moo the quote_sub override fails
 186 # in very puzzling and hard to detect ways: so add a version check
 187 # just this once
 188 use Sub::Quote qw(qsub);
 189 BEGIN { Sub::Quote->VERSION('2.002002') }
 190
 191 # Already correctly prototyped: perlbrew exec perl -MStorable -e 'warn prototype \&Storable::dclone'
 192 BEGIN { *deep_clone = \&Storable::dclone }
 193
 194 use base 'Exporter';
 195 our @EXPORT_OK = qw(
 196   sigwarn_silencer modver_gt_or_eq modver_gt_or_eq_and_lt
 197   fail_on_internal_wantarray fail_on_internal_call
 198   refdesc refcount hrefaddr set_subname get_subname describe_class_methods
 199   scope_guard detected_reinvoked_destructor emit_loud_diag
 200   true false
 201   is_exception dbic_internal_try visit_namespaces
 202   quote_sub qsub perlstring serialize deep_clone dump_value uniq
 203   parent_dir mkdir_p
 204   UNRESOLVABLE_CONDITION
 205 );
 206
 207 use constant UNRESOLVABLE_CONDITION => \ '1 = 0';
 208
 209 # Override forcing no_defer, and adding naming consistency checks
 210 our %refs_closed_over_by_quote_sub_installed_crefs;
 211 sub quote_sub {
 212   Carp::confess( "Anonymous quoting not supported by the DBIC quote_sub override - supply a sub name" ) if
 213     @_ < 2
 214       or
 215     ! defined $_[1]
 216       or
 217     length ref $_[1]
 218   ;
 219
 220   Carp::confess( "The DBIC quote_sub override expects sub name '$_[0]' to be fully qualified" )
 221     unless (my $stash) = $_[0] =~ /^(.+)::/;
 222
 223   Carp::confess(
 224     "The DBIC sub_quote override does not support 'no_install'"
 225   ) if (
 226     $_[3]
 227       and
 228     $_[3]->{no_install}
 229   );
 230
 231   Carp::confess(
 232     'The DBIC quote_sub override expects the namespace-part of sub name '
 233   . "'$_[0]' to match the supplied package argument '$_[3]->{package}'"
 234   ) if (
 235     $_[3]
 236       and
 237     defined $_[3]->{package}
 238       and
 239     $stash ne $_[3]->{package}
 240   );
 241
 242   my @caller = caller(0);
 243   my $sq_opts = {
 244     package => $caller[0],
 245     hints => $caller[8],
 246     warning_bits => $caller[9],
 247     hintshash => $caller[10],
 248     %{ $_[3] || {} },
 249
 250     # explicitly forced for everything
 251     no_defer => 1,
 252   };
 253
 254   weaken (
 255     # just use a growing counter, no need to perform neither compaction
 256     # nor any special ithread-level handling
 257     $refs_closed_over_by_quote_sub_installed_crefs
 258      { scalar keys %refs_closed_over_by_quote_sub_installed_crefs }
 259       = $_
 260   ) for grep {
 261     length ref $_
 262       and
 263     (
 264       ! DBIx::Class::_ENV_::BROKEN_WEAK_SCALARREF_VALUES
 265         or
 266       ref $_ ne 'SCALAR'
 267     )
 268   } values %{ $_[2] || {} };
 269
 270   Sub::Quote::quote_sub( $_[0], $_[1], $_[2]||{}, $sq_opts );
 271 }
 272
 273 sub sigwarn_silencer ($) {
 274   my $pattern = shift;
 275
 276   croak "Expecting a regexp" if ref $pattern ne 'Regexp';
 277
 278   my $orig_sig_warn = $SIG{__WARN__} || sub { CORE::warn(@_) };
 279
 280   return sub { &$orig_sig_warn unless $_[0] =~ $pattern };
 281 }
 282
 283 sub perlstring ($) { q{"}. quotemeta( shift ). q{"} };
 284
 285 sub hrefaddr ($) { sprintf '0x%x', &refaddr||0 }
 286
 287 sub refdesc ($) {
 288   croak "Expecting a reference" if ! length ref $_[0];
 289
 290   # be careful not to trigger stringification,
 291   # reuse @_ as a scratch-pad
 292   sprintf '%s%s(0x%x)',
 293     ( defined( $_[1] = blessed $_[0]) ? "$_[1]=" : '' ),
 294     reftype $_[0],
 295     refaddr($_[0]),
 296   ;
 297 }
 298
 299 sub refcount ($) {
 300   croak "Expecting a reference" if ! length ref $_[0];
 301
 302   # No tempvars - must operate on $_[0], otherwise the pad
 303   # will count as an extra ref
 304   B::svref_2object($_[0])->REFCNT;
 305 }
 306
 307 sub visit_namespaces {
 308   my $args = { (ref $_[0]) ? %{$_[0]} : @_ };
 309
 310   my $visited_count = 1;
 311
 312   # A package and a namespace are subtly different things
 313   $args->{package} ||= 'main';
 314   $args->{package} = 'main' if $args->{package} =~ /^ :: (?: main )? $/x;
 315   $args->{package} =~ s/^:://;
 316
 317   if ( $args->{action}->($args->{package}) ) {
 318     my $ns =
 319       ( ($args->{package} eq 'main') ? '' :  $args->{package} )
 320         .
 321       '::'
 322     ;
 323
 324     $visited_count += visit_namespaces( %$args, package => $_ ) for
 325       grep
 326         # this happens sometimes on %:: traversal
 327         { $_ ne '::main' }
 328         map
 329           { $_ =~ /^(.+?)::$/ ? "$ns$1" : () }
 330           do { no strict 'refs'; keys %$ns }
 331     ;
 332   }
 333
 334   $visited_count;
 335 }
 336
 337 # FIXME In another life switch these to a polyfill like the ones in namespace::clean
 338 sub get_subname ($) {
 339   my $gv = B::svref_2object( $_[0] )->GV;
 340   wantarray
 341     ? ( $gv->STASH->NAME, $gv->NAME )
 342     : ( join '::', $gv->STASH->NAME, $gv->NAME )
 343   ;
 344 }
 345 sub set_subname ($$) {
 346
 347   # fully qualify name
 348   splice @_, 0, 1, caller(0) . "::$_[0]"
 349     if $_[0] !~ /::|'/;
 350
 351   &Sub::Name::subname;
 352 }
 353
 354 sub serialize ($) {
 355   local $Storable::canonical = 1;
 356   nfreeze($_[0]);
 357 }
 358
 359 sub uniq {
 360   my( %seen, $seen_undef, $numeric_preserving_copy );
 361   grep { not (
 362     defined $_
 363       ? $seen{ $numeric_preserving_copy = $_ }++
 364       : $seen_undef++
 365   ) } @_;
 366 }
 367
 368 my $dd_obj;
 369 sub dump_value ($) {
 370   local $Data::Dumper::Indent = 1
 371     unless defined $Data::Dumper::Indent;
 372
 373   my $dump_str = (
 374     $dd_obj
 375       ||=
 376     do {
 377       require Data::Dumper;
 378       my $d = Data::Dumper->new([])
 379         ->Purity(0)
 380         ->Pad('')
 381         ->Useqq(1)
 382         ->Terse(1)
 383         ->Freezer('')
 384         ->Quotekeys(0)
 385         ->Bless('bless')
 386         ->Pair(' => ')
 387         ->Sortkeys(1)
 388         ->Deparse(1)
 389       ;
 390
 391       $d->Sparseseen(1) if modver_gt_or_eq (
 392         'Data::Dumper', '2.136'
 393       );
 394
 395       $d;
 396     }
 397   )->Values([$_[0]])->Dump;
 398
 399   $dd_obj->Reset->Values([]);
 400
 401   $dump_str;
 402 }
 403
 404 my $seen_loud_screams;
 405 sub emit_loud_diag {
 406   my $args = { ref $_[0] eq 'HASH' ? %{$_[0]} : @_ };
 407
 408   unless ( defined $args->{msg} and length $args->{msg} ) {
 409     emit_loud_diag(
 410       msg => "No 'msg' value supplied to emit_loud_diag()"
 411     );
 412     exit 70;
 413   }
 414
 415   my $msg = "\n" . join( ': ',
 416     ( $0 eq '-e' ? () : $0 ),
 417     $args->{msg}
 418   );
 419
 420   # when we die - we usually want to keep doing it
 421   $args->{emit_dups} = !!$args->{confess}
 422     unless exists $args->{emit_dups};
 423
 424   local $Carp::CarpLevel =
 425     ( $args->{skip_frames} || 0 )
 426       +
 427     $Carp::CarpLevel
 428       +
 429     # hide our own frame
 430     1
 431   ;
 432
 433   my $longmess = Carp::longmess();
 434
 435   # different object references will thwart deduplication without this
 436   ( my $key = "${msg}\n${longmess}" ) =~ s/\b0x[0-9a-f]+\b/0x.../gi;
 437
 438   return $seen_loud_screams->{$key} if
 439     $seen_loud_screams->{$key}++
 440       and
 441     ! $args->{emit_dups}
 442   ;
 443
 444   $msg .= $longmess
 445     unless $msg =~ /\n\z/;
 446
 447   print STDERR "$msg\n"
 448     or
 449   print STDOUT "\n!!!STDERR ISN'T WRITABLE!!!:$msg\n";
 450
 451   return $seen_loud_screams->{$key}
 452     unless $args->{confess};
 453
 454   # increment *again*, because... Carp.
 455   $Carp::CarpLevel++;
 456
 457   # not $msg - Carp will reapply the longmess on its own
 458   Carp::confess($args->{msg});
 459 }
 460
 461
 462 ###
 463 ### This is *NOT* boolean.pm - deliberately not using a singleton
 464 ###
 465 {
 466   package # hide from pause
 467     DBIx::Class::_Util::_Bool;
 468   use overload
 469     bool => sub { ${$_[0]} },
 470     fallback => 1,
 471   ;
 472 }
 473 sub true () { my $x = 1; bless \$x, "DBIx::Class::_Util::_Bool" }
 474 sub false () { my $x = 0; bless \$x, "DBIx::Class::_Util::_Bool" }
 475
 476 sub scope_guard (&) {
 477   croak 'Calling scope_guard() in void context makes no sense'
 478     if ! defined wantarray;
 479
 480   # no direct blessing of coderefs - DESTROY is buggy on those
 481   bless [ $_[0] ], 'DBIx::Class::_Util::ScopeGuard';
 482 }
 483 {
 484   package #
 485     DBIx::Class::_Util::ScopeGuard;
 486
 487   sub DESTROY {
 488     &DBIx::Class::_Util::detected_reinvoked_destructor;
 489
 490     local $@ if DBIx::Class::_ENV_::UNSTABLE_DOLLARAT;
 491
 492     eval {
 493       $_[0]->[0]->();
 494       1;
 495     }
 496       or
 497     DBIx::Class::_Util::emit_loud_diag(
 498       emit_dups => 1,
 499       msg => "Execution of scope guard $_[0] resulted in the non-trappable exception:\n\n$@\n "
 500     );
 501   }
 502 }
 503
 504
 505 sub is_exception ($) {
 506   my $e = $_[0];
 507
 508   # FIXME
 509   # this is not strictly correct - an eval setting $@ to undef
 510   # is *not* the same as an eval setting $@ to ''
 511   # but for the sake of simplicity assume the following for
 512   # the time being
 513   return 0 unless defined $e;
 514
 515   my ($not_blank, $suberror);
 516   {
 517     local $SIG{__DIE__} if $SIG{__DIE__};
 518     local $@;
 519     eval {
 520       # The ne() here is deliberate - a plain length($e), or worse "$e" ne
 521       # will entirely obviate the need for the encolsing eval{}, as the
 522       # condition we guard against is a missing fallback overload
 523       $not_blank = ( $e ne '' );
 524       1;
 525     } or $suberror = $@;
 526   }
 527
 528   if (defined $suberror) {
 529     if (length (my $class = blessed($e) )) {
 530       carp_unique( sprintf(
 531         'External exception class %s implements partial (broken) overloading '
 532       . 'preventing its instances from being used in simple ($x eq $y) '
 533       . 'comparisons. Given Perl\'s "globally cooperative" exception '
 534       . 'handling this type of brokenness is extremely dangerous on '
 535       . 'exception objects, as it may (and often does) result in silent '
 536       . '"exception substitution". DBIx::Class tries to work around this '
 537       . 'as much as possible, but other parts of your software stack may '
 538       . 'not be even aware of this. Please submit a bugreport against the '
 539       . 'distribution containing %s and in the meantime apply a fix similar '
 540       . 'to the one shown at %s, in order to ensure your exception handling '
 541       . 'is saner application-wide. What follows is the actual error text '
 542       . "as generated by Perl itself:\n\n%s\n ",
 543         $class,
 544         $class,
 545         'http://v.gd/DBIC_overload_tempfix/',
 546         $suberror,
 547       ));
 548
 549       # workaround, keeps spice flowing
 550       $not_blank = !!( length $e );
 551     }
 552     else {
 553       # not blessed yet failed the 'ne'... this makes 0 sense...
 554       # just throw further
 555       die $suberror
 556     }
 557   }
 558   elsif (
 559     # a ref evaluating to '' is definitively a "null object"
 560     ( not $not_blank )
 561       and
 562     length( my $class = ref $e )
 563   ) {
 564     carp_unique(
 565       "Objects of external exception class '$class' stringify to '' (the "
 566     . 'empty string), implementing the so called null-object-pattern. '
 567     . 'Given Perl\'s "globally cooperative" exception handling using this '
 568     . 'class of exceptions is extremely dangerous, as it may (and often '
 569     . 'does) result in silent discarding of errors. DBIx::Class tries to '
 570     . 'work around this as much as possible, but other parts of your '
 571     . 'software stack may not be even aware of the problem. Please submit '
 572     . "a bugreport against the distribution containing '$class'",
 573     );
 574
 575     $not_blank = 1;
 576   }
 577
 578   return $not_blank;
 579 }
 580
 581 {
 582   my $callstack_state;
 583
 584   # Recreate the logic of try(), while reusing the catch()/finally() as-is
 585   #
 586   # FIXME: We need to move away from Try::Tiny entirely (way too heavy and
 587   # yes, shows up ON TOP of profiles) but this is a batle for another maint
 588   sub dbic_internal_try (&;@) {
 589
 590     my $try_cref = shift;
 591     my $catch_cref = undef;  # apparently this is a thing... https://rt.perl.org/Public/Bug/Display.html?id=119311
 592
 593     for my $arg (@_) {
 594
 595       if( ref($arg) eq 'Try::Tiny::Catch' ) {
 596
 597         croak 'dbic_internal_try() may not be followed by multiple catch() blocks'
 598           if $catch_cref;
 599
 600         $catch_cref = $$arg;
 601       }
 602       elsif ( ref($arg) eq 'Try::Tiny::Finally' ) {
 603         croak 'dbic_internal_try() does not support finally{}';
 604       }
 605       else {
 606         croak(
 607           'dbic_internal_try() encountered an unexpected argument '
 608         . "'@{[ defined $arg ? $arg : 'UNDEF' ]}' - perhaps "
 609         . 'a missing semi-colon before or ' # trailing space important
 610         );
 611       }
 612     }
 613
 614     my $wantarray = wantarray;
 615     my $preexisting_exception = $@;
 616
 617     my @ret;
 618     my $all_good = eval {
 619       $@ = $preexisting_exception;
 620
 621       local $callstack_state->{in_internal_try} = 1
 622         unless $callstack_state->{in_internal_try};
 623
 624       # always unset - someone may have snuck it in
 625       local $SIG{__DIE__} if $SIG{__DIE__};
 626
 627       if( $wantarray ) {
 628         @ret = $try_cref->();
 629       }
 630       elsif( defined $wantarray ) {
 631         $ret[0] = $try_cref->();
 632       }
 633       else {
 634         $try_cref->();
 635       }
 636
 637       1;
 638     };
 639
 640     my $exception = $@;
 641     $@ = $preexisting_exception;
 642
 643     if ( $all_good ) {
 644       return $wantarray ? @ret : $ret[0]
 645     }
 646     elsif ( $catch_cref ) {
 647       for ( $exception ) {
 648         return $catch_cref->($exception);
 649       }
 650     }
 651
 652     return;
 653   }
 654
 655   sub in_internal_try { !! $callstack_state->{in_internal_try} }
 656 }
 657
 658 {
 659   my $destruction_registry = {};
 660
 661   sub DBIx::Class::__Util_iThreads_handler__::CLONE {
 662     %$destruction_registry = map {
 663       (defined $_)
 664         ? ( refaddr($_) => $_ )
 665         : ()
 666     } values %$destruction_registry;
 667
 668     weaken($_) for values %$destruction_registry;
 669
 670     # Dummy NEXTSTATE ensuring the all temporaries on the stack are garbage
 671     # collected before leaving this scope. Depending on the code above, this
 672     # may very well be just a preventive measure guarding future modifications
 673     undef;
 674   }
 675
 676   # This is almost invariably invoked from within DESTROY
 677   # throwing exceptions won't work
 678   sub detected_reinvoked_destructor {
 679
 680     # quick "garbage collection" pass - prevents the registry
 681     # from slowly growing with a bunch of undef-valued keys
 682     defined $destruction_registry->{$_} or delete $destruction_registry->{$_}
 683       for keys %$destruction_registry;
 684
 685     if (! length ref $_[0]) {
 686       emit_loud_diag(
 687         emit_dups => 1,
 688         msg => (caller(0))[3] . '() expects a blessed reference'
 689       );
 690       return undef; # don't know wtf to do
 691     }
 692     elsif (! defined $destruction_registry->{ my $addr = refaddr($_[0]) } ) {
 693       weaken( $destruction_registry->{$addr} = $_[0] );
 694       return 0;
 695     }
 696     else {
 697       emit_loud_diag( msg => sprintf (
 698         'Preventing *MULTIPLE* DESTROY() invocations on %s - an *EXTREMELY '
 699       . 'DANGEROUS* condition which is *ALMOST CERTAINLY GLOBAL* within your '
 700       . 'application, affecting *ALL* classes without active protection against '
 701       . 'this. Diagnose and fix the root cause ASAP!!!%s',
 702       refdesc $_[0],
 703         ( ( $INC{'Devel/StackTrace.pm'} and ! do { local $@; eval { Devel::StackTrace->VERSION(2) } } )
 704           ? " (likely culprit Devel::StackTrace\@@{[ Devel::StackTrace->VERSION ]} found in %INC, http://is.gd/D_ST_refcap)"
 705           : ''
 706         )
 707       ));
 708
 709       return 1;
 710     }
 711   }
 712 }
 713
 714 my $module_name_rx = qr/ \A [A-Z_a-z] [0-9A-Z_a-z]* (?: :: [0-9A-Z_a-z]+ )* \z /x;
 715 my $ver_rx =         qr/ \A [0-9]+ (?: \. [0-9]+ )* (?: \_ [0-9]+ )*        \z /x;
 716
 717 sub modver_gt_or_eq ($$) {
 718   my ($mod, $ver) = @_;
 719
 720   croak "Nonsensical module name supplied"
 721     if ! defined $mod or $mod !~ $module_name_rx;
 722
 723   croak "Nonsensical minimum version supplied"
 724     if ! defined $ver or $ver !~ $ver_rx;
 725
 726   no strict 'refs';
 727   my $ver_cache = ${"${mod}::__DBIC_MODULE_VERSION_CHECKS__"} ||= ( $mod->VERSION
 728     ? {}
 729     : croak "$mod does not seem to provide a version (perhaps it never loaded)"
 730   );
 731
 732   ! defined $ver_cache->{$ver}
 733     and
 734   $ver_cache->{$ver} = do {
 735
 736     local $SIG{__WARN__} = sigwarn_silencer( qr/\Qisn't numeric in subroutine entry/ )
 737       if SPURIOUS_VERSION_CHECK_WARNINGS;
 738
 739     local $SIG{__DIE__} if $SIG{__DIE__};
 740     local $@;
 741     eval { $mod->VERSION($ver) } ? 1 : 0;
 742   };
 743
 744   $ver_cache->{$ver};
 745 }
 746
 747 sub modver_gt_or_eq_and_lt ($$$) {
 748   my ($mod, $v_ge, $v_lt) = @_;
 749
 750   croak "Nonsensical maximum version supplied"
 751     if ! defined $v_lt or $v_lt !~ $ver_rx;
 752
 753   return (
 754     modver_gt_or_eq($mod, $v_ge)
 755       and
 756     ! modver_gt_or_eq($mod, $v_lt)
 757   ) ? 1 : 0;
 758 }
 759
 760 {
 761
 762   sub describe_class_methods {
 763     my $args = (
 764       ref $_[0] eq 'HASH'                 ? $_[0]
 765     : ( @_ == 1 and ! length ref $_[0] )  ? { class => $_[0] }
 766     :                                       { @_ }
 767     );
 768
 769     my ($class, $requested_mro) = @{$args}{qw( class use_mro )};
 770
 771     croak "Expecting a class name either as the sole argument or a 'class' option"
 772       if not defined $class or $class !~ $module_name_rx;
 773
 774     croak(
 775       "The supplied 'class' argument is tainted: this is *extremely* "
 776     . 'dangerous, fix your code ASAP!!! ( for more details read through '
 777     . 'https://is.gd/perl_mro_taint_wtf )'
 778     ) if (
 779       DBIx::Class::_ENV_::TAINT_MODE
 780         and
 781       Scalar::Util::tainted($class)
 782     );
 783
 784     $requested_mro ||= mro::get_mro($class);
 785
 786     # mro::set_mro() does not bump pkg_gen - WHAT THE FUCK?!
 787     my $query_cache_key = "$class|$requested_mro";
 788
 789     my $internal_cache_key =
 790       ( mro::get_mro($class) eq $requested_mro )
 791         ? $class
 792         : $query_cache_key
 793     ;
 794
 795     # use a cache on old MRO, since while we are recursing in this function
 796     # nothing can possibly change (the speedup is immense)
 797     # (yes, people could be tie()ing the stash and adding methods on access
 798     # but there is a limit to how much crazy can be supported here)
 799     #
 800     # we use the cache for linear_isa lookups on new MRO as well - it adds
 801     # a *tiny* speedup, and simplifies the code a lot
 802     #
 803     local $__describe_class_query_cache->{'!internal!'} = {}
 804       unless $__describe_class_query_cache->{'!internal!'};
 805
 806     my $my_gen = 0;
 807
 808     $my_gen += get_real_pkg_gen($_) for ( my @full_ISA = (
 809
 810       @{
 811         $__describe_class_query_cache->{'!internal!'}{$internal_cache_key}{linear_isa}
 812           ||=
 813         mro::get_linear_isa($class, $requested_mro)
 814       },
 815
 816       ((
 817         $__describe_class_query_cache->{'!internal!'}{$class}{is_universal}
 818           ||=
 819         mro::is_universal($class)
 820       ) ? () : @{
 821         $__describe_class_query_cache->{'!internal!'}{UNIVERSAL}{linear_isa}
 822           ||=
 823         mro::get_linear_isa("UNIVERSAL")
 824       }),
 825
 826     ));
 827
 828     my $slot = $__describe_class_query_cache->{$query_cache_key} ||= {};
 829
 830     unless ( ($slot->{cumulative_gen}||0) == $my_gen ) {
 831
 832       # reset
 833       %$slot = (
 834         class => $class,
 835         isa => { map { $_ => 1 } @full_ISA },
 836         linear_isa => [
 837           @{ $__describe_class_query_cache->{'!internal!'}{$internal_cache_key}{linear_isa} }
 838             [ 1 .. $#{$__describe_class_query_cache->{'!internal!'}{$internal_cache_key}{linear_isa}} ]
 839         ],
 840         mro => {
 841           type => $requested_mro,
 842           is_c3 => ( ($requested_mro eq 'c3') ? 1 : 0 ),
 843         },
 844         cumulative_gen => $my_gen,
 845       );
 846
 847       # remove ourselves from ISA
 848       shift @full_ISA;
 849
 850       # ensure the cache is populated for the parents, code below can then
 851       # efficiently operate over the query_cache directly
 852       describe_class_methods($_) for reverse @full_ISA;
 853
 854       no strict 'refs';
 855
 856       # combine full ISA-order inherited and local method list into a
 857       # "shadowing stack"
 858
 859       (
 860         unshift @{ $slot->{methods}{$_->{name}} }, $_
 861
 862           and
 863
 864         (
 865           $_->{via_class} ne $class
 866             or
 867           $slot->{methods_defined_in_class}{$_->{name}} = $_
 868         )
 869
 870           and
 871
 872         @{ $slot->{methods}{$_->{name}} } > 1
 873
 874           and
 875
 876         $slot->{methods_with_supers}{$_->{name}} = $slot->{methods}{$_->{name}}
 877
 878       ) for (
 879
 880         # what describe_class_methods for @full_ISA produced above
 881         ( map { values %{
 882           $__describe_class_query_cache->{$_}{methods_defined_in_class} || {}
 883         } } map { "$_|" . mro::get_mro($_) } reverse @full_ISA ),
 884
 885         # our own non-cleaned subs + their attributes
 886         ( map {
 887           (
 888             # need to account for dummy helper crefs under OLD_MRO
 889             (
 890               ! DBIx::Class::_ENV_::OLD_MRO
 891                 or
 892               ! ( ( $Class::C3::MRO{$class} || {} )->{methods}{$_} )
 893             )
 894               and
 895             # these 2 OR-ed checks are sufficient for 5.10+
 896             (
 897               ref(\ "${class}::"->{$_} ) ne 'GLOB'
 898                 or
 899               defined( *{ "${class}::"->{$_} }{CODE} )
 900             )
 901           ) ? {
 902               via_class => $class,
 903               name => $_,
 904               attributes => { map { $_ => 1 } do {
 905                 my @attrs;
 906                 local $@;
 907                 local $SIG{__DIE__} if $SIG{__DIE__};
 908                 # attributes::get may throw on blessed-false crefs :/
 909                 eval { @attrs = attributes::get( \&{"${class}::${_}"} ); 1 }
 910                   or warn "Unable to determine attributes of the \\&${class}::$_ method due to following error: $@";
 911                 @attrs;
 912               } },
 913             }
 914             : ()
 915         } keys %{"${class}::"} )
 916       );
 917
 918
 919       # recalculate the pkg_gen on newer perls under Taint mode,
 920       # because of shit like:
 921       # perl -T -Mmro -e 'package Foo; sub bar {}; defined( *{ "Foo::"->{bar}}{CODE} ) and warn mro::get_pkg_gen("Foo") for (1,2,3)'
 922       #
 923       if (
 924         ! DBIx::Class::_ENV_::OLD_MRO
 925           and
 926         DBIx::Class::_ENV_::TAINT_MODE
 927       ) {
 928
 929         $slot->{cumulative_gen} = 0;
 930         $slot->{cumulative_gen} += get_real_pkg_gen($_)
 931           for $class, @full_ISA;
 932       }
 933     }
 934
 935     # RV
 936     +{ %$slot };
 937   }
 938 }
 939
 940
 941 #
 942 # Why not just use some higher-level module or at least File::Spec here?
 943 # Because:
 944 # 1)  This is a *very* rarely used function, and the deptree is large
 945 #     enough already as it is
 946 #
 947 # 2)  (more importantly) Our tooling is utter shit in this area. There
 948 #     is no comprehensive support for UNC paths in PathTools and there
 949 #     are also various small bugs in representation across different
 950 #     path-manipulation CPAN offerings.
 951 #
 952 # Since this routine is strictly used for logical path processing (it
 953 # *must* be able to work with not-yet-existing paths), use this seemingly
 954 # simple but I *think* complete implementation to feed to other consumers
 955 #
 956 # If bugs are ever uncovered in this routine, *YOU ARE URGED TO RESIST*
 957 # the impulse to bring in an external dependency. During runtime there
 958 # is exactly one spot that could potentially maybe once in a blue moon
 959 # use this function. Keep it lean.
 960 #
 961 sub parent_dir ($) {
 962   ( $_[0] =~ m{  [\/\\]  ( \.{0,2} ) ( [\/\\]* ) \z }x )
 963     ? (
 964       $_[0]
 965         .
 966       ( ( length($1) and ! length($2) ) ? '/' : '' )
 967         .
 968       '../'
 969     )
 970     : (
 971       require File::Spec
 972         and
 973       File::Spec->catpath (
 974         ( File::Spec->splitpath( "$_[0]" ) )[0,1],
 975         '/',
 976       )
 977     )
 978   ;
 979 }
 980
 981 sub mkdir_p ($) {
 982   require File::Path;
 983   # do not ask for a recent version, use 1.x API calls
 984   File::Path::mkpath([ "$_[0]" ]);  # File::Path does not like objects
 985 }
 986
 987
 988 {
 989   my $list_ctx_ok_stack_marker;
 990
 991   sub fail_on_internal_wantarray () {
 992     return if $list_ctx_ok_stack_marker;
 993
 994     if (! defined wantarray) {
 995       croak('fail_on_internal_wantarray() needs a tempvar to save the stack marker guard');
 996     }
 997
 998     my $cf = 1;
 999     while ( ( (CORE::caller($cf+1))[3] || '' ) =~ / :: (?:
1000
1001       # these are public API parts that alter behavior on wantarray
1002       search | search_related | slice | search_literal
1003
1004         |
1005
1006       # these are explicitly prefixed, since we only recognize them as valid
1007       # escapes when they come from the guts of CDBICompat
1008       CDBICompat .*? :: (?: search_where | retrieve_from_sql | retrieve_all )
1009
1010     ) $/x ) {
1011       $cf++;
1012     }
1013
1014     my ($fr, $want, $argdesc);
1015     {
1016       package DB;
1017       $fr = [ CORE::caller($cf) ];
1018       $want = ( CORE::caller($cf-1) )[5];
1019       $argdesc = ref $DB::args[0]
1020         ? DBIx::Class::_Util::refdesc($DB::args[0])
1021         : 'non '
1022       ;
1023     };
1024
1025     if (
1026       $want and $fr->[0] =~ /^(?:DBIx::Class|DBICx::)/
1027     ) {
1028       DBIx::Class::Exception->throw( sprintf (
1029         "Improper use of %s instance in list context at %s line %d\n\n    Stacktrace starts",
1030         $argdesc, @{$fr}[1,2]
1031       ), 'with_stacktrace');
1032     }
1033
1034     weaken( $list_ctx_ok_stack_marker = my $mark = [] );
1035
1036     $mark;
1037   }
1038 }
1039
1040 sub fail_on_internal_call {
1041   my ($fr, $argdesc);
1042   {
1043     package DB;
1044     $fr = [ CORE::caller(1) ];
1045     $argdesc =
1046       ( not defined $DB::args[0] )  ? 'UNAVAILABLE'
1047     : ( length ref $DB::args[0] )   ? DBIx::Class::_Util::refdesc($DB::args[0])
1048     : $DB::args[0] . ''
1049     ;
1050   };
1051
1052   my @fr2;
1053   # need to make allowance for a proxy-yet-direct call
1054   my $check_fr = (
1055     $fr->[0] eq 'DBIx::Class::ResultSourceProxy'
1056       and
1057     @fr2 = (CORE::caller(2))
1058       and
1059     (
1060       ( $fr->[3] =~ /([^:])+$/ )[0]
1061         eq
1062       ( $fr2[3] =~ /([^:])+$/ )[0]
1063     )
1064   )
1065     ? \@fr2
1066     : $fr
1067   ;
1068
1069
1070   die "\nMethod $fr->[3] is not marked with the 'DBIC_method_is_indirect_sugar' attribute\n\n" unless (
1071
1072     # unlikely but who knows...
1073     ! @$fr
1074
1075       or
1076
1077     # This is a weird-ass double-purpose method, only one branch of which is marked
1078     # as an illegal indirect call
1079     # Hence the 'indirect' attribute makes no sense
1080     # FIXME - likely need to mark this in some other manner
1081     $fr->[3] eq 'DBIx::Class::ResultSet::new'
1082
1083       or
1084
1085     # RsrcProxy stuff is special and not attr-annotated on purpose
1086     # Yet it is marked (correctly) as fail_on_internal_call(), as DBIC
1087     # itself should not call these methods as first-entry
1088     $fr->[3] =~ /^DBIx::Class::ResultSourceProxy::[^:]+$/
1089
1090       or
1091
1092     # FIXME - there is likely a more fine-graned way to escape "foreign"
1093     # callers, based on annotations... (albeit a slower one)
1094     # For the time being just skip in a dumb way
1095     $fr->[3] !~ /^DBIx::Class|^DBICx::|^DBICTest::/
1096
1097       or
1098
1099     grep
1100       { $_ eq 'DBIC_method_is_indirect_sugar' }
1101       do { no strict 'refs'; attributes::get( \&{ $fr->[3] }) }
1102   );
1103
1104
1105   if (
1106     defined $fr->[0]
1107       and
1108     $check_fr->[0] =~ /^(?:DBIx::Class|DBICx::)/
1109       and
1110     $check_fr->[1] !~ /\b(?:CDBICompat|ResultSetProxy)\b/  # no point touching there
1111   ) {
1112     DBIx::Class::Exception->throw( sprintf (
1113       "Illegal internal call of indirect proxy-method %s() with argument '%s': examine the last lines of the proxy method deparse below to determine what to call directly instead at %s on line %d\n\n%s\n\n    Stacktrace starts",
1114       $fr->[3], $argdesc, @{$fr}[1,2], ( $fr->[6] || do {
1115         require B::Deparse;
1116         no strict 'refs';
1117         B::Deparse->new->coderef2text(\&{$fr->[3]})
1118       }),
1119     ), 'with_stacktrace');
1120   }
1121 }
1122
1123 if (DBIx::Class::_ENV_::ASSERT_NO_ERRONEOUS_METAINSTANCE_USE) {
1124
1125   no warnings 'redefine';
1126
1127   my $next_bless = defined(&CORE::GLOBAL::bless)
1128     ? \&CORE::GLOBAL::bless
1129     : sub { CORE::bless($_[0], $_[1]) }
1130   ;
1131
1132   *CORE::GLOBAL::bless = sub {
1133     my $class = (@_ > 1) ? $_[1] : CORE::caller();
1134
1135     # allow for reblessing (role application)
1136     return $next_bless->( $_[0], $class )
1137       if defined blessed $_[0];
1138
1139     my $obj = $next_bless->( $_[0], $class );
1140
1141     my $calling_sub = (CORE::caller(1))[3] || '';
1142
1143     (
1144       # before 5.18 ->isa() will choke on the "0" package
1145       # which we test for in several obscure cases, sigh...
1146       !( DBIx::Class::_ENV_::PERL_VERSION < 5.018 )
1147         or
1148       $class
1149     )
1150       and
1151     (
1152       (
1153         $calling_sub !~ /^ (?:
1154           DBIx::Class::Schema::clone
1155             |
1156           DBIx::Class::DB::setup_schema_instance
1157         )/x
1158           and
1159         $class->isa("DBIx::Class::Schema")
1160       )
1161         or
1162       (
1163         $calling_sub ne 'DBIx::Class::ResultSource::new'
1164           and
1165         $class->isa("DBIx::Class::ResultSource")
1166       )
1167     )
1168       and
1169     local $Carp::CarpLevel = $Carp::CarpLevel + 1
1170       and
1171     Carp::confess("Improper instantiation of '$obj': you *MUST* call the corresponding constructor");
1172
1173
1174     $obj;
1175   };
1176 }
1177
1178 1;