lib/DBIx/Class/_Util.pm

   1 package # hide from PAUSE
   2   DBIx::Class::_Util;
   3
   4 use warnings;
   5 use strict;
   6
   7 use constant SPURIOUS_VERSION_CHECK_WARNINGS => ($] < 5.010 ? 1 : 0);
   8
   9 BEGIN {
  10   package # hide from pause
  11     DBIx::Class::_ENV_;
  12
  13   use Config;
  14
  15   use constant {
  16
  17     # but of course
  18     BROKEN_FORK => ($^O eq 'MSWin32') ? 1 : 0,
  19
  20     BROKEN_GOTO => ($] < '5.008003') ? 1 : 0,
  21
  22     HAS_ITHREADS => $Config{useithreads} ? 1 : 0,
  23
  24     # ::Runmode would only be loaded by DBICTest, which in turn implies t/
  25     DBICTEST => eval { DBICTest::RunMode->is_author } ? 1 : 0,
  26
  27     # During 5.13 dev cycle HELEMs started to leak on copy
  28     # add an escape for these perls ON SMOKERS - a user will still get death
  29     PEEPEENESS => ( eval { DBICTest::RunMode->is_smoker } && ($] >= 5.013005 and $] <= 5.013006) ),
  30
  31     SHUFFLE_UNORDERED_RESULTSETS => $ENV{DBIC_SHUFFLE_UNORDERED_RESULTSETS} ? 1 : 0,
  32
  33     ASSERT_NO_INTERNAL_WANTARRAY => $ENV{DBIC_ASSERT_NO_INTERNAL_WANTARRAY} ? 1 : 0,
  34
  35     ASSERT_NO_INTERNAL_INDIRECT_CALLS => $ENV{DBIC_ASSERT_NO_INTERNAL_INDIRECT_CALLS} ? 1 : 0,
  36
  37     STRESSTEST_UTF8_UPGRADE_GENERATED_COLLAPSER_SOURCE => $ENV{DBIC_STRESSTEST_UTF8_UPGRADE_GENERATED_COLLAPSER_SOURCE} ? 1 : 0,
  38
  39     STRESSTEST_COLUMN_INFO_UNAWARE_STORAGE => $ENV{DBIC_STRESSTEST_COLUMN_INFO_UNAWARE_STORAGE} ? 1 : 0,
  40
  41     IV_SIZE => $Config{ivsize},
  42
  43     OS_NAME => $^O,
  44   };
  45
  46   if ($] < 5.009_005) {
  47     require MRO::Compat;
  48     constant->import( OLD_MRO => 1 );
  49   }
  50   else {
  51     require mro;
  52     constant->import( OLD_MRO => 0 );
  53   }
  54 }
  55
  56 # FIXME - this is not supposed to be here
  57 # Carp::Skip to the rescue soon
  58 use DBIx::Class::Carp '^DBIx::Class|^DBICTest';
  59
  60 use B ();
  61 use Carp 'croak';
  62 use Storable 'nfreeze';
  63 use Scalar::Util qw(weaken blessed reftype refaddr);
  64 use List::Util qw(first);
  65 use Sub::Quote qw(qsub quote_sub);
  66
  67 # Already correctly prototyped: perlbrew exec perl -MStorable -e 'warn prototype \&Storable::dclone'
  68 BEGIN { *deep_clone = \&Storable::dclone }
  69
  70 use base 'Exporter';
  71 our @EXPORT_OK = qw(
  72   sigwarn_silencer modver_gt_or_eq modver_gt_or_eq_and_lt
  73   fail_on_internal_wantarray fail_on_internal_call
  74   refdesc refcount hrefaddr is_exception detected_reinvoked_destructor
  75   quote_sub qsub perlstring serialize deep_clone
  76   UNRESOLVABLE_CONDITION
  77 );
  78
  79 use constant UNRESOLVABLE_CONDITION => \ '1 = 0';
  80
  81 sub sigwarn_silencer ($) {
  82   my $pattern = shift;
  83
  84   croak "Expecting a regexp" if ref $pattern ne 'Regexp';
  85
  86   my $orig_sig_warn = $SIG{__WARN__} || sub { CORE::warn(@_) };
  87
  88   return sub { &$orig_sig_warn unless $_[0] =~ $pattern };
  89 }
  90
  91 sub perlstring ($) { q{"}. quotemeta( shift ). q{"} };
  92
  93 sub hrefaddr ($) { sprintf '0x%x', &refaddr||0 }
  94
  95 sub refdesc ($) {
  96   croak "Expecting a reference" if ! length ref $_[0];
  97
  98   # be careful not to trigger stringification,
  99   # reuse @_ as a scratch-pad
 100   sprintf '%s%s(0x%x)',
 101     ( defined( $_[1] = blessed $_[0]) ? "$_[1]=" : '' ),
 102     reftype $_[0],
 103     refaddr($_[0]),
 104   ;
 105 }
 106
 107 sub refcount ($) {
 108   croak "Expecting a reference" if ! length ref $_[0];
 109
 110   # No tempvars - must operate on $_[0], otherwise the pad
 111   # will count as an extra ref
 112   B::svref_2object($_[0])->REFCNT;
 113 }
 114
 115 sub serialize ($) {
 116   local $Storable::canonical = 1;
 117   nfreeze($_[0]);
 118 }
 119
 120 sub is_exception ($) {
 121   my $e = $_[0];
 122
 123   # this is not strictly correct - an eval setting $@ to undef
 124   # is *not* the same as an eval setting $@ to ''
 125   # but for the sake of simplicity assume the following for
 126   # the time being
 127   return 0 unless defined $e;
 128
 129   my ($not_blank, $suberror);
 130   {
 131     local $@;
 132     eval {
 133       $not_blank = ($e ne '') ? 1 : 0;
 134       1;
 135     } or $suberror = $@;
 136   }
 137
 138   if (defined $suberror) {
 139     if (length (my $class = blessed($e) )) {
 140       carp_unique( sprintf(
 141         'External exception class %s implements partial (broken) overloading '
 142       . 'preventing its instances from being used in simple ($x eq $y) '
 143       . 'comparisons. Given Perl\'s "globally cooperative" exception '
 144       . 'handling this type of brokenness is extremely dangerous on '
 145       . 'exception objects, as it may (and often does) result in silent '
 146       . '"exception substitution". DBIx::Class tries to work around this '
 147       . 'as much as possible, but other parts of your software stack may '
 148       . 'not be even aware of this. Please submit a bugreport against the '
 149       . 'distribution containing %s and in the meantime apply a fix similar '
 150       . 'to the one shown at %s, in order to ensure your exception handling '
 151       . 'is saner application-wide. What follows is the actual error text '
 152       . "as generated by Perl itself:\n\n%s\n ",
 153         $class,
 154         $class,
 155         'http://v.gd/DBIC_overload_tempfix/',
 156         $suberror,
 157       ));
 158
 159       # workaround, keeps spice flowing
 160       $not_blank = ("$e" ne '') ? 1 : 0;
 161     }
 162     else {
 163       # not blessed yet failed the 'ne'... this makes 0 sense...
 164       # just throw further
 165       die $suberror
 166     }
 167   }
 168   elsif (
 169     # a ref evaluating to '' is definitively a "null object"
 170     ( not $not_blank )
 171       and
 172     length( my $class = ref $e )
 173   ) {
 174     carp_unique( sprintf(
 175       "Objects of external exception class '%s' stringify to '' (the "
 176     . 'empty string), implementing the so called null-object-pattern. '
 177     . 'Given Perl\'s "globally cooperative" exception handling using this '
 178     . 'class of exceptions is extremely dangerous, as it may (and often '
 179     . 'does) result in silent discarding of errors. DBIx::Class tries to '
 180     . 'work around this as much as possible, but other parts of your '
 181     . 'software stack may not be even aware of the problem. Please submit '
 182     . 'a bugreport against the distribution containing %s.',
 183
 184       ($class) x 2,
 185     ));
 186
 187     $not_blank = 1;
 188   }
 189
 190   return $not_blank;
 191 }
 192
 193 {
 194   my $destruction_registry = {};
 195
 196   sub CLONE {
 197     $destruction_registry = { map
 198       { defined $_ ? ( refaddr($_) => $_ ) : () }
 199       values %$destruction_registry
 200     };
 201   }
 202
 203   # This is almost invariably invoked from within DESTROY
 204   # throwing exceptions won't work
 205   sub detected_reinvoked_destructor {
 206
 207     # quick "garbage collection" pass - prevents the registry
 208     # from slowly growing with a bunch of undef-valued keys
 209     defined $destruction_registry->{$_} or delete $destruction_registry->{$_}
 210       for keys %$destruction_registry;
 211
 212     if (! length ref $_[0]) {
 213       printf STDERR '%s() expects a blessed reference %s',
 214         (caller(0))[3],
 215         Carp::longmess,
 216       ;
 217       return undef; # don't know wtf to do
 218     }
 219     elsif (! defined $destruction_registry->{ my $addr = refaddr($_[0]) } ) {
 220       weaken( $destruction_registry->{$addr} = $_[0] );
 221       return 0;
 222     }
 223     else {
 224       carp_unique ( sprintf (
 225         'Preventing *MULTIPLE* DESTROY() invocations on %s - an *EXTREMELY '
 226       . 'DANGEROUS* condition which is *ALMOST CERTAINLY GLOBAL* within your '
 227       . 'application, affecting *ALL* classes without active protection against '
 228       . 'this. Diagnose and fix the root cause ASAP!!!%s',
 229       refdesc $_[0],
 230         ( ( $INC{'Devel/StackTrace.pm'} and ! do { local $@; eval { Devel::StackTrace->VERSION(2) } } )
 231           ? " (likely culprit Devel::StackTrace\@@{[ Devel::StackTrace->VERSION ]} found in %INC, http://is.gd/D_ST_refcap)"
 232           : ''
 233         )
 234       ));
 235
 236       return 1;
 237     }
 238   }
 239 }
 240
 241 sub modver_gt_or_eq ($$) {
 242   my ($mod, $ver) = @_;
 243
 244   croak "Nonsensical module name supplied"
 245     if ! defined $mod or ! length $mod;
 246
 247   croak "Nonsensical minimum version supplied"
 248     if ! defined $ver or $ver =~ /[^0-9\.\_]/;
 249
 250   local $SIG{__WARN__} = sigwarn_silencer( qr/\Qisn't numeric in subroutine entry/ )
 251     if SPURIOUS_VERSION_CHECK_WARNINGS;
 252
 253   croak "$mod does not seem to provide a version (perhaps it never loaded)"
 254     unless $mod->VERSION;
 255
 256   local $@;
 257   eval { $mod->VERSION($ver) } ? 1 : 0;
 258 }
 259
 260 sub modver_gt_or_eq_and_lt ($$$) {
 261   my ($mod, $v_ge, $v_lt) = @_;
 262
 263   croak "Nonsensical maximum version supplied"
 264     if ! defined $v_lt or $v_lt =~ /[^0-9\.\_]/;
 265
 266   return (
 267     modver_gt_or_eq($mod, $v_ge)
 268       and
 269     ! modver_gt_or_eq($mod, $v_lt)
 270   ) ? 1 : 0;
 271 }
 272
 273 {
 274   my $list_ctx_ok_stack_marker;
 275
 276   sub fail_on_internal_wantarray () {
 277     return if $list_ctx_ok_stack_marker;
 278
 279     if (! defined wantarray) {
 280       croak('fail_on_internal_wantarray() needs a tempvar to save the stack marker guard');
 281     }
 282
 283     my $cf = 1;
 284     while ( ( (CORE::caller($cf+1))[3] || '' ) =~ / :: (?:
 285
 286       # these are public API parts that alter behavior on wantarray
 287       search | search_related | slice | search_literal
 288
 289         |
 290
 291       # these are explicitly prefixed, since we only recognize them as valid
 292       # escapes when they come from the guts of CDBICompat
 293       CDBICompat .*? :: (?: search_where | retrieve_from_sql | retrieve_all )
 294
 295     ) $/x ) {
 296       $cf++;
 297     }
 298
 299     my ($fr, $want, $argdesc);
 300     {
 301       package DB;
 302       $fr = [ CORE::caller($cf) ];
 303       $want = ( CORE::caller($cf-1) )[5];
 304       $argdesc = ref $DB::args[0]
 305         ? DBIx::Class::_Util::refdesc($DB::args[0])
 306         : 'non '
 307       ;
 308     };
 309
 310     if (
 311       $want and $fr->[0] =~ /^(?:DBIx::Class|DBICx::)/
 312     ) {
 313       DBIx::Class::Exception->throw( sprintf (
 314         "Improper use of %s instance in list context at %s line %d\n\n    Stacktrace starts",
 315         $argdesc, @{$fr}[1,2]
 316       ), 'with_stacktrace');
 317     }
 318
 319     my $mark = [];
 320     weaken ( $list_ctx_ok_stack_marker = $mark );
 321     $mark;
 322   }
 323 }
 324
 325 sub fail_on_internal_call {
 326   my ($fr, $argdesc);
 327   {
 328     package DB;
 329     $fr = [ CORE::caller(1) ];
 330     $argdesc = ref $DB::args[0]
 331       ? DBIx::Class::_Util::refdesc($DB::args[0])
 332       : undef
 333     ;
 334   };
 335
 336   if (
 337     $argdesc
 338       and
 339     $fr->[0] =~ /^(?:DBIx::Class|DBICx::)/
 340       and
 341     $fr->[1] !~ /\b(?:CDBICompat|ResultSetProxy)\b/  # no point touching there
 342   ) {
 343     DBIx::Class::Exception->throw( sprintf (
 344       "Illegal internal call of indirect proxy-method %s() with argument %s: examine the last lines of the proxy method deparse below to determine what to call directly instead at %s on line %d\n\n%s\n\n    Stacktrace starts",
 345       $fr->[3], $argdesc, @{$fr}[1,2], ( $fr->[6] || do {
 346         require B::Deparse;
 347         no strict 'refs';
 348         B::Deparse->new->coderef2text(\&{$fr->[3]})
 349       }),
 350     ), 'with_stacktrace');
 351   }
 352 }
 353
 354 1;