lib/DBIx/Class/_Util.pm

   1 package # hide from PAUSE
   2   DBIx::Class::_Util;
   3
   4 use DBIx::Class::StartupCheck;  # load es early as we can, usually a noop
   5
   6 use warnings;
   7 use strict;
   8
   9 use constant SPURIOUS_VERSION_CHECK_WARNINGS => ( "$]" < 5.010 ? 1 : 0);
  10
  11 BEGIN {
  12   package # hide from pause
  13     DBIx::Class::_ENV_;
  14
  15   use Config;
  16
  17   use constant {
  18
  19     # but of course
  20     BROKEN_FORK => ($^O eq 'MSWin32') ? 1 : 0,
  21
  22     BROKEN_GOTO => ( "$]" < 5.008003 ) ? 1 : 0,
  23
  24     HAS_ITHREADS => $Config{useithreads} ? 1 : 0,
  25
  26     UNSTABLE_DOLLARAT => ( "$]" < 5.013002 ) ? 1 : 0,
  27
  28     ( map
  29       #
  30       # the "DBIC_" prefix below is crucial - this is what makes CI pick up
  31       # all envvars without further adjusting its scripts
  32       # DO NOT CHANGE to the more logical { $_ => !!( $ENV{"DBIC_$_"} ) }
  33       #
  34       { substr($_, 5) => !!( $ENV{$_} ) }
  35       qw(
  36         DBIC_SHUFFLE_UNORDERED_RESULTSETS
  37         DBIC_ASSERT_NO_INTERNAL_WANTARRAY
  38         DBIC_ASSERT_NO_INTERNAL_INDIRECT_CALLS
  39         DBIC_STRESSTEST_UTF8_UPGRADE_GENERATED_COLLAPSER_SOURCE
  40         DBIC_STRESSTEST_COLUMN_INFO_UNAWARE_STORAGE
  41       )
  42     ),
  43
  44     IV_SIZE => $Config{ivsize},
  45
  46     OS_NAME => $^O,
  47   };
  48
  49   if ( "$]" < 5.009_005) {
  50     require MRO::Compat;
  51     constant->import( OLD_MRO => 1 );
  52   }
  53   else {
  54     require mro;
  55     constant->import( OLD_MRO => 0 );
  56   }
  57
  58   # Both of these are no longer used for anything. However bring
  59   # them back after they were purged in 08a8d8f1, as there appear
  60   # to be outfits with *COPY PASTED* pieces of lib/DBIx/Class/Storage/*
  61   # in their production codebases. There is no point in breaking these
  62   # if whatever they used actually continues to work
  63   my $warned;
  64   my $sigh = sub {
  65
  66     require Carp;
  67     my $cluck = "The @{[ (caller(1))[3] ]} constant is no more - adjust your code" . Carp::longmess();
  68
  69     warn $cluck unless $warned->{$cluck}++;
  70
  71     0;
  72   };
  73   sub DBICTEST () { &$sigh }
  74   sub PEEPEENESS () { &$sigh }
  75 }
  76
  77 # FIXME - this is not supposed to be here
  78 # Carp::Skip to the rescue soon
  79 use DBIx::Class::Carp '^DBIx::Class|^DBICTest';
  80
  81 use B ();
  82 use Carp 'croak';
  83 use Storable 'nfreeze';
  84 use Scalar::Util qw(weaken blessed reftype refaddr);
  85 use Sub::Quote qw(qsub);
  86 use Sub::Name ();
  87
  88 # Already correctly prototyped: perlbrew exec perl -MStorable -e 'warn prototype \&Storable::dclone'
  89 BEGIN { *deep_clone = \&Storable::dclone }
  90
  91 use base 'Exporter';
  92 our @EXPORT_OK = qw(
  93   sigwarn_silencer modver_gt_or_eq modver_gt_or_eq_and_lt
  94   fail_on_internal_wantarray fail_on_internal_call
  95   refdesc refcount hrefaddr set_subname
  96   scope_guard detected_reinvoked_destructor
  97   is_exception dbic_internal_try
  98   quote_sub qsub perlstring serialize deep_clone dump_value
  99   parent_dir mkdir_p
 100   UNRESOLVABLE_CONDITION
 101 );
 102
 103 use constant UNRESOLVABLE_CONDITION => \ '1 = 0';
 104
 105 BEGIN {
 106   # add preliminary attribute support
 107   # FIXME FIXME FIXME
 108   # To be revisited when Moo with proper attr support ships
 109   Sub::Quote->VERSION(2.002);
 110   require attributes;
 111 }
 112 # Override forcing no_defer, and adding naming consistency checks
 113 sub quote_sub {
 114   Carp::confess( "Anonymous quoting not supported by the DBIC sub_quote override - supply a sub name" ) if
 115     @_ < 2
 116       or
 117     ! defined $_[1]
 118       or
 119     length ref $_[1]
 120   ;
 121
 122   Carp::confess( "The DBIC sub_quote override expects sub name '$_[0]' to be fully qualified" )
 123     unless $_[0] =~ /::/;
 124
 125   Carp::confess( "The DBIC sub_quote override expects the sub name '$_[0]' to match the supplied 'package' argument" ) if
 126     $_[3]
 127       and
 128     defined $_[3]->{package}
 129       and
 130     index( $_[0], $_[3]->{package} ) != 0
 131   ;
 132
 133   my @caller = caller(0);
 134   my $sq_opts = {
 135     package => $caller[0],
 136     hints => $caller[8],
 137     warning_bits => $caller[9],
 138     hintshash => $caller[10],
 139     %{ $_[3] || {} },
 140
 141     # explicitly forced for everything
 142     no_defer => 1,
 143   };
 144
 145   my $cref = Sub::Quote::quote_sub( $_[0], $_[1], $_[2]||{}, $sq_opts );
 146
 147   # FIXME FIXME FIXME
 148   # To be revisited when Moo with proper attr support ships
 149   if(
 150     # external application does not work on things like :prototype(...), :lvalue, etc
 151     my @attrs = grep {
 152       $_ !~ /^[a-z]/
 153         or
 154       Carp::confess( "The DBIC sub_quote override does not support applying of reserved attribute '$_'" )
 155     } @{ $sq_opts->{attributes} || []}
 156   ) {
 157     Carp::confess( "The DBIC sub_quote override does not allow mixing 'attributes' with 'no_install'" )
 158       if $sq_opts->{no_install};
 159
 160     # might be different from $sq_opts->{package};
 161     my ($install_into) = $_[0] =~ /(.+)::[^:]+$/;
 162
 163     attributes->import( $install_into, $cref, @attrs );
 164   }
 165
 166   $cref;
 167 }
 168
 169 sub sigwarn_silencer ($) {
 170   my $pattern = shift;
 171
 172   croak "Expecting a regexp" if ref $pattern ne 'Regexp';
 173
 174   my $orig_sig_warn = $SIG{__WARN__} || sub { CORE::warn(@_) };
 175
 176   return sub { &$orig_sig_warn unless $_[0] =~ $pattern };
 177 }
 178
 179 sub perlstring ($) { q{"}. quotemeta( shift ). q{"} };
 180
 181 sub hrefaddr ($) { sprintf '0x%x', &refaddr||0 }
 182
 183 sub refdesc ($) {
 184   croak "Expecting a reference" if ! length ref $_[0];
 185
 186   # be careful not to trigger stringification,
 187   # reuse @_ as a scratch-pad
 188   sprintf '%s%s(0x%x)',
 189     ( defined( $_[1] = blessed $_[0]) ? "$_[1]=" : '' ),
 190     reftype $_[0],
 191     refaddr($_[0]),
 192   ;
 193 }
 194
 195 sub refcount ($) {
 196   croak "Expecting a reference" if ! length ref $_[0];
 197
 198   # No tempvars - must operate on $_[0], otherwise the pad
 199   # will count as an extra ref
 200   B::svref_2object($_[0])->REFCNT;
 201 }
 202
 203 # FIXME In another life switch this to a polyfill like the one in namespace::clean
 204 sub set_subname ($$) {
 205
 206   # fully qualify name
 207   splice @_, 0, 1, caller(0) . "::$_[0]"
 208     if $_[0] !~ /::|'/;
 209
 210   &Sub::Name::subname;
 211 }
 212
 213 sub serialize ($) {
 214   local $Storable::canonical = 1;
 215   nfreeze($_[0]);
 216 }
 217
 218 my $dd_obj;
 219 sub dump_value ($) {
 220   local $Data::Dumper::Indent = 1
 221     unless defined $Data::Dumper::Indent;
 222
 223   my $dump_str = (
 224     $dd_obj
 225       ||=
 226     do {
 227       require Data::Dumper;
 228       my $d = Data::Dumper->new([])
 229         ->Purity(0)
 230         ->Pad('')
 231         ->Useqq(1)
 232         ->Terse(1)
 233         ->Freezer('')
 234         ->Quotekeys(0)
 235         ->Bless('bless')
 236         ->Pair(' => ')
 237         ->Sortkeys(1)
 238         ->Deparse(1)
 239       ;
 240
 241       $d->Sparseseen(1) if modver_gt_or_eq (
 242         'Data::Dumper', '2.136'
 243       );
 244
 245       $d;
 246     }
 247   )->Values([$_[0]])->Dump;
 248
 249   $dd_obj->Reset->Values([]);
 250
 251   $dump_str;
 252 }
 253
 254 sub scope_guard (&) {
 255   croak 'Calling scope_guard() in void context makes no sense'
 256     if ! defined wantarray;
 257
 258   # no direct blessing of coderefs - DESTROY is buggy on those
 259   bless [ $_[0] ], 'DBIx::Class::_Util::ScopeGuard';
 260 }
 261 {
 262   package #
 263     DBIx::Class::_Util::ScopeGuard;
 264
 265   sub DESTROY {
 266     &DBIx::Class::_Util::detected_reinvoked_destructor;
 267
 268     local $@ if DBIx::Class::_ENV_::UNSTABLE_DOLLARAT;
 269
 270     eval {
 271       $_[0]->[0]->();
 272       1;
 273     }
 274       or
 275     Carp::cluck(
 276       "Execution of scope guard $_[0] resulted in the non-trappable exception:\n\n$@"
 277     );
 278   }
 279 }
 280
 281
 282 sub is_exception ($) {
 283   my $e = $_[0];
 284
 285   # FIXME
 286   # this is not strictly correct - an eval setting $@ to undef
 287   # is *not* the same as an eval setting $@ to ''
 288   # but for the sake of simplicity assume the following for
 289   # the time being
 290   return 0 unless defined $e;
 291
 292   my ($not_blank, $suberror);
 293   {
 294     local $SIG{__DIE__} if $SIG{__DIE__};
 295     local $@;
 296     eval {
 297       # The ne() here is deliberate - a plain length($e), or worse "$e" ne
 298       # will entirely obviate the need for the encolsing eval{}, as the
 299       # condition we guard against is a missing fallback overload
 300       $not_blank = ( $e ne '' );
 301       1;
 302     } or $suberror = $@;
 303   }
 304
 305   if (defined $suberror) {
 306     if (length (my $class = blessed($e) )) {
 307       carp_unique( sprintf(
 308         'External exception class %s implements partial (broken) overloading '
 309       . 'preventing its instances from being used in simple ($x eq $y) '
 310       . 'comparisons. Given Perl\'s "globally cooperative" exception '
 311       . 'handling this type of brokenness is extremely dangerous on '
 312       . 'exception objects, as it may (and often does) result in silent '
 313       . '"exception substitution". DBIx::Class tries to work around this '
 314       . 'as much as possible, but other parts of your software stack may '
 315       . 'not be even aware of this. Please submit a bugreport against the '
 316       . 'distribution containing %s and in the meantime apply a fix similar '
 317       . 'to the one shown at %s, in order to ensure your exception handling '
 318       . 'is saner application-wide. What follows is the actual error text '
 319       . "as generated by Perl itself:\n\n%s\n ",
 320         $class,
 321         $class,
 322         'http://v.gd/DBIC_overload_tempfix/',
 323         $suberror,
 324       ));
 325
 326       # workaround, keeps spice flowing
 327       $not_blank = !!( length $e );
 328     }
 329     else {
 330       # not blessed yet failed the 'ne'... this makes 0 sense...
 331       # just throw further
 332       die $suberror
 333     }
 334   }
 335   elsif (
 336     # a ref evaluating to '' is definitively a "null object"
 337     ( not $not_blank )
 338       and
 339     length( my $class = ref $e )
 340   ) {
 341     carp_unique( sprintf(
 342       "Objects of external exception class '%s' stringify to '' (the "
 343     . 'empty string), implementing the so called null-object-pattern. '
 344     . 'Given Perl\'s "globally cooperative" exception handling using this '
 345     . 'class of exceptions is extremely dangerous, as it may (and often '
 346     . 'does) result in silent discarding of errors. DBIx::Class tries to '
 347     . 'work around this as much as possible, but other parts of your '
 348     . 'software stack may not be even aware of the problem. Please submit '
 349     . 'a bugreport against the distribution containing %s',
 350
 351       ($class) x 2,
 352     ));
 353
 354     $not_blank = 1;
 355   }
 356
 357   return $not_blank;
 358 }
 359
 360 {
 361   my $callstack_state;
 362
 363   # Recreate the logic of try(), while reusing the catch()/finally() as-is
 364   #
 365   # FIXME: We need to move away from Try::Tiny entirely (way too heavy and
 366   # yes, shows up ON TOP of profiles) but this is a batle for another maint
 367   sub dbic_internal_try (&;@) {
 368
 369     my $try_cref = shift;
 370     my $catch_cref = undef;  # apparently this is a thing... https://rt.perl.org/Public/Bug/Display.html?id=119311
 371
 372     for my $arg (@_) {
 373
 374       if( ref($arg) eq 'Try::Tiny::Catch' ) {
 375
 376         croak 'dbic_internal_try() may not be followed by multiple catch() blocks'
 377           if $catch_cref;
 378
 379         $catch_cref = $$arg;
 380       }
 381       elsif ( ref($arg) eq 'Try::Tiny::Finally' ) {
 382         croak 'dbic_internal_try() does not support finally{}';
 383       }
 384       else {
 385         croak(
 386           'dbic_internal_try() encountered an unexpected argument '
 387         . "'@{[ defined $arg ? $arg : 'UNDEF' ]}' - perhaps "
 388         . 'a missing semi-colon before or ' # trailing space important
 389         );
 390       }
 391     }
 392
 393     my $wantarray = wantarray;
 394     my $preexisting_exception = $@;
 395
 396     my @ret;
 397     my $all_good = eval {
 398       $@ = $preexisting_exception;
 399
 400       local $callstack_state->{in_internal_try} = 1
 401         unless $callstack_state->{in_internal_try};
 402
 403       # always unset - someone may have snuck it in
 404       local $SIG{__DIE__} if $SIG{__DIE__};
 405
 406       if( $wantarray ) {
 407         @ret = $try_cref->();
 408       }
 409       elsif( defined $wantarray ) {
 410         $ret[0] = $try_cref->();
 411       }
 412       else {
 413         $try_cref->();
 414       }
 415
 416       1;
 417     };
 418
 419     my $exception = $@;
 420     $@ = $preexisting_exception;
 421
 422     if ( $all_good ) {
 423       return $wantarray ? @ret : $ret[0]
 424     }
 425     elsif ( $catch_cref ) {
 426       for ( $exception ) {
 427         return $catch_cref->($exception);
 428       }
 429     }
 430
 431     return;
 432   }
 433
 434   sub in_internal_try { !! $callstack_state->{in_internal_try} }
 435 }
 436
 437 {
 438   my $destruction_registry = {};
 439
 440   sub CLONE {
 441     %$destruction_registry = map {
 442       (defined $_)
 443         ? ( refaddr($_) => $_ )
 444         : ()
 445     } values %$destruction_registry;
 446
 447     weaken($_) for values %$destruction_registry;
 448
 449     # Dummy NEXTSTATE ensuring the all temporaries on the stack are garbage
 450     # collected before leaving this scope. Depending on the code above, this
 451     # may very well be just a preventive measure guarding future modifications
 452     undef;
 453   }
 454
 455   # This is almost invariably invoked from within DESTROY
 456   # throwing exceptions won't work
 457   sub detected_reinvoked_destructor {
 458
 459     # quick "garbage collection" pass - prevents the registry
 460     # from slowly growing with a bunch of undef-valued keys
 461     defined $destruction_registry->{$_} or delete $destruction_registry->{$_}
 462       for keys %$destruction_registry;
 463
 464     if (! length ref $_[0]) {
 465       printf STDERR '%s() expects a blessed reference %s',
 466         (caller(0))[3],
 467         Carp::longmess,
 468       ;
 469       return undef; # don't know wtf to do
 470     }
 471     elsif (! defined $destruction_registry->{ my $addr = refaddr($_[0]) } ) {
 472       weaken( $destruction_registry->{$addr} = $_[0] );
 473       return 0;
 474     }
 475     else {
 476       carp_unique ( sprintf (
 477         'Preventing *MULTIPLE* DESTROY() invocations on %s - an *EXTREMELY '
 478       . 'DANGEROUS* condition which is *ALMOST CERTAINLY GLOBAL* within your '
 479       . 'application, affecting *ALL* classes without active protection against '
 480       . 'this. Diagnose and fix the root cause ASAP!!!%s',
 481       refdesc $_[0],
 482         ( ( $INC{'Devel/StackTrace.pm'} and ! do { local $@; eval { Devel::StackTrace->VERSION(2) } } )
 483           ? " (likely culprit Devel::StackTrace\@@{[ Devel::StackTrace->VERSION ]} found in %INC, http://is.gd/D_ST_refcap)"
 484           : ''
 485         )
 486       ));
 487
 488       return 1;
 489     }
 490   }
 491 }
 492
 493 my $module_name_rx = qr/ \A [A-Z_a-z] [0-9A-Z_a-z]* (?: :: [0-9A-Z_a-z]+ )* \z /x;
 494 my $ver_rx =         qr/ \A [0-9]+ (?: \. [0-9]+ )* (?: \_ [0-9]+ )*        \z /x;
 495
 496 sub modver_gt_or_eq ($$) {
 497   my ($mod, $ver) = @_;
 498
 499   croak "Nonsensical module name supplied"
 500     if ! defined $mod or $mod !~ $module_name_rx;
 501
 502   croak "Nonsensical minimum version supplied"
 503     if ! defined $ver or $ver !~ $ver_rx;
 504
 505   no strict 'refs';
 506   my $ver_cache = ${"${mod}::__DBIC_MODULE_VERSION_CHECKS__"} ||= ( $mod->VERSION
 507     ? {}
 508     : croak "$mod does not seem to provide a version (perhaps it never loaded)"
 509   );
 510
 511   ! defined $ver_cache->{$ver}
 512     and
 513   $ver_cache->{$ver} = do {
 514
 515     local $SIG{__WARN__} = sigwarn_silencer( qr/\Qisn't numeric in subroutine entry/ )
 516       if SPURIOUS_VERSION_CHECK_WARNINGS;
 517
 518     local $SIG{__DIE__} if $SIG{__DIE__};
 519     local $@;
 520     eval { $mod->VERSION($ver) } ? 1 : 0;
 521   };
 522
 523   $ver_cache->{$ver};
 524 }
 525
 526 sub modver_gt_or_eq_and_lt ($$$) {
 527   my ($mod, $v_ge, $v_lt) = @_;
 528
 529   croak "Nonsensical maximum version supplied"
 530     if ! defined $v_lt or $v_lt !~ $ver_rx;
 531
 532   return (
 533     modver_gt_or_eq($mod, $v_ge)
 534       and
 535     ! modver_gt_or_eq($mod, $v_lt)
 536   ) ? 1 : 0;
 537 }
 538
 539
 540 #
 541 # Why not just use some higher-level module or at least File::Spec here?
 542 # Because:
 543 # 1)  This is a *very* rarely used function, and the deptree is large
 544 #     enough already as it is
 545 #
 546 # 2)  (more importantly) Our tooling is utter shit in this area. There
 547 #     is no comprehensive support for UNC paths in PathTools and there
 548 #     are also various small bugs in representation across different
 549 #     path-manipulation CPAN offerings.
 550 #
 551 # Since this routine is strictly used for logical path processing (it
 552 # *must* be able to work with not-yet-existing paths), use this seemingly
 553 # simple but I *think* complete implementation to feed to other consumers
 554 #
 555 # If bugs are ever uncovered in this routine, *YOU ARE URGED TO RESIST*
 556 # the impulse to bring in an external dependency. During runtime there
 557 # is exactly one spot that could potentially maybe once in a blue moon
 558 # use this function. Keep it lean.
 559 #
 560 sub parent_dir ($) {
 561   ( $_[0] =~ m{  [\/\\]  ( \.{0,2} ) ( [\/\\]* ) \z }x )
 562     ? (
 563       $_[0]
 564         .
 565       ( ( length($1) and ! length($2) ) ? '/' : '' )
 566         .
 567       '../'
 568     )
 569     : (
 570       require File::Spec
 571         and
 572       File::Spec->catpath (
 573         ( File::Spec->splitpath( "$_[0]" ) )[0,1],
 574         '/',
 575       )
 576     )
 577   ;
 578 }
 579
 580 sub mkdir_p ($) {
 581   require File::Path;
 582   # do not ask for a recent version, use 1.x API calls
 583   File::Path::mkpath([ "$_[0]" ]);  # File::Path does not like objects
 584 }
 585
 586
 587 {
 588   my $list_ctx_ok_stack_marker;
 589
 590   sub fail_on_internal_wantarray () {
 591     return if $list_ctx_ok_stack_marker;
 592
 593     if (! defined wantarray) {
 594       croak('fail_on_internal_wantarray() needs a tempvar to save the stack marker guard');
 595     }
 596
 597     my $cf = 1;
 598     while ( ( (CORE::caller($cf+1))[3] || '' ) =~ / :: (?:
 599
 600       # these are public API parts that alter behavior on wantarray
 601       search | search_related | slice | search_literal
 602
 603         |
 604
 605       # these are explicitly prefixed, since we only recognize them as valid
 606       # escapes when they come from the guts of CDBICompat
 607       CDBICompat .*? :: (?: search_where | retrieve_from_sql | retrieve_all )
 608
 609     ) $/x ) {
 610       $cf++;
 611     }
 612
 613     my ($fr, $want, $argdesc);
 614     {
 615       package DB;
 616       $fr = [ CORE::caller($cf) ];
 617       $want = ( CORE::caller($cf-1) )[5];
 618       $argdesc = ref $DB::args[0]
 619         ? DBIx::Class::_Util::refdesc($DB::args[0])
 620         : 'non '
 621       ;
 622     };
 623
 624     if (
 625       $want and $fr->[0] =~ /^(?:DBIx::Class|DBICx::)/
 626     ) {
 627       DBIx::Class::Exception->throw( sprintf (
 628         "Improper use of %s instance in list context at %s line %d\n\n    Stacktrace starts",
 629         $argdesc, @{$fr}[1,2]
 630       ), 'with_stacktrace');
 631     }
 632
 633     weaken( $list_ctx_ok_stack_marker = my $mark = [] );
 634
 635     $mark;
 636   }
 637 }
 638
 639 sub fail_on_internal_call {
 640   my ($fr, $argdesc);
 641   {
 642     package DB;
 643     $fr = [ CORE::caller(1) ];
 644     $argdesc = ref $DB::args[0]
 645       ? DBIx::Class::_Util::refdesc($DB::args[0])
 646       : ( $DB::args[0] . '' )
 647     ;
 648   };
 649
 650   if (
 651     $argdesc
 652       and
 653     $fr->[0] =~ /^(?:DBIx::Class|DBICx::)/
 654       and
 655     $fr->[1] !~ /\b(?:CDBICompat|ResultSetProxy)\b/  # no point touching there
 656   ) {
 657     DBIx::Class::Exception->throw( sprintf (
 658       "Illegal internal call of indirect proxy-method %s() with argument '%s': examine the last lines of the proxy method deparse below to determine what to call directly instead at %s on line %d\n\n%s\n\n    Stacktrace starts",
 659       $fr->[3], $argdesc, @{$fr}[1,2], ( $fr->[6] || do {
 660         require B::Deparse;
 661         no strict 'refs';
 662         B::Deparse->new->coderef2text(\&{$fr->[3]})
 663       }),
 664     ), 'with_stacktrace');
 665   }
 666 }
 667
 668 1;