lib/DBIx/Class/_Util.pm

   1 package # hide from PAUSE
   2   DBIx::Class::_Util;
   3
   4 use warnings;
   5 use strict;
   6
   7 use constant SPURIOUS_VERSION_CHECK_WARNINGS => (
   8   ( $ENV{DBICTEST_VERSION_WARNS_INDISCRIMINATELY} or $] < 5.010 )
   9     ? 1
  10     : 0
  11 );
  12
  13 BEGIN {
  14   package # hide from pause
  15     DBIx::Class::_ENV_;
  16
  17   use Config;
  18
  19   use constant {
  20
  21     # but of course
  22     BROKEN_FORK => ($^O eq 'MSWin32') ? 1 : 0,
  23
  24     BROKEN_GOTO => ($] < '5.008003') ? 1 : 0,
  25
  26     HAS_ITHREADS => $Config{useithreads} ? 1 : 0,
  27
  28     DBICTEST => $INC{"DBICTest/Util.pm"} ? 1 : 0,
  29
  30     # During 5.13 dev cycle HELEMs started to leak on copy
  31     # add an escape for these perls ON SMOKERS - a user will still get death
  32     PEEPEENESS => ( eval { DBICTest::RunMode->is_smoker } && ($] >= 5.013005 and $] <= 5.013006) ),
  33
  34     SHUFFLE_UNORDERED_RESULTSETS => $ENV{DBIC_SHUFFLE_UNORDERED_RESULTSETS} ? 1 : 0,
  35
  36     ASSERT_NO_INTERNAL_WANTARRAY => $ENV{DBIC_ASSERT_NO_INTERNAL_WANTARRAY} ? 1 : 0,
  37
  38     ASSERT_NO_INTERNAL_INDIRECT_CALLS => $ENV{DBIC_ASSERT_NO_INTERNAL_INDIRECT_CALLS} ? 1 : 0,
  39
  40     STRESSTEST_UTF8_UPGRADE_GENERATED_COLLAPSER_SOURCE => $ENV{DBIC_STRESSTEST_UTF8_UPGRADE_GENERATED_COLLAPSER_SOURCE} ? 1 : 0,
  41
  42     IV_SIZE => $Config{ivsize},
  43
  44     OS_NAME => $^O,
  45   };
  46
  47   if ($] < 5.009_005) {
  48     require MRO::Compat;
  49     constant->import( OLD_MRO => 1 );
  50   }
  51   else {
  52     require mro;
  53     constant->import( OLD_MRO => 0 );
  54   }
  55 }
  56
  57 # FIXME - this is not supposed to be here
  58 # Carp::Skip to the rescue soon
  59 use DBIx::Class::Carp '^DBIx::Class|^DBICTest';
  60
  61 use B ();
  62 use Carp 'croak';
  63 use Storable 'nfreeze';
  64 use Scalar::Util qw(weaken blessed reftype refaddr);
  65 use List::Util qw(first);
  66 use Sub::Quote qw(qsub quote_sub);
  67
  68 use base 'Exporter';
  69 our @EXPORT_OK = qw(
  70   sigwarn_silencer modver_gt_or_eq modver_gt_or_eq_and_lt
  71   fail_on_internal_wantarray fail_on_internal_call
  72   refdesc refcount hrefaddr is_exception detected_reinvoked_destructor
  73   quote_sub qsub perlstring serialize
  74   UNRESOLVABLE_CONDITION
  75 );
  76
  77 use constant UNRESOLVABLE_CONDITION => \ '1 = 0';
  78
  79 sub sigwarn_silencer ($) {
  80   my $pattern = shift;
  81
  82   croak "Expecting a regexp" if ref $pattern ne 'Regexp';
  83
  84   my $orig_sig_warn = $SIG{__WARN__} || sub { CORE::warn(@_) };
  85
  86   return sub { &$orig_sig_warn unless $_[0] =~ $pattern };
  87 }
  88
  89 sub perlstring ($) { q{"}. quotemeta( shift ). q{"} };
  90
  91 sub hrefaddr ($) { sprintf '0x%x', &refaddr||0 }
  92
  93 sub refdesc ($) {
  94   croak "Expecting a reference" if ! length ref $_[0];
  95
  96   # be careful not to trigger stringification,
  97   # reuse @_ as a scratch-pad
  98   sprintf '%s%s(0x%x)',
  99     ( defined( $_[1] = blessed $_[0]) ? "$_[1]=" : '' ),
 100     reftype $_[0],
 101     refaddr($_[0]),
 102   ;
 103 }
 104
 105 sub refcount ($) {
 106   croak "Expecting a reference" if ! length ref $_[0];
 107
 108   # No tempvars - must operate on $_[0], otherwise the pad
 109   # will count as an extra ref
 110   B::svref_2object($_[0])->REFCNT;
 111 }
 112
 113 sub serialize ($) {
 114   local $Storable::canonical = 1;
 115   nfreeze($_[0]);
 116 }
 117
 118 sub is_exception ($) {
 119   my $e = $_[0];
 120
 121   # this is not strictly correct - an eval setting $@ to undef
 122   # is *not* the same as an eval setting $@ to ''
 123   # but for the sake of simplicity assume the following for
 124   # the time being
 125   return 0 unless defined $e;
 126
 127   my ($not_blank, $suberror);
 128   {
 129     local $@;
 130     eval {
 131       $not_blank = ($e ne '') ? 1 : 0;
 132       1;
 133     } or $suberror = $@;
 134   }
 135
 136   if (defined $suberror) {
 137     if (length (my $class = blessed($e) )) {
 138       carp_unique( sprintf(
 139         'External exception class %s implements partial (broken) overloading '
 140       . 'preventing its instances from being used in simple ($x eq $y) '
 141       . 'comparisons. Given Perl\'s "globally cooperative" exception '
 142       . 'handling this type of brokenness is extremely dangerous on '
 143       . 'exception objects, as it may (and often does) result in silent '
 144       . '"exception substitution". DBIx::Class tries to work around this '
 145       . 'as much as possible, but other parts of your software stack may '
 146       . 'not be even aware of this. Please submit a bugreport against the '
 147       . 'distribution containing %s and in the meantime apply a fix similar '
 148       . 'to the one shown at %s, in order to ensure your exception handling '
 149       . 'is saner application-wide. What follows is the actual error text '
 150       . "as generated by Perl itself:\n\n%s\n ",
 151         $class,
 152         $class,
 153         'http://v.gd/DBIC_overload_tempfix/',
 154         $suberror,
 155       ));
 156
 157       # workaround, keeps spice flowing
 158       $not_blank = ("$e" ne '') ? 1 : 0;
 159     }
 160     else {
 161       # not blessed yet failed the 'ne'... this makes 0 sense...
 162       # just throw further
 163       die $suberror
 164     }
 165   }
 166
 167   return $not_blank;
 168 }
 169
 170 {
 171   my $destruction_registry = {};
 172
 173   sub CLONE {
 174     $destruction_registry = { map
 175       { defined $_ ? ( refaddr($_) => $_ ) : () }
 176       values %$destruction_registry
 177     };
 178   }
 179
 180   # This is almost invariably invoked from within DESTROY
 181   # throwing exceptions won't work
 182   sub detected_reinvoked_destructor {
 183
 184     # quick "garbage collection" pass - prevents the registry
 185     # from slowly growing with a bunch of undef-valued keys
 186     defined $destruction_registry->{$_} or delete $destruction_registry->{$_}
 187       for keys %$destruction_registry;
 188
 189     if (! length ref $_[0]) {
 190       printf STDERR '%s() expects a blessed reference %s',
 191         (caller(0))[3],
 192         Carp::longmess,
 193       ;
 194       return undef; # don't know wtf to do
 195     }
 196     elsif (! defined $destruction_registry->{ my $addr = refaddr($_[0]) } ) {
 197       weaken( $destruction_registry->{$addr} = $_[0] );
 198       return 0;
 199     }
 200     else {
 201       carp_unique ( sprintf (
 202         'Preventing *MULTIPLE* DESTROY() invocations on %s - an *EXTREMELY '
 203       . 'DANGEROUS* condition which is *ALMOST CERTAINLY GLOBAL* within your '
 204       . 'application, affecting *ALL* classes without active protection against '
 205       . 'this. Diagnose and fix the root cause ASAP!!!%s',
 206       refdesc $_[0],
 207         ( ( $INC{'Devel/StackTrace.pm'} and ! do { local $@; eval { Devel::StackTrace->VERSION(2) } } )
 208           ? " (likely culprit Devel::StackTrace\@@{[ Devel::StackTrace->VERSION ]} found in %INC, http://is.gd/D_ST_refcap)"
 209           : ''
 210         )
 211       ));
 212
 213       return 1;
 214     }
 215   }
 216 }
 217
 218 sub modver_gt_or_eq ($$) {
 219   my ($mod, $ver) = @_;
 220
 221   croak "Nonsensical module name supplied"
 222     if ! defined $mod or ! length $mod;
 223
 224   croak "Nonsensical minimum version supplied"
 225     if ! defined $ver or $ver =~ /[^0-9\.\_]/;
 226
 227   local $SIG{__WARN__} = sigwarn_silencer( qr/\Qisn't numeric in subroutine entry/ )
 228     if SPURIOUS_VERSION_CHECK_WARNINGS;
 229
 230   croak "$mod does not seem to provide a version (perhaps it never loaded)"
 231     unless $mod->VERSION;
 232
 233   local $@;
 234   eval { $mod->VERSION($ver) } ? 1 : 0;
 235 }
 236
 237 sub modver_gt_or_eq_and_lt ($$$) {
 238   my ($mod, $v_ge, $v_lt) = @_;
 239
 240   croak "Nonsensical maximum version supplied"
 241     if ! defined $v_lt or $v_lt =~ /[^0-9\.\_]/;
 242
 243   return (
 244     modver_gt_or_eq($mod, $v_ge)
 245       and
 246     ! modver_gt_or_eq($mod, $v_lt)
 247   ) ? 1 : 0;
 248 }
 249
 250 {
 251   my $list_ctx_ok_stack_marker;
 252
 253   sub fail_on_internal_wantarray () {
 254     return if $list_ctx_ok_stack_marker;
 255
 256     if (! defined wantarray) {
 257       croak('fail_on_internal_wantarray() needs a tempvar to save the stack marker guard');
 258     }
 259
 260     my $cf = 1;
 261     while ( ( (caller($cf+1))[3] || '' ) =~ / :: (?:
 262
 263       # these are public API parts that alter behavior on wantarray
 264       search | search_related | slice | search_literal
 265
 266         |
 267
 268       # these are explicitly prefixed, since we only recognize them as valid
 269       # escapes when they come from the guts of CDBICompat
 270       CDBICompat .*? :: (?: search_where | retrieve_from_sql | retrieve_all )
 271
 272     ) $/x ) {
 273       $cf++;
 274     }
 275
 276     my ($fr, $want, $argdesc);
 277     {
 278       package DB;
 279       $fr = [ caller($cf) ];
 280       $want = ( caller($cf-1) )[5];
 281       $argdesc = ref $DB::args[0]
 282         ? DBIx::Class::_Util::refdesc($DB::args[0])
 283         : 'non '
 284       ;
 285     };
 286
 287     if (
 288       $want and $fr->[0] =~ /^(?:DBIx::Class|DBICx::)/
 289     ) {
 290       DBIx::Class::Exception->throw( sprintf (
 291         "Improper use of %s instance in list context at %s line %d\n\n    Stacktrace starts",
 292         $argdesc, @{$fr}[1,2]
 293       ), 'with_stacktrace');
 294     }
 295
 296     my $mark = [];
 297     weaken ( $list_ctx_ok_stack_marker = $mark );
 298     $mark;
 299   }
 300 }
 301
 302 sub fail_on_internal_call {
 303   my ($fr, $argdesc);
 304   {
 305     package DB;
 306     $fr = [ caller(1) ];
 307     $argdesc = ref $DB::args[0]
 308       ? DBIx::Class::_Util::refdesc($DB::args[0])
 309       : undef
 310     ;
 311   };
 312
 313   if (
 314     $argdesc
 315       and
 316     $fr->[0] =~ /^(?:DBIx::Class|DBICx::)/
 317       and
 318     $fr->[1] !~ /\b(?:CDBICompat|ResultSetProxy)\b/  # no point touching there
 319   ) {
 320     DBIx::Class::Exception->throw( sprintf (
 321       "Illegal internal call of indirect proxy-method %s() with argument %s: examine the last lines of the proxy method deparse below to determine what to call directly instead at %s on line %d\n\n%s\n\n    Stacktrace starts",
 322       $fr->[3], $argdesc, @{$fr}[1,2], ( $fr->[6] || do {
 323         require B::Deparse;
 324         no strict 'refs';
 325         B::Deparse->new->coderef2text(\&{$fr->[3]})
 326       }),
 327     ), 'with_stacktrace');
 328   }
 329 }
 330
 331 1;