lib/DBIx/Class/_Util.pm

   1 package # hide from PAUSE
   2   DBIx::Class::_Util;
   3
   4 use warnings;
   5 use strict;
   6
   7 use constant SPURIOUS_VERSION_CHECK_WARNINGS => ($] < 5.010 ? 1 : 0);
   8
   9 BEGIN {
  10   package # hide from pause
  11     DBIx::Class::_ENV_;
  12
  13   use Config;
  14
  15   use constant {
  16
  17     # but of course
  18     BROKEN_FORK => ($^O eq 'MSWin32') ? 1 : 0,
  19
  20     HAS_ITHREADS => $Config{useithreads} ? 1 : 0,
  21
  22     # ::Runmode would only be loaded by DBICTest, which in turn implies t/
  23     DBICTEST => eval { DBICTest::RunMode->is_author } ? 1 : 0,
  24
  25     # During 5.13 dev cycle HELEMs started to leak on copy
  26     # add an escape for these perls ON SMOKERS - a user will still get death
  27     PEEPEENESS => ( eval { DBICTest::RunMode->is_smoker } && ($] >= 5.013005 and $] <= 5.013006) ),
  28
  29     SHUFFLE_UNORDERED_RESULTSETS => $ENV{DBIC_SHUFFLE_UNORDERED_RESULTSETS} ? 1 : 0,
  30
  31     ASSERT_NO_INTERNAL_WANTARRAY => $ENV{DBIC_ASSERT_NO_INTERNAL_WANTARRAY} ? 1 : 0,
  32
  33     ASSERT_NO_INTERNAL_INDIRECT_CALLS => $ENV{DBIC_ASSERT_NO_INTERNAL_INDIRECT_CALLS} ? 1 : 0,
  34
  35     IV_SIZE => $Config{ivsize},
  36
  37     OS_NAME => $^O,
  38   };
  39
  40   if ($] < 5.009_005) {
  41     require MRO::Compat;
  42     constant->import( OLD_MRO => 1 );
  43   }
  44   else {
  45     require mro;
  46     constant->import( OLD_MRO => 0 );
  47   }
  48 }
  49
  50 # FIXME - this is not supposed to be here
  51 # Carp::Skip to the rescue soon
  52 use DBIx::Class::Carp '^DBIx::Class|^DBICTest';
  53
  54 use Carp 'croak';
  55 use Scalar::Util qw(weaken blessed reftype);
  56 use List::Util qw(first);
  57
  58 use base 'Exporter';
  59 our @EXPORT_OK = qw(
  60   sigwarn_silencer modver_gt_or_eq
  61   fail_on_internal_wantarray fail_on_internal_call
  62   refdesc refcount hrefaddr is_exception
  63   UNRESOLVABLE_CONDITION
  64 );
  65
  66 use constant UNRESOLVABLE_CONDITION => \ '1 = 0';
  67
  68 sub sigwarn_silencer ($) {
  69   my $pattern = shift;
  70
  71   croak "Expecting a regexp" if ref $pattern ne 'Regexp';
  72
  73   my $orig_sig_warn = $SIG{__WARN__} || sub { CORE::warn(@_) };
  74
  75   return sub { &$orig_sig_warn unless $_[0] =~ $pattern };
  76 }
  77
  78 sub hrefaddr ($) { sprintf '0x%x', &Scalar::Util::refaddr||0 }
  79
  80 sub refdesc ($) {
  81   croak "Expecting a reference" if ! length ref $_[0];
  82
  83   # be careful not to trigger stringification,
  84   # reuse @_ as a scratch-pad
  85   sprintf '%s%s(0x%x)',
  86     ( defined( $_[1] = blessed $_[0]) ? "$_[1]=" : '' ),
  87     reftype $_[0],
  88     Scalar::Util::refaddr($_[0]),
  89   ;
  90 }
  91
  92 sub refcount ($) {
  93   croak "Expecting a reference" if ! length ref $_[0];
  94
  95   require B;
  96   # No tempvars - must operate on $_[0], otherwise the pad
  97   # will count as an extra ref
  98   B::svref_2object($_[0])->REFCNT;
  99 }
 100
 101 sub is_exception ($) {
 102   my $e = $_[0];
 103
 104   # this is not strictly correct - an eval setting $@ to undef
 105   # is *not* the same as an eval setting $@ to ''
 106   # but for the sake of simplicity assume the following for
 107   # the time being
 108   return 0 unless defined $e;
 109
 110   my ($not_blank, $suberror);
 111   {
 112     local $@;
 113     eval {
 114       $not_blank = ($e ne '') ? 1 : 0;
 115       1;
 116     } or $suberror = $@;
 117   }
 118
 119   if (defined $suberror) {
 120     if (length (my $class = blessed($e) )) {
 121       carp_unique( sprintf(
 122         'External exception class %s implements partial (broken) overloading '
 123       . 'preventing its instances from being used in simple ($x eq $y) '
 124       . 'comparisons. Given Perl\'s "globally cooperative" exception '
 125       . 'handling this type of brokenness is extremely dangerous on '
 126       . 'exception objects, as it may (and often does) result in silent '
 127       . '"exception substitution". DBIx::Class tries to work around this '
 128       . 'as much as possible, but other parts of your software stack may '
 129       . 'not be even aware of this. Please submit a bugreport against the '
 130       . 'distribution containing %s and in the meantime apply a fix similar '
 131       . 'to the one shown at %s, in order to ensure your exception handling '
 132       . 'is saner application-wide. What follows is the actual error text '
 133       . "as generated by Perl itself:\n\n%s\n ",
 134         $class,
 135         $class,
 136         'http://v.gd/DBIC_overload_tempfix/',
 137         $suberror,
 138       ));
 139
 140       # workaround, keeps spice flowing
 141       $not_blank = ("$e" ne '') ? 1 : 0;
 142     }
 143     else {
 144       # not blessed yet failed the 'ne'... this makes 0 sense...
 145       # just throw further
 146       die $suberror
 147     }
 148   }
 149
 150   return $not_blank;
 151 }
 152
 153 sub modver_gt_or_eq ($$) {
 154   my ($mod, $ver) = @_;
 155
 156   croak "Nonsensical module name supplied"
 157     if ! defined $mod or ! length $mod;
 158
 159   croak "Nonsensical minimum version supplied"
 160     if ! defined $ver or $ver =~ /[^0-9\.\_]/;
 161
 162   local $SIG{__WARN__} = sigwarn_silencer( qr/\Qisn't numeric in subroutine entry/ )
 163     if SPURIOUS_VERSION_CHECK_WARNINGS;
 164
 165   croak "$mod does not seem to provide a version (perhaps it never loaded)"
 166     unless $mod->VERSION;
 167
 168   local $@;
 169   eval { $mod->VERSION($ver) } ? 1 : 0;
 170 }
 171
 172 {
 173   my $list_ctx_ok_stack_marker;
 174
 175   sub fail_on_internal_wantarray () {
 176     return if $list_ctx_ok_stack_marker;
 177
 178     if (! defined wantarray) {
 179       croak('fail_on_internal_wantarray() needs a tempvar to save the stack marker guard');
 180     }
 181
 182     my $cf = 1;
 183     while ( ( (caller($cf+1))[3] || '' ) =~ / :: (?:
 184
 185       # these are public API parts that alter behavior on wantarray
 186       search | search_related | slice | search_literal
 187
 188         |
 189
 190       # these are explicitly prefixed, since we only recognize them as valid
 191       # escapes when they come from the guts of CDBICompat
 192       CDBICompat .*? :: (?: search_where | retrieve_from_sql | retrieve_all )
 193
 194     ) $/x ) {
 195       $cf++;
 196     }
 197
 198     my ($fr, $want, $argdesc);
 199     {
 200       package DB;
 201       $fr = [ caller($cf) ];
 202       $want = ( caller($cf-1) )[5];
 203       $argdesc = ref $DB::args[0]
 204         ? DBIx::Class::_Util::refdesc($DB::args[0])
 205         : 'non '
 206       ;
 207     };
 208
 209     if (
 210       $want and $fr->[0] =~ /^(?:DBIx::Class|DBICx::)/
 211     ) {
 212       DBIx::Class::Exception->throw( sprintf (
 213         "Improper use of %s instance in list context at %s line %d\n\n    Stacktrace starts",
 214         $argdesc, @{$fr}[1,2]
 215       ), 'with_stacktrace');
 216     }
 217
 218     my $mark = [];
 219     weaken ( $list_ctx_ok_stack_marker = $mark );
 220     $mark;
 221   }
 222 }
 223
 224 sub fail_on_internal_call {
 225   my ($fr, $argdesc);
 226   {
 227     package DB;
 228     $fr = [ caller(1) ];
 229     $argdesc = ref $DB::args[0]
 230       ? DBIx::Class::_Util::refdesc($DB::args[0])
 231       : undef
 232     ;
 233   };
 234
 235   if (
 236     $argdesc
 237       and
 238     $fr->[0] =~ /^(?:DBIx::Class|DBICx::)/
 239       and
 240     $fr->[1] !~ /\b(?:CDBICompat|ResultSetProxy)\b/  # no point touching there
 241   ) {
 242     DBIx::Class::Exception->throw( sprintf (
 243       "Illegal internal call of indirect proxy-method %s() with argument %s: examine the last lines of the proxy method deparse below to determine what to call directly instead at %s on line %d\n\n%s\n\n    Stacktrace starts",
 244       $fr->[3], $argdesc, @{$fr}[1,2], ( $fr->[6] || do {
 245         require B::Deparse;
 246         no strict 'refs';
 247         B::Deparse->new->coderef2text(\&{$fr->[3]})
 248       }),
 249     ), 'with_stacktrace');
 250   }
 251 }
 252
 253 1;