lib/DBIx/Class/_Util.pm

   1 package # hide from PAUSE
   2   DBIx::Class::_Util;
   3
   4 use warnings;
   5 use strict;
   6
   7 use constant SPURIOUS_VERSION_CHECK_WARNINGS => ( "$]" < 5.010 ? 1 : 0);
   8
   9 BEGIN {
  10   package # hide from pause
  11     DBIx::Class::_ENV_;
  12
  13   use Config;
  14
  15   use constant {
  16
  17     # but of course
  18     BROKEN_FORK => ($^O eq 'MSWin32') ? 1 : 0,
  19
  20     BROKEN_GOTO => ( "$]" < 5.008003 ) ? 1 : 0,
  21
  22     HAS_ITHREADS => $Config{useithreads} ? 1 : 0,
  23
  24     UNSTABLE_DOLLARAT => ( "$]" < 5.013002 ) ? 1 : 0,
  25
  26     ( map
  27       #
  28       # the "DBIC_" prefix below is crucial - this is what makes CI pick up
  29       # all envvars without further adjusting its scripts
  30       # DO NOT CHANGE to the more logical { $_ => !!( $ENV{"DBIC_$_"} ) }
  31       #
  32       { substr($_, 5) => !!( $ENV{$_} ) }
  33       qw(
  34         DBIC_SHUFFLE_UNORDERED_RESULTSETS
  35         DBIC_ASSERT_NO_INTERNAL_WANTARRAY
  36         DBIC_ASSERT_NO_INTERNAL_INDIRECT_CALLS
  37         DBIC_STRESSTEST_UTF8_UPGRADE_GENERATED_COLLAPSER_SOURCE
  38         DBIC_STRESSTEST_COLUMN_INFO_UNAWARE_STORAGE
  39       )
  40     ),
  41
  42     IV_SIZE => $Config{ivsize},
  43
  44     OS_NAME => $^O,
  45   };
  46
  47   if ( "$]" < 5.009_005) {
  48     require MRO::Compat;
  49     constant->import( OLD_MRO => 1 );
  50   }
  51   else {
  52     require mro;
  53     constant->import( OLD_MRO => 0 );
  54   }
  55 }
  56
  57 # FIXME - this is not supposed to be here
  58 # Carp::Skip to the rescue soon
  59 use DBIx::Class::Carp '^DBIx::Class|^DBICTest';
  60
  61 use B ();
  62 use Carp 'croak';
  63 use Storable 'nfreeze';
  64 use Scalar::Util qw(weaken blessed reftype refaddr);
  65 use List::Util qw(first);
  66 use Sub::Quote qw(qsub quote_sub);
  67
  68 # Already correctly prototyped: perlbrew exec perl -MStorable -e 'warn prototype \&Storable::dclone'
  69 BEGIN { *deep_clone = \&Storable::dclone }
  70
  71 use base 'Exporter';
  72 our @EXPORT_OK = qw(
  73   sigwarn_silencer modver_gt_or_eq modver_gt_or_eq_and_lt
  74   fail_on_internal_wantarray fail_on_internal_call
  75   refdesc refcount hrefaddr
  76   scope_guard detected_reinvoked_destructor
  77   is_exception dbic_internal_try
  78   quote_sub qsub perlstring serialize deep_clone
  79   parent_dir mkdir_p
  80   UNRESOLVABLE_CONDITION
  81 );
  82
  83 use constant UNRESOLVABLE_CONDITION => \ '1 = 0';
  84
  85 sub sigwarn_silencer ($) {
  86   my $pattern = shift;
  87
  88   croak "Expecting a regexp" if ref $pattern ne 'Regexp';
  89
  90   my $orig_sig_warn = $SIG{__WARN__} || sub { CORE::warn(@_) };
  91
  92   return sub { &$orig_sig_warn unless $_[0] =~ $pattern };
  93 }
  94
  95 sub perlstring ($) { q{"}. quotemeta( shift ). q{"} };
  96
  97 sub hrefaddr ($) { sprintf '0x%x', &refaddr||0 }
  98
  99 sub refdesc ($) {
 100   croak "Expecting a reference" if ! length ref $_[0];
 101
 102   # be careful not to trigger stringification,
 103   # reuse @_ as a scratch-pad
 104   sprintf '%s%s(0x%x)',
 105     ( defined( $_[1] = blessed $_[0]) ? "$_[1]=" : '' ),
 106     reftype $_[0],
 107     refaddr($_[0]),
 108   ;
 109 }
 110
 111 sub refcount ($) {
 112   croak "Expecting a reference" if ! length ref $_[0];
 113
 114   # No tempvars - must operate on $_[0], otherwise the pad
 115   # will count as an extra ref
 116   B::svref_2object($_[0])->REFCNT;
 117 }
 118
 119 sub serialize ($) {
 120   local $Storable::canonical = 1;
 121   nfreeze($_[0]);
 122 }
 123
 124 sub scope_guard (&) {
 125   croak 'Calling scope_guard() in void context makes no sense'
 126     if ! defined wantarray;
 127
 128   # no direct blessing of coderefs - DESTROY is buggy on those
 129   bless [ $_[0] ], 'DBIx::Class::_Util::ScopeGuard';
 130 }
 131 {
 132   package #
 133     DBIx::Class::_Util::ScopeGuard;
 134
 135   sub DESTROY {
 136     &DBIx::Class::_Util::detected_reinvoked_destructor;
 137
 138     local $@ if DBIx::Class::_ENV_::UNSTABLE_DOLLARAT;
 139
 140     eval {
 141       $_[0]->[0]->();
 142       1;
 143     }
 144       or
 145     Carp::cluck(
 146       "Execution of scope guard $_[0] resulted in the non-trappable exception:\n\n$@"
 147     );
 148   }
 149 }
 150
 151
 152 sub is_exception ($) {
 153   my $e = $_[0];
 154
 155   # FIXME
 156   # this is not strictly correct - an eval setting $@ to undef
 157   # is *not* the same as an eval setting $@ to ''
 158   # but for the sake of simplicity assume the following for
 159   # the time being
 160   return 0 unless defined $e;
 161
 162   my ($not_blank, $suberror);
 163   {
 164     local $SIG{__DIE__} if $SIG{__DIE__};
 165     local $@;
 166     eval {
 167       # The ne() here is deliberate - a plain length($e), or worse "$e" ne
 168       # will entirely obviate the need for the encolsing eval{}, as the
 169       # condition we guard against is a missing fallback overload
 170       $not_blank = ( $e ne '' );
 171       1;
 172     } or $suberror = $@;
 173   }
 174
 175   if (defined $suberror) {
 176     if (length (my $class = blessed($e) )) {
 177       carp_unique( sprintf(
 178         'External exception class %s implements partial (broken) overloading '
 179       . 'preventing its instances from being used in simple ($x eq $y) '
 180       . 'comparisons. Given Perl\'s "globally cooperative" exception '
 181       . 'handling this type of brokenness is extremely dangerous on '
 182       . 'exception objects, as it may (and often does) result in silent '
 183       . '"exception substitution". DBIx::Class tries to work around this '
 184       . 'as much as possible, but other parts of your software stack may '
 185       . 'not be even aware of this. Please submit a bugreport against the '
 186       . 'distribution containing %s and in the meantime apply a fix similar '
 187       . 'to the one shown at %s, in order to ensure your exception handling '
 188       . 'is saner application-wide. What follows is the actual error text '
 189       . "as generated by Perl itself:\n\n%s\n ",
 190         $class,
 191         $class,
 192         'http://v.gd/DBIC_overload_tempfix/',
 193         $suberror,
 194       ));
 195
 196       # workaround, keeps spice flowing
 197       $not_blank = !!( length $e );
 198     }
 199     else {
 200       # not blessed yet failed the 'ne'... this makes 0 sense...
 201       # just throw further
 202       die $suberror
 203     }
 204   }
 205   elsif (
 206     # a ref evaluating to '' is definitively a "null object"
 207     ( not $not_blank )
 208       and
 209     length( my $class = ref $e )
 210   ) {
 211     carp_unique( sprintf(
 212       "Objects of external exception class '%s' stringify to '' (the "
 213     . 'empty string), implementing the so called null-object-pattern. '
 214     . 'Given Perl\'s "globally cooperative" exception handling using this '
 215     . 'class of exceptions is extremely dangerous, as it may (and often '
 216     . 'does) result in silent discarding of errors. DBIx::Class tries to '
 217     . 'work around this as much as possible, but other parts of your '
 218     . 'software stack may not be even aware of the problem. Please submit '
 219     . 'a bugreport against the distribution containing %s',
 220
 221       ($class) x 2,
 222     ));
 223
 224     $not_blank = 1;
 225   }
 226
 227   return $not_blank;
 228 }
 229
 230 {
 231   my $callstack_state;
 232
 233   # Recreate the logic of try(), while reusing the catch()/finally() as-is
 234   #
 235   # FIXME: We need to move away from Try::Tiny entirely (way too heavy and
 236   # yes, shows up ON TOP of profiles) but this is a batle for another maint
 237   sub dbic_internal_try (&;@) {
 238
 239     my $try_cref = shift;
 240     my $catch_cref = undef;  # apparently this is a thing... https://rt.perl.org/Public/Bug/Display.html?id=119311
 241
 242     for my $arg (@_) {
 243
 244       if( ref($arg) eq 'Try::Tiny::Catch' ) {
 245
 246         croak 'dbic_internal_try() may not be followed by multiple catch() blocks'
 247           if $catch_cref;
 248
 249         $catch_cref = $$arg;
 250       }
 251       elsif ( ref($arg) eq 'Try::Tiny::Finally' ) {
 252         croak 'dbic_internal_try() does not support finally{}';
 253       }
 254       else {
 255         croak(
 256           'dbic_internal_try() encountered an unexpected argument '
 257         . "'@{[ defined $arg ? $arg : 'UNDEF' ]}' - perhaps "
 258         . 'a missing semi-colon before or ' # trailing space important
 259         );
 260       }
 261     }
 262
 263     my $wantarray = wantarray;
 264     my $preexisting_exception = $@;
 265
 266     my @ret;
 267     my $all_good = eval {
 268       $@ = $preexisting_exception;
 269
 270       local $callstack_state->{in_internal_try} = 1
 271         unless $callstack_state->{in_internal_try};
 272
 273       # always unset - someone may have snuck it in
 274       local $SIG{__DIE__} if $SIG{__DIE__};
 275
 276       if( $wantarray ) {
 277         @ret = $try_cref->();
 278       }
 279       elsif( defined $wantarray ) {
 280         $ret[0] = $try_cref->();
 281       }
 282       else {
 283         $try_cref->();
 284       }
 285
 286       1;
 287     };
 288
 289     my $exception = $@;
 290     $@ = $preexisting_exception;
 291
 292     if ( $all_good ) {
 293       return $wantarray ? @ret : $ret[0]
 294     }
 295     elsif ( $catch_cref ) {
 296       for ( $exception ) {
 297         return $catch_cref->($exception);
 298       }
 299     }
 300
 301     return;
 302   }
 303
 304   sub in_internal_try { !! $callstack_state->{in_internal_try} }
 305 }
 306
 307 {
 308   my $destruction_registry = {};
 309
 310   sub CLONE {
 311     $destruction_registry = { map
 312       { defined $_ ? ( refaddr($_) => $_ ) : () }
 313       values %$destruction_registry
 314     };
 315
 316     # Dummy NEXTSTATE ensuring the all temporaries on the stack are garbage
 317     # collected before leaving this scope. Depending on the code above, this
 318     # may very well be just a preventive measure guarding future modifications
 319     undef;
 320   }
 321
 322   # This is almost invariably invoked from within DESTROY
 323   # throwing exceptions won't work
 324   sub detected_reinvoked_destructor {
 325
 326     # quick "garbage collection" pass - prevents the registry
 327     # from slowly growing with a bunch of undef-valued keys
 328     defined $destruction_registry->{$_} or delete $destruction_registry->{$_}
 329       for keys %$destruction_registry;
 330
 331     if (! length ref $_[0]) {
 332       printf STDERR '%s() expects a blessed reference %s',
 333         (caller(0))[3],
 334         Carp::longmess,
 335       ;
 336       return undef; # don't know wtf to do
 337     }
 338     elsif (! defined $destruction_registry->{ my $addr = refaddr($_[0]) } ) {
 339       weaken( $destruction_registry->{$addr} = $_[0] );
 340       return 0;
 341     }
 342     else {
 343       carp_unique ( sprintf (
 344         'Preventing *MULTIPLE* DESTROY() invocations on %s - an *EXTREMELY '
 345       . 'DANGEROUS* condition which is *ALMOST CERTAINLY GLOBAL* within your '
 346       . 'application, affecting *ALL* classes without active protection against '
 347       . 'this. Diagnose and fix the root cause ASAP!!!%s',
 348       refdesc $_[0],
 349         ( ( $INC{'Devel/StackTrace.pm'} and ! do { local $@; eval { Devel::StackTrace->VERSION(2) } } )
 350           ? " (likely culprit Devel::StackTrace\@@{[ Devel::StackTrace->VERSION ]} found in %INC, http://is.gd/D_ST_refcap)"
 351           : ''
 352         )
 353       ));
 354
 355       return 1;
 356     }
 357   }
 358 }
 359
 360 my $module_name_rx = qr/ \A [A-Z_a-z] [0-9A-Z_a-z]* (?: :: [0-9A-Z_a-z]+ )* \z /x;
 361 my $ver_rx =         qr/ \A [0-9]+ (?: \. [0-9]+ )* (?: \_ [0-9]+ )*        \z /x;
 362
 363 sub modver_gt_or_eq ($$) {
 364   my ($mod, $ver) = @_;
 365
 366   croak "Nonsensical module name supplied"
 367     if ! defined $mod or $mod !~ $module_name_rx;
 368
 369   croak "Nonsensical minimum version supplied"
 370     if ! defined $ver or $ver !~ $ver_rx;
 371
 372   no strict 'refs';
 373   my $ver_cache = ${"${mod}::__DBIC_MODULE_VERSION_CHECKS__"} ||= ( $mod->VERSION
 374     ? {}
 375     : croak "$mod does not seem to provide a version (perhaps it never loaded)"
 376   );
 377
 378   ! defined $ver_cache->{$ver}
 379     and
 380   $ver_cache->{$ver} = do {
 381
 382     local $SIG{__WARN__} = sigwarn_silencer( qr/\Qisn't numeric in subroutine entry/ )
 383       if SPURIOUS_VERSION_CHECK_WARNINGS;
 384
 385     local $SIG{__DIE__} if $SIG{__DIE__};
 386     local $@;
 387     eval { $mod->VERSION($ver) } ? 1 : 0;
 388   };
 389
 390   $ver_cache->{$ver};
 391 }
 392
 393 sub modver_gt_or_eq_and_lt ($$$) {
 394   my ($mod, $v_ge, $v_lt) = @_;
 395
 396   croak "Nonsensical maximum version supplied"
 397     if ! defined $v_lt or $v_lt !~ $ver_rx;
 398
 399   return (
 400     modver_gt_or_eq($mod, $v_ge)
 401       and
 402     ! modver_gt_or_eq($mod, $v_lt)
 403   ) ? 1 : 0;
 404 }
 405
 406
 407 #
 408 # Why not just use some higher-level module or at least File::Spec here?
 409 # Because:
 410 # 1)  This is a *very* rarely used function, and the deptree is large
 411 #     enough already as it is
 412 #
 413 # 2)  (more importantly) Our tooling is utter shit in this area. There
 414 #     is no comprehensive support for UNC paths in PathTools and there
 415 #     are also various small bugs in representation across different
 416 #     path-manipulation CPAN offerings.
 417 #
 418 # Since this routine is strictly used for logical path processing (it
 419 # *must* be able to work with not-yet-existing paths), use this seemingly
 420 # simple but I *think* complete implementation to feed to other consumers
 421 #
 422 # If bugs are ever uncovered in this routine, *YOU ARE URGED TO RESIST*
 423 # the impulse to bring in an external dependency. During runtime there
 424 # is exactly one spot that could potentially maybe once in a blue moon
 425 # use this function. Keep it lean.
 426 #
 427 sub parent_dir ($) {
 428   ( $_[0] =~ m{  [\/\\]  ( \.{0,2} ) ( [\/\\]* ) \z }x )
 429     ? (
 430       $_[0]
 431         .
 432       ( ( length($1) and ! length($2) ) ? '/' : '' )
 433         .
 434       '../'
 435     )
 436     : (
 437       require File::Spec
 438         and
 439       File::Spec->catpath (
 440         ( File::Spec->splitpath( "$_[0]" ) )[0,1],
 441         '/',
 442       )
 443     )
 444   ;
 445 }
 446
 447 sub mkdir_p ($) {
 448   require File::Path;
 449   # do not ask for a recent version, use 1.x API calls
 450   File::Path::mkpath([ "$_[0]" ]);  # File::Path does not like objects
 451 }
 452
 453
 454 {
 455   my $list_ctx_ok_stack_marker;
 456
 457   sub fail_on_internal_wantarray () {
 458     return if $list_ctx_ok_stack_marker;
 459
 460     if (! defined wantarray) {
 461       croak('fail_on_internal_wantarray() needs a tempvar to save the stack marker guard');
 462     }
 463
 464     my $cf = 1;
 465     while ( ( (CORE::caller($cf+1))[3] || '' ) =~ / :: (?:
 466
 467       # these are public API parts that alter behavior on wantarray
 468       search | search_related | slice | search_literal
 469
 470         |
 471
 472       # these are explicitly prefixed, since we only recognize them as valid
 473       # escapes when they come from the guts of CDBICompat
 474       CDBICompat .*? :: (?: search_where | retrieve_from_sql | retrieve_all )
 475
 476     ) $/x ) {
 477       $cf++;
 478     }
 479
 480     my ($fr, $want, $argdesc);
 481     {
 482       package DB;
 483       $fr = [ CORE::caller($cf) ];
 484       $want = ( CORE::caller($cf-1) )[5];
 485       $argdesc = ref $DB::args[0]
 486         ? DBIx::Class::_Util::refdesc($DB::args[0])
 487         : 'non '
 488       ;
 489     };
 490
 491     if (
 492       $want and $fr->[0] =~ /^(?:DBIx::Class|DBICx::)/
 493     ) {
 494       DBIx::Class::Exception->throw( sprintf (
 495         "Improper use of %s instance in list context at %s line %d\n\n    Stacktrace starts",
 496         $argdesc, @{$fr}[1,2]
 497       ), 'with_stacktrace');
 498     }
 499
 500     my $mark = [];
 501     weaken ( $list_ctx_ok_stack_marker = $mark );
 502     $mark;
 503   }
 504 }
 505
 506 sub fail_on_internal_call {
 507   my ($fr, $argdesc);
 508   {
 509     package DB;
 510     $fr = [ CORE::caller(1) ];
 511     $argdesc = ref $DB::args[0]
 512       ? DBIx::Class::_Util::refdesc($DB::args[0])
 513       : undef
 514     ;
 515   };
 516
 517   if (
 518     $argdesc
 519       and
 520     $fr->[0] =~ /^(?:DBIx::Class|DBICx::)/
 521       and
 522     $fr->[1] !~ /\b(?:CDBICompat|ResultSetProxy)\b/  # no point touching there
 523   ) {
 524     DBIx::Class::Exception->throw( sprintf (
 525       "Illegal internal call of indirect proxy-method %s() with argument %s: examine the last lines of the proxy method deparse below to determine what to call directly instead at %s on line %d\n\n%s\n\n    Stacktrace starts",
 526       $fr->[3], $argdesc, @{$fr}[1,2], ( $fr->[6] || do {
 527         require B::Deparse;
 528         no strict 'refs';
 529         B::Deparse->new->coderef2text(\&{$fr->[3]})
 530       }),
 531     ), 'with_stacktrace');
 532   }
 533 }
 534
 535 1;