lib/DBIx/Class/_Util.pm

   1 package # hide from PAUSE
   2   DBIx::Class::_Util;
   3
   4 # load es early as we can, usually a noop
   5 use DBIx::Class::StartupCheck;
   6
   7 use warnings;
   8 use strict;
   9
  10 # For the love of everything that is crab-like: DO NOT reach into this
  11 # The entire thing is really fragile and should not be screwed with
  12 # unless absolutely and unavoidably necessary
  13 our $__describe_class_query_cache;
  14
  15 BEGIN {
  16   package # hide from pause
  17     DBIx::Class::_ENV_;
  18
  19   use Config;
  20
  21   use constant {
  22     PERL_VERSION => "$]",
  23     OS_NAME => "$^O",
  24   };
  25
  26   use constant {
  27
  28     # but of course
  29     BROKEN_FORK => (OS_NAME eq 'MSWin32') ? 1 : 0,
  30
  31     BROKEN_GOTO => ( PERL_VERSION < 5.008003 ) ? 1 : 0,
  32
  33     # perl -MScalar::Util=weaken -e 'weaken( $hash{key} = \"value" )'
  34     BROKEN_WEAK_SCALARREF_VALUES => ( PERL_VERSION < 5.008003 ) ? 1 : 0,
  35
  36     HAS_ITHREADS => $Config{useithreads} ? 1 : 0,
  37
  38     TAINT_MODE => 0 + ${^TAINT}, # tri-state: 0, 1, -1
  39
  40     UNSTABLE_DOLLARAT => ( PERL_VERSION < 5.013002 ) ? 1 : 0,
  41
  42     ( map
  43       #
  44       # the "DBIC_" prefix below is crucial - this is what makes CI pick up
  45       # all envvars without further adjusting its scripts
  46       # DO NOT CHANGE to the more logical { $_ => !!( $ENV{"DBIC_$_"} ) }
  47       #
  48       { substr($_, 5) => !!( $ENV{$_} ) }
  49       qw(
  50         DBIC_SHUFFLE_UNORDERED_RESULTSETS
  51         DBIC_ASSERT_NO_INTERNAL_WANTARRAY
  52         DBIC_ASSERT_NO_INTERNAL_INDIRECT_CALLS
  53         DBIC_ASSERT_NO_ERRONEOUS_METAINSTANCE_USE
  54         DBIC_ASSERT_NO_FAILING_SANITY_CHECKS
  55         DBIC_ASSERT_NO_INCONSISTENT_RELATIONSHIP_RESOLUTION
  56         DBIC_STRESSTEST_UTF8_UPGRADE_GENERATED_COLLAPSER_SOURCE
  57         DBIC_STRESSTEST_COLUMN_INFO_UNAWARE_STORAGE
  58       )
  59     ),
  60
  61     IV_SIZE => $Config{ivsize},
  62   };
  63
  64   if ( PERL_VERSION < 5.009_005) {
  65     require MRO::Compat;
  66     constant->import( OLD_MRO => 1 );
  67
  68     #
  69     # Yes, I know this is a rather PHP-ish name, but please first read
  70     # https://metacpan.org/source/BOBTFISH/MRO-Compat-0.12/lib/MRO/Compat.pm#L363-368
  71     #
  72     # Even if we are using Class::C3::XS it still won't work, as doing
  73     #   defined( *{ "SubClass::"->{$_} }{CODE} )
  74     # will set pkg_gen to the same value for SubClass and *ALL PARENTS*
  75     #
  76     *DBIx::Class::_Util::get_real_pkg_gen = sub ($) {
  77       require Digest::MD5;
  78       require Math::BigInt;
  79
  80       my $cur_class;
  81       no strict 'refs';
  82
  83       # the non-assign-unless-there-is-a-hash is deliberate
  84       ( $__describe_class_query_cache->{'!internal!'} || {} )->{$_[0]}{gen} ||= (
  85         Math::BigInt->new( '0x' . ( Digest::MD5::md5_hex( join "\0", map {
  86
  87           ( $__describe_class_query_cache->{'!internal!'} || {} )->{$_}{methlist} ||= (
  88
  89             $cur_class = $_
  90
  91               and
  92
  93             # RV to be hashed up and turned into a number
  94             join "\0", (
  95               $cur_class,
  96               map
  97                 {(
  98                   # stringification should be sufficient, ignore names/refaddr entirely
  99                   $_,
 100                   do {
 101                     my @attrs;
 102                     local $@;
 103                     local $SIG{__DIE__} if $SIG{__DIE__};
 104                     # attributes::get may throw on blessed-false crefs :/
 105                     eval { @attrs = attributes::get( $_ ); 1 }
 106                       or warn "Unable to determine attributes of coderef $_ due to the following error: $@";
 107                     @attrs;
 108                   },
 109                 )}
 110                 map
 111                   {(
 112                     # skip dummy C::C3 helper crefs
 113                     ! ( ( $Class::C3::MRO{$cur_class} || {} )->{methods}{$_} )
 114                       and
 115                     (
 116                       ref(\ "${cur_class}::"->{$_} ) ne 'GLOB'
 117                         or
 118                       defined( *{ "${cur_class}::"->{$_} }{CODE} )
 119                     )
 120                   )
 121                     ? ( \&{"${cur_class}::$_"} )
 122                     : ()
 123                   }
 124                   keys %{ "${cur_class}::" }
 125             )
 126           )
 127         } (
 128
 129           @{
 130             ( $__describe_class_query_cache->{'!internal!'} || {} )->{$_[0]}{linear_isa}
 131               ||=
 132             mro::get_linear_isa($_[0])
 133           },
 134
 135           ((
 136             ( $__describe_class_query_cache->{'!internal!'} || {} )->{$_[0]}{is_universal}
 137               ||=
 138             mro::is_universal($_[0])
 139           ) ? () : @{
 140             ( $__describe_class_query_cache->{'!internal!'} || {} )->{UNIVERSAL}{linear_isa}
 141               ||=
 142             mro::get_linear_isa("UNIVERSAL")
 143           } ),
 144
 145         ) ) ) )
 146       );
 147     };
 148   }
 149   else {
 150     require mro;
 151     constant->import( OLD_MRO => 0 );
 152     *DBIx::Class::_Util::get_real_pkg_gen = \&mro::get_pkg_gen;
 153   }
 154
 155   # Both of these are no longer used for anything. However bring
 156   # them back after they were purged in 08a8d8f1, as there appear
 157   # to be outfits with *COPY PASTED* pieces of lib/DBIx/Class/Storage/*
 158   # in their production codebases. There is no point in breaking these
 159   # if whatever they used actually continues to work
 160   my $sigh = sub {
 161     DBIx::Class::_Util::emit_loud_diag(
 162       skip_frames => 1,
 163       msg => "The @{[ (caller(1))[3] ]} constant is no more - adjust your code"
 164     );
 165
 166     0;
 167   };
 168   sub DBICTEST () { &$sigh }
 169   sub PEEPEENESS () { &$sigh }
 170 }
 171
 172 use constant SPURIOUS_VERSION_CHECK_WARNINGS => ( DBIx::Class::_ENV_::PERL_VERSION < 5.010 ? 1 : 0);
 173
 174 # FIXME - this is not supposed to be here
 175 # Carp::Skip to the rescue soon
 176 use DBIx::Class::Carp '^DBIx::Class|^DBICTest';
 177
 178 # Ensure it is always there, in case we need to do a $schema-less throw()
 179 use DBIx::Class::Exception ();
 180
 181 use B ();
 182 use Carp 'croak';
 183 use Storable 'nfreeze';
 184 use Scalar::Util qw(weaken blessed reftype refaddr);
 185 use Sub::Name ();
 186 use attributes ();
 187
 188 # Usually versions are not specified anywhere aside the Makefile.PL
 189 # (writing them out in-code is extremely obnoxious)
 190 # However without a recent enough Moo the quote_sub override fails
 191 # in very puzzling and hard to detect ways: so add a version check
 192 # just this once
 193 use Sub::Quote qw(qsub);
 194 BEGIN { Sub::Quote->VERSION('2.002002') }
 195
 196 # Already correctly prototyped: perlbrew exec perl -MStorable -e 'warn prototype \&Storable::dclone'
 197 BEGIN { *deep_clone = \&Storable::dclone }
 198
 199 use base 'Exporter';
 200 our @EXPORT_OK = qw(
 201   sigwarn_silencer modver_gt_or_eq modver_gt_or_eq_and_lt
 202   fail_on_internal_wantarray fail_on_internal_call
 203   refdesc refcount hrefaddr set_subname get_subname describe_class_methods
 204   scope_guard detected_reinvoked_destructor emit_loud_diag
 205   true false
 206   is_exception dbic_internal_try dbic_internal_catch visit_namespaces
 207   quote_sub qsub perlstring serialize deep_clone dump_value uniq bag_eq
 208   parent_dir mkdir_p
 209   UNRESOLVABLE_CONDITION DUMMY_ALIASPAIR
 210 );
 211
 212 use constant UNRESOLVABLE_CONDITION => \ '1 = 0';
 213
 214 use constant DUMMY_ALIASPAIR => (
 215   foreign_alias => "!!!\xFF()!!!_DUMMY_FOREIGN_ALIAS_SHOULD_NEVER_BE_SEEN_IN_USE_!!!()\xFF!!!",
 216   self_alias => "!!!\xFE()!!!_DUMMY_SELF_ALIAS_SHOULD_NEVER_BE_SEEN_IN_USE_!!!()\xFE!!!",
 217 );
 218
 219 # Override forcing no_defer, and adding naming consistency checks
 220 our %refs_closed_over_by_quote_sub_installed_crefs;
 221 sub quote_sub {
 222   Carp::confess( "Anonymous quoting not supported by the DBIC quote_sub override - supply a sub name" ) if
 223     @_ < 2
 224       or
 225     ! defined $_[1]
 226       or
 227     length ref $_[1]
 228   ;
 229
 230   Carp::confess( "The DBIC quote_sub override expects sub name '$_[0]' to be fully qualified" )
 231     unless (my $stash) = $_[0] =~ /^(.+)::/;
 232
 233   Carp::confess(
 234     "The DBIC sub_quote override does not support 'no_install'"
 235   ) if (
 236     $_[3]
 237       and
 238     $_[3]->{no_install}
 239   );
 240
 241   Carp::confess(
 242     'The DBIC quote_sub override expects the namespace-part of sub name '
 243   . "'$_[0]' to match the supplied package argument '$_[3]->{package}'"
 244   ) if (
 245     $_[3]
 246       and
 247     defined $_[3]->{package}
 248       and
 249     $stash ne $_[3]->{package}
 250   );
 251
 252   my @caller = caller(0);
 253   my $sq_opts = {
 254     package => $caller[0],
 255     hints => $caller[8],
 256     warning_bits => $caller[9],
 257     hintshash => $caller[10],
 258     %{ $_[3] || {} },
 259
 260     # explicitly forced for everything
 261     no_defer => 1,
 262   };
 263
 264   weaken (
 265     # just use a growing counter, no need to perform neither compaction
 266     # nor any special ithread-level handling
 267     $refs_closed_over_by_quote_sub_installed_crefs
 268      { scalar keys %refs_closed_over_by_quote_sub_installed_crefs }
 269       = $_
 270   ) for grep {
 271     length ref $_
 272       and
 273     (
 274       ! DBIx::Class::_ENV_::BROKEN_WEAK_SCALARREF_VALUES
 275         or
 276       ref $_ ne 'SCALAR'
 277     )
 278   } values %{ $_[2] || {} };
 279
 280   Sub::Quote::quote_sub( $_[0], $_[1], $_[2]||{}, $sq_opts );
 281 }
 282
 283 sub sigwarn_silencer ($) {
 284   my $pattern = shift;
 285
 286   croak "Expecting a regexp" if ref $pattern ne 'Regexp';
 287
 288   my $orig_sig_warn = $SIG{__WARN__} || sub { CORE::warn(@_) };
 289
 290   return sub { &$orig_sig_warn unless $_[0] =~ $pattern };
 291 }
 292
 293 sub perlstring ($) { q{"}. quotemeta( shift ). q{"} };
 294
 295 sub hrefaddr ($) { sprintf '0x%x', &refaddr||0 }
 296
 297 sub refdesc ($) {
 298   croak "Expecting a reference" if ! length ref $_[0];
 299
 300   # be careful not to trigger stringification,
 301   # reuse @_ as a scratch-pad
 302   sprintf '%s%s(0x%x)',
 303     ( defined( $_[1] = blessed $_[0]) ? "$_[1]=" : '' ),
 304     reftype $_[0],
 305     refaddr($_[0]),
 306   ;
 307 }
 308
 309 sub refcount ($) {
 310   croak "Expecting a reference" if ! length ref $_[0];
 311
 312   # No tempvars - must operate on $_[0], otherwise the pad
 313   # will count as an extra ref
 314   B::svref_2object($_[0])->REFCNT;
 315 }
 316
 317 sub visit_namespaces {
 318   my $args = { (ref $_[0]) ? %{$_[0]} : @_ };
 319
 320   my $visited_count = 1;
 321
 322   # A package and a namespace are subtly different things
 323   $args->{package} ||= 'main';
 324   $args->{package} = 'main' if $args->{package} =~ /^ :: (?: main )? $/x;
 325   $args->{package} =~ s/^:://;
 326
 327   if ( $args->{action}->($args->{package}) ) {
 328     my $ns =
 329       ( ($args->{package} eq 'main') ? '' :  $args->{package} )
 330         .
 331       '::'
 332     ;
 333
 334     $visited_count += visit_namespaces( %$args, package => $_ ) for
 335       grep
 336         # this happens sometimes on %:: traversal
 337         { $_ ne '::main' }
 338         map
 339           { $_ =~ /^(.+?)::$/ ? "$ns$1" : () }
 340           do { no strict 'refs'; keys %$ns }
 341     ;
 342   }
 343
 344   $visited_count;
 345 }
 346
 347 # FIXME In another life switch these to a polyfill like the ones in namespace::clean
 348 sub get_subname ($) {
 349   my $gv = B::svref_2object( $_[0] )->GV;
 350   wantarray
 351     ? ( $gv->STASH->NAME, $gv->NAME )
 352     : ( join '::', $gv->STASH->NAME, $gv->NAME )
 353   ;
 354 }
 355 sub set_subname ($$) {
 356
 357   # fully qualify name
 358   splice @_, 0, 1, caller(0) . "::$_[0]"
 359     if $_[0] !~ /::|'/;
 360
 361   &Sub::Name::subname;
 362 }
 363
 364 sub serialize ($) {
 365   # stable hash order
 366   local $Storable::canonical = 1;
 367
 368   # explicitly false - there is nothing sensible that can come out of
 369   # an attempt at CODE serialization
 370   local $Storable::Deparse;
 371
 372   # take no chances
 373   local $Storable::forgive_me;
 374
 375   # FIXME
 376   # A number of codepaths *expect* this to be Storable.pm-based so that
 377   # the STORABLE_freeze hooks in the metadata subtree get executed properly
 378   nfreeze($_[0]);
 379 }
 380
 381 sub uniq {
 382   my( %seen, $seen_undef, $numeric_preserving_copy );
 383   grep { not (
 384     defined $_
 385       ? $seen{ $numeric_preserving_copy = $_ }++
 386       : $seen_undef++
 387   ) } @_;
 388 }
 389
 390 sub bag_eq ($$) {
 391   croak "bag_eq() requiress two arrayrefs as arguments" if (
 392     ref($_[0]) ne 'ARRAY'
 393       or
 394     ref($_[1]) ne 'ARRAY'
 395   );
 396
 397   return '' unless @{$_[0]} == @{$_[1]};
 398
 399   my( %seen, $numeric_preserving_copy );
 400
 401   ( defined $_
 402     ? $seen{'value' . ( $numeric_preserving_copy = $_ )}++
 403     : $seen{'undef'}++
 404   ) for @{$_[0]};
 405
 406   ( defined $_
 407     ? $seen{'value' . ( $numeric_preserving_copy = $_ )}--
 408     : $seen{'undef'}--
 409   ) for @{$_[1]};
 410
 411   return (
 412     (grep { $_ } values %seen)
 413       ? ''
 414       : 1
 415   );
 416 }
 417
 418 my $dd_obj;
 419 sub dump_value ($) {
 420   local $Data::Dumper::Indent = 1
 421     unless defined $Data::Dumper::Indent;
 422
 423   my $dump_str = (
 424     $dd_obj
 425       ||=
 426     do {
 427       require Data::Dumper;
 428       my $d = Data::Dumper->new([])
 429         ->Purity(0)
 430         ->Pad('')
 431         ->Useqq(1)
 432         ->Terse(1)
 433         ->Freezer('')
 434         ->Quotekeys(0)
 435         ->Bless('bless')
 436         ->Pair(' => ')
 437         ->Sortkeys(1)
 438         ->Deparse(1)
 439       ;
 440
 441       # FIXME - this is kinda ridiculous - there ought to be a
 442       # Data::Dumper->new_with_defaults or somesuch...
 443       #
 444       if( modver_gt_or_eq ( 'Data::Dumper', '2.136' ) ) {
 445         $d->Sparseseen(1);
 446
 447         if( modver_gt_or_eq ( 'Data::Dumper', '2.153' ) ) {
 448           $d->Maxrecurse(1000);
 449
 450           if( modver_gt_or_eq ( 'Data::Dumper', '2.160' ) ) {
 451             $d->Trailingcomma(1);
 452           }
 453         }
 454       }
 455
 456       $d;
 457     }
 458   )->Values([$_[0]])->Dump;
 459
 460   $dd_obj->Reset->Values([]);
 461
 462   $dump_str;
 463 }
 464
 465 my $seen_loud_screams;
 466 sub emit_loud_diag {
 467   my $args = { ref $_[0] eq 'HASH' ? %{$_[0]} : @_ };
 468
 469   unless ( defined $args->{msg} and length $args->{msg} ) {
 470     emit_loud_diag(
 471       msg => "No 'msg' value supplied to emit_loud_diag()"
 472     );
 473     exit 70;
 474   }
 475
 476   my $msg = "\n" . join( ': ',
 477     ( $0 eq '-e' ? () : $0 ),
 478     $args->{msg}
 479   );
 480
 481   # when we die - we usually want to keep doing it
 482   $args->{emit_dups} = !!$args->{confess}
 483     unless exists $args->{emit_dups};
 484
 485   local $Carp::CarpLevel =
 486     ( $args->{skip_frames} || 0 )
 487       +
 488     $Carp::CarpLevel
 489       +
 490     # hide our own frame
 491     1
 492   ;
 493
 494   my $longmess = Carp::longmess();
 495
 496   # different object references will thwart deduplication without this
 497   ( my $key = "${msg}\n${longmess}" ) =~ s/\b0x[0-9a-f]+\b/0x.../gi;
 498
 499   return $seen_loud_screams->{$key} if
 500     $seen_loud_screams->{$key}++
 501       and
 502     ! $args->{emit_dups}
 503   ;
 504
 505   $msg .= $longmess
 506     unless $msg =~ /\n\z/;
 507
 508   print STDERR "$msg\n"
 509     or
 510   print STDOUT "\n!!!STDERR ISN'T WRITABLE!!!:$msg\n";
 511
 512   return $seen_loud_screams->{$key}
 513     unless $args->{confess};
 514
 515   # increment *again*, because... Carp.
 516   $Carp::CarpLevel++;
 517
 518   # not $msg - Carp will reapply the longmess on its own
 519   Carp::confess($args->{msg});
 520 }
 521
 522
 523 ###
 524 ### This is *NOT* boolean.pm - deliberately not using a singleton
 525 ###
 526 {
 527   package # hide from pause
 528     DBIx::Class::_Util::_Bool;
 529   use overload
 530     bool => sub { ${$_[0]} },
 531     fallback => 1,
 532   ;
 533 }
 534 sub true () { my $x = 1; bless \$x, "DBIx::Class::_Util::_Bool" }
 535 sub false () { my $x = 0; bless \$x, "DBIx::Class::_Util::_Bool" }
 536
 537 sub scope_guard (&) {
 538   croak 'Calling scope_guard() in void context makes no sense'
 539     if ! defined wantarray;
 540
 541   # no direct blessing of coderefs - DESTROY is buggy on those
 542   bless [ $_[0] ], 'DBIx::Class::_Util::ScopeGuard';
 543 }
 544 {
 545   package #
 546     DBIx::Class::_Util::ScopeGuard;
 547
 548   sub DESTROY {
 549     &DBIx::Class::_Util::detected_reinvoked_destructor;
 550
 551     local $@ if DBIx::Class::_ENV_::UNSTABLE_DOLLARAT;
 552
 553     eval {
 554       $_[0]->[0]->();
 555       1;
 556     }
 557       or
 558     DBIx::Class::_Util::emit_loud_diag(
 559       emit_dups => 1,
 560       msg => "Execution of scope guard $_[0] resulted in the non-trappable exception:\n\n$@\n "
 561     );
 562   }
 563 }
 564
 565
 566 sub is_exception ($) {
 567   my $e = $_[0];
 568
 569   # FIXME
 570   # this is not strictly correct - an eval setting $@ to undef
 571   # is *not* the same as an eval setting $@ to ''
 572   # but for the sake of simplicity assume the following for
 573   # the time being
 574   return 0 unless defined $e;
 575
 576   my ($not_blank, $suberror);
 577   {
 578     local $SIG{__DIE__} if $SIG{__DIE__};
 579     local $@;
 580     eval {
 581       # The ne() here is deliberate - a plain length($e), or worse "$e" ne
 582       # will entirely obviate the need for the encolsing eval{}, as the
 583       # condition we guard against is a missing fallback overload
 584       $not_blank = ( $e ne '' );
 585       1;
 586     } or $suberror = $@;
 587   }
 588
 589   if (defined $suberror) {
 590     if (length (my $class = blessed($e) )) {
 591       carp_unique( sprintf(
 592         'External exception class %s implements partial (broken) overloading '
 593       . 'preventing its instances from being used in simple ($x eq $y) '
 594       . 'comparisons. Given Perl\'s "globally cooperative" exception '
 595       . 'handling this type of brokenness is extremely dangerous on '
 596       . 'exception objects, as it may (and often does) result in silent '
 597       . '"exception substitution". DBIx::Class tries to work around this '
 598       . 'as much as possible, but other parts of your software stack may '
 599       . 'not be even aware of this. Please submit a bugreport against the '
 600       . 'distribution containing %s and in the meantime apply a fix similar '
 601       . 'to the one shown at %s, in order to ensure your exception handling '
 602       . 'is saner application-wide. What follows is the actual error text '
 603       . "as generated by Perl itself:\n\n%s\n ",
 604         $class,
 605         $class,
 606         'http://v.gd/DBIC_overload_tempfix/',
 607         $suberror,
 608       ));
 609
 610       # workaround, keeps spice flowing
 611       $not_blank = !!( length $e );
 612     }
 613     else {
 614       # not blessed yet failed the 'ne'... this makes 0 sense...
 615       # just throw further
 616       die $suberror
 617     }
 618   }
 619   elsif (
 620     # a ref evaluating to '' is definitively a "null object"
 621     ( not $not_blank )
 622       and
 623     length( my $class = ref $e )
 624   ) {
 625     carp_unique(
 626       "Objects of external exception class '$class' stringify to '' (the "
 627     . 'empty string), implementing the so called null-object-pattern. '
 628     . 'Given Perl\'s "globally cooperative" exception handling using this '
 629     . 'class of exceptions is extremely dangerous, as it may (and often '
 630     . 'does) result in silent discarding of errors. DBIx::Class tries to '
 631     . 'work around this as much as possible, but other parts of your '
 632     . 'software stack may not be even aware of the problem. Please submit '
 633     . "a bugreport against the distribution containing '$class'",
 634     );
 635
 636     $not_blank = 1;
 637   }
 638
 639   return $not_blank;
 640 }
 641
 642 {
 643   my $callstack_state;
 644
 645   # Recreate the logic of Try::Tiny, but without the crazy Sub::Name
 646   # invocations and without support for finally() altogether
 647   # ( yes, these days Try::Tiny is so "tiny" it shows *ON TOP* of most
 648   #   random profiles https://youtu.be/PYCbumw0Fis?t=1919 )
 649   sub dbic_internal_try (&;@) {
 650
 651     my $try_cref = shift;
 652     my $catch_cref = undef;  # apparently this is a thing... https://rt.perl.org/Public/Bug/Display.html?id=119311
 653
 654     for my $arg (@_) {
 655
 656       croak 'dbic_internal_try() may not be followed by multiple dbic_internal_catch() blocks'
 657         if $catch_cref;
 658
 659       ($catch_cref = $$arg), next
 660         if ref($arg) eq 'DBIx::Class::_Util::Catch';
 661
 662       croak( 'Mixing dbic_internal_try() with Try::Tiny::catch() is not supported' )
 663         if ref($arg) eq 'Try::Tiny::Catch';
 664
 665       croak( 'dbic_internal_try() does not support finally{}' )
 666         if ref($arg) eq 'Try::Tiny::Finally';
 667
 668       croak(
 669         'dbic_internal_try() encountered an unexpected argument '
 670       . "'@{[ defined $arg ? $arg : 'UNDEF' ]}' - perhaps "
 671       . 'a missing semi-colon before or ' # trailing space important
 672       );
 673     }
 674
 675     my $wantarray = wantarray;
 676     my $preexisting_exception = $@;
 677
 678     my @ret;
 679     my $saul_goodman = eval {
 680       $@ = $preexisting_exception;
 681
 682       local $callstack_state->{in_internal_try} = 1
 683         unless $callstack_state->{in_internal_try};
 684
 685       # always unset - someone may have snuck it in
 686       local $SIG{__DIE__} if $SIG{__DIE__};
 687
 688       if( $wantarray ) {
 689         @ret = $try_cref->();
 690       }
 691       elsif( defined $wantarray ) {
 692         $ret[0] = $try_cref->();
 693       }
 694       else {
 695         $try_cref->();
 696       }
 697
 698       1;
 699     };
 700
 701     my $exception = $@;
 702     $@ = $preexisting_exception;
 703
 704     if ( $saul_goodman ) {
 705       return $wantarray ? @ret : $ret[0]
 706     }
 707     elsif ( $catch_cref ) {
 708       for ( $exception ) {
 709         return $catch_cref->($exception);
 710       }
 711     }
 712
 713     return;
 714   }
 715
 716   sub dbic_internal_catch (&;@) {
 717
 718     croak( 'Useless use of bare dbic_internal_catch()' )
 719       unless wantarray;
 720
 721     croak( 'dbic_internal_catch() must receive exactly one argument at end of expression' )
 722       if @_ > 1;
 723
 724     bless(
 725       \( $_[0] ),
 726       'DBIx::Class::_Util::Catch'
 727     ),
 728   }
 729
 730   sub in_internal_try () {
 731     !! $callstack_state->{in_internal_try}
 732   }
 733 }
 734
 735 {
 736   my $destruction_registry = {};
 737
 738   sub DBIx::Class::__Util_iThreads_handler__::CLONE {
 739     %$destruction_registry = map {
 740       (defined $_)
 741         ? ( refaddr($_) => $_ )
 742         : ()
 743     } values %$destruction_registry;
 744
 745     weaken($_) for values %$destruction_registry;
 746
 747     # Dummy NEXTSTATE ensuring the all temporaries on the stack are garbage
 748     # collected before leaving this scope. Depending on the code above, this
 749     # may very well be just a preventive measure guarding future modifications
 750     undef;
 751   }
 752
 753   # This is almost invariably invoked from within DESTROY
 754   # throwing exceptions won't work
 755   sub detected_reinvoked_destructor {
 756
 757     # quick "garbage collection" pass - prevents the registry
 758     # from slowly growing with a bunch of undef-valued keys
 759     defined $destruction_registry->{$_} or delete $destruction_registry->{$_}
 760       for keys %$destruction_registry;
 761
 762     if (! length ref $_[0]) {
 763       emit_loud_diag(
 764         emit_dups => 1,
 765         msg => (caller(0))[3] . '() expects a blessed reference'
 766       );
 767       return undef; # don't know wtf to do
 768     }
 769     elsif (! defined $destruction_registry->{ my $addr = refaddr($_[0]) } ) {
 770       weaken( $destruction_registry->{$addr} = $_[0] );
 771       return 0;
 772     }
 773     else {
 774       emit_loud_diag( msg => sprintf (
 775         'Preventing *MULTIPLE* DESTROY() invocations on %s - an *EXTREMELY '
 776       . 'DANGEROUS* condition which is *ALMOST CERTAINLY GLOBAL* within your '
 777       . 'application, affecting *ALL* classes without active protection against '
 778       . 'this. Diagnose and fix the root cause ASAP!!!%s',
 779       refdesc $_[0],
 780         ( ( $INC{'Devel/StackTrace.pm'} and ! do { local $@; eval { Devel::StackTrace->VERSION(2) } } )
 781           ? " (likely culprit Devel::StackTrace\@@{[ Devel::StackTrace->VERSION ]} found in %INC, http://is.gd/D_ST_refcap)"
 782           : ''
 783         )
 784       ));
 785
 786       return 1;
 787     }
 788   }
 789 }
 790
 791 my $module_name_rx = qr/ \A [A-Z_a-z] [0-9A-Z_a-z]* (?: :: [0-9A-Z_a-z]+ )* \z /x;
 792 my $ver_rx =         qr/ \A [0-9]+ (?: \. [0-9]+ )* (?: \_ [0-9]+ )*        \z /x;
 793
 794 sub modver_gt_or_eq ($$) {
 795   my ($mod, $ver) = @_;
 796
 797   croak "Nonsensical module name supplied"
 798     if ! defined $mod or $mod !~ $module_name_rx;
 799
 800   croak "Nonsensical minimum version supplied"
 801     if ! defined $ver or $ver !~ $ver_rx;
 802
 803   my $ver_cache = do {
 804     no strict 'refs';
 805     ${"${mod}::__DBIC_MODULE_VERSION_CHECKS__"} ||= {}
 806   };
 807
 808   ! defined $ver_cache->{$ver}
 809     and
 810   $ver_cache->{$ver} = do {
 811
 812     local $SIG{__WARN__} = sigwarn_silencer( qr/\Qisn't numeric in subroutine entry/ )
 813       if SPURIOUS_VERSION_CHECK_WARNINGS;
 814
 815     # prevent captures by potential __WARN__ hooks or the like:
 816     # there is nothing of value that can be happening here, and
 817     # leaving a hook in-place can only serve to fail some test
 818     local $SIG{__WARN__} if (
 819       ! SPURIOUS_VERSION_CHECK_WARNINGS
 820         and
 821       $SIG{__WARN__}
 822     );
 823
 824     croak "$mod does not seem to provide a version (perhaps it never loaded)"
 825       unless $mod->VERSION;
 826
 827     local $SIG{__DIE__} if $SIG{__DIE__};
 828     local $@;
 829     eval { $mod->VERSION($ver) } ? 1 : 0;
 830   };
 831
 832   $ver_cache->{$ver};
 833 }
 834
 835 sub modver_gt_or_eq_and_lt ($$$) {
 836   my ($mod, $v_ge, $v_lt) = @_;
 837
 838   croak "Nonsensical maximum version supplied"
 839     if ! defined $v_lt or $v_lt !~ $ver_rx;
 840
 841   return (
 842     modver_gt_or_eq($mod, $v_ge)
 843       and
 844     ! modver_gt_or_eq($mod, $v_lt)
 845   ) ? 1 : 0;
 846 }
 847
 848 {
 849
 850   sub describe_class_methods {
 851     my $args = (
 852       ref $_[0] eq 'HASH'                 ? $_[0]
 853     : ( @_ == 1 and ! length ref $_[0] )  ? { class => $_[0] }
 854     :                                       { @_ }
 855     );
 856
 857     my ($class, $requested_mro) = @{$args}{qw( class use_mro )};
 858
 859     croak "Expecting a class name either as the sole argument or a 'class' option"
 860       if not defined $class or $class !~ $module_name_rx;
 861
 862     croak(
 863       "The supplied 'class' argument is tainted: this is *extremely* "
 864     . 'dangerous, fix your code ASAP!!! ( for more details read through '
 865     . 'https://is.gd/perl_mro_taint_wtf )'
 866     ) if (
 867       DBIx::Class::_ENV_::TAINT_MODE
 868         and
 869       Scalar::Util::tainted($class)
 870     );
 871
 872     $requested_mro ||= mro::get_mro($class);
 873
 874     # mro::set_mro() does not bump pkg_gen - WHAT THE FUCK?!
 875     my $query_cache_key = "$class|$requested_mro";
 876
 877     my $internal_cache_key =
 878       ( mro::get_mro($class) eq $requested_mro )
 879         ? $class
 880         : $query_cache_key
 881     ;
 882
 883     # use a cache on old MRO, since while we are recursing in this function
 884     # nothing can possibly change (the speedup is immense)
 885     # (yes, people could be tie()ing the stash and adding methods on access
 886     # but there is a limit to how much crazy can be supported here)
 887     #
 888     # we use the cache for linear_isa lookups on new MRO as well - it adds
 889     # a *tiny* speedup, and simplifies the code a lot
 890     #
 891     local $__describe_class_query_cache->{'!internal!'} = {}
 892       unless $__describe_class_query_cache->{'!internal!'};
 893
 894     my $my_gen = 0;
 895
 896     $my_gen += get_real_pkg_gen($_) for ( my @full_ISA = (
 897
 898       @{
 899         $__describe_class_query_cache->{'!internal!'}{$internal_cache_key}{linear_isa}
 900           ||=
 901         mro::get_linear_isa($class, $requested_mro)
 902       },
 903
 904       ((
 905         $__describe_class_query_cache->{'!internal!'}{$class}{is_universal}
 906           ||=
 907         mro::is_universal($class)
 908       ) ? () : @{
 909         $__describe_class_query_cache->{'!internal!'}{UNIVERSAL}{linear_isa}
 910           ||=
 911         mro::get_linear_isa("UNIVERSAL")
 912       }),
 913
 914     ));
 915
 916     my $slot = $__describe_class_query_cache->{$query_cache_key} ||= {};
 917
 918     unless ( ($slot->{cumulative_gen}||0) == $my_gen ) {
 919
 920       # reset
 921       %$slot = (
 922         class => $class,
 923         isa => { map { $_ => 1 } @full_ISA },
 924         linear_isa => [
 925           @{ $__describe_class_query_cache->{'!internal!'}{$internal_cache_key}{linear_isa} }
 926             [ 1 .. $#{$__describe_class_query_cache->{'!internal!'}{$internal_cache_key}{linear_isa}} ]
 927         ],
 928         mro => {
 929           type => $requested_mro,
 930           is_c3 => ( ($requested_mro eq 'c3') ? 1 : 0 ),
 931         },
 932         cumulative_gen => $my_gen,
 933       );
 934
 935       # remove ourselves from ISA
 936       shift @full_ISA;
 937
 938       # ensure the cache is populated for the parents, code below can then
 939       # efficiently operate over the query_cache directly
 940       describe_class_methods($_) for reverse @full_ISA;
 941
 942       no strict 'refs';
 943
 944       # combine full ISA-order inherited and local method list into a
 945       # "shadowing stack"
 946
 947       (
 948         unshift @{ $slot->{methods}{$_->{name}} }, $_
 949
 950           and
 951
 952         (
 953           $_->{via_class} ne $class
 954             or
 955           $slot->{methods_defined_in_class}{$_->{name}} = $_
 956         )
 957
 958           and
 959
 960         @{ $slot->{methods}{$_->{name}} } > 1
 961
 962           and
 963
 964         $slot->{methods_with_supers}{$_->{name}} = $slot->{methods}{$_->{name}}
 965
 966       ) for (
 967
 968         # what describe_class_methods for @full_ISA produced above
 969         ( map { values %{
 970           $__describe_class_query_cache->{$_}{methods_defined_in_class} || {}
 971         } } map { "$_|" . mro::get_mro($_) } reverse @full_ISA ),
 972
 973         # our own non-cleaned subs + their attributes
 974         ( map {
 975           (
 976             # need to account for dummy helper crefs under OLD_MRO
 977             (
 978               ! DBIx::Class::_ENV_::OLD_MRO
 979                 or
 980               ! ( ( $Class::C3::MRO{$class} || {} )->{methods}{$_} )
 981             )
 982               and
 983             # these 2 OR-ed checks are sufficient for 5.10+
 984             (
 985               ref(\ "${class}::"->{$_} ) ne 'GLOB'
 986                 or
 987               defined( *{ "${class}::"->{$_} }{CODE} )
 988             )
 989           ) ? {
 990               via_class => $class,
 991               name => $_,
 992               attributes => { map { $_ => 1 } do {
 993                 my @attrs;
 994                 local $@;
 995                 local $SIG{__DIE__} if $SIG{__DIE__};
 996                 # attributes::get may throw on blessed-false crefs :/
 997                 eval { @attrs = attributes::get( \&{"${class}::${_}"} ); 1 }
 998                   or warn "Unable to determine attributes of the \\&${class}::$_ method due to following error: $@";
 999                 @attrs;
1000               } },
1001             }
1002             : ()
1003         } keys %{"${class}::"} )
1004       );
1005
1006
1007       # recalculate the pkg_gen on newer perls under Taint mode,
1008       # because of shit like:
1009       # perl -T -Mmro -e 'package Foo; sub bar {}; defined( *{ "Foo::"->{bar}}{CODE} ) and warn mro::get_pkg_gen("Foo") for (1,2,3)'
1010       #
1011       if (
1012         ! DBIx::Class::_ENV_::OLD_MRO
1013           and
1014         DBIx::Class::_ENV_::TAINT_MODE
1015       ) {
1016
1017         $slot->{cumulative_gen} = 0;
1018         $slot->{cumulative_gen} += get_real_pkg_gen($_)
1019           for $class, @full_ISA;
1020       }
1021     }
1022
1023     # RV
1024     +{ %$slot };
1025   }
1026 }
1027
1028
1029 #
1030 # Why not just use some higher-level module or at least File::Spec here?
1031 # Because:
1032 # 1)  This is a *very* rarely used function, and the deptree is large
1033 #     enough already as it is
1034 #
1035 # 2)  (more importantly) Our tooling is utter shit in this area. There
1036 #     is no comprehensive support for UNC paths in PathTools and there
1037 #     are also various small bugs in representation across different
1038 #     path-manipulation CPAN offerings.
1039 #
1040 # Since this routine is strictly used for logical path processing (it
1041 # *must* be able to work with not-yet-existing paths), use this seemingly
1042 # simple but I *think* complete implementation to feed to other consumers
1043 #
1044 # If bugs are ever uncovered in this routine, *YOU ARE URGED TO RESIST*
1045 # the impulse to bring in an external dependency. During runtime there
1046 # is exactly one spot that could potentially maybe once in a blue moon
1047 # use this function. Keep it lean.
1048 #
1049 sub parent_dir ($) {
1050   ( $_[0] =~ m{  [\/\\]  ( \.{0,2} ) ( [\/\\]* ) \z }x )
1051     ? (
1052       $_[0]
1053         .
1054       ( ( length($1) and ! length($2) ) ? '/' : '' )
1055         .
1056       '../'
1057     )
1058     : (
1059       require File::Spec
1060         and
1061       File::Spec->catpath (
1062         ( File::Spec->splitpath( "$_[0]" ) )[0,1],
1063         '/',
1064       )
1065     )
1066   ;
1067 }
1068
1069 sub mkdir_p ($) {
1070   require File::Path;
1071   # do not ask for a recent version, use 1.x API calls
1072   File::Path::mkpath([ "$_[0]" ]);  # File::Path does not like objects
1073 }
1074
1075
1076 {
1077   my $list_ctx_ok_stack_marker;
1078
1079   sub fail_on_internal_wantarray () {
1080     return if $list_ctx_ok_stack_marker;
1081
1082     if (! defined wantarray) {
1083       croak('fail_on_internal_wantarray() needs a tempvar to save the stack marker guard');
1084     }
1085
1086     my $cf = 1;
1087     while ( ( (CORE::caller($cf+1))[3] || '' ) =~ / :: (?:
1088
1089       # these are public API parts that alter behavior on wantarray
1090       search | search_related | slice | search_literal
1091
1092         |
1093
1094       # these are explicitly prefixed, since we only recognize them as valid
1095       # escapes when they come from the guts of CDBICompat
1096       CDBICompat .*? :: (?: search_where | retrieve_from_sql | retrieve_all )
1097
1098     ) $/x ) {
1099       $cf++;
1100     }
1101
1102     my ($fr, $want, $argdesc);
1103     {
1104       package DB;
1105       $fr = [ CORE::caller($cf) ];
1106       $want = ( CORE::caller($cf-1) )[5];
1107       $argdesc = ref $DB::args[0]
1108         ? DBIx::Class::_Util::refdesc($DB::args[0])
1109         : 'non '
1110       ;
1111     };
1112
1113     if (
1114       $want and $fr->[0] =~ /^(?:DBIx::Class|DBICx::)/
1115     ) {
1116       DBIx::Class::Exception->throw( sprintf (
1117         "Improper use of %s instance in list context at %s line %d\n\n    Stacktrace starts",
1118         $argdesc, @{$fr}[1,2]
1119       ), 'with_stacktrace');
1120     }
1121
1122     weaken( $list_ctx_ok_stack_marker = my $mark = [] );
1123
1124     $mark;
1125   }
1126 }
1127
1128 sub fail_on_internal_call {
1129   my ($fr, $argdesc);
1130   {
1131     package DB;
1132     $fr = [ CORE::caller(1) ];
1133     $argdesc =
1134       ( not defined $DB::args[0] )  ? 'UNAVAILABLE'
1135     : ( length ref $DB::args[0] )   ? DBIx::Class::_Util::refdesc($DB::args[0])
1136     : $DB::args[0] . ''
1137     ;
1138   };
1139
1140   my @fr2;
1141   # need to make allowance for a proxy-yet-direct call
1142   my $check_fr = (
1143     $fr->[0] eq 'DBIx::Class::ResultSourceProxy'
1144       and
1145     @fr2 = (CORE::caller(2))
1146       and
1147     (
1148       ( $fr->[3] =~ /([^:])+$/ )[0]
1149         eq
1150       ( $fr2[3] =~ /([^:])+$/ )[0]
1151     )
1152   )
1153     ? \@fr2
1154     : $fr
1155   ;
1156
1157
1158   die "\nMethod $fr->[3] is not marked with the 'DBIC_method_is_indirect_sugar' attribute\n\n" unless (
1159
1160     # unlikely but who knows...
1161     ! @$fr
1162
1163       or
1164
1165     # This is a weird-ass double-purpose method, only one branch of which is marked
1166     # as an illegal indirect call
1167     # Hence the 'indirect' attribute makes no sense
1168     # FIXME - likely need to mark this in some other manner
1169     $fr->[3] eq 'DBIx::Class::ResultSet::new'
1170
1171       or
1172
1173     # RsrcProxy stuff is special and not attr-annotated on purpose
1174     # Yet it is marked (correctly) as fail_on_internal_call(), as DBIC
1175     # itself should not call these methods as first-entry
1176     $fr->[3] =~ /^DBIx::Class::ResultSourceProxy::[^:]+$/
1177
1178       or
1179
1180     # FIXME - there is likely a more fine-graned way to escape "foreign"
1181     # callers, based on annotations... (albeit a slower one)
1182     # For the time being just skip in a dumb way
1183     $fr->[3] !~ /^DBIx::Class|^DBICx::|^DBICTest::/
1184
1185       or
1186
1187     grep
1188       { $_ eq 'DBIC_method_is_indirect_sugar' }
1189       do { no strict 'refs'; attributes::get( \&{ $fr->[3] }) }
1190   );
1191
1192
1193   if (
1194     defined $fr->[0]
1195       and
1196     $check_fr->[0] =~ /^(?:DBIx::Class|DBICx::)/
1197       and
1198     $check_fr->[1] !~ /\b(?:CDBICompat|ResultSetProxy)\b/  # no point touching there
1199       and
1200     # one step higher
1201     @fr2 = CORE::caller(@fr2 ? 3 : 2)
1202       and
1203     # if the frame that called us is an indirect itself - nothing to see here
1204     ! grep
1205       { $_ eq 'DBIC_method_is_indirect_sugar' }
1206       do {
1207         no strict 'refs';
1208         attributes::get( \&{ $fr2[3] })
1209       }
1210   ) {
1211     DBIx::Class::Exception->throw( sprintf (
1212       "Illegal internal call of indirect proxy-method %s() with argument '%s': examine the last lines of the proxy method deparse below to determine what to call directly instead at %s on line %d\n\n%s\n\n    Stacktrace starts",
1213       $fr->[3], $argdesc, @{$fr}[1,2], ( $fr->[6] || do {
1214         require B::Deparse;
1215         no strict 'refs';
1216         B::Deparse->new->coderef2text(\&{$fr->[3]})
1217       }),
1218     ), 'with_stacktrace');
1219   }
1220 }
1221
1222 if (DBIx::Class::_ENV_::ASSERT_NO_ERRONEOUS_METAINSTANCE_USE) {
1223
1224   no warnings 'redefine';
1225
1226   my $next_bless = defined(&CORE::GLOBAL::bless)
1227     ? \&CORE::GLOBAL::bless
1228     : sub { CORE::bless($_[0], $_[1]) }
1229   ;
1230
1231   *CORE::GLOBAL::bless = sub {
1232     my $class = (@_ > 1) ? $_[1] : CORE::caller();
1233
1234     # allow for reblessing (role application)
1235     return $next_bless->( $_[0], $class )
1236       if defined blessed $_[0];
1237
1238     my $obj = $next_bless->( $_[0], $class );
1239
1240     my $calling_sub = (CORE::caller(1))[3] || '';
1241
1242     (
1243       # before 5.18 ->isa() will choke on the "0" package
1244       # which we test for in several obscure cases, sigh...
1245       !( DBIx::Class::_ENV_::PERL_VERSION < 5.018 )
1246         or
1247       $class
1248     )
1249       and
1250     (
1251       (
1252         $calling_sub !~ /^ (?:
1253           DBIx::Class::Schema::clone
1254             |
1255           DBIx::Class::DB::setup_schema_instance
1256         )/x
1257           and
1258         $class->isa("DBIx::Class::Schema")
1259       )
1260         or
1261       (
1262         $calling_sub ne 'DBIx::Class::ResultSource::new'
1263           and
1264         $class->isa("DBIx::Class::ResultSource")
1265       )
1266     )
1267       and
1268     local $Carp::CarpLevel = $Carp::CarpLevel + 1
1269       and
1270     Carp::confess("Improper instantiation of '$obj': you *MUST* call the corresponding constructor");
1271
1272
1273     $obj;
1274   };
1275 }
1276
1277 1;