lib/DBIx/Class/_Util.pm

   1 package # hide from PAUSE
   2   DBIx::Class::_Util;
   3
   4 use DBIx::Class::StartupCheck;  # load es early as we can, usually a noop
   5
   6 use warnings;
   7 use strict;
   8
   9 # For the love of everything that is crab-like: DO NOT reach into this
  10 # The entire thing is really fragile and should not be screwed with
  11 # unless absolutely and unavoidably necessary
  12 our $__describe_class_query_cache;
  13
  14 BEGIN {
  15   package # hide from pause
  16     DBIx::Class::_ENV_;
  17
  18   use Config;
  19
  20   use constant {
  21     PERL_VERSION => "$]",
  22     OS_NAME => "$^O",
  23   };
  24
  25   use constant {
  26
  27     # but of course
  28     BROKEN_FORK => (OS_NAME eq 'MSWin32') ? 1 : 0,
  29
  30     BROKEN_GOTO => ( PERL_VERSION < 5.008003 ) ? 1 : 0,
  31
  32     # perl -MScalar::Util=weaken -e 'weaken( $hash{key} = \"value" )'
  33     BROKEN_WEAK_SCALARREF_VALUES => ( PERL_VERSION < 5.008003 ) ? 1 : 0,
  34
  35     HAS_ITHREADS => $Config{useithreads} ? 1 : 0,
  36
  37     TAINT_MODE => 0 + ${^TAINT}, # tri-state: 0, 1, -1
  38
  39     UNSTABLE_DOLLARAT => ( PERL_VERSION < 5.013002 ) ? 1 : 0,
  40
  41     ( map
  42       #
  43       # the "DBIC_" prefix below is crucial - this is what makes CI pick up
  44       # all envvars without further adjusting its scripts
  45       # DO NOT CHANGE to the more logical { $_ => !!( $ENV{"DBIC_$_"} ) }
  46       #
  47       { substr($_, 5) => !!( $ENV{$_} ) }
  48       qw(
  49         DBIC_SHUFFLE_UNORDERED_RESULTSETS
  50         DBIC_ASSERT_NO_INTERNAL_WANTARRAY
  51         DBIC_ASSERT_NO_INTERNAL_INDIRECT_CALLS
  52         DBIC_ASSERT_NO_ERRONEOUS_METAINSTANCE_USE
  53         DBIC_ASSERT_NO_FAILING_SANITY_CHECKS
  54         DBIC_STRESSTEST_UTF8_UPGRADE_GENERATED_COLLAPSER_SOURCE
  55         DBIC_STRESSTEST_COLUMN_INFO_UNAWARE_STORAGE
  56       )
  57     ),
  58
  59     IV_SIZE => $Config{ivsize},
  60   };
  61
  62   if ( PERL_VERSION < 5.009_005) {
  63     require MRO::Compat;
  64     constant->import( OLD_MRO => 1 );
  65
  66     #
  67     # Yes, I know this is a rather PHP-ish name, but please first read
  68     # https://metacpan.org/source/BOBTFISH/MRO-Compat-0.12/lib/MRO/Compat.pm#L363-368
  69     #
  70     # Even if we are using Class::C3::XS it still won't work, as doing
  71     #   defined( *{ "SubClass::"->{$_} }{CODE} )
  72     # will set pkg_gen to the same value for SubClass and *ALL PARENTS*
  73     #
  74     *DBIx::Class::_Util::get_real_pkg_gen = sub ($) {
  75       require Digest::MD5;
  76       require Math::BigInt;
  77
  78       my $cur_class;
  79       no strict 'refs';
  80
  81       # the non-assign-unless-there-is-a-hash is deliberate
  82       ( $__describe_class_query_cache->{'!internal!'} || {} )->{$_[0]}{gen} ||= (
  83         Math::BigInt->new( '0x' . ( Digest::MD5::md5_hex( join "\0", map {
  84
  85           ( $__describe_class_query_cache->{'!internal!'} || {} )->{$_}{methlist} ||= (
  86
  87             $cur_class = $_
  88
  89               and
  90
  91             # RV to be hashed up and turned into a number
  92             join "\0", (
  93               $cur_class,
  94               map
  95                 {(
  96                   # stringification should be sufficient, ignore names/refaddr entirely
  97                   $_,
  98                   do {
  99                     my @attrs;
 100                     local $@;
 101                     local $SIG{__DIE__} if $SIG{__DIE__};
 102                     # attributes::get may throw on blessed-false crefs :/
 103                     eval { @attrs = attributes::get( $_ ); 1 }
 104                       or warn "Unable to determine attributes of coderef $_ due to the following error: $@";
 105                     @attrs;
 106                   },
 107                 )}
 108                 map
 109                   {(
 110                     # skip dummy C::C3 helper crefs
 111                     ! ( ( $Class::C3::MRO{$cur_class} || {} )->{methods}{$_} )
 112                       and
 113                     (
 114                       ref(\ "${cur_class}::"->{$_} ) ne 'GLOB'
 115                         or
 116                       defined( *{ "${cur_class}::"->{$_} }{CODE} )
 117                     )
 118                   )
 119                     ? ( \&{"${cur_class}::$_"} )
 120                     : ()
 121                   }
 122                   keys %{ "${cur_class}::" }
 123             )
 124           )
 125         } (
 126
 127           @{
 128             ( $__describe_class_query_cache->{'!internal!'} || {} )->{$_[0]}{linear_isa}
 129               ||=
 130             mro::get_linear_isa($_[0])
 131           },
 132
 133           ((
 134             ( $__describe_class_query_cache->{'!internal!'} || {} )->{$_[0]}{is_universal}
 135               ||=
 136             mro::is_universal($_[0])
 137           ) ? () : @{
 138             ( $__describe_class_query_cache->{'!internal!'} || {} )->{UNIVERSAL}{linear_isa}
 139               ||=
 140             mro::get_linear_isa("UNIVERSAL")
 141           } ),
 142
 143         ) ) ) )
 144       );
 145     };
 146   }
 147   else {
 148     require mro;
 149     constant->import( OLD_MRO => 0 );
 150     *DBIx::Class::_Util::get_real_pkg_gen = \&mro::get_pkg_gen;
 151   }
 152
 153   # Both of these are no longer used for anything. However bring
 154   # them back after they were purged in 08a8d8f1, as there appear
 155   # to be outfits with *COPY PASTED* pieces of lib/DBIx/Class/Storage/*
 156   # in their production codebases. There is no point in breaking these
 157   # if whatever they used actually continues to work
 158   my $sigh = sub {
 159     DBIx::Class::_Util::emit_loud_diag(
 160       skip_frames => 1,
 161       msg => "The @{[ (caller(1))[3] ]} constant is no more - adjust your code"
 162     );
 163
 164     0;
 165   };
 166   sub DBICTEST () { &$sigh }
 167   sub PEEPEENESS () { &$sigh }
 168 }
 169
 170 use constant SPURIOUS_VERSION_CHECK_WARNINGS => ( DBIx::Class::_ENV_::PERL_VERSION < 5.010 ? 1 : 0);
 171
 172 # FIXME - this is not supposed to be here
 173 # Carp::Skip to the rescue soon
 174 use DBIx::Class::Carp '^DBIx::Class|^DBICTest';
 175
 176 use B ();
 177 use Carp 'croak';
 178 use Storable 'nfreeze';
 179 use Scalar::Util qw(weaken blessed reftype refaddr);
 180 use Sub::Name ();
 181 use attributes ();
 182
 183 # Usually versions are not specified anywhere aside the Makefile.PL
 184 # (writing them out in-code is extremely obnoxious)
 185 # However without a recent enough Moo the quote_sub override fails
 186 # in very puzzling and hard to detect ways: so add a version check
 187 # just this once
 188 use Sub::Quote qw(qsub);
 189 BEGIN { Sub::Quote->VERSION('2.002002') }
 190
 191 # Already correctly prototyped: perlbrew exec perl -MStorable -e 'warn prototype \&Storable::dclone'
 192 BEGIN { *deep_clone = \&Storable::dclone }
 193
 194 use base 'Exporter';
 195 our @EXPORT_OK = qw(
 196   sigwarn_silencer modver_gt_or_eq modver_gt_or_eq_and_lt
 197   fail_on_internal_wantarray fail_on_internal_call
 198   refdesc refcount hrefaddr set_subname get_subname describe_class_methods
 199   scope_guard detected_reinvoked_destructor emit_loud_diag
 200   true false
 201   is_exception dbic_internal_try visit_namespaces
 202   quote_sub qsub perlstring serialize deep_clone dump_value uniq
 203   parent_dir mkdir_p
 204   UNRESOLVABLE_CONDITION
 205 );
 206
 207 use constant UNRESOLVABLE_CONDITION => \ '1 = 0';
 208
 209 # Override forcing no_defer, and adding naming consistency checks
 210 our %refs_closed_over_by_quote_sub_installed_crefs;
 211 sub quote_sub {
 212   Carp::confess( "Anonymous quoting not supported by the DBIC quote_sub override - supply a sub name" ) if
 213     @_ < 2
 214       or
 215     ! defined $_[1]
 216       or
 217     length ref $_[1]
 218   ;
 219
 220   Carp::confess( "The DBIC quote_sub override expects sub name '$_[0]' to be fully qualified" )
 221     unless (my $stash) = $_[0] =~ /^(.+)::/;
 222
 223   Carp::confess(
 224     "The DBIC sub_quote override does not support 'no_install'"
 225   ) if (
 226     $_[3]
 227       and
 228     $_[3]->{no_install}
 229   );
 230
 231   Carp::confess(
 232     'The DBIC quote_sub override expects the namespace-part of sub name '
 233   . "'$_[0]' to match the supplied package argument '$_[3]->{package}'"
 234   ) if (
 235     $_[3]
 236       and
 237     defined $_[3]->{package}
 238       and
 239     $stash ne $_[3]->{package}
 240   );
 241
 242   my @caller = caller(0);
 243   my $sq_opts = {
 244     package => $caller[0],
 245     hints => $caller[8],
 246     warning_bits => $caller[9],
 247     hintshash => $caller[10],
 248     %{ $_[3] || {} },
 249
 250     # explicitly forced for everything
 251     no_defer => 1,
 252   };
 253
 254   weaken (
 255     # just use a growing counter, no need to perform neither compaction
 256     # nor any special ithread-level handling
 257     $refs_closed_over_by_quote_sub_installed_crefs
 258      { scalar keys %refs_closed_over_by_quote_sub_installed_crefs }
 259       = $_
 260   ) for grep {
 261     length ref $_
 262       and
 263     (
 264       ! DBIx::Class::_ENV_::BROKEN_WEAK_SCALARREF_VALUES
 265         or
 266       ref $_ ne 'SCALAR'
 267     )
 268   } values %{ $_[2] || {} };
 269
 270   Sub::Quote::quote_sub( $_[0], $_[1], $_[2]||{}, $sq_opts );
 271 }
 272
 273 sub sigwarn_silencer ($) {
 274   my $pattern = shift;
 275
 276   croak "Expecting a regexp" if ref $pattern ne 'Regexp';
 277
 278   my $orig_sig_warn = $SIG{__WARN__} || sub { CORE::warn(@_) };
 279
 280   return sub { &$orig_sig_warn unless $_[0] =~ $pattern };
 281 }
 282
 283 sub perlstring ($) { q{"}. quotemeta( shift ). q{"} };
 284
 285 sub hrefaddr ($) { sprintf '0x%x', &refaddr||0 }
 286
 287 sub refdesc ($) {
 288   croak "Expecting a reference" if ! length ref $_[0];
 289
 290   # be careful not to trigger stringification,
 291   # reuse @_ as a scratch-pad
 292   sprintf '%s%s(0x%x)',
 293     ( defined( $_[1] = blessed $_[0]) ? "$_[1]=" : '' ),
 294     reftype $_[0],
 295     refaddr($_[0]),
 296   ;
 297 }
 298
 299 sub refcount ($) {
 300   croak "Expecting a reference" if ! length ref $_[0];
 301
 302   # No tempvars - must operate on $_[0], otherwise the pad
 303   # will count as an extra ref
 304   B::svref_2object($_[0])->REFCNT;
 305 }
 306
 307 sub visit_namespaces {
 308   my $args = { (ref $_[0]) ? %{$_[0]} : @_ };
 309
 310   my $visited_count = 1;
 311
 312   # A package and a namespace are subtly different things
 313   $args->{package} ||= 'main';
 314   $args->{package} = 'main' if $args->{package} =~ /^ :: (?: main )? $/x;
 315   $args->{package} =~ s/^:://;
 316
 317   if ( $args->{action}->($args->{package}) ) {
 318     my $ns =
 319       ( ($args->{package} eq 'main') ? '' :  $args->{package} )
 320         .
 321       '::'
 322     ;
 323
 324     $visited_count += visit_namespaces( %$args, package => $_ ) for
 325       grep
 326         # this happens sometimes on %:: traversal
 327         { $_ ne '::main' }
 328         map
 329           { $_ =~ /^(.+?)::$/ ? "$ns$1" : () }
 330           do { no strict 'refs'; keys %$ns }
 331     ;
 332   }
 333
 334   $visited_count;
 335 }
 336
 337 # FIXME In another life switch these to a polyfill like the ones in namespace::clean
 338 sub get_subname ($) {
 339   my $gv = B::svref_2object( $_[0] )->GV;
 340   wantarray
 341     ? ( $gv->STASH->NAME, $gv->NAME )
 342     : ( join '::', $gv->STASH->NAME, $gv->NAME )
 343   ;
 344 }
 345 sub set_subname ($$) {
 346
 347   # fully qualify name
 348   splice @_, 0, 1, caller(0) . "::$_[0]"
 349     if $_[0] !~ /::|'/;
 350
 351   &Sub::Name::subname;
 352 }
 353
 354 sub serialize ($) {
 355   # stable hash order
 356   local $Storable::canonical = 1;
 357
 358   # explicitly false - there is nothing sensible that can come out of
 359   # an attempt at CODE serialization
 360   local $Storable::Deparse;
 361
 362   # take no chances
 363   local $Storable::forgive_me;
 364
 365   # FIXME
 366   # A number of codepaths *expect* this to be Storable.pm-based so that
 367   # the STORABLE_freeze hooks in the metadata subtree get executed properly
 368   nfreeze($_[0]);
 369 }
 370
 371 sub uniq {
 372   my( %seen, $seen_undef, $numeric_preserving_copy );
 373   grep { not (
 374     defined $_
 375       ? $seen{ $numeric_preserving_copy = $_ }++
 376       : $seen_undef++
 377   ) } @_;
 378 }
 379
 380 my $dd_obj;
 381 sub dump_value ($) {
 382   local $Data::Dumper::Indent = 1
 383     unless defined $Data::Dumper::Indent;
 384
 385   my $dump_str = (
 386     $dd_obj
 387       ||=
 388     do {
 389       require Data::Dumper;
 390       my $d = Data::Dumper->new([])
 391         ->Purity(0)
 392         ->Pad('')
 393         ->Useqq(1)
 394         ->Terse(1)
 395         ->Freezer('')
 396         ->Quotekeys(0)
 397         ->Bless('bless')
 398         ->Pair(' => ')
 399         ->Sortkeys(1)
 400         ->Deparse(1)
 401       ;
 402
 403       # FIXME - this is kinda ridiculous - there ought to be a
 404       # Data::Dumper->new_with_defaults or somesuch...
 405       #
 406       if( modver_gt_or_eq ( 'Data::Dumper', '2.136' ) ) {
 407         $d->Sparseseen(1);
 408
 409         if( modver_gt_or_eq ( 'Data::Dumper', '2.153' ) ) {
 410           $d->Maxrecurse(1000);
 411
 412           if( modver_gt_or_eq ( 'Data::Dumper', '2.160' ) ) {
 413             $d->Trailingcomma(1);
 414           }
 415         }
 416       }
 417
 418       $d;
 419     }
 420   )->Values([$_[0]])->Dump;
 421
 422   $dd_obj->Reset->Values([]);
 423
 424   $dump_str;
 425 }
 426
 427 my $seen_loud_screams;
 428 sub emit_loud_diag {
 429   my $args = { ref $_[0] eq 'HASH' ? %{$_[0]} : @_ };
 430
 431   unless ( defined $args->{msg} and length $args->{msg} ) {
 432     emit_loud_diag(
 433       msg => "No 'msg' value supplied to emit_loud_diag()"
 434     );
 435     exit 70;
 436   }
 437
 438   my $msg = "\n" . join( ': ',
 439     ( $0 eq '-e' ? () : $0 ),
 440     $args->{msg}
 441   );
 442
 443   # when we die - we usually want to keep doing it
 444   $args->{emit_dups} = !!$args->{confess}
 445     unless exists $args->{emit_dups};
 446
 447   local $Carp::CarpLevel =
 448     ( $args->{skip_frames} || 0 )
 449       +
 450     $Carp::CarpLevel
 451       +
 452     # hide our own frame
 453     1
 454   ;
 455
 456   my $longmess = Carp::longmess();
 457
 458   # different object references will thwart deduplication without this
 459   ( my $key = "${msg}\n${longmess}" ) =~ s/\b0x[0-9a-f]+\b/0x.../gi;
 460
 461   return $seen_loud_screams->{$key} if
 462     $seen_loud_screams->{$key}++
 463       and
 464     ! $args->{emit_dups}
 465   ;
 466
 467   $msg .= $longmess
 468     unless $msg =~ /\n\z/;
 469
 470   print STDERR "$msg\n"
 471     or
 472   print STDOUT "\n!!!STDERR ISN'T WRITABLE!!!:$msg\n";
 473
 474   return $seen_loud_screams->{$key}
 475     unless $args->{confess};
 476
 477   # increment *again*, because... Carp.
 478   $Carp::CarpLevel++;
 479
 480   # not $msg - Carp will reapply the longmess on its own
 481   Carp::confess($args->{msg});
 482 }
 483
 484
 485 ###
 486 ### This is *NOT* boolean.pm - deliberately not using a singleton
 487 ###
 488 {
 489   package # hide from pause
 490     DBIx::Class::_Util::_Bool;
 491   use overload
 492     bool => sub { ${$_[0]} },
 493     fallback => 1,
 494   ;
 495 }
 496 sub true () { my $x = 1; bless \$x, "DBIx::Class::_Util::_Bool" }
 497 sub false () { my $x = 0; bless \$x, "DBIx::Class::_Util::_Bool" }
 498
 499 sub scope_guard (&) {
 500   croak 'Calling scope_guard() in void context makes no sense'
 501     if ! defined wantarray;
 502
 503   # no direct blessing of coderefs - DESTROY is buggy on those
 504   bless [ $_[0] ], 'DBIx::Class::_Util::ScopeGuard';
 505 }
 506 {
 507   package #
 508     DBIx::Class::_Util::ScopeGuard;
 509
 510   sub DESTROY {
 511     &DBIx::Class::_Util::detected_reinvoked_destructor;
 512
 513     local $@ if DBIx::Class::_ENV_::UNSTABLE_DOLLARAT;
 514
 515     eval {
 516       $_[0]->[0]->();
 517       1;
 518     }
 519       or
 520     DBIx::Class::_Util::emit_loud_diag(
 521       emit_dups => 1,
 522       msg => "Execution of scope guard $_[0] resulted in the non-trappable exception:\n\n$@\n "
 523     );
 524   }
 525 }
 526
 527
 528 sub is_exception ($) {
 529   my $e = $_[0];
 530
 531   # FIXME
 532   # this is not strictly correct - an eval setting $@ to undef
 533   # is *not* the same as an eval setting $@ to ''
 534   # but for the sake of simplicity assume the following for
 535   # the time being
 536   return 0 unless defined $e;
 537
 538   my ($not_blank, $suberror);
 539   {
 540     local $SIG{__DIE__} if $SIG{__DIE__};
 541     local $@;
 542     eval {
 543       # The ne() here is deliberate - a plain length($e), or worse "$e" ne
 544       # will entirely obviate the need for the encolsing eval{}, as the
 545       # condition we guard against is a missing fallback overload
 546       $not_blank = ( $e ne '' );
 547       1;
 548     } or $suberror = $@;
 549   }
 550
 551   if (defined $suberror) {
 552     if (length (my $class = blessed($e) )) {
 553       carp_unique( sprintf(
 554         'External exception class %s implements partial (broken) overloading '
 555       . 'preventing its instances from being used in simple ($x eq $y) '
 556       . 'comparisons. Given Perl\'s "globally cooperative" exception '
 557       . 'handling this type of brokenness is extremely dangerous on '
 558       . 'exception objects, as it may (and often does) result in silent '
 559       . '"exception substitution". DBIx::Class tries to work around this '
 560       . 'as much as possible, but other parts of your software stack may '
 561       . 'not be even aware of this. Please submit a bugreport against the '
 562       . 'distribution containing %s and in the meantime apply a fix similar '
 563       . 'to the one shown at %s, in order to ensure your exception handling '
 564       . 'is saner application-wide. What follows is the actual error text '
 565       . "as generated by Perl itself:\n\n%s\n ",
 566         $class,
 567         $class,
 568         'http://v.gd/DBIC_overload_tempfix/',
 569         $suberror,
 570       ));
 571
 572       # workaround, keeps spice flowing
 573       $not_blank = !!( length $e );
 574     }
 575     else {
 576       # not blessed yet failed the 'ne'... this makes 0 sense...
 577       # just throw further
 578       die $suberror
 579     }
 580   }
 581   elsif (
 582     # a ref evaluating to '' is definitively a "null object"
 583     ( not $not_blank )
 584       and
 585     length( my $class = ref $e )
 586   ) {
 587     carp_unique(
 588       "Objects of external exception class '$class' stringify to '' (the "
 589     . 'empty string), implementing the so called null-object-pattern. '
 590     . 'Given Perl\'s "globally cooperative" exception handling using this '
 591     . 'class of exceptions is extremely dangerous, as it may (and often '
 592     . 'does) result in silent discarding of errors. DBIx::Class tries to '
 593     . 'work around this as much as possible, but other parts of your '
 594     . 'software stack may not be even aware of the problem. Please submit '
 595     . "a bugreport against the distribution containing '$class'",
 596     );
 597
 598     $not_blank = 1;
 599   }
 600
 601   return $not_blank;
 602 }
 603
 604 {
 605   my $callstack_state;
 606
 607   # Recreate the logic of try(), while reusing the catch()/finally() as-is
 608   #
 609   # FIXME: We need to move away from Try::Tiny entirely (way too heavy and
 610   # yes, shows up ON TOP of profiles) but this is a batle for another maint
 611   sub dbic_internal_try (&;@) {
 612
 613     my $try_cref = shift;
 614     my $catch_cref = undef;  # apparently this is a thing... https://rt.perl.org/Public/Bug/Display.html?id=119311
 615
 616     for my $arg (@_) {
 617
 618       if( ref($arg) eq 'Try::Tiny::Catch' ) {
 619
 620         croak 'dbic_internal_try() may not be followed by multiple catch() blocks'
 621           if $catch_cref;
 622
 623         $catch_cref = $$arg;
 624       }
 625       elsif ( ref($arg) eq 'Try::Tiny::Finally' ) {
 626         croak 'dbic_internal_try() does not support finally{}';
 627       }
 628       else {
 629         croak(
 630           'dbic_internal_try() encountered an unexpected argument '
 631         . "'@{[ defined $arg ? $arg : 'UNDEF' ]}' - perhaps "
 632         . 'a missing semi-colon before or ' # trailing space important
 633         );
 634       }
 635     }
 636
 637     my $wantarray = wantarray;
 638     my $preexisting_exception = $@;
 639
 640     my @ret;
 641     my $all_good = eval {
 642       $@ = $preexisting_exception;
 643
 644       local $callstack_state->{in_internal_try} = 1
 645         unless $callstack_state->{in_internal_try};
 646
 647       # always unset - someone may have snuck it in
 648       local $SIG{__DIE__} if $SIG{__DIE__};
 649
 650       if( $wantarray ) {
 651         @ret = $try_cref->();
 652       }
 653       elsif( defined $wantarray ) {
 654         $ret[0] = $try_cref->();
 655       }
 656       else {
 657         $try_cref->();
 658       }
 659
 660       1;
 661     };
 662
 663     my $exception = $@;
 664     $@ = $preexisting_exception;
 665
 666     if ( $all_good ) {
 667       return $wantarray ? @ret : $ret[0]
 668     }
 669     elsif ( $catch_cref ) {
 670       for ( $exception ) {
 671         return $catch_cref->($exception);
 672       }
 673     }
 674
 675     return;
 676   }
 677
 678   sub in_internal_try { !! $callstack_state->{in_internal_try} }
 679 }
 680
 681 {
 682   my $destruction_registry = {};
 683
 684   sub DBIx::Class::__Util_iThreads_handler__::CLONE {
 685     %$destruction_registry = map {
 686       (defined $_)
 687         ? ( refaddr($_) => $_ )
 688         : ()
 689     } values %$destruction_registry;
 690
 691     weaken($_) for values %$destruction_registry;
 692
 693     # Dummy NEXTSTATE ensuring the all temporaries on the stack are garbage
 694     # collected before leaving this scope. Depending on the code above, this
 695     # may very well be just a preventive measure guarding future modifications
 696     undef;
 697   }
 698
 699   # This is almost invariably invoked from within DESTROY
 700   # throwing exceptions won't work
 701   sub detected_reinvoked_destructor {
 702
 703     # quick "garbage collection" pass - prevents the registry
 704     # from slowly growing with a bunch of undef-valued keys
 705     defined $destruction_registry->{$_} or delete $destruction_registry->{$_}
 706       for keys %$destruction_registry;
 707
 708     if (! length ref $_[0]) {
 709       emit_loud_diag(
 710         emit_dups => 1,
 711         msg => (caller(0))[3] . '() expects a blessed reference'
 712       );
 713       return undef; # don't know wtf to do
 714     }
 715     elsif (! defined $destruction_registry->{ my $addr = refaddr($_[0]) } ) {
 716       weaken( $destruction_registry->{$addr} = $_[0] );
 717       return 0;
 718     }
 719     else {
 720       emit_loud_diag( msg => sprintf (
 721         'Preventing *MULTIPLE* DESTROY() invocations on %s - an *EXTREMELY '
 722       . 'DANGEROUS* condition which is *ALMOST CERTAINLY GLOBAL* within your '
 723       . 'application, affecting *ALL* classes without active protection against '
 724       . 'this. Diagnose and fix the root cause ASAP!!!%s',
 725       refdesc $_[0],
 726         ( ( $INC{'Devel/StackTrace.pm'} and ! do { local $@; eval { Devel::StackTrace->VERSION(2) } } )
 727           ? " (likely culprit Devel::StackTrace\@@{[ Devel::StackTrace->VERSION ]} found in %INC, http://is.gd/D_ST_refcap)"
 728           : ''
 729         )
 730       ));
 731
 732       return 1;
 733     }
 734   }
 735 }
 736
 737 my $module_name_rx = qr/ \A [A-Z_a-z] [0-9A-Z_a-z]* (?: :: [0-9A-Z_a-z]+ )* \z /x;
 738 my $ver_rx =         qr/ \A [0-9]+ (?: \. [0-9]+ )* (?: \_ [0-9]+ )*        \z /x;
 739
 740 sub modver_gt_or_eq ($$) {
 741   my ($mod, $ver) = @_;
 742
 743   croak "Nonsensical module name supplied"
 744     if ! defined $mod or $mod !~ $module_name_rx;
 745
 746   croak "Nonsensical minimum version supplied"
 747     if ! defined $ver or $ver !~ $ver_rx;
 748
 749   my $ver_cache = do {
 750     no strict 'refs';
 751     ${"${mod}::__DBIC_MODULE_VERSION_CHECKS__"} ||= {}
 752   };
 753
 754   ! defined $ver_cache->{$ver}
 755     and
 756   $ver_cache->{$ver} = do {
 757
 758     local $SIG{__WARN__} = sigwarn_silencer( qr/\Qisn't numeric in subroutine entry/ )
 759       if SPURIOUS_VERSION_CHECK_WARNINGS;
 760
 761     # prevent captures by potential __WARN__ hooks or the like:
 762     # there is nothing of value that can be happening here, and
 763     # leaving a hook in-place can only serve to fail some test
 764     local $SIG{__WARN__} if (
 765       ! SPURIOUS_VERSION_CHECK_WARNINGS
 766         and
 767       $SIG{__WARN__}
 768     );
 769
 770     croak "$mod does not seem to provide a version (perhaps it never loaded)"
 771       unless $mod->VERSION;
 772
 773     local $SIG{__DIE__} if $SIG{__DIE__};
 774     local $@;
 775     eval { $mod->VERSION($ver) } ? 1 : 0;
 776   };
 777
 778   $ver_cache->{$ver};
 779 }
 780
 781 sub modver_gt_or_eq_and_lt ($$$) {
 782   my ($mod, $v_ge, $v_lt) = @_;
 783
 784   croak "Nonsensical maximum version supplied"
 785     if ! defined $v_lt or $v_lt !~ $ver_rx;
 786
 787   return (
 788     modver_gt_or_eq($mod, $v_ge)
 789       and
 790     ! modver_gt_or_eq($mod, $v_lt)
 791   ) ? 1 : 0;
 792 }
 793
 794 {
 795
 796   sub describe_class_methods {
 797     my $args = (
 798       ref $_[0] eq 'HASH'                 ? $_[0]
 799     : ( @_ == 1 and ! length ref $_[0] )  ? { class => $_[0] }
 800     :                                       { @_ }
 801     );
 802
 803     my ($class, $requested_mro) = @{$args}{qw( class use_mro )};
 804
 805     croak "Expecting a class name either as the sole argument or a 'class' option"
 806       if not defined $class or $class !~ $module_name_rx;
 807
 808     croak(
 809       "The supplied 'class' argument is tainted: this is *extremely* "
 810     . 'dangerous, fix your code ASAP!!! ( for more details read through '
 811     . 'https://is.gd/perl_mro_taint_wtf )'
 812     ) if (
 813       DBIx::Class::_ENV_::TAINT_MODE
 814         and
 815       Scalar::Util::tainted($class)
 816     );
 817
 818     $requested_mro ||= mro::get_mro($class);
 819
 820     # mro::set_mro() does not bump pkg_gen - WHAT THE FUCK?!
 821     my $query_cache_key = "$class|$requested_mro";
 822
 823     my $internal_cache_key =
 824       ( mro::get_mro($class) eq $requested_mro )
 825         ? $class
 826         : $query_cache_key
 827     ;
 828
 829     # use a cache on old MRO, since while we are recursing in this function
 830     # nothing can possibly change (the speedup is immense)
 831     # (yes, people could be tie()ing the stash and adding methods on access
 832     # but there is a limit to how much crazy can be supported here)
 833     #
 834     # we use the cache for linear_isa lookups on new MRO as well - it adds
 835     # a *tiny* speedup, and simplifies the code a lot
 836     #
 837     local $__describe_class_query_cache->{'!internal!'} = {}
 838       unless $__describe_class_query_cache->{'!internal!'};
 839
 840     my $my_gen = 0;
 841
 842     $my_gen += get_real_pkg_gen($_) for ( my @full_ISA = (
 843
 844       @{
 845         $__describe_class_query_cache->{'!internal!'}{$internal_cache_key}{linear_isa}
 846           ||=
 847         mro::get_linear_isa($class, $requested_mro)
 848       },
 849
 850       ((
 851         $__describe_class_query_cache->{'!internal!'}{$class}{is_universal}
 852           ||=
 853         mro::is_universal($class)
 854       ) ? () : @{
 855         $__describe_class_query_cache->{'!internal!'}{UNIVERSAL}{linear_isa}
 856           ||=
 857         mro::get_linear_isa("UNIVERSAL")
 858       }),
 859
 860     ));
 861
 862     my $slot = $__describe_class_query_cache->{$query_cache_key} ||= {};
 863
 864     unless ( ($slot->{cumulative_gen}||0) == $my_gen ) {
 865
 866       # reset
 867       %$slot = (
 868         class => $class,
 869         isa => { map { $_ => 1 } @full_ISA },
 870         linear_isa => [
 871           @{ $__describe_class_query_cache->{'!internal!'}{$internal_cache_key}{linear_isa} }
 872             [ 1 .. $#{$__describe_class_query_cache->{'!internal!'}{$internal_cache_key}{linear_isa}} ]
 873         ],
 874         mro => {
 875           type => $requested_mro,
 876           is_c3 => ( ($requested_mro eq 'c3') ? 1 : 0 ),
 877         },
 878         cumulative_gen => $my_gen,
 879       );
 880
 881       # remove ourselves from ISA
 882       shift @full_ISA;
 883
 884       # ensure the cache is populated for the parents, code below can then
 885       # efficiently operate over the query_cache directly
 886       describe_class_methods($_) for reverse @full_ISA;
 887
 888       no strict 'refs';
 889
 890       # combine full ISA-order inherited and local method list into a
 891       # "shadowing stack"
 892
 893       (
 894         unshift @{ $slot->{methods}{$_->{name}} }, $_
 895
 896           and
 897
 898         (
 899           $_->{via_class} ne $class
 900             or
 901           $slot->{methods_defined_in_class}{$_->{name}} = $_
 902         )
 903
 904           and
 905
 906         @{ $slot->{methods}{$_->{name}} } > 1
 907
 908           and
 909
 910         $slot->{methods_with_supers}{$_->{name}} = $slot->{methods}{$_->{name}}
 911
 912       ) for (
 913
 914         # what describe_class_methods for @full_ISA produced above
 915         ( map { values %{
 916           $__describe_class_query_cache->{$_}{methods_defined_in_class} || {}
 917         } } map { "$_|" . mro::get_mro($_) } reverse @full_ISA ),
 918
 919         # our own non-cleaned subs + their attributes
 920         ( map {
 921           (
 922             # need to account for dummy helper crefs under OLD_MRO
 923             (
 924               ! DBIx::Class::_ENV_::OLD_MRO
 925                 or
 926               ! ( ( $Class::C3::MRO{$class} || {} )->{methods}{$_} )
 927             )
 928               and
 929             # these 2 OR-ed checks are sufficient for 5.10+
 930             (
 931               ref(\ "${class}::"->{$_} ) ne 'GLOB'
 932                 or
 933               defined( *{ "${class}::"->{$_} }{CODE} )
 934             )
 935           ) ? {
 936               via_class => $class,
 937               name => $_,
 938               attributes => { map { $_ => 1 } do {
 939                 my @attrs;
 940                 local $@;
 941                 local $SIG{__DIE__} if $SIG{__DIE__};
 942                 # attributes::get may throw on blessed-false crefs :/
 943                 eval { @attrs = attributes::get( \&{"${class}::${_}"} ); 1 }
 944                   or warn "Unable to determine attributes of the \\&${class}::$_ method due to following error: $@";
 945                 @attrs;
 946               } },
 947             }
 948             : ()
 949         } keys %{"${class}::"} )
 950       );
 951
 952
 953       # recalculate the pkg_gen on newer perls under Taint mode,
 954       # because of shit like:
 955       # perl -T -Mmro -e 'package Foo; sub bar {}; defined( *{ "Foo::"->{bar}}{CODE} ) and warn mro::get_pkg_gen("Foo") for (1,2,3)'
 956       #
 957       if (
 958         ! DBIx::Class::_ENV_::OLD_MRO
 959           and
 960         DBIx::Class::_ENV_::TAINT_MODE
 961       ) {
 962
 963         $slot->{cumulative_gen} = 0;
 964         $slot->{cumulative_gen} += get_real_pkg_gen($_)
 965           for $class, @full_ISA;
 966       }
 967     }
 968
 969     # RV
 970     +{ %$slot };
 971   }
 972 }
 973
 974
 975 #
 976 # Why not just use some higher-level module or at least File::Spec here?
 977 # Because:
 978 # 1)  This is a *very* rarely used function, and the deptree is large
 979 #     enough already as it is
 980 #
 981 # 2)  (more importantly) Our tooling is utter shit in this area. There
 982 #     is no comprehensive support for UNC paths in PathTools and there
 983 #     are also various small bugs in representation across different
 984 #     path-manipulation CPAN offerings.
 985 #
 986 # Since this routine is strictly used for logical path processing (it
 987 # *must* be able to work with not-yet-existing paths), use this seemingly
 988 # simple but I *think* complete implementation to feed to other consumers
 989 #
 990 # If bugs are ever uncovered in this routine, *YOU ARE URGED TO RESIST*
 991 # the impulse to bring in an external dependency. During runtime there
 992 # is exactly one spot that could potentially maybe once in a blue moon
 993 # use this function. Keep it lean.
 994 #
 995 sub parent_dir ($) {
 996   ( $_[0] =~ m{  [\/\\]  ( \.{0,2} ) ( [\/\\]* ) \z }x )
 997     ? (
 998       $_[0]
 999         .
1000       ( ( length($1) and ! length($2) ) ? '/' : '' )
1001         .
1002       '../'
1003     )
1004     : (
1005       require File::Spec
1006         and
1007       File::Spec->catpath (
1008         ( File::Spec->splitpath( "$_[0]" ) )[0,1],
1009         '/',
1010       )
1011     )
1012   ;
1013 }
1014
1015 sub mkdir_p ($) {
1016   require File::Path;
1017   # do not ask for a recent version, use 1.x API calls
1018   File::Path::mkpath([ "$_[0]" ]);  # File::Path does not like objects
1019 }
1020
1021
1022 {
1023   my $list_ctx_ok_stack_marker;
1024
1025   sub fail_on_internal_wantarray () {
1026     return if $list_ctx_ok_stack_marker;
1027
1028     if (! defined wantarray) {
1029       croak('fail_on_internal_wantarray() needs a tempvar to save the stack marker guard');
1030     }
1031
1032     my $cf = 1;
1033     while ( ( (CORE::caller($cf+1))[3] || '' ) =~ / :: (?:
1034
1035       # these are public API parts that alter behavior on wantarray
1036       search | search_related | slice | search_literal
1037
1038         |
1039
1040       # these are explicitly prefixed, since we only recognize them as valid
1041       # escapes when they come from the guts of CDBICompat
1042       CDBICompat .*? :: (?: search_where | retrieve_from_sql | retrieve_all )
1043
1044     ) $/x ) {
1045       $cf++;
1046     }
1047
1048     my ($fr, $want, $argdesc);
1049     {
1050       package DB;
1051       $fr = [ CORE::caller($cf) ];
1052       $want = ( CORE::caller($cf-1) )[5];
1053       $argdesc = ref $DB::args[0]
1054         ? DBIx::Class::_Util::refdesc($DB::args[0])
1055         : 'non '
1056       ;
1057     };
1058
1059     if (
1060       $want and $fr->[0] =~ /^(?:DBIx::Class|DBICx::)/
1061     ) {
1062       DBIx::Class::Exception->throw( sprintf (
1063         "Improper use of %s instance in list context at %s line %d\n\n    Stacktrace starts",
1064         $argdesc, @{$fr}[1,2]
1065       ), 'with_stacktrace');
1066     }
1067
1068     weaken( $list_ctx_ok_stack_marker = my $mark = [] );
1069
1070     $mark;
1071   }
1072 }
1073
1074 sub fail_on_internal_call {
1075   my ($fr, $argdesc);
1076   {
1077     package DB;
1078     $fr = [ CORE::caller(1) ];
1079     $argdesc =
1080       ( not defined $DB::args[0] )  ? 'UNAVAILABLE'
1081     : ( length ref $DB::args[0] )   ? DBIx::Class::_Util::refdesc($DB::args[0])
1082     : $DB::args[0] . ''
1083     ;
1084   };
1085
1086   my @fr2;
1087   # need to make allowance for a proxy-yet-direct call
1088   my $check_fr = (
1089     $fr->[0] eq 'DBIx::Class::ResultSourceProxy'
1090       and
1091     @fr2 = (CORE::caller(2))
1092       and
1093     (
1094       ( $fr->[3] =~ /([^:])+$/ )[0]
1095         eq
1096       ( $fr2[3] =~ /([^:])+$/ )[0]
1097     )
1098   )
1099     ? \@fr2
1100     : $fr
1101   ;
1102
1103
1104   die "\nMethod $fr->[3] is not marked with the 'DBIC_method_is_indirect_sugar' attribute\n\n" unless (
1105
1106     # unlikely but who knows...
1107     ! @$fr
1108
1109       or
1110
1111     # This is a weird-ass double-purpose method, only one branch of which is marked
1112     # as an illegal indirect call
1113     # Hence the 'indirect' attribute makes no sense
1114     # FIXME - likely need to mark this in some other manner
1115     $fr->[3] eq 'DBIx::Class::ResultSet::new'
1116
1117       or
1118
1119     # RsrcProxy stuff is special and not attr-annotated on purpose
1120     # Yet it is marked (correctly) as fail_on_internal_call(), as DBIC
1121     # itself should not call these methods as first-entry
1122     $fr->[3] =~ /^DBIx::Class::ResultSourceProxy::[^:]+$/
1123
1124       or
1125
1126     # FIXME - there is likely a more fine-graned way to escape "foreign"
1127     # callers, based on annotations... (albeit a slower one)
1128     # For the time being just skip in a dumb way
1129     $fr->[3] !~ /^DBIx::Class|^DBICx::|^DBICTest::/
1130
1131       or
1132
1133     grep
1134       { $_ eq 'DBIC_method_is_indirect_sugar' }
1135       do { no strict 'refs'; attributes::get( \&{ $fr->[3] }) }
1136   );
1137
1138
1139   if (
1140     defined $fr->[0]
1141       and
1142     $check_fr->[0] =~ /^(?:DBIx::Class|DBICx::)/
1143       and
1144     $check_fr->[1] !~ /\b(?:CDBICompat|ResultSetProxy)\b/  # no point touching there
1145   ) {
1146     DBIx::Class::Exception->throw( sprintf (
1147       "Illegal internal call of indirect proxy-method %s() with argument '%s': examine the last lines of the proxy method deparse below to determine what to call directly instead at %s on line %d\n\n%s\n\n    Stacktrace starts",
1148       $fr->[3], $argdesc, @{$fr}[1,2], ( $fr->[6] || do {
1149         require B::Deparse;
1150         no strict 'refs';
1151         B::Deparse->new->coderef2text(\&{$fr->[3]})
1152       }),
1153     ), 'with_stacktrace');
1154   }
1155 }
1156
1157 if (DBIx::Class::_ENV_::ASSERT_NO_ERRONEOUS_METAINSTANCE_USE) {
1158
1159   no warnings 'redefine';
1160
1161   my $next_bless = defined(&CORE::GLOBAL::bless)
1162     ? \&CORE::GLOBAL::bless
1163     : sub { CORE::bless($_[0], $_[1]) }
1164   ;
1165
1166   *CORE::GLOBAL::bless = sub {
1167     my $class = (@_ > 1) ? $_[1] : CORE::caller();
1168
1169     # allow for reblessing (role application)
1170     return $next_bless->( $_[0], $class )
1171       if defined blessed $_[0];
1172
1173     my $obj = $next_bless->( $_[0], $class );
1174
1175     my $calling_sub = (CORE::caller(1))[3] || '';
1176
1177     (
1178       # before 5.18 ->isa() will choke on the "0" package
1179       # which we test for in several obscure cases, sigh...
1180       !( DBIx::Class::_ENV_::PERL_VERSION < 5.018 )
1181         or
1182       $class
1183     )
1184       and
1185     (
1186       (
1187         $calling_sub !~ /^ (?:
1188           DBIx::Class::Schema::clone
1189             |
1190           DBIx::Class::DB::setup_schema_instance
1191         )/x
1192           and
1193         $class->isa("DBIx::Class::Schema")
1194       )
1195         or
1196       (
1197         $calling_sub ne 'DBIx::Class::ResultSource::new'
1198           and
1199         $class->isa("DBIx::Class::ResultSource")
1200       )
1201     )
1202       and
1203     local $Carp::CarpLevel = $Carp::CarpLevel + 1
1204       and
1205     Carp::confess("Improper instantiation of '$obj': you *MUST* call the corresponding constructor");
1206
1207
1208     $obj;
1209   };
1210 }
1211
1212 1;