lib/DBIx/Class/_Util.pm

   1 package # hide from PAUSE
   2   DBIx::Class::_Util;
   3
   4 use warnings;
   5 use strict;
   6
   7 use constant SPURIOUS_VERSION_CHECK_WARNINGS => ( "$]" < 5.010 ? 1 : 0);
   8
   9 BEGIN {
  10   package # hide from pause
  11     DBIx::Class::_ENV_;
  12
  13   use Config;
  14
  15   use constant {
  16
  17     # but of course
  18     BROKEN_FORK => ($^O eq 'MSWin32') ? 1 : 0,
  19
  20     BROKEN_GOTO => ( "$]" < 5.008003 ) ? 1 : 0,
  21
  22     HAS_ITHREADS => $Config{useithreads} ? 1 : 0,
  23
  24     UNSTABLE_DOLLARAT => ( "$]" < 5.013002 ) ? 1 : 0,
  25
  26     DBICTEST => $INC{"DBICTest/Util.pm"} ? 1 : 0,
  27
  28     # During 5.13 dev cycle HELEMs started to leak on copy
  29     # add an escape for these perls ON SMOKERS - a user will still get death
  30     PEEPEENESS => ( eval { DBICTest::RunMode->is_smoker } && ( "$]" >= 5.013005 and "$]" <= 5.013006) ),
  31
  32     SHUFFLE_UNORDERED_RESULTSETS => $ENV{DBIC_SHUFFLE_UNORDERED_RESULTSETS} ? 1 : 0,
  33
  34     ASSERT_NO_INTERNAL_WANTARRAY => $ENV{DBIC_ASSERT_NO_INTERNAL_WANTARRAY} ? 1 : 0,
  35
  36     ASSERT_NO_INTERNAL_INDIRECT_CALLS => $ENV{DBIC_ASSERT_NO_INTERNAL_INDIRECT_CALLS} ? 1 : 0,
  37
  38     STRESSTEST_UTF8_UPGRADE_GENERATED_COLLAPSER_SOURCE => $ENV{DBIC_STRESSTEST_UTF8_UPGRADE_GENERATED_COLLAPSER_SOURCE} ? 1 : 0,
  39
  40     STRESSTEST_COLUMN_INFO_UNAWARE_STORAGE => $ENV{DBIC_STRESSTEST_COLUMN_INFO_UNAWARE_STORAGE} ? 1 : 0,
  41
  42     IV_SIZE => $Config{ivsize},
  43
  44     OS_NAME => $^O,
  45   };
  46
  47   if ( "$]" < 5.009_005) {
  48     require MRO::Compat;
  49     constant->import( OLD_MRO => 1 );
  50   }
  51   else {
  52     require mro;
  53     constant->import( OLD_MRO => 0 );
  54   }
  55 }
  56
  57 # FIXME - this is not supposed to be here
  58 # Carp::Skip to the rescue soon
  59 use DBIx::Class::Carp '^DBIx::Class|^DBICTest';
  60
  61 use B ();
  62 use Carp 'croak';
  63 use Storable 'nfreeze';
  64 use Scalar::Util qw(weaken blessed reftype refaddr);
  65 use List::Util qw(first);
  66 use Sub::Quote qw(qsub quote_sub);
  67
  68 # Already correctly prototyped: perlbrew exec perl -MStorable -e 'warn prototype \&Storable::dclone'
  69 BEGIN { *deep_clone = \&Storable::dclone }
  70
  71 use base 'Exporter';
  72 our @EXPORT_OK = qw(
  73   sigwarn_silencer modver_gt_or_eq modver_gt_or_eq_and_lt
  74   fail_on_internal_wantarray fail_on_internal_call
  75   refdesc refcount hrefaddr
  76   scope_guard is_exception detected_reinvoked_destructor
  77   quote_sub qsub perlstring serialize deep_clone
  78   UNRESOLVABLE_CONDITION
  79 );
  80
  81 use constant UNRESOLVABLE_CONDITION => \ '1 = 0';
  82
  83 sub sigwarn_silencer ($) {
  84   my $pattern = shift;
  85
  86   croak "Expecting a regexp" if ref $pattern ne 'Regexp';
  87
  88   my $orig_sig_warn = $SIG{__WARN__} || sub { CORE::warn(@_) };
  89
  90   return sub { &$orig_sig_warn unless $_[0] =~ $pattern };
  91 }
  92
  93 sub perlstring ($) { q{"}. quotemeta( shift ). q{"} };
  94
  95 sub hrefaddr ($) { sprintf '0x%x', &refaddr||0 }
  96
  97 sub refdesc ($) {
  98   croak "Expecting a reference" if ! length ref $_[0];
  99
 100   # be careful not to trigger stringification,
 101   # reuse @_ as a scratch-pad
 102   sprintf '%s%s(0x%x)',
 103     ( defined( $_[1] = blessed $_[0]) ? "$_[1]=" : '' ),
 104     reftype $_[0],
 105     refaddr($_[0]),
 106   ;
 107 }
 108
 109 sub refcount ($) {
 110   croak "Expecting a reference" if ! length ref $_[0];
 111
 112   # No tempvars - must operate on $_[0], otherwise the pad
 113   # will count as an extra ref
 114   B::svref_2object($_[0])->REFCNT;
 115 }
 116
 117 sub serialize ($) {
 118   local $Storable::canonical = 1;
 119   nfreeze($_[0]);
 120 }
 121
 122 sub scope_guard (&) {
 123   croak 'Calling scope_guard() in void context makes no sense'
 124     if ! defined wantarray;
 125
 126   # no direct blessing of coderefs - DESTROY is buggy on those
 127   bless [ $_[0] ], 'DBIx::Class::_Util::ScopeGuard';
 128 }
 129 {
 130   package #
 131     DBIx::Class::_Util::ScopeGuard;
 132
 133   sub DESTROY {
 134     &DBIx::Class::_Util::detected_reinvoked_destructor;
 135
 136     local $@ if DBIx::Class::_ENV_::UNSTABLE_DOLLARAT;
 137
 138     eval {
 139       $_[0]->[0]->();
 140       1;
 141     } or do {
 142       Carp::cluck "Execution of scope guard $_[0] resulted in the non-trappable exception:\n\n$@";
 143     };
 144   }
 145 }
 146
 147
 148 sub is_exception ($) {
 149   my $e = $_[0];
 150
 151   # this is not strictly correct - an eval setting $@ to undef
 152   # is *not* the same as an eval setting $@ to ''
 153   # but for the sake of simplicity assume the following for
 154   # the time being
 155   return 0 unless defined $e;
 156
 157   my ($not_blank, $suberror);
 158   {
 159     local $@;
 160     eval {
 161       $not_blank = ($e ne '') ? 1 : 0;
 162       1;
 163     } or $suberror = $@;
 164   }
 165
 166   if (defined $suberror) {
 167     if (length (my $class = blessed($e) )) {
 168       carp_unique( sprintf(
 169         'External exception class %s implements partial (broken) overloading '
 170       . 'preventing its instances from being used in simple ($x eq $y) '
 171       . 'comparisons. Given Perl\'s "globally cooperative" exception '
 172       . 'handling this type of brokenness is extremely dangerous on '
 173       . 'exception objects, as it may (and often does) result in silent '
 174       . '"exception substitution". DBIx::Class tries to work around this '
 175       . 'as much as possible, but other parts of your software stack may '
 176       . 'not be even aware of this. Please submit a bugreport against the '
 177       . 'distribution containing %s and in the meantime apply a fix similar '
 178       . 'to the one shown at %s, in order to ensure your exception handling '
 179       . 'is saner application-wide. What follows is the actual error text '
 180       . "as generated by Perl itself:\n\n%s\n ",
 181         $class,
 182         $class,
 183         'http://v.gd/DBIC_overload_tempfix/',
 184         $suberror,
 185       ));
 186
 187       # workaround, keeps spice flowing
 188       $not_blank = ("$e" ne '') ? 1 : 0;
 189     }
 190     else {
 191       # not blessed yet failed the 'ne'... this makes 0 sense...
 192       # just throw further
 193       die $suberror
 194     }
 195   }
 196   elsif (
 197     # a ref evaluating to '' is definitively a "null object"
 198     ( not $not_blank )
 199       and
 200     length( my $class = ref $e )
 201   ) {
 202     carp_unique( sprintf(
 203       "Objects of external exception class '%s' stringify to '' (the "
 204     . 'empty string), implementing the so called null-object-pattern. '
 205     . 'Given Perl\'s "globally cooperative" exception handling using this '
 206     . 'class of exceptions is extremely dangerous, as it may (and often '
 207     . 'does) result in silent discarding of errors. DBIx::Class tries to '
 208     . 'work around this as much as possible, but other parts of your '
 209     . 'software stack may not be even aware of the problem. Please submit '
 210     . 'a bugreport against the distribution containing %s.',
 211
 212       ($class) x 2,
 213     ));
 214
 215     $not_blank = 1;
 216   }
 217
 218   return $not_blank;
 219 }
 220
 221 {
 222   my $destruction_registry = {};
 223
 224   sub CLONE {
 225     $destruction_registry = { map
 226       { defined $_ ? ( refaddr($_) => $_ ) : () }
 227       values %$destruction_registry
 228     };
 229   }
 230
 231   # This is almost invariably invoked from within DESTROY
 232   # throwing exceptions won't work
 233   sub detected_reinvoked_destructor {
 234
 235     # quick "garbage collection" pass - prevents the registry
 236     # from slowly growing with a bunch of undef-valued keys
 237     defined $destruction_registry->{$_} or delete $destruction_registry->{$_}
 238       for keys %$destruction_registry;
 239
 240     if (! length ref $_[0]) {
 241       printf STDERR '%s() expects a blessed reference %s',
 242         (caller(0))[3],
 243         Carp::longmess,
 244       ;
 245       return undef; # don't know wtf to do
 246     }
 247     elsif (! defined $destruction_registry->{ my $addr = refaddr($_[0]) } ) {
 248       weaken( $destruction_registry->{$addr} = $_[0] );
 249       return 0;
 250     }
 251     else {
 252       carp_unique ( sprintf (
 253         'Preventing *MULTIPLE* DESTROY() invocations on %s - an *EXTREMELY '
 254       . 'DANGEROUS* condition which is *ALMOST CERTAINLY GLOBAL* within your '
 255       . 'application, affecting *ALL* classes without active protection against '
 256       . 'this. Diagnose and fix the root cause ASAP!!!%s',
 257       refdesc $_[0],
 258         ( ( $INC{'Devel/StackTrace.pm'} and ! do { local $@; eval { Devel::StackTrace->VERSION(2) } } )
 259           ? " (likely culprit Devel::StackTrace\@@{[ Devel::StackTrace->VERSION ]} found in %INC, http://is.gd/D_ST_refcap)"
 260           : ''
 261         )
 262       ));
 263
 264       return 1;
 265     }
 266   }
 267 }
 268
 269 sub modver_gt_or_eq ($$) {
 270   my ($mod, $ver) = @_;
 271
 272   croak "Nonsensical module name supplied"
 273     if ! defined $mod or ! length $mod;
 274
 275   croak "Nonsensical minimum version supplied"
 276     if ! defined $ver or $ver =~ /[^0-9\.\_]/;
 277
 278   local $SIG{__WARN__} = sigwarn_silencer( qr/\Qisn't numeric in subroutine entry/ )
 279     if SPURIOUS_VERSION_CHECK_WARNINGS;
 280
 281   croak "$mod does not seem to provide a version (perhaps it never loaded)"
 282     unless $mod->VERSION;
 283
 284   local $@;
 285   eval { $mod->VERSION($ver) } ? 1 : 0;
 286 }
 287
 288 sub modver_gt_or_eq_and_lt ($$$) {
 289   my ($mod, $v_ge, $v_lt) = @_;
 290
 291   croak "Nonsensical maximum version supplied"
 292     if ! defined $v_lt or $v_lt =~ /[^0-9\.\_]/;
 293
 294   return (
 295     modver_gt_or_eq($mod, $v_ge)
 296       and
 297     ! modver_gt_or_eq($mod, $v_lt)
 298   ) ? 1 : 0;
 299 }
 300
 301 {
 302   my $list_ctx_ok_stack_marker;
 303
 304   sub fail_on_internal_wantarray () {
 305     return if $list_ctx_ok_stack_marker;
 306
 307     if (! defined wantarray) {
 308       croak('fail_on_internal_wantarray() needs a tempvar to save the stack marker guard');
 309     }
 310
 311     my $cf = 1;
 312     while ( ( (CORE::caller($cf+1))[3] || '' ) =~ / :: (?:
 313
 314       # these are public API parts that alter behavior on wantarray
 315       search | search_related | slice | search_literal
 316
 317         |
 318
 319       # these are explicitly prefixed, since we only recognize them as valid
 320       # escapes when they come from the guts of CDBICompat
 321       CDBICompat .*? :: (?: search_where | retrieve_from_sql | retrieve_all )
 322
 323     ) $/x ) {
 324       $cf++;
 325     }
 326
 327     my ($fr, $want, $argdesc);
 328     {
 329       package DB;
 330       $fr = [ CORE::caller($cf) ];
 331       $want = ( CORE::caller($cf-1) )[5];
 332       $argdesc = ref $DB::args[0]
 333         ? DBIx::Class::_Util::refdesc($DB::args[0])
 334         : 'non '
 335       ;
 336     };
 337
 338     if (
 339       $want and $fr->[0] =~ /^(?:DBIx::Class|DBICx::)/
 340     ) {
 341       DBIx::Class::Exception->throw( sprintf (
 342         "Improper use of %s instance in list context at %s line %d\n\n    Stacktrace starts",
 343         $argdesc, @{$fr}[1,2]
 344       ), 'with_stacktrace');
 345     }
 346
 347     my $mark = [];
 348     weaken ( $list_ctx_ok_stack_marker = $mark );
 349     $mark;
 350   }
 351 }
 352
 353 sub fail_on_internal_call {
 354   my ($fr, $argdesc);
 355   {
 356     package DB;
 357     $fr = [ CORE::caller(1) ];
 358     $argdesc = ref $DB::args[0]
 359       ? DBIx::Class::_Util::refdesc($DB::args[0])
 360       : undef
 361     ;
 362   };
 363
 364   if (
 365     $argdesc
 366       and
 367     $fr->[0] =~ /^(?:DBIx::Class|DBICx::)/
 368       and
 369     $fr->[1] !~ /\b(?:CDBICompat|ResultSetProxy)\b/  # no point touching there
 370   ) {
 371     DBIx::Class::Exception->throw( sprintf (
 372       "Illegal internal call of indirect proxy-method %s() with argument %s: examine the last lines of the proxy method deparse below to determine what to call directly instead at %s on line %d\n\n%s\n\n    Stacktrace starts",
 373       $fr->[3], $argdesc, @{$fr}[1,2], ( $fr->[6] || do {
 374         require B::Deparse;
 375         no strict 'refs';
 376         B::Deparse->new->coderef2text(\&{$fr->[3]})
 377       }),
 378     ), 'with_stacktrace');
 379   }
 380 }
 381
 382 1;