lib/DBIx/Class/_Util.pm

   1 package # hide from PAUSE
   2   DBIx::Class::_Util;
   3
   4 use warnings;
   5 use strict;
   6
   7 use constant SPURIOUS_VERSION_CHECK_WARNINGS => ($] < 5.010 ? 1 : 0);
   8
   9 BEGIN {
  10   package # hide from pause
  11     DBIx::Class::_ENV_;
  12
  13   use Config;
  14
  15   use constant {
  16
  17     # but of course
  18     BROKEN_FORK => ($^O eq 'MSWin32') ? 1 : 0,
  19
  20     HAS_ITHREADS => $Config{useithreads} ? 1 : 0,
  21
  22     # ::Runmode would only be loaded by DBICTest, which in turn implies t/
  23     DBICTEST => eval { DBICTest::RunMode->is_author } ? 1 : 0,
  24
  25     # During 5.13 dev cycle HELEMs started to leak on copy
  26     # add an escape for these perls ON SMOKERS - a user will still get death
  27     PEEPEENESS => ( eval { DBICTest::RunMode->is_smoker } && ($] >= 5.013005 and $] <= 5.013006) ),
  28
  29     SHUFFLE_UNORDERED_RESULTSETS => $ENV{DBIC_SHUFFLE_UNORDERED_RESULTSETS} ? 1 : 0,
  30
  31     ASSERT_NO_INTERNAL_WANTARRAY => $ENV{DBIC_ASSERT_NO_INTERNAL_WANTARRAY} ? 1 : 0,
  32
  33     ASSERT_NO_INTERNAL_INDIRECT_CALLS => $ENV{DBIC_ASSERT_NO_INTERNAL_INDIRECT_CALLS} ? 1 : 0,
  34
  35     IV_SIZE => $Config{ivsize},
  36
  37     OS_NAME => $^O,
  38   };
  39
  40   if ($] < 5.009_005) {
  41     require MRO::Compat;
  42     constant->import( OLD_MRO => 1 );
  43   }
  44   else {
  45     require mro;
  46     constant->import( OLD_MRO => 0 );
  47   }
  48 }
  49
  50 # FIXME - this is not supposed to be here
  51 # Carp::Skip to the rescue soon
  52 use DBIx::Class::Carp '^DBIx::Class|^DBICTest';
  53
  54 use Carp 'croak';
  55 use Scalar::Util qw(weaken blessed reftype);
  56 use List::Util qw(first);
  57
  58 use base 'Exporter';
  59 our @EXPORT_OK = qw(
  60   sigwarn_silencer modver_gt_or_eq
  61   fail_on_internal_wantarray fail_on_internal_call
  62   refdesc refcount hrefaddr is_exception
  63   perlstring
  64   UNRESOLVABLE_CONDITION
  65 );
  66
  67 use constant UNRESOLVABLE_CONDITION => \ '1 = 0';
  68
  69 sub sigwarn_silencer ($) {
  70   my $pattern = shift;
  71
  72   croak "Expecting a regexp" if ref $pattern ne 'Regexp';
  73
  74   my $orig_sig_warn = $SIG{__WARN__} || sub { CORE::warn(@_) };
  75
  76   return sub { &$orig_sig_warn unless $_[0] =~ $pattern };
  77 }
  78
  79 sub perlstring ($) { q{"}. quotemeta( shift ). q{"} };
  80
  81 sub hrefaddr ($) { sprintf '0x%x', &Scalar::Util::refaddr||0 }
  82
  83 sub refdesc ($) {
  84   croak "Expecting a reference" if ! length ref $_[0];
  85
  86   # be careful not to trigger stringification,
  87   # reuse @_ as a scratch-pad
  88   sprintf '%s%s(0x%x)',
  89     ( defined( $_[1] = blessed $_[0]) ? "$_[1]=" : '' ),
  90     reftype $_[0],
  91     Scalar::Util::refaddr($_[0]),
  92   ;
  93 }
  94
  95 sub refcount ($) {
  96   croak "Expecting a reference" if ! length ref $_[0];
  97
  98   require B;
  99   # No tempvars - must operate on $_[0], otherwise the pad
 100   # will count as an extra ref
 101   B::svref_2object($_[0])->REFCNT;
 102 }
 103
 104 sub is_exception ($) {
 105   my $e = $_[0];
 106
 107   # this is not strictly correct - an eval setting $@ to undef
 108   # is *not* the same as an eval setting $@ to ''
 109   # but for the sake of simplicity assume the following for
 110   # the time being
 111   return 0 unless defined $e;
 112
 113   my ($not_blank, $suberror);
 114   {
 115     local $@;
 116     eval {
 117       $not_blank = ($e ne '') ? 1 : 0;
 118       1;
 119     } or $suberror = $@;
 120   }
 121
 122   if (defined $suberror) {
 123     if (length (my $class = blessed($e) )) {
 124       carp_unique( sprintf(
 125         'External exception class %s implements partial (broken) overloading '
 126       . 'preventing its instances from being used in simple ($x eq $y) '
 127       . 'comparisons. Given Perl\'s "globally cooperative" exception '
 128       . 'handling this type of brokenness is extremely dangerous on '
 129       . 'exception objects, as it may (and often does) result in silent '
 130       . '"exception substitution". DBIx::Class tries to work around this '
 131       . 'as much as possible, but other parts of your software stack may '
 132       . 'not be even aware of this. Please submit a bugreport against the '
 133       . 'distribution containing %s and in the meantime apply a fix similar '
 134       . 'to the one shown at %s, in order to ensure your exception handling '
 135       . 'is saner application-wide. What follows is the actual error text '
 136       . "as generated by Perl itself:\n\n%s\n ",
 137         $class,
 138         $class,
 139         'http://v.gd/DBIC_overload_tempfix/',
 140         $suberror,
 141       ));
 142
 143       # workaround, keeps spice flowing
 144       $not_blank = ("$e" ne '') ? 1 : 0;
 145     }
 146     else {
 147       # not blessed yet failed the 'ne'... this makes 0 sense...
 148       # just throw further
 149       die $suberror
 150     }
 151   }
 152
 153   return $not_blank;
 154 }
 155
 156 sub modver_gt_or_eq ($$) {
 157   my ($mod, $ver) = @_;
 158
 159   croak "Nonsensical module name supplied"
 160     if ! defined $mod or ! length $mod;
 161
 162   croak "Nonsensical minimum version supplied"
 163     if ! defined $ver or $ver =~ /[^0-9\.\_]/;
 164
 165   local $SIG{__WARN__} = sigwarn_silencer( qr/\Qisn't numeric in subroutine entry/ )
 166     if SPURIOUS_VERSION_CHECK_WARNINGS;
 167
 168   croak "$mod does not seem to provide a version (perhaps it never loaded)"
 169     unless $mod->VERSION;
 170
 171   local $@;
 172   eval { $mod->VERSION($ver) } ? 1 : 0;
 173 }
 174
 175 {
 176   my $list_ctx_ok_stack_marker;
 177
 178   sub fail_on_internal_wantarray () {
 179     return if $list_ctx_ok_stack_marker;
 180
 181     if (! defined wantarray) {
 182       croak('fail_on_internal_wantarray() needs a tempvar to save the stack marker guard');
 183     }
 184
 185     my $cf = 1;
 186     while ( ( (caller($cf+1))[3] || '' ) =~ / :: (?:
 187
 188       # these are public API parts that alter behavior on wantarray
 189       search | search_related | slice | search_literal
 190
 191         |
 192
 193       # these are explicitly prefixed, since we only recognize them as valid
 194       # escapes when they come from the guts of CDBICompat
 195       CDBICompat .*? :: (?: search_where | retrieve_from_sql | retrieve_all )
 196
 197     ) $/x ) {
 198       $cf++;
 199     }
 200
 201     my ($fr, $want, $argdesc);
 202     {
 203       package DB;
 204       $fr = [ caller($cf) ];
 205       $want = ( caller($cf-1) )[5];
 206       $argdesc = ref $DB::args[0]
 207         ? DBIx::Class::_Util::refdesc($DB::args[0])
 208         : 'non '
 209       ;
 210     };
 211
 212     if (
 213       $want and $fr->[0] =~ /^(?:DBIx::Class|DBICx::)/
 214     ) {
 215       DBIx::Class::Exception->throw( sprintf (
 216         "Improper use of %s instance in list context at %s line %d\n\n    Stacktrace starts",
 217         $argdesc, @{$fr}[1,2]
 218       ), 'with_stacktrace');
 219     }
 220
 221     my $mark = [];
 222     weaken ( $list_ctx_ok_stack_marker = $mark );
 223     $mark;
 224   }
 225 }
 226
 227 sub fail_on_internal_call {
 228   my ($fr, $argdesc);
 229   {
 230     package DB;
 231     $fr = [ caller(1) ];
 232     $argdesc = ref $DB::args[0]
 233       ? DBIx::Class::_Util::refdesc($DB::args[0])
 234       : undef
 235     ;
 236   };
 237
 238   if (
 239     $argdesc
 240       and
 241     $fr->[0] =~ /^(?:DBIx::Class|DBICx::)/
 242       and
 243     $fr->[1] !~ /\b(?:CDBICompat|ResultSetProxy)\b/  # no point touching there
 244   ) {
 245     DBIx::Class::Exception->throw( sprintf (
 246       "Illegal internal call of indirect proxy-method %s() with argument %s: examine the last lines of the proxy method deparse below to determine what to call directly instead at %s on line %d\n\n%s\n\n    Stacktrace starts",
 247       $fr->[3], $argdesc, @{$fr}[1,2], ( $fr->[6] || do {
 248         require B::Deparse;
 249         no strict 'refs';
 250         B::Deparse->new->coderef2text(\&{$fr->[3]})
 251       }),
 252     ), 'with_stacktrace');
 253   }
 254 }
 255
 256 1;