lib/DBIx/Class/_Util.pm

   1 package # hide from PAUSE
   2   DBIx::Class::_Util;
   3
   4 use DBIx::Class::StartupCheck;  # load es early as we can, usually a noop
   5
   6 use warnings;
   7 use strict;
   8
   9 use constant SPURIOUS_VERSION_CHECK_WARNINGS => ( "$]" < 5.010 ? 1 : 0);
  10
  11 BEGIN {
  12   package # hide from pause
  13     DBIx::Class::_ENV_;
  14
  15   use Config;
  16
  17   use constant {
  18
  19     # but of course
  20     BROKEN_FORK => ($^O eq 'MSWin32') ? 1 : 0,
  21
  22     BROKEN_GOTO => ( "$]" < 5.008003 ) ? 1 : 0,
  23
  24     HAS_ITHREADS => $Config{useithreads} ? 1 : 0,
  25
  26     UNSTABLE_DOLLARAT => ( "$]" < 5.013002 ) ? 1 : 0,
  27
  28     ( map
  29       #
  30       # the "DBIC_" prefix below is crucial - this is what makes CI pick up
  31       # all envvars without further adjusting its scripts
  32       # DO NOT CHANGE to the more logical { $_ => !!( $ENV{"DBIC_$_"} ) }
  33       #
  34       { substr($_, 5) => !!( $ENV{$_} ) }
  35       qw(
  36         DBIC_SHUFFLE_UNORDERED_RESULTSETS
  37         DBIC_ASSERT_NO_INTERNAL_WANTARRAY
  38         DBIC_ASSERT_NO_INTERNAL_INDIRECT_CALLS
  39         DBIC_STRESSTEST_UTF8_UPGRADE_GENERATED_COLLAPSER_SOURCE
  40         DBIC_STRESSTEST_COLUMN_INFO_UNAWARE_STORAGE
  41       )
  42     ),
  43
  44     IV_SIZE => $Config{ivsize},
  45
  46     OS_NAME => $^O,
  47   };
  48
  49   if ( "$]" < 5.009_005) {
  50     require MRO::Compat;
  51     constant->import( OLD_MRO => 1 );
  52   }
  53   else {
  54     require mro;
  55     constant->import( OLD_MRO => 0 );
  56   }
  57
  58   # Both of these are no longer used for anything. However bring
  59   # them back after they were purged in 08a8d8f1, as there appear
  60   # to be outfits with *COPY PASTED* pieces of lib/DBIx/Class/Storage/*
  61   # in their production codebases. There is no point in breaking these
  62   # if whatever they used actually continues to work
  63   my $warned;
  64   my $sigh = sub {
  65
  66     require Carp;
  67     my $cluck = "The @{[ (caller(1))[3] ]} constant is no more - adjust your code" . Carp::longmess();
  68
  69     warn $cluck unless $warned->{$cluck}++;
  70
  71     0;
  72   };
  73   sub DBICTEST () { &$sigh }
  74   sub PEEPEENESS () { &$sigh }
  75 }
  76
  77 # FIXME - this is not supposed to be here
  78 # Carp::Skip to the rescue soon
  79 use DBIx::Class::Carp '^DBIx::Class|^DBICTest';
  80
  81 use B ();
  82 use Carp 'croak';
  83 use Storable 'nfreeze';
  84 use Scalar::Util qw(weaken blessed reftype refaddr);
  85 use Sub::Quote qw(qsub quote_sub);
  86 use Sub::Name ();
  87
  88 # Already correctly prototyped: perlbrew exec perl -MStorable -e 'warn prototype \&Storable::dclone'
  89 BEGIN { *deep_clone = \&Storable::dclone }
  90
  91 use base 'Exporter';
  92 our @EXPORT_OK = qw(
  93   sigwarn_silencer modver_gt_or_eq modver_gt_or_eq_and_lt
  94   fail_on_internal_wantarray fail_on_internal_call
  95   refdesc refcount hrefaddr set_subname
  96   scope_guard detected_reinvoked_destructor
  97   is_exception dbic_internal_try
  98   quote_sub qsub perlstring serialize deep_clone dump_value
  99   parent_dir mkdir_p
 100   UNRESOLVABLE_CONDITION
 101 );
 102
 103 use constant UNRESOLVABLE_CONDITION => \ '1 = 0';
 104
 105 sub sigwarn_silencer ($) {
 106   my $pattern = shift;
 107
 108   croak "Expecting a regexp" if ref $pattern ne 'Regexp';
 109
 110   my $orig_sig_warn = $SIG{__WARN__} || sub { CORE::warn(@_) };
 111
 112   return sub { &$orig_sig_warn unless $_[0] =~ $pattern };
 113 }
 114
 115 sub perlstring ($) { q{"}. quotemeta( shift ). q{"} };
 116
 117 sub hrefaddr ($) { sprintf '0x%x', &refaddr||0 }
 118
 119 sub refdesc ($) {
 120   croak "Expecting a reference" if ! length ref $_[0];
 121
 122   # be careful not to trigger stringification,
 123   # reuse @_ as a scratch-pad
 124   sprintf '%s%s(0x%x)',
 125     ( defined( $_[1] = blessed $_[0]) ? "$_[1]=" : '' ),
 126     reftype $_[0],
 127     refaddr($_[0]),
 128   ;
 129 }
 130
 131 sub refcount ($) {
 132   croak "Expecting a reference" if ! length ref $_[0];
 133
 134   # No tempvars - must operate on $_[0], otherwise the pad
 135   # will count as an extra ref
 136   B::svref_2object($_[0])->REFCNT;
 137 }
 138
 139 # FIXME In another life switch this to a polyfill like the one in namespace::clean
 140 sub set_subname ($$) {
 141
 142   # fully qualify name
 143   splice @_, 0, 1, caller(0) . "::$_[0]"
 144     if $_[0] !~ /::|'/;
 145
 146   &Sub::Name::subname;
 147 }
 148
 149 sub serialize ($) {
 150   local $Storable::canonical = 1;
 151   nfreeze($_[0]);
 152 }
 153
 154 my $dd_obj;
 155 sub dump_value ($) {
 156   local $Data::Dumper::Indent = 1
 157     unless defined $Data::Dumper::Indent;
 158
 159   my $dump_str = (
 160     $dd_obj
 161       ||=
 162     do {
 163       require Data::Dumper;
 164       my $d = Data::Dumper->new([])
 165         ->Purity(0)
 166         ->Pad('')
 167         ->Useqq(1)
 168         ->Terse(1)
 169         ->Freezer('')
 170         ->Quotekeys(0)
 171         ->Bless('bless')
 172         ->Pair(' => ')
 173         ->Sortkeys(1)
 174         ->Deparse(1)
 175       ;
 176
 177       $d->Sparseseen(1) if modver_gt_or_eq (
 178         'Data::Dumper', '2.136'
 179       );
 180
 181       $d;
 182     }
 183   )->Values([$_[0]])->Dump;
 184
 185   $dd_obj->Reset->Values([]);
 186
 187   $dump_str;
 188 }
 189
 190 sub scope_guard (&) {
 191   croak 'Calling scope_guard() in void context makes no sense'
 192     if ! defined wantarray;
 193
 194   # no direct blessing of coderefs - DESTROY is buggy on those
 195   bless [ $_[0] ], 'DBIx::Class::_Util::ScopeGuard';
 196 }
 197 {
 198   package #
 199     DBIx::Class::_Util::ScopeGuard;
 200
 201   sub DESTROY {
 202     &DBIx::Class::_Util::detected_reinvoked_destructor;
 203
 204     local $@ if DBIx::Class::_ENV_::UNSTABLE_DOLLARAT;
 205
 206     eval {
 207       $_[0]->[0]->();
 208       1;
 209     }
 210       or
 211     Carp::cluck(
 212       "Execution of scope guard $_[0] resulted in the non-trappable exception:\n\n$@"
 213     );
 214   }
 215 }
 216
 217
 218 sub is_exception ($) {
 219   my $e = $_[0];
 220
 221   # FIXME
 222   # this is not strictly correct - an eval setting $@ to undef
 223   # is *not* the same as an eval setting $@ to ''
 224   # but for the sake of simplicity assume the following for
 225   # the time being
 226   return 0 unless defined $e;
 227
 228   my ($not_blank, $suberror);
 229   {
 230     local $SIG{__DIE__} if $SIG{__DIE__};
 231     local $@;
 232     eval {
 233       # The ne() here is deliberate - a plain length($e), or worse "$e" ne
 234       # will entirely obviate the need for the encolsing eval{}, as the
 235       # condition we guard against is a missing fallback overload
 236       $not_blank = ( $e ne '' );
 237       1;
 238     } or $suberror = $@;
 239   }
 240
 241   if (defined $suberror) {
 242     if (length (my $class = blessed($e) )) {
 243       carp_unique( sprintf(
 244         'External exception class %s implements partial (broken) overloading '
 245       . 'preventing its instances from being used in simple ($x eq $y) '
 246       . 'comparisons. Given Perl\'s "globally cooperative" exception '
 247       . 'handling this type of brokenness is extremely dangerous on '
 248       . 'exception objects, as it may (and often does) result in silent '
 249       . '"exception substitution". DBIx::Class tries to work around this '
 250       . 'as much as possible, but other parts of your software stack may '
 251       . 'not be even aware of this. Please submit a bugreport against the '
 252       . 'distribution containing %s and in the meantime apply a fix similar '
 253       . 'to the one shown at %s, in order to ensure your exception handling '
 254       . 'is saner application-wide. What follows is the actual error text '
 255       . "as generated by Perl itself:\n\n%s\n ",
 256         $class,
 257         $class,
 258         'http://v.gd/DBIC_overload_tempfix/',
 259         $suberror,
 260       ));
 261
 262       # workaround, keeps spice flowing
 263       $not_blank = !!( length $e );
 264     }
 265     else {
 266       # not blessed yet failed the 'ne'... this makes 0 sense...
 267       # just throw further
 268       die $suberror
 269     }
 270   }
 271   elsif (
 272     # a ref evaluating to '' is definitively a "null object"
 273     ( not $not_blank )
 274       and
 275     length( my $class = ref $e )
 276   ) {
 277     carp_unique( sprintf(
 278       "Objects of external exception class '%s' stringify to '' (the "
 279     . 'empty string), implementing the so called null-object-pattern. '
 280     . 'Given Perl\'s "globally cooperative" exception handling using this '
 281     . 'class of exceptions is extremely dangerous, as it may (and often '
 282     . 'does) result in silent discarding of errors. DBIx::Class tries to '
 283     . 'work around this as much as possible, but other parts of your '
 284     . 'software stack may not be even aware of the problem. Please submit '
 285     . 'a bugreport against the distribution containing %s',
 286
 287       ($class) x 2,
 288     ));
 289
 290     $not_blank = 1;
 291   }
 292
 293   return $not_blank;
 294 }
 295
 296 {
 297   my $callstack_state;
 298
 299   # Recreate the logic of try(), while reusing the catch()/finally() as-is
 300   #
 301   # FIXME: We need to move away from Try::Tiny entirely (way too heavy and
 302   # yes, shows up ON TOP of profiles) but this is a batle for another maint
 303   sub dbic_internal_try (&;@) {
 304
 305     my $try_cref = shift;
 306     my $catch_cref = undef;  # apparently this is a thing... https://rt.perl.org/Public/Bug/Display.html?id=119311
 307
 308     for my $arg (@_) {
 309
 310       if( ref($arg) eq 'Try::Tiny::Catch' ) {
 311
 312         croak 'dbic_internal_try() may not be followed by multiple catch() blocks'
 313           if $catch_cref;
 314
 315         $catch_cref = $$arg;
 316       }
 317       elsif ( ref($arg) eq 'Try::Tiny::Finally' ) {
 318         croak 'dbic_internal_try() does not support finally{}';
 319       }
 320       else {
 321         croak(
 322           'dbic_internal_try() encountered an unexpected argument '
 323         . "'@{[ defined $arg ? $arg : 'UNDEF' ]}' - perhaps "
 324         . 'a missing semi-colon before or ' # trailing space important
 325         );
 326       }
 327     }
 328
 329     my $wantarray = wantarray;
 330     my $preexisting_exception = $@;
 331
 332     my @ret;
 333     my $all_good = eval {
 334       $@ = $preexisting_exception;
 335
 336       local $callstack_state->{in_internal_try} = 1
 337         unless $callstack_state->{in_internal_try};
 338
 339       # always unset - someone may have snuck it in
 340       local $SIG{__DIE__} if $SIG{__DIE__};
 341
 342       if( $wantarray ) {
 343         @ret = $try_cref->();
 344       }
 345       elsif( defined $wantarray ) {
 346         $ret[0] = $try_cref->();
 347       }
 348       else {
 349         $try_cref->();
 350       }
 351
 352       1;
 353     };
 354
 355     my $exception = $@;
 356     $@ = $preexisting_exception;
 357
 358     if ( $all_good ) {
 359       return $wantarray ? @ret : $ret[0]
 360     }
 361     elsif ( $catch_cref ) {
 362       for ( $exception ) {
 363         return $catch_cref->($exception);
 364       }
 365     }
 366
 367     return;
 368   }
 369
 370   sub in_internal_try { !! $callstack_state->{in_internal_try} }
 371 }
 372
 373 {
 374   my $destruction_registry = {};
 375
 376   sub CLONE {
 377     %$destruction_registry = map {
 378       (defined $_)
 379         ? ( refaddr($_) => $_ )
 380         : ()
 381     } values %$destruction_registry;
 382
 383     weaken($_) for values %$destruction_registry;
 384
 385     # Dummy NEXTSTATE ensuring the all temporaries on the stack are garbage
 386     # collected before leaving this scope. Depending on the code above, this
 387     # may very well be just a preventive measure guarding future modifications
 388     undef;
 389   }
 390
 391   # This is almost invariably invoked from within DESTROY
 392   # throwing exceptions won't work
 393   sub detected_reinvoked_destructor {
 394
 395     # quick "garbage collection" pass - prevents the registry
 396     # from slowly growing with a bunch of undef-valued keys
 397     defined $destruction_registry->{$_} or delete $destruction_registry->{$_}
 398       for keys %$destruction_registry;
 399
 400     if (! length ref $_[0]) {
 401       printf STDERR '%s() expects a blessed reference %s',
 402         (caller(0))[3],
 403         Carp::longmess,
 404       ;
 405       return undef; # don't know wtf to do
 406     }
 407     elsif (! defined $destruction_registry->{ my $addr = refaddr($_[0]) } ) {
 408       weaken( $destruction_registry->{$addr} = $_[0] );
 409       return 0;
 410     }
 411     else {
 412       carp_unique ( sprintf (
 413         'Preventing *MULTIPLE* DESTROY() invocations on %s - an *EXTREMELY '
 414       . 'DANGEROUS* condition which is *ALMOST CERTAINLY GLOBAL* within your '
 415       . 'application, affecting *ALL* classes without active protection against '
 416       . 'this. Diagnose and fix the root cause ASAP!!!%s',
 417       refdesc $_[0],
 418         ( ( $INC{'Devel/StackTrace.pm'} and ! do { local $@; eval { Devel::StackTrace->VERSION(2) } } )
 419           ? " (likely culprit Devel::StackTrace\@@{[ Devel::StackTrace->VERSION ]} found in %INC, http://is.gd/D_ST_refcap)"
 420           : ''
 421         )
 422       ));
 423
 424       return 1;
 425     }
 426   }
 427 }
 428
 429 my $module_name_rx = qr/ \A [A-Z_a-z] [0-9A-Z_a-z]* (?: :: [0-9A-Z_a-z]+ )* \z /x;
 430 my $ver_rx =         qr/ \A [0-9]+ (?: \. [0-9]+ )* (?: \_ [0-9]+ )*        \z /x;
 431
 432 sub modver_gt_or_eq ($$) {
 433   my ($mod, $ver) = @_;
 434
 435   croak "Nonsensical module name supplied"
 436     if ! defined $mod or $mod !~ $module_name_rx;
 437
 438   croak "Nonsensical minimum version supplied"
 439     if ! defined $ver or $ver !~ $ver_rx;
 440
 441   no strict 'refs';
 442   my $ver_cache = ${"${mod}::__DBIC_MODULE_VERSION_CHECKS__"} ||= ( $mod->VERSION
 443     ? {}
 444     : croak "$mod does not seem to provide a version (perhaps it never loaded)"
 445   );
 446
 447   ! defined $ver_cache->{$ver}
 448     and
 449   $ver_cache->{$ver} = do {
 450
 451     local $SIG{__WARN__} = sigwarn_silencer( qr/\Qisn't numeric in subroutine entry/ )
 452       if SPURIOUS_VERSION_CHECK_WARNINGS;
 453
 454     local $SIG{__DIE__} if $SIG{__DIE__};
 455     local $@;
 456     eval { $mod->VERSION($ver) } ? 1 : 0;
 457   };
 458
 459   $ver_cache->{$ver};
 460 }
 461
 462 sub modver_gt_or_eq_and_lt ($$$) {
 463   my ($mod, $v_ge, $v_lt) = @_;
 464
 465   croak "Nonsensical maximum version supplied"
 466     if ! defined $v_lt or $v_lt !~ $ver_rx;
 467
 468   return (
 469     modver_gt_or_eq($mod, $v_ge)
 470       and
 471     ! modver_gt_or_eq($mod, $v_lt)
 472   ) ? 1 : 0;
 473 }
 474
 475
 476 #
 477 # Why not just use some higher-level module or at least File::Spec here?
 478 # Because:
 479 # 1)  This is a *very* rarely used function, and the deptree is large
 480 #     enough already as it is
 481 #
 482 # 2)  (more importantly) Our tooling is utter shit in this area. There
 483 #     is no comprehensive support for UNC paths in PathTools and there
 484 #     are also various small bugs in representation across different
 485 #     path-manipulation CPAN offerings.
 486 #
 487 # Since this routine is strictly used for logical path processing (it
 488 # *must* be able to work with not-yet-existing paths), use this seemingly
 489 # simple but I *think* complete implementation to feed to other consumers
 490 #
 491 # If bugs are ever uncovered in this routine, *YOU ARE URGED TO RESIST*
 492 # the impulse to bring in an external dependency. During runtime there
 493 # is exactly one spot that could potentially maybe once in a blue moon
 494 # use this function. Keep it lean.
 495 #
 496 sub parent_dir ($) {
 497   ( $_[0] =~ m{  [\/\\]  ( \.{0,2} ) ( [\/\\]* ) \z }x )
 498     ? (
 499       $_[0]
 500         .
 501       ( ( length($1) and ! length($2) ) ? '/' : '' )
 502         .
 503       '../'
 504     )
 505     : (
 506       require File::Spec
 507         and
 508       File::Spec->catpath (
 509         ( File::Spec->splitpath( "$_[0]" ) )[0,1],
 510         '/',
 511       )
 512     )
 513   ;
 514 }
 515
 516 sub mkdir_p ($) {
 517   require File::Path;
 518   # do not ask for a recent version, use 1.x API calls
 519   File::Path::mkpath([ "$_[0]" ]);  # File::Path does not like objects
 520 }
 521
 522
 523 {
 524   my $list_ctx_ok_stack_marker;
 525
 526   sub fail_on_internal_wantarray () {
 527     return if $list_ctx_ok_stack_marker;
 528
 529     if (! defined wantarray) {
 530       croak('fail_on_internal_wantarray() needs a tempvar to save the stack marker guard');
 531     }
 532
 533     my $cf = 1;
 534     while ( ( (CORE::caller($cf+1))[3] || '' ) =~ / :: (?:
 535
 536       # these are public API parts that alter behavior on wantarray
 537       search | search_related | slice | search_literal
 538
 539         |
 540
 541       # these are explicitly prefixed, since we only recognize them as valid
 542       # escapes when they come from the guts of CDBICompat
 543       CDBICompat .*? :: (?: search_where | retrieve_from_sql | retrieve_all )
 544
 545     ) $/x ) {
 546       $cf++;
 547     }
 548
 549     my ($fr, $want, $argdesc);
 550     {
 551       package DB;
 552       $fr = [ CORE::caller($cf) ];
 553       $want = ( CORE::caller($cf-1) )[5];
 554       $argdesc = ref $DB::args[0]
 555         ? DBIx::Class::_Util::refdesc($DB::args[0])
 556         : 'non '
 557       ;
 558     };
 559
 560     if (
 561       $want and $fr->[0] =~ /^(?:DBIx::Class|DBICx::)/
 562     ) {
 563       DBIx::Class::Exception->throw( sprintf (
 564         "Improper use of %s instance in list context at %s line %d\n\n    Stacktrace starts",
 565         $argdesc, @{$fr}[1,2]
 566       ), 'with_stacktrace');
 567     }
 568
 569     weaken( $list_ctx_ok_stack_marker = my $mark = [] );
 570
 571     $mark;
 572   }
 573 }
 574
 575 sub fail_on_internal_call {
 576   my ($fr, $argdesc);
 577   {
 578     package DB;
 579     $fr = [ CORE::caller(1) ];
 580     $argdesc = ref $DB::args[0]
 581       ? DBIx::Class::_Util::refdesc($DB::args[0])
 582       : ( $DB::args[0] . '' )
 583     ;
 584   };
 585
 586   if (
 587     $argdesc
 588       and
 589     $fr->[0] =~ /^(?:DBIx::Class|DBICx::)/
 590       and
 591     $fr->[1] !~ /\b(?:CDBICompat|ResultSetProxy)\b/  # no point touching there
 592   ) {
 593     DBIx::Class::Exception->throw( sprintf (
 594       "Illegal internal call of indirect proxy-method %s() with argument '%s': examine the last lines of the proxy method deparse below to determine what to call directly instead at %s on line %d\n\n%s\n\n    Stacktrace starts",
 595       $fr->[3], $argdesc, @{$fr}[1,2], ( $fr->[6] || do {
 596         require B::Deparse;
 597         no strict 'refs';
 598         B::Deparse->new->coderef2text(\&{$fr->[3]})
 599       }),
 600     ), 'with_stacktrace');
 601   }
 602 }
 603
 604 1;