lib/DBIx/Class/_Util.pm

   1 package # hide from PAUSE
   2   DBIx::Class::_Util;
   3
   4 use DBIx::Class::StartupCheck;  # load es early as we can, usually a noop
   5
   6 use warnings;
   7 use strict;
   8
   9 my $mro_recursor_stack;
  10
  11 BEGIN {
  12   package # hide from pause
  13     DBIx::Class::_ENV_;
  14
  15   use Config;
  16
  17   use constant {
  18     PERL_VERSION => "$]",
  19     OS_NAME => "$^O",
  20   };
  21
  22   use constant {
  23
  24     # but of course
  25     BROKEN_FORK => (OS_NAME eq 'MSWin32') ? 1 : 0,
  26
  27     BROKEN_GOTO => ( PERL_VERSION < 5.008003 ) ? 1 : 0,
  28
  29     # perl -MScalar::Util=weaken -e 'weaken( $hash{key} = \"value" )'
  30     BROKEN_WEAK_SCALARREF_VALUES => ( PERL_VERSION < 5.008003 ) ? 1 : 0,
  31
  32     HAS_ITHREADS => $Config{useithreads} ? 1 : 0,
  33
  34     UNSTABLE_DOLLARAT => ( PERL_VERSION < 5.013002 ) ? 1 : 0,
  35
  36     ( map
  37       #
  38       # the "DBIC_" prefix below is crucial - this is what makes CI pick up
  39       # all envvars without further adjusting its scripts
  40       # DO NOT CHANGE to the more logical { $_ => !!( $ENV{"DBIC_$_"} ) }
  41       #
  42       { substr($_, 5) => !!( $ENV{$_} ) }
  43       qw(
  44         DBIC_SHUFFLE_UNORDERED_RESULTSETS
  45         DBIC_ASSERT_NO_INTERNAL_WANTARRAY
  46         DBIC_ASSERT_NO_INTERNAL_INDIRECT_CALLS
  47         DBIC_STRESSTEST_UTF8_UPGRADE_GENERATED_COLLAPSER_SOURCE
  48         DBIC_STRESSTEST_COLUMN_INFO_UNAWARE_STORAGE
  49       )
  50     ),
  51
  52     IV_SIZE => $Config{ivsize},
  53   };
  54
  55   if ( PERL_VERSION < 5.009_005) {
  56     require MRO::Compat;
  57     constant->import( OLD_MRO => 1 );
  58
  59     #
  60     # Yes, I know this is a rather PHP-ish name, but please first read
  61     # https://metacpan.org/source/BOBTFISH/MRO-Compat-0.12/lib/MRO/Compat.pm#L363-368
  62     #
  63     # Even if we are using Class::C3::XS it still won't work, as doing
  64     #   defined( *{ "SubClass::"->{$_} }{CODE} )
  65     # will set pkg_gen to the same value for SubClass and *ALL PARENTS*
  66     #
  67     *DBIx::Class::_Util::get_real_pkg_gen = sub ($) {
  68       require Digest::MD5;
  69       require Math::BigInt;
  70
  71       # the non-assign-unless-there-is-a-hash is deliberate
  72       ( $mro_recursor_stack->{cache} || {} )->{$_[0]}{gen} ||= (
  73         Math::BigInt->new( '0x' . ( Digest::MD5::md5_hex( join "\0", map {
  74
  75           ( $mro_recursor_stack->{cache} || {} )->{$_}{methlist} ||= do {
  76
  77             my $class = $_;
  78             no strict 'refs';
  79
  80             # RV to be hashed up and turned into a number
  81             join "\0", (
  82               $class,
  83               map
  84                 {(
  85                   # stringification should be sufficient, ignore names/refaddr entirely
  86                   $_,
  87                   attributes::get( $_ ),
  88                 )}
  89                 map
  90                   {(
  91                     # skip dummy C::C3 helper crefs
  92                     ! ( ( $Class::C3::MRO{$class} || {} )->{methods}{$_} )
  93                       and
  94                     (
  95                       ref(\ "${class}::"->{$_} ) ne 'GLOB'
  96                         or
  97                       defined( *{ "${class}::"->{$_} }{CODE} )
  98                     )
  99                   )
 100                     ? ( \&{"${class}::$_"} )
 101                     : ()
 102                   }
 103                   keys %{ "${class}::" }
 104             );
 105           }
 106         } (
 107
 108           @{
 109             ( $mro_recursor_stack->{cache} || {} )->{$_[0]}{linear_isa}
 110               ||=
 111             mro::get_linear_isa($_[0])
 112           },
 113
 114           ((
 115             ( $mro_recursor_stack->{cache} || {} )->{$_[0]}{is_universal}
 116               ||=
 117             mro::is_universal($_[0])
 118           ) ? () : @{
 119             ( $mro_recursor_stack->{cache} || {} )->{UNIVERSAL}{linear_isa}
 120               ||=
 121             mro::get_linear_isa("UNIVERSAL")
 122           } ),
 123
 124         ) ) ) )
 125       );
 126     };
 127   }
 128   else {
 129     require mro;
 130     constant->import( OLD_MRO => 0 );
 131     *DBIx::Class::_Util::get_real_pkg_gen = \&mro::get_pkg_gen;
 132   }
 133
 134   # Both of these are no longer used for anything. However bring
 135   # them back after they were purged in 08a8d8f1, as there appear
 136   # to be outfits with *COPY PASTED* pieces of lib/DBIx/Class/Storage/*
 137   # in their production codebases. There is no point in breaking these
 138   # if whatever they used actually continues to work
 139   my $warned;
 140   my $sigh = sub {
 141
 142     require Carp;
 143     my $cluck = "The @{[ (caller(1))[3] ]} constant is no more - adjust your code" . Carp::longmess();
 144
 145     warn $cluck unless $warned->{$cluck}++;
 146
 147     0;
 148   };
 149   sub DBICTEST () { &$sigh }
 150   sub PEEPEENESS () { &$sigh }
 151 }
 152
 153 use constant SPURIOUS_VERSION_CHECK_WARNINGS => ( DBIx::Class::_ENV_::PERL_VERSION < 5.010 ? 1 : 0);
 154
 155 # FIXME - this is not supposed to be here
 156 # Carp::Skip to the rescue soon
 157 use DBIx::Class::Carp '^DBIx::Class|^DBICTest';
 158
 159 use B ();
 160 use Carp 'croak';
 161 use Storable 'nfreeze';
 162 use Scalar::Util qw(weaken blessed reftype refaddr);
 163 use Sub::Quote qw(qsub);
 164 use Sub::Name ();
 165 use attributes ();
 166
 167 # Already correctly prototyped: perlbrew exec perl -MStorable -e 'warn prototype \&Storable::dclone'
 168 BEGIN { *deep_clone = \&Storable::dclone }
 169
 170 use base 'Exporter';
 171 our @EXPORT_OK = qw(
 172   sigwarn_silencer modver_gt_or_eq modver_gt_or_eq_and_lt
 173   fail_on_internal_wantarray fail_on_internal_call
 174   refdesc refcount hrefaddr set_subname describe_class_methods
 175   scope_guard detected_reinvoked_destructor
 176   true false
 177   is_exception dbic_internal_try visit_namespaces
 178   quote_sub qsub perlstring serialize deep_clone dump_value uniq
 179   parent_dir mkdir_p
 180   UNRESOLVABLE_CONDITION
 181 );
 182
 183 use constant UNRESOLVABLE_CONDITION => \ '1 = 0';
 184
 185 # Override forcing no_defer, and adding naming consistency checks
 186 our %refs_closed_over_by_quote_sub_installed_crefs;
 187 sub quote_sub {
 188   Carp::confess( "Anonymous quoting not supported by the DBIC quote_sub override - supply a sub name" ) if
 189     @_ < 2
 190       or
 191     ! defined $_[1]
 192       or
 193     length ref $_[1]
 194   ;
 195
 196   Carp::confess( "The DBIC quote_sub override expects sub name '$_[0]' to be fully qualified" )
 197     unless (my $stash) = $_[0] =~ /^(.+)::/;
 198
 199   Carp::confess(
 200     "The DBIC sub_quote override does not support 'no_install'"
 201   ) if (
 202     $_[3]
 203       and
 204     $_[3]->{no_install}
 205   );
 206
 207   Carp::confess(
 208     'The DBIC quote_sub override expects the namespace-part of sub name '
 209   . "'$_[0]' to match the supplied package argument '$_[3]->{package}'"
 210   ) if (
 211     $_[3]
 212       and
 213     defined $_[3]->{package}
 214       and
 215     $stash ne $_[3]->{package}
 216   );
 217
 218   my @caller = caller(0);
 219   my $sq_opts = {
 220     package => $caller[0],
 221     hints => $caller[8],
 222     warning_bits => $caller[9],
 223     hintshash => $caller[10],
 224     %{ $_[3] || {} },
 225
 226     # explicitly forced for everything
 227     no_defer => 1,
 228   };
 229
 230   weaken (
 231     # just use a growing counter, no need to perform neither compaction
 232     # nor any special ithread-level handling
 233     $refs_closed_over_by_quote_sub_installed_crefs
 234      { scalar keys %refs_closed_over_by_quote_sub_installed_crefs }
 235       = $_
 236   ) for grep {
 237     length ref $_
 238       and
 239     (
 240       ! DBIx::Class::_ENV_::BROKEN_WEAK_SCALARREF_VALUES
 241         or
 242       ref $_ ne 'SCALAR'
 243     )
 244   } values %{ $_[2] || {} };
 245
 246   Sub::Quote::quote_sub( $_[0], $_[1], $_[2]||{}, $sq_opts );
 247 }
 248
 249 sub sigwarn_silencer ($) {
 250   my $pattern = shift;
 251
 252   croak "Expecting a regexp" if ref $pattern ne 'Regexp';
 253
 254   my $orig_sig_warn = $SIG{__WARN__} || sub { CORE::warn(@_) };
 255
 256   return sub { &$orig_sig_warn unless $_[0] =~ $pattern };
 257 }
 258
 259 sub perlstring ($) { q{"}. quotemeta( shift ). q{"} };
 260
 261 sub hrefaddr ($) { sprintf '0x%x', &refaddr||0 }
 262
 263 sub refdesc ($) {
 264   croak "Expecting a reference" if ! length ref $_[0];
 265
 266   # be careful not to trigger stringification,
 267   # reuse @_ as a scratch-pad
 268   sprintf '%s%s(0x%x)',
 269     ( defined( $_[1] = blessed $_[0]) ? "$_[1]=" : '' ),
 270     reftype $_[0],
 271     refaddr($_[0]),
 272   ;
 273 }
 274
 275 sub refcount ($) {
 276   croak "Expecting a reference" if ! length ref $_[0];
 277
 278   # No tempvars - must operate on $_[0], otherwise the pad
 279   # will count as an extra ref
 280   B::svref_2object($_[0])->REFCNT;
 281 }
 282
 283 sub visit_namespaces {
 284   my $args = { (ref $_[0]) ? %{$_[0]} : @_ };
 285
 286   my $visited_count = 1;
 287
 288   # A package and a namespace are subtly different things
 289   $args->{package} ||= 'main';
 290   $args->{package} = 'main' if $args->{package} =~ /^ :: (?: main )? $/x;
 291   $args->{package} =~ s/^:://;
 292
 293   if ( $args->{action}->($args->{package}) ) {
 294     my $ns =
 295       ( ($args->{package} eq 'main') ? '' :  $args->{package} )
 296         .
 297       '::'
 298     ;
 299
 300     $visited_count += visit_namespaces( %$args, package => $_ ) for
 301       grep
 302         # this happens sometimes on %:: traversal
 303         { $_ ne '::main' }
 304         map
 305           { $_ =~ /^(.+?)::$/ ? "$ns$1" : () }
 306           do { no strict 'refs'; keys %$ns }
 307     ;
 308   }
 309
 310   $visited_count;
 311 }
 312
 313 # FIXME In another life switch this to a polyfill like the one in namespace::clean
 314 sub set_subname ($$) {
 315
 316   # fully qualify name
 317   splice @_, 0, 1, caller(0) . "::$_[0]"
 318     if $_[0] !~ /::|'/;
 319
 320   &Sub::Name::subname;
 321 }
 322
 323 sub serialize ($) {
 324   local $Storable::canonical = 1;
 325   nfreeze($_[0]);
 326 }
 327
 328 sub uniq {
 329   my( %seen, $seen_undef, $numeric_preserving_copy );
 330   grep { not (
 331     defined $_
 332       ? $seen{ $numeric_preserving_copy = $_ }++
 333       : $seen_undef++
 334   ) } @_;
 335 }
 336
 337 my $dd_obj;
 338 sub dump_value ($) {
 339   local $Data::Dumper::Indent = 1
 340     unless defined $Data::Dumper::Indent;
 341
 342   my $dump_str = (
 343     $dd_obj
 344       ||=
 345     do {
 346       require Data::Dumper;
 347       my $d = Data::Dumper->new([])
 348         ->Purity(0)
 349         ->Pad('')
 350         ->Useqq(1)
 351         ->Terse(1)
 352         ->Freezer('')
 353         ->Quotekeys(0)
 354         ->Bless('bless')
 355         ->Pair(' => ')
 356         ->Sortkeys(1)
 357         ->Deparse(1)
 358       ;
 359
 360       $d->Sparseseen(1) if modver_gt_or_eq (
 361         'Data::Dumper', '2.136'
 362       );
 363
 364       $d;
 365     }
 366   )->Values([$_[0]])->Dump;
 367
 368   $dd_obj->Reset->Values([]);
 369
 370   $dump_str;
 371 }
 372
 373 ###
 374 ### This is *NOT* boolean.pm - deliberately not using a singleton
 375 ###
 376 {
 377   package # hide from pause
 378     DBIx::Class::_Util::_Bool;
 379   use overload
 380     bool => sub { ${$_[0]} },
 381     fallback => 1,
 382   ;
 383 }
 384 sub true () { my $x = 1; bless \$x, "DBIx::Class::_Util::_Bool" }
 385 sub false () { my $x = 0; bless \$x, "DBIx::Class::_Util::_Bool" }
 386
 387 sub scope_guard (&) {
 388   croak 'Calling scope_guard() in void context makes no sense'
 389     if ! defined wantarray;
 390
 391   # no direct blessing of coderefs - DESTROY is buggy on those
 392   bless [ $_[0] ], 'DBIx::Class::_Util::ScopeGuard';
 393 }
 394 {
 395   package #
 396     DBIx::Class::_Util::ScopeGuard;
 397
 398   sub DESTROY {
 399     &DBIx::Class::_Util::detected_reinvoked_destructor;
 400
 401     local $@ if DBIx::Class::_ENV_::UNSTABLE_DOLLARAT;
 402
 403     eval {
 404       $_[0]->[0]->();
 405       1;
 406     }
 407       or
 408     Carp::cluck(
 409       "Execution of scope guard $_[0] resulted in the non-trappable exception:\n\n$@"
 410     );
 411   }
 412 }
 413
 414
 415 sub is_exception ($) {
 416   my $e = $_[0];
 417
 418   # FIXME
 419   # this is not strictly correct - an eval setting $@ to undef
 420   # is *not* the same as an eval setting $@ to ''
 421   # but for the sake of simplicity assume the following for
 422   # the time being
 423   return 0 unless defined $e;
 424
 425   my ($not_blank, $suberror);
 426   {
 427     local $SIG{__DIE__} if $SIG{__DIE__};
 428     local $@;
 429     eval {
 430       # The ne() here is deliberate - a plain length($e), or worse "$e" ne
 431       # will entirely obviate the need for the encolsing eval{}, as the
 432       # condition we guard against is a missing fallback overload
 433       $not_blank = ( $e ne '' );
 434       1;
 435     } or $suberror = $@;
 436   }
 437
 438   if (defined $suberror) {
 439     if (length (my $class = blessed($e) )) {
 440       carp_unique( sprintf(
 441         'External exception class %s implements partial (broken) overloading '
 442       . 'preventing its instances from being used in simple ($x eq $y) '
 443       . 'comparisons. Given Perl\'s "globally cooperative" exception '
 444       . 'handling this type of brokenness is extremely dangerous on '
 445       . 'exception objects, as it may (and often does) result in silent '
 446       . '"exception substitution". DBIx::Class tries to work around this '
 447       . 'as much as possible, but other parts of your software stack may '
 448       . 'not be even aware of this. Please submit a bugreport against the '
 449       . 'distribution containing %s and in the meantime apply a fix similar '
 450       . 'to the one shown at %s, in order to ensure your exception handling '
 451       . 'is saner application-wide. What follows is the actual error text '
 452       . "as generated by Perl itself:\n\n%s\n ",
 453         $class,
 454         $class,
 455         'http://v.gd/DBIC_overload_tempfix/',
 456         $suberror,
 457       ));
 458
 459       # workaround, keeps spice flowing
 460       $not_blank = !!( length $e );
 461     }
 462     else {
 463       # not blessed yet failed the 'ne'... this makes 0 sense...
 464       # just throw further
 465       die $suberror
 466     }
 467   }
 468   elsif (
 469     # a ref evaluating to '' is definitively a "null object"
 470     ( not $not_blank )
 471       and
 472     length( my $class = ref $e )
 473   ) {
 474     carp_unique( sprintf(
 475       "Objects of external exception class '%s' stringify to '' (the "
 476     . 'empty string), implementing the so called null-object-pattern. '
 477     . 'Given Perl\'s "globally cooperative" exception handling using this '
 478     . 'class of exceptions is extremely dangerous, as it may (and often '
 479     . 'does) result in silent discarding of errors. DBIx::Class tries to '
 480     . 'work around this as much as possible, but other parts of your '
 481     . 'software stack may not be even aware of the problem. Please submit '
 482     . 'a bugreport against the distribution containing %s',
 483
 484       ($class) x 2,
 485     ));
 486
 487     $not_blank = 1;
 488   }
 489
 490   return $not_blank;
 491 }
 492
 493 {
 494   my $callstack_state;
 495
 496   # Recreate the logic of try(), while reusing the catch()/finally() as-is
 497   #
 498   # FIXME: We need to move away from Try::Tiny entirely (way too heavy and
 499   # yes, shows up ON TOP of profiles) but this is a batle for another maint
 500   sub dbic_internal_try (&;@) {
 501
 502     my $try_cref = shift;
 503     my $catch_cref = undef;  # apparently this is a thing... https://rt.perl.org/Public/Bug/Display.html?id=119311
 504
 505     for my $arg (@_) {
 506
 507       if( ref($arg) eq 'Try::Tiny::Catch' ) {
 508
 509         croak 'dbic_internal_try() may not be followed by multiple catch() blocks'
 510           if $catch_cref;
 511
 512         $catch_cref = $$arg;
 513       }
 514       elsif ( ref($arg) eq 'Try::Tiny::Finally' ) {
 515         croak 'dbic_internal_try() does not support finally{}';
 516       }
 517       else {
 518         croak(
 519           'dbic_internal_try() encountered an unexpected argument '
 520         . "'@{[ defined $arg ? $arg : 'UNDEF' ]}' - perhaps "
 521         . 'a missing semi-colon before or ' # trailing space important
 522         );
 523       }
 524     }
 525
 526     my $wantarray = wantarray;
 527     my $preexisting_exception = $@;
 528
 529     my @ret;
 530     my $all_good = eval {
 531       $@ = $preexisting_exception;
 532
 533       local $callstack_state->{in_internal_try} = 1
 534         unless $callstack_state->{in_internal_try};
 535
 536       # always unset - someone may have snuck it in
 537       local $SIG{__DIE__} if $SIG{__DIE__};
 538
 539       if( $wantarray ) {
 540         @ret = $try_cref->();
 541       }
 542       elsif( defined $wantarray ) {
 543         $ret[0] = $try_cref->();
 544       }
 545       else {
 546         $try_cref->();
 547       }
 548
 549       1;
 550     };
 551
 552     my $exception = $@;
 553     $@ = $preexisting_exception;
 554
 555     if ( $all_good ) {
 556       return $wantarray ? @ret : $ret[0]
 557     }
 558     elsif ( $catch_cref ) {
 559       for ( $exception ) {
 560         return $catch_cref->($exception);
 561       }
 562     }
 563
 564     return;
 565   }
 566
 567   sub in_internal_try { !! $callstack_state->{in_internal_try} }
 568 }
 569
 570 {
 571   my $destruction_registry = {};
 572
 573   sub DBIx::Class::__Util_iThreads_handler__::CLONE {
 574     %$destruction_registry = map {
 575       (defined $_)
 576         ? ( refaddr($_) => $_ )
 577         : ()
 578     } values %$destruction_registry;
 579
 580     weaken($_) for values %$destruction_registry;
 581
 582     # Dummy NEXTSTATE ensuring the all temporaries on the stack are garbage
 583     # collected before leaving this scope. Depending on the code above, this
 584     # may very well be just a preventive measure guarding future modifications
 585     undef;
 586   }
 587
 588   # This is almost invariably invoked from within DESTROY
 589   # throwing exceptions won't work
 590   sub detected_reinvoked_destructor {
 591
 592     # quick "garbage collection" pass - prevents the registry
 593     # from slowly growing with a bunch of undef-valued keys
 594     defined $destruction_registry->{$_} or delete $destruction_registry->{$_}
 595       for keys %$destruction_registry;
 596
 597     if (! length ref $_[0]) {
 598       printf STDERR '%s() expects a blessed reference %s',
 599         (caller(0))[3],
 600         Carp::longmess,
 601       ;
 602       return undef; # don't know wtf to do
 603     }
 604     elsif (! defined $destruction_registry->{ my $addr = refaddr($_[0]) } ) {
 605       weaken( $destruction_registry->{$addr} = $_[0] );
 606       return 0;
 607     }
 608     else {
 609       carp_unique ( sprintf (
 610         'Preventing *MULTIPLE* DESTROY() invocations on %s - an *EXTREMELY '
 611       . 'DANGEROUS* condition which is *ALMOST CERTAINLY GLOBAL* within your '
 612       . 'application, affecting *ALL* classes without active protection against '
 613       . 'this. Diagnose and fix the root cause ASAP!!!%s',
 614       refdesc $_[0],
 615         ( ( $INC{'Devel/StackTrace.pm'} and ! do { local $@; eval { Devel::StackTrace->VERSION(2) } } )
 616           ? " (likely culprit Devel::StackTrace\@@{[ Devel::StackTrace->VERSION ]} found in %INC, http://is.gd/D_ST_refcap)"
 617           : ''
 618         )
 619       ));
 620
 621       return 1;
 622     }
 623   }
 624 }
 625
 626 my $module_name_rx = qr/ \A [A-Z_a-z] [0-9A-Z_a-z]* (?: :: [0-9A-Z_a-z]+ )* \z /x;
 627 my $ver_rx =         qr/ \A [0-9]+ (?: \. [0-9]+ )* (?: \_ [0-9]+ )*        \z /x;
 628
 629 sub modver_gt_or_eq ($$) {
 630   my ($mod, $ver) = @_;
 631
 632   croak "Nonsensical module name supplied"
 633     if ! defined $mod or $mod !~ $module_name_rx;
 634
 635   croak "Nonsensical minimum version supplied"
 636     if ! defined $ver or $ver !~ $ver_rx;
 637
 638   no strict 'refs';
 639   my $ver_cache = ${"${mod}::__DBIC_MODULE_VERSION_CHECKS__"} ||= ( $mod->VERSION
 640     ? {}
 641     : croak "$mod does not seem to provide a version (perhaps it never loaded)"
 642   );
 643
 644   ! defined $ver_cache->{$ver}
 645     and
 646   $ver_cache->{$ver} = do {
 647
 648     local $SIG{__WARN__} = sigwarn_silencer( qr/\Qisn't numeric in subroutine entry/ )
 649       if SPURIOUS_VERSION_CHECK_WARNINGS;
 650
 651     local $SIG{__DIE__} if $SIG{__DIE__};
 652     local $@;
 653     eval { $mod->VERSION($ver) } ? 1 : 0;
 654   };
 655
 656   $ver_cache->{$ver};
 657 }
 658
 659 sub modver_gt_or_eq_and_lt ($$$) {
 660   my ($mod, $v_ge, $v_lt) = @_;
 661
 662   croak "Nonsensical maximum version supplied"
 663     if ! defined $v_lt or $v_lt !~ $ver_rx;
 664
 665   return (
 666     modver_gt_or_eq($mod, $v_ge)
 667       and
 668     ! modver_gt_or_eq($mod, $v_lt)
 669   ) ? 1 : 0;
 670 }
 671
 672 {
 673   # FIXME - should be a private my(), but I'm too uncertain whether
 674   # all bases are covered
 675   our $describe_class_query_cache;
 676
 677   sub describe_class_methods {
 678     my ($class, $requested_mro) = @_;
 679
 680     croak "Expecting a class name"
 681       if not defined $class or $class !~ $module_name_rx;
 682
 683     $requested_mro ||= mro::get_mro($class);
 684
 685     # mro::set_mro() does not bump pkg_gen - WHAT THE FUCK?!
 686     my $query_cache_key = "$class|$requested_mro";
 687
 688     my $stack_cache_key =
 689       ( mro::get_mro($class) eq $requested_mro )
 690         ? $class
 691         : $query_cache_key
 692     ;
 693
 694     # use a cache on old MRO, since while we are recursing in this function
 695     # nothing can possibly change (the speedup is immense)
 696     # (yes, people could be tie()ing the stash and adding methods on access
 697     # but there is a limit to how much crazy can be supported here)
 698     #
 699     # we use the cache for linear_isa lookups on new MRO as well - it adds
 700     # a *tiny* speedup, and simplifies the code a lot
 701     #
 702     local $mro_recursor_stack->{cache} = {}
 703       unless $mro_recursor_stack->{cache};
 704
 705     my $my_gen = 0;
 706
 707     $my_gen += get_real_pkg_gen($_) for ( my @full_ISA = (
 708
 709       @{
 710         $mro_recursor_stack->{cache}{$stack_cache_key}{linear_isa}
 711           ||=
 712         mro::get_linear_isa($class, $requested_mro)
 713       },
 714
 715       ((
 716         $mro_recursor_stack->{cache}{$class}{is_universal}
 717           ||=
 718         mro::is_universal($class)
 719       ) ? () : @{
 720         $mro_recursor_stack->{cache}{UNIVERSAL}{linear_isa}
 721           ||=
 722         mro::get_linear_isa("UNIVERSAL")
 723       }),
 724
 725     ));
 726
 727     my $slot = $describe_class_query_cache->{$query_cache_key} ||= {};
 728
 729     unless ( ($slot->{cumulative_gen}||0) == $my_gen ) {
 730
 731       # remove ourselves from ISA
 732       shift @full_ISA;
 733
 734       # reset
 735       %$slot = (
 736         class => $class,
 737         isa => [
 738           @{ $mro_recursor_stack->{cache}{$stack_cache_key}{linear_isa} }
 739             [ 1 .. $#{$mro_recursor_stack->{cache}{$stack_cache_key}{linear_isa}} ]
 740         ],
 741         mro => {
 742           type => $requested_mro,
 743           is_c3 => ( ($requested_mro eq 'c3') ? 1 : 0 ),
 744         },
 745         cumulative_gen => $my_gen,
 746       );
 747
 748       # ensure the cache is populated for the parents, code below can then
 749       # efficiently operate over the query_cache directly
 750       describe_class_methods($_) for reverse @full_ISA;
 751
 752       no strict 'refs';
 753
 754       # combine full ISA-order inherited and local method list into a
 755       # "shadowing stack"
 756
 757       (
 758         unshift @{ $slot->{methods}{$_->{name}} }, $_
 759
 760           and
 761
 762         (
 763           $_->{via_class} ne $class
 764             or
 765           $slot->{methods_defined_in_class}{$_->{name}} = $_
 766         )
 767
 768           and
 769
 770         @{ $slot->{methods}{$_->{name}} } > 1
 771
 772           and
 773
 774         $slot->{methods_with_supers}{$_->{name}} = $slot->{methods}{$_->{name}}
 775
 776       ) for (
 777
 778         # what describe_class_methods for @full_ISA produced above
 779         ( map { values %{
 780           $describe_class_query_cache->{$_}{methods_defined_in_class} || {}
 781         } } map { "$_|" . mro::get_mro($_) } reverse @full_ISA ),
 782
 783         # our own non-cleaned subs + their attributes
 784         ( map {
 785           (
 786             # need to account for dummy helper crefs under OLD_MRO
 787             (
 788               ! DBIx::Class::_ENV_::OLD_MRO
 789                 or
 790               ! ( ( $Class::C3::MRO{$class} || {} )->{methods}{$_} )
 791             )
 792               and
 793             # these 2 OR-ed checks are sufficient for 5.10+
 794             (
 795               ref(\ "${class}::"->{$_} ) ne 'GLOB'
 796                 or
 797               defined( *{ "${class}::"->{$_} }{CODE} )
 798             )
 799           ) ? {
 800               via_class => $class,
 801               name => $_,
 802               attributes => {
 803                 map { $_ => 1 } attributes::get( \&{"${class}::${_}"} )
 804               },
 805             }
 806             : ()
 807         } keys %{"${class}::"} )
 808       );
 809
 810
 811       # recalculate the pkg_gen on newer perls under Taint mode,
 812       # because of shit like:
 813       # perl -T -Mmro -e 'package Foo; sub bar {}; defined( *{ "Foo::"->{bar}}{CODE} ) and warn mro::get_pkg_gen("Foo") for (1,2,3)'
 814       #
 815       if (
 816         ! DBIx::Class::_ENV_::OLD_MRO
 817           and
 818         ${^TAINT}
 819       ) {
 820
 821         $slot->{cumulative_gen} = 0;
 822         $slot->{cumulative_gen} += get_real_pkg_gen($_)
 823           for $class, @full_ISA;
 824       }
 825     }
 826
 827     # RV
 828     +{ %$slot };
 829   }
 830 }
 831
 832
 833 #
 834 # Why not just use some higher-level module or at least File::Spec here?
 835 # Because:
 836 # 1)  This is a *very* rarely used function, and the deptree is large
 837 #     enough already as it is
 838 #
 839 # 2)  (more importantly) Our tooling is utter shit in this area. There
 840 #     is no comprehensive support for UNC paths in PathTools and there
 841 #     are also various small bugs in representation across different
 842 #     path-manipulation CPAN offerings.
 843 #
 844 # Since this routine is strictly used for logical path processing (it
 845 # *must* be able to work with not-yet-existing paths), use this seemingly
 846 # simple but I *think* complete implementation to feed to other consumers
 847 #
 848 # If bugs are ever uncovered in this routine, *YOU ARE URGED TO RESIST*
 849 # the impulse to bring in an external dependency. During runtime there
 850 # is exactly one spot that could potentially maybe once in a blue moon
 851 # use this function. Keep it lean.
 852 #
 853 sub parent_dir ($) {
 854   ( $_[0] =~ m{  [\/\\]  ( \.{0,2} ) ( [\/\\]* ) \z }x )
 855     ? (
 856       $_[0]
 857         .
 858       ( ( length($1) and ! length($2) ) ? '/' : '' )
 859         .
 860       '../'
 861     )
 862     : (
 863       require File::Spec
 864         and
 865       File::Spec->catpath (
 866         ( File::Spec->splitpath( "$_[0]" ) )[0,1],
 867         '/',
 868       )
 869     )
 870   ;
 871 }
 872
 873 sub mkdir_p ($) {
 874   require File::Path;
 875   # do not ask for a recent version, use 1.x API calls
 876   File::Path::mkpath([ "$_[0]" ]);  # File::Path does not like objects
 877 }
 878
 879
 880 {
 881   my $list_ctx_ok_stack_marker;
 882
 883   sub fail_on_internal_wantarray () {
 884     return if $list_ctx_ok_stack_marker;
 885
 886     if (! defined wantarray) {
 887       croak('fail_on_internal_wantarray() needs a tempvar to save the stack marker guard');
 888     }
 889
 890     my $cf = 1;
 891     while ( ( (CORE::caller($cf+1))[3] || '' ) =~ / :: (?:
 892
 893       # these are public API parts that alter behavior on wantarray
 894       search | search_related | slice | search_literal
 895
 896         |
 897
 898       # these are explicitly prefixed, since we only recognize them as valid
 899       # escapes when they come from the guts of CDBICompat
 900       CDBICompat .*? :: (?: search_where | retrieve_from_sql | retrieve_all )
 901
 902     ) $/x ) {
 903       $cf++;
 904     }
 905
 906     my ($fr, $want, $argdesc);
 907     {
 908       package DB;
 909       $fr = [ CORE::caller($cf) ];
 910       $want = ( CORE::caller($cf-1) )[5];
 911       $argdesc = ref $DB::args[0]
 912         ? DBIx::Class::_Util::refdesc($DB::args[0])
 913         : 'non '
 914       ;
 915     };
 916
 917     if (
 918       $want and $fr->[0] =~ /^(?:DBIx::Class|DBICx::)/
 919     ) {
 920       DBIx::Class::Exception->throw( sprintf (
 921         "Improper use of %s instance in list context at %s line %d\n\n    Stacktrace starts",
 922         $argdesc, @{$fr}[1,2]
 923       ), 'with_stacktrace');
 924     }
 925
 926     weaken( $list_ctx_ok_stack_marker = my $mark = [] );
 927
 928     $mark;
 929   }
 930 }
 931
 932 sub fail_on_internal_call {
 933   my ($fr, $argdesc);
 934   {
 935     package DB;
 936     $fr = [ CORE::caller(1) ];
 937     $argdesc = ref $DB::args[0]
 938       ? DBIx::Class::_Util::refdesc($DB::args[0])
 939       : ( $DB::args[0] . '' )
 940     ;
 941   };
 942
 943   my @fr2;
 944   # need to make allowance for a proxy-yet-direct call
 945   my $check_fr = (
 946     $fr->[0] eq 'DBIx::Class::ResultSourceProxy'
 947       and
 948     @fr2 = (CORE::caller(2))
 949       and
 950     (
 951       ( $fr->[3] =~ /([^:])+$/ )[0]
 952         eq
 953       ( $fr2[3] =~ /([^:])+$/ )[0]
 954     )
 955   )
 956     ? \@fr2
 957     : $fr
 958   ;
 959
 960   if (
 961     $argdesc
 962       and
 963     $check_fr->[0] =~ /^(?:DBIx::Class|DBICx::)/
 964       and
 965     $check_fr->[1] !~ /\b(?:CDBICompat|ResultSetProxy)\b/  # no point touching there
 966   ) {
 967     DBIx::Class::Exception->throw( sprintf (
 968       "Illegal internal call of indirect proxy-method %s() with argument '%s': examine the last lines of the proxy method deparse below to determine what to call directly instead at %s on line %d\n\n%s\n\n    Stacktrace starts",
 969       $fr->[3], $argdesc, @{$fr}[1,2], ( $fr->[6] || do {
 970         require B::Deparse;
 971         no strict 'refs';
 972         B::Deparse->new->coderef2text(\&{$fr->[3]})
 973       }),
 974     ), 'with_stacktrace');
 975   }
 976 }
 977
 978 1;