lib/DBIx/Class/_Util.pm

   1 package # hide from PAUSE
   2   DBIx::Class::_Util;
   3
   4 use warnings;
   5 use strict;
   6
   7 use constant SPURIOUS_VERSION_CHECK_WARNINGS => ( "$]" < 5.010 ? 1 : 0);
   8
   9 BEGIN {
  10   package # hide from pause
  11     DBIx::Class::_ENV_;
  12
  13   use Config;
  14
  15   use constant {
  16
  17     # but of course
  18     BROKEN_FORK => ($^O eq 'MSWin32') ? 1 : 0,
  19
  20     BROKEN_GOTO => ( "$]" < 5.008003 ) ? 1 : 0,
  21
  22     HAS_ITHREADS => $Config{useithreads} ? 1 : 0,
  23
  24     UNSTABLE_DOLLARAT => ( "$]" < 5.013002 ) ? 1 : 0,
  25
  26     DBICTEST => $INC{"DBICTest/Util.pm"} ? 1 : 0,
  27
  28     # During 5.13 dev cycle HELEMs started to leak on copy
  29     # add an escape for these perls ON SMOKERS - a user will still get death
  30     PEEPEENESS => ( eval { DBICTest::RunMode->is_smoker } && ( "$]" >= 5.013005 and "$]" <= 5.013006) ),
  31
  32     SHUFFLE_UNORDERED_RESULTSETS => $ENV{DBIC_SHUFFLE_UNORDERED_RESULTSETS} ? 1 : 0,
  33
  34     ASSERT_NO_INTERNAL_WANTARRAY => $ENV{DBIC_ASSERT_NO_INTERNAL_WANTARRAY} ? 1 : 0,
  35
  36     ASSERT_NO_INTERNAL_INDIRECT_CALLS => $ENV{DBIC_ASSERT_NO_INTERNAL_INDIRECT_CALLS} ? 1 : 0,
  37
  38     STRESSTEST_UTF8_UPGRADE_GENERATED_COLLAPSER_SOURCE => $ENV{DBIC_STRESSTEST_UTF8_UPGRADE_GENERATED_COLLAPSER_SOURCE} ? 1 : 0,
  39
  40     STRESSTEST_COLUMN_INFO_UNAWARE_STORAGE => $ENV{DBIC_STRESSTEST_COLUMN_INFO_UNAWARE_STORAGE} ? 1 : 0,
  41
  42     IV_SIZE => $Config{ivsize},
  43
  44     OS_NAME => $^O,
  45   };
  46
  47   if ( "$]" < 5.009_005) {
  48     require MRO::Compat;
  49     constant->import( OLD_MRO => 1 );
  50   }
  51   else {
  52     require mro;
  53     constant->import( OLD_MRO => 0 );
  54   }
  55 }
  56
  57 # FIXME - this is not supposed to be here
  58 # Carp::Skip to the rescue soon
  59 use DBIx::Class::Carp '^DBIx::Class|^DBICTest';
  60
  61 use B ();
  62 use Carp 'croak';
  63 use Storable 'nfreeze';
  64 use Scalar::Util qw(weaken blessed reftype refaddr);
  65 use List::Util qw(first);
  66 use Sub::Quote qw(qsub quote_sub);
  67
  68 # Already correctly prototyped: perlbrew exec perl -MStorable -e 'warn prototype \&Storable::dclone'
  69 BEGIN { *deep_clone = \&Storable::dclone }
  70
  71 use base 'Exporter';
  72 our @EXPORT_OK = qw(
  73   sigwarn_silencer modver_gt_or_eq modver_gt_or_eq_and_lt
  74   fail_on_internal_wantarray fail_on_internal_call
  75   refdesc refcount hrefaddr
  76   scope_guard is_exception detected_reinvoked_destructor
  77   quote_sub qsub perlstring serialize deep_clone
  78   UNRESOLVABLE_CONDITION
  79 );
  80
  81 use constant UNRESOLVABLE_CONDITION => \ '1 = 0';
  82
  83 sub sigwarn_silencer ($) {
  84   my $pattern = shift;
  85
  86   croak "Expecting a regexp" if ref $pattern ne 'Regexp';
  87
  88   my $orig_sig_warn = $SIG{__WARN__} || sub { CORE::warn(@_) };
  89
  90   return sub { &$orig_sig_warn unless $_[0] =~ $pattern };
  91 }
  92
  93 sub perlstring ($) { q{"}. quotemeta( shift ). q{"} };
  94
  95 sub hrefaddr ($) { sprintf '0x%x', &refaddr||0 }
  96
  97 sub refdesc ($) {
  98   croak "Expecting a reference" if ! length ref $_[0];
  99
 100   # be careful not to trigger stringification,
 101   # reuse @_ as a scratch-pad
 102   sprintf '%s%s(0x%x)',
 103     ( defined( $_[1] = blessed $_[0]) ? "$_[1]=" : '' ),
 104     reftype $_[0],
 105     refaddr($_[0]),
 106   ;
 107 }
 108
 109 sub refcount ($) {
 110   croak "Expecting a reference" if ! length ref $_[0];
 111
 112   # No tempvars - must operate on $_[0], otherwise the pad
 113   # will count as an extra ref
 114   B::svref_2object($_[0])->REFCNT;
 115 }
 116
 117 sub serialize ($) {
 118   local $Storable::canonical = 1;
 119   nfreeze($_[0]);
 120 }
 121
 122 sub scope_guard (&) {
 123   croak 'Calling scope_guard() in void context makes no sense'
 124     if ! defined wantarray;
 125
 126   # no direct blessing of coderefs - DESTROY is buggy on those
 127   bless [ $_[0] ], 'DBIx::Class::_Util::ScopeGuard';
 128 }
 129 {
 130   package #
 131     DBIx::Class::_Util::ScopeGuard;
 132
 133   sub DESTROY {
 134     &DBIx::Class::_Util::detected_reinvoked_destructor;
 135
 136     local $@ if DBIx::Class::_ENV_::UNSTABLE_DOLLARAT;
 137
 138     eval {
 139       $_[0]->[0]->();
 140       1;
 141     } or do {
 142       Carp::cluck "Execution of scope guard $_[0] resulted in the non-trappable exception:\n\n$@";
 143     };
 144   }
 145 }
 146
 147
 148 sub is_exception ($) {
 149   my $e = $_[0];
 150
 151   # this is not strictly correct - an eval setting $@ to undef
 152   # is *not* the same as an eval setting $@ to ''
 153   # but for the sake of simplicity assume the following for
 154   # the time being
 155   return 0 unless defined $e;
 156
 157   my ($not_blank, $suberror);
 158   {
 159     local $@;
 160     eval {
 161       # The ne() here is deliberate - a plain length($e), or worse "$e" ne
 162       # will entirely obviate the need for the encolsing eval{}, as the
 163       # condition we guard against is a missing fallback overload
 164       $not_blank = ( $e ne '' );
 165       1;
 166     } or $suberror = $@;
 167   }
 168
 169   if (defined $suberror) {
 170     if (length (my $class = blessed($e) )) {
 171       carp_unique( sprintf(
 172         'External exception class %s implements partial (broken) overloading '
 173       . 'preventing its instances from being used in simple ($x eq $y) '
 174       . 'comparisons. Given Perl\'s "globally cooperative" exception '
 175       . 'handling this type of brokenness is extremely dangerous on '
 176       . 'exception objects, as it may (and often does) result in silent '
 177       . '"exception substitution". DBIx::Class tries to work around this '
 178       . 'as much as possible, but other parts of your software stack may '
 179       . 'not be even aware of this. Please submit a bugreport against the '
 180       . 'distribution containing %s and in the meantime apply a fix similar '
 181       . 'to the one shown at %s, in order to ensure your exception handling '
 182       . 'is saner application-wide. What follows is the actual error text '
 183       . "as generated by Perl itself:\n\n%s\n ",
 184         $class,
 185         $class,
 186         'http://v.gd/DBIC_overload_tempfix/',
 187         $suberror,
 188       ));
 189
 190       # workaround, keeps spice flowing
 191       $not_blank = !!( length $e );
 192     }
 193     else {
 194       # not blessed yet failed the 'ne'... this makes 0 sense...
 195       # just throw further
 196       die $suberror
 197     }
 198   }
 199   elsif (
 200     # a ref evaluating to '' is definitively a "null object"
 201     ( not $not_blank )
 202       and
 203     length( my $class = ref $e )
 204   ) {
 205     carp_unique( sprintf(
 206       "Objects of external exception class '%s' stringify to '' (the "
 207     . 'empty string), implementing the so called null-object-pattern. '
 208     . 'Given Perl\'s "globally cooperative" exception handling using this '
 209     . 'class of exceptions is extremely dangerous, as it may (and often '
 210     . 'does) result in silent discarding of errors. DBIx::Class tries to '
 211     . 'work around this as much as possible, but other parts of your '
 212     . 'software stack may not be even aware of the problem. Please submit '
 213     . 'a bugreport against the distribution containing %s.',
 214
 215       ($class) x 2,
 216     ));
 217
 218     $not_blank = 1;
 219   }
 220
 221   return $not_blank;
 222 }
 223
 224 {
 225   my $destruction_registry = {};
 226
 227   sub CLONE {
 228     $destruction_registry = { map
 229       { defined $_ ? ( refaddr($_) => $_ ) : () }
 230       values %$destruction_registry
 231     };
 232   }
 233
 234   # This is almost invariably invoked from within DESTROY
 235   # throwing exceptions won't work
 236   sub detected_reinvoked_destructor {
 237
 238     # quick "garbage collection" pass - prevents the registry
 239     # from slowly growing with a bunch of undef-valued keys
 240     defined $destruction_registry->{$_} or delete $destruction_registry->{$_}
 241       for keys %$destruction_registry;
 242
 243     if (! length ref $_[0]) {
 244       printf STDERR '%s() expects a blessed reference %s',
 245         (caller(0))[3],
 246         Carp::longmess,
 247       ;
 248       return undef; # don't know wtf to do
 249     }
 250     elsif (! defined $destruction_registry->{ my $addr = refaddr($_[0]) } ) {
 251       weaken( $destruction_registry->{$addr} = $_[0] );
 252       return 0;
 253     }
 254     else {
 255       carp_unique ( sprintf (
 256         'Preventing *MULTIPLE* DESTROY() invocations on %s - an *EXTREMELY '
 257       . 'DANGEROUS* condition which is *ALMOST CERTAINLY GLOBAL* within your '
 258       . 'application, affecting *ALL* classes without active protection against '
 259       . 'this. Diagnose and fix the root cause ASAP!!!%s',
 260       refdesc $_[0],
 261         ( ( $INC{'Devel/StackTrace.pm'} and ! do { local $@; eval { Devel::StackTrace->VERSION(2) } } )
 262           ? " (likely culprit Devel::StackTrace\@@{[ Devel::StackTrace->VERSION ]} found in %INC, http://is.gd/D_ST_refcap)"
 263           : ''
 264         )
 265       ));
 266
 267       return 1;
 268     }
 269   }
 270 }
 271
 272 sub modver_gt_or_eq ($$) {
 273   my ($mod, $ver) = @_;
 274
 275   croak "Nonsensical module name supplied"
 276     if ! defined $mod or ! length $mod;
 277
 278   croak "Nonsensical minimum version supplied"
 279     if ! defined $ver or $ver =~ /[^0-9\.\_]/;
 280
 281   local $SIG{__WARN__} = sigwarn_silencer( qr/\Qisn't numeric in subroutine entry/ )
 282     if SPURIOUS_VERSION_CHECK_WARNINGS;
 283
 284   croak "$mod does not seem to provide a version (perhaps it never loaded)"
 285     unless $mod->VERSION;
 286
 287   local $@;
 288   eval { $mod->VERSION($ver) } ? 1 : 0;
 289 }
 290
 291 sub modver_gt_or_eq_and_lt ($$$) {
 292   my ($mod, $v_ge, $v_lt) = @_;
 293
 294   croak "Nonsensical maximum version supplied"
 295     if ! defined $v_lt or $v_lt =~ /[^0-9\.\_]/;
 296
 297   return (
 298     modver_gt_or_eq($mod, $v_ge)
 299       and
 300     ! modver_gt_or_eq($mod, $v_lt)
 301   ) ? 1 : 0;
 302 }
 303
 304 {
 305   my $list_ctx_ok_stack_marker;
 306
 307   sub fail_on_internal_wantarray () {
 308     return if $list_ctx_ok_stack_marker;
 309
 310     if (! defined wantarray) {
 311       croak('fail_on_internal_wantarray() needs a tempvar to save the stack marker guard');
 312     }
 313
 314     my $cf = 1;
 315     while ( ( (CORE::caller($cf+1))[3] || '' ) =~ / :: (?:
 316
 317       # these are public API parts that alter behavior on wantarray
 318       search | search_related | slice | search_literal
 319
 320         |
 321
 322       # these are explicitly prefixed, since we only recognize them as valid
 323       # escapes when they come from the guts of CDBICompat
 324       CDBICompat .*? :: (?: search_where | retrieve_from_sql | retrieve_all )
 325
 326     ) $/x ) {
 327       $cf++;
 328     }
 329
 330     my ($fr, $want, $argdesc);
 331     {
 332       package DB;
 333       $fr = [ CORE::caller($cf) ];
 334       $want = ( CORE::caller($cf-1) )[5];
 335       $argdesc = ref $DB::args[0]
 336         ? DBIx::Class::_Util::refdesc($DB::args[0])
 337         : 'non '
 338       ;
 339     };
 340
 341     if (
 342       $want and $fr->[0] =~ /^(?:DBIx::Class|DBICx::)/
 343     ) {
 344       DBIx::Class::Exception->throw( sprintf (
 345         "Improper use of %s instance in list context at %s line %d\n\n    Stacktrace starts",
 346         $argdesc, @{$fr}[1,2]
 347       ), 'with_stacktrace');
 348     }
 349
 350     my $mark = [];
 351     weaken ( $list_ctx_ok_stack_marker = $mark );
 352     $mark;
 353   }
 354 }
 355
 356 sub fail_on_internal_call {
 357   my ($fr, $argdesc);
 358   {
 359     package DB;
 360     $fr = [ CORE::caller(1) ];
 361     $argdesc = ref $DB::args[0]
 362       ? DBIx::Class::_Util::refdesc($DB::args[0])
 363       : undef
 364     ;
 365   };
 366
 367   if (
 368     $argdesc
 369       and
 370     $fr->[0] =~ /^(?:DBIx::Class|DBICx::)/
 371       and
 372     $fr->[1] !~ /\b(?:CDBICompat|ResultSetProxy)\b/  # no point touching there
 373   ) {
 374     DBIx::Class::Exception->throw( sprintf (
 375       "Illegal internal call of indirect proxy-method %s() with argument %s: examine the last lines of the proxy method deparse below to determine what to call directly instead at %s on line %d\n\n%s\n\n    Stacktrace starts",
 376       $fr->[3], $argdesc, @{$fr}[1,2], ( $fr->[6] || do {
 377         require B::Deparse;
 378         no strict 'refs';
 379         B::Deparse->new->coderef2text(\&{$fr->[3]})
 380       }),
 381     ), 'with_stacktrace');
 382   }
 383 }
 384
 385 1;