lib/DBIx/Class/_Util.pm

   1 package # hide from PAUSE
   2   DBIx::Class::_Util;
   3
   4 use DBIx::Class::StartupCheck;  # load es early as we can, usually a noop
   5
   6 use warnings;
   7 use strict;
   8
   9 use constant SPURIOUS_VERSION_CHECK_WARNINGS => ( "$]" < 5.010 ? 1 : 0);
  10
  11 my $mro_recursor_stack;
  12
  13 BEGIN {
  14   package # hide from pause
  15     DBIx::Class::_ENV_;
  16
  17   use Config;
  18
  19   use constant {
  20
  21     # but of course
  22     BROKEN_FORK => ($^O eq 'MSWin32') ? 1 : 0,
  23
  24     BROKEN_GOTO => ( "$]" < 5.008003 ) ? 1 : 0,
  25
  26     HAS_ITHREADS => $Config{useithreads} ? 1 : 0,
  27
  28     UNSTABLE_DOLLARAT => ( "$]" < 5.013002 ) ? 1 : 0,
  29
  30     ( map
  31       #
  32       # the "DBIC_" prefix below is crucial - this is what makes CI pick up
  33       # all envvars without further adjusting its scripts
  34       # DO NOT CHANGE to the more logical { $_ => !!( $ENV{"DBIC_$_"} ) }
  35       #
  36       { substr($_, 5) => !!( $ENV{$_} ) }
  37       qw(
  38         DBIC_SHUFFLE_UNORDERED_RESULTSETS
  39         DBIC_ASSERT_NO_INTERNAL_WANTARRAY
  40         DBIC_ASSERT_NO_INTERNAL_INDIRECT_CALLS
  41         DBIC_STRESSTEST_UTF8_UPGRADE_GENERATED_COLLAPSER_SOURCE
  42         DBIC_STRESSTEST_COLUMN_INFO_UNAWARE_STORAGE
  43       )
  44     ),
  45
  46     IV_SIZE => $Config{ivsize},
  47
  48     OS_NAME => $^O,
  49   };
  50
  51   if ( "$]" < 5.009_005) {
  52     require MRO::Compat;
  53     constant->import( OLD_MRO => 1 );
  54
  55     #
  56     # Yes, I know this is a rather PHP-ish name, but please first read
  57     # https://metacpan.org/source/BOBTFISH/MRO-Compat-0.12/lib/MRO/Compat.pm#L363-368
  58     #
  59     # Even if we are using Class::C3::XS it still won't work, as doing
  60     #   defined( *{ "SubClass::"->{$_} }{CODE} )
  61     # will set pkg_gen to the same value for SubClass and *ALL PARENTS*
  62     #
  63     *DBIx::Class::_Util::get_real_pkg_gen = sub ($) {
  64       require Digest::MD5;
  65       require Math::BigInt;
  66
  67       # the non-assign-unless-there-is-a-hash is deliberate
  68       ( $mro_recursor_stack->{cache} || {} )->{$_[0]}{gen} ||= (
  69         Math::BigInt->new( '0x' . ( Digest::MD5::md5_hex( join "\0", map {
  70
  71           ( $mro_recursor_stack->{cache} || {} )->{$_}{methlist} ||= do {
  72
  73             my $class = $_;
  74
  75             no strict 'refs';
  76             my %methlist =
  77               map
  78                 # this is essentially a uniq_by step
  79                 # it is crucial on OLD_MRO
  80                 {( Scalar::Util::refaddr($_) => $_ )}
  81                 map
  82                   {
  83                     (
  84                       ref(\ "${class}::"->{$_} ) ne 'GLOB'
  85                         or
  86                       defined( *{ "${class}::"->{$_} }{CODE} )
  87                     )
  88                     ? ( \&{"${class}::$_"} )
  89                     : ()
  90                   }
  91                   keys %{ "${class}::" }
  92             ;
  93
  94             # RV to be hashed up and turned into a number
  95             join "\0", (
  96               $class,
  97               map {(
  98                 $_, # refaddr is sufficient, ignore names entirely
  99                 attributes::get( $methlist{$_} )
 100               )} sort keys %methlist
 101             ),
 102           }
 103         } (
 104
 105           @{
 106             ( $mro_recursor_stack->{cache} || {} )->{$_[0]}{linear_isa}
 107               ||=
 108             mro::get_linear_isa($_[0])
 109           },
 110
 111           ((
 112             ( $mro_recursor_stack->{cache} || {} )->{$_[0]}{is_universal}
 113               ||=
 114             mro::is_universal($_[0])
 115           ) ? () : @{
 116             ( $mro_recursor_stack->{cache} || {} )->{UNIVERSAL}{linear_isa}
 117               ||=
 118             mro::get_linear_isa("UNIVERSAL")
 119           } ),
 120
 121         ) ) ) )
 122       );
 123     };
 124   }
 125   else {
 126     require mro;
 127     constant->import( OLD_MRO => 0 );
 128     *DBIx::Class::_Util::get_real_pkg_gen = \&mro::get_pkg_gen;
 129   }
 130
 131   # Both of these are no longer used for anything. However bring
 132   # them back after they were purged in 08a8d8f1, as there appear
 133   # to be outfits with *COPY PASTED* pieces of lib/DBIx/Class/Storage/*
 134   # in their production codebases. There is no point in breaking these
 135   # if whatever they used actually continues to work
 136   my $warned;
 137   my $sigh = sub {
 138
 139     require Carp;
 140     my $cluck = "The @{[ (caller(1))[3] ]} constant is no more - adjust your code" . Carp::longmess();
 141
 142     warn $cluck unless $warned->{$cluck}++;
 143
 144     0;
 145   };
 146   sub DBICTEST () { &$sigh }
 147   sub PEEPEENESS () { &$sigh }
 148 }
 149
 150 # FIXME - this is not supposed to be here
 151 # Carp::Skip to the rescue soon
 152 use DBIx::Class::Carp '^DBIx::Class|^DBICTest';
 153
 154 use B ();
 155 use Carp 'croak';
 156 use Storable 'nfreeze';
 157 use Scalar::Util qw(weaken blessed reftype refaddr);
 158 use Sub::Quote qw(qsub);
 159 use Sub::Name ();
 160 use attributes ();
 161
 162 # Already correctly prototyped: perlbrew exec perl -MStorable -e 'warn prototype \&Storable::dclone'
 163 BEGIN { *deep_clone = \&Storable::dclone }
 164
 165 use base 'Exporter';
 166 our @EXPORT_OK = qw(
 167   sigwarn_silencer modver_gt_or_eq modver_gt_or_eq_and_lt
 168   fail_on_internal_wantarray fail_on_internal_call
 169   refdesc refcount hrefaddr set_subname describe_class_methods
 170   scope_guard detected_reinvoked_destructor
 171   is_exception dbic_internal_try visit_namespaces
 172   quote_sub qsub perlstring serialize deep_clone dump_value uniq
 173   parent_dir mkdir_p
 174   UNRESOLVABLE_CONDITION
 175 );
 176
 177 use constant UNRESOLVABLE_CONDITION => \ '1 = 0';
 178
 179 BEGIN {
 180   # add preliminary attribute support
 181   # FIXME FIXME FIXME
 182   # To be revisited when Moo with proper attr support ships
 183   Sub::Quote->VERSION(2.002);
 184 }
 185 # Override forcing no_defer, and adding naming consistency checks
 186 sub quote_sub {
 187   Carp::confess( "Anonymous quoting not supported by the DBIC sub_quote override - supply a sub name" ) if
 188     @_ < 2
 189       or
 190     ! defined $_[1]
 191       or
 192     length ref $_[1]
 193   ;
 194
 195   Carp::confess( "The DBIC sub_quote override expects sub name '$_[0]' to be fully qualified" )
 196     unless $_[0] =~ /::/;
 197
 198   Carp::confess( "The DBIC sub_quote override expects the sub name '$_[0]' to match the supplied 'package' argument" ) if
 199     $_[3]
 200       and
 201     defined $_[3]->{package}
 202       and
 203     index( $_[0], $_[3]->{package} ) != 0
 204   ;
 205
 206   my @caller = caller(0);
 207   my $sq_opts = {
 208     package => $caller[0],
 209     hints => $caller[8],
 210     warning_bits => $caller[9],
 211     hintshash => $caller[10],
 212     %{ $_[3] || {} },
 213
 214     # explicitly forced for everything
 215     no_defer => 1,
 216   };
 217
 218   my $cref = Sub::Quote::quote_sub( $_[0], $_[1], $_[2]||{}, $sq_opts );
 219
 220   # FIXME FIXME FIXME
 221   # To be revisited when Moo with proper attr support ships
 222   if(
 223     # external application does not work on things like :prototype(...), :lvalue, etc
 224     my @attrs = grep {
 225       $_ !~ /^[a-z]/
 226         or
 227       Carp::confess( "The DBIC sub_quote override does not support applying of reserved attribute '$_'" )
 228     } @{ $sq_opts->{attributes} || []}
 229   ) {
 230     Carp::confess( "The DBIC sub_quote override does not allow mixing 'attributes' with 'no_install'" )
 231       if $sq_opts->{no_install};
 232
 233     # might be different from $sq_opts->{package};
 234     my ($install_into) = $_[0] =~ /(.+)::[^:]+$/;
 235
 236     attributes->import( $install_into, $cref, @attrs );
 237   }
 238
 239   $cref;
 240 }
 241
 242 sub sigwarn_silencer ($) {
 243   my $pattern = shift;
 244
 245   croak "Expecting a regexp" if ref $pattern ne 'Regexp';
 246
 247   my $orig_sig_warn = $SIG{__WARN__} || sub { CORE::warn(@_) };
 248
 249   return sub { &$orig_sig_warn unless $_[0] =~ $pattern };
 250 }
 251
 252 sub perlstring ($) { q{"}. quotemeta( shift ). q{"} };
 253
 254 sub hrefaddr ($) { sprintf '0x%x', &refaddr||0 }
 255
 256 sub refdesc ($) {
 257   croak "Expecting a reference" if ! length ref $_[0];
 258
 259   # be careful not to trigger stringification,
 260   # reuse @_ as a scratch-pad
 261   sprintf '%s%s(0x%x)',
 262     ( defined( $_[1] = blessed $_[0]) ? "$_[1]=" : '' ),
 263     reftype $_[0],
 264     refaddr($_[0]),
 265   ;
 266 }
 267
 268 sub refcount ($) {
 269   croak "Expecting a reference" if ! length ref $_[0];
 270
 271   # No tempvars - must operate on $_[0], otherwise the pad
 272   # will count as an extra ref
 273   B::svref_2object($_[0])->REFCNT;
 274 }
 275
 276 sub visit_namespaces {
 277   my $args = { (ref $_[0]) ? %{$_[0]} : @_ };
 278
 279   my $visited_count = 1;
 280
 281   # A package and a namespace are subtly different things
 282   $args->{package} ||= 'main';
 283   $args->{package} = 'main' if $args->{package} =~ /^ :: (?: main )? $/x;
 284   $args->{package} =~ s/^:://;
 285
 286   if ( $args->{action}->($args->{package}) ) {
 287     my $ns =
 288       ( ($args->{package} eq 'main') ? '' :  $args->{package} )
 289         .
 290       '::'
 291     ;
 292
 293     $visited_count += visit_namespaces( %$args, package => $_ ) for
 294       grep
 295         # this happens sometimes on %:: traversal
 296         { $_ ne '::main' }
 297         map
 298           { $_ =~ /^(.+?)::$/ ? "$ns$1" : () }
 299           do { no strict 'refs'; keys %$ns }
 300     ;
 301   }
 302
 303   $visited_count;
 304 }
 305
 306 # FIXME In another life switch this to a polyfill like the one in namespace::clean
 307 sub set_subname ($$) {
 308
 309   # fully qualify name
 310   splice @_, 0, 1, caller(0) . "::$_[0]"
 311     if $_[0] !~ /::|'/;
 312
 313   &Sub::Name::subname;
 314 }
 315
 316 sub serialize ($) {
 317   local $Storable::canonical = 1;
 318   nfreeze($_[0]);
 319 }
 320
 321 sub uniq {
 322   my( %seen, $seen_undef, $numeric_preserving_copy );
 323   grep { not (
 324     defined $_
 325       ? $seen{ $numeric_preserving_copy = $_ }++
 326       : $seen_undef++
 327   ) } @_;
 328 }
 329
 330 my $dd_obj;
 331 sub dump_value ($) {
 332   local $Data::Dumper::Indent = 1
 333     unless defined $Data::Dumper::Indent;
 334
 335   my $dump_str = (
 336     $dd_obj
 337       ||=
 338     do {
 339       require Data::Dumper;
 340       my $d = Data::Dumper->new([])
 341         ->Purity(0)
 342         ->Pad('')
 343         ->Useqq(1)
 344         ->Terse(1)
 345         ->Freezer('')
 346         ->Quotekeys(0)
 347         ->Bless('bless')
 348         ->Pair(' => ')
 349         ->Sortkeys(1)
 350         ->Deparse(1)
 351       ;
 352
 353       $d->Sparseseen(1) if modver_gt_or_eq (
 354         'Data::Dumper', '2.136'
 355       );
 356
 357       $d;
 358     }
 359   )->Values([$_[0]])->Dump;
 360
 361   $dd_obj->Reset->Values([]);
 362
 363   $dump_str;
 364 }
 365
 366 sub scope_guard (&) {
 367   croak 'Calling scope_guard() in void context makes no sense'
 368     if ! defined wantarray;
 369
 370   # no direct blessing of coderefs - DESTROY is buggy on those
 371   bless [ $_[0] ], 'DBIx::Class::_Util::ScopeGuard';
 372 }
 373 {
 374   package #
 375     DBIx::Class::_Util::ScopeGuard;
 376
 377   sub DESTROY {
 378     &DBIx::Class::_Util::detected_reinvoked_destructor;
 379
 380     local $@ if DBIx::Class::_ENV_::UNSTABLE_DOLLARAT;
 381
 382     eval {
 383       $_[0]->[0]->();
 384       1;
 385     }
 386       or
 387     Carp::cluck(
 388       "Execution of scope guard $_[0] resulted in the non-trappable exception:\n\n$@"
 389     );
 390   }
 391 }
 392
 393
 394 sub is_exception ($) {
 395   my $e = $_[0];
 396
 397   # FIXME
 398   # this is not strictly correct - an eval setting $@ to undef
 399   # is *not* the same as an eval setting $@ to ''
 400   # but for the sake of simplicity assume the following for
 401   # the time being
 402   return 0 unless defined $e;
 403
 404   my ($not_blank, $suberror);
 405   {
 406     local $SIG{__DIE__} if $SIG{__DIE__};
 407     local $@;
 408     eval {
 409       # The ne() here is deliberate - a plain length($e), or worse "$e" ne
 410       # will entirely obviate the need for the encolsing eval{}, as the
 411       # condition we guard against is a missing fallback overload
 412       $not_blank = ( $e ne '' );
 413       1;
 414     } or $suberror = $@;
 415   }
 416
 417   if (defined $suberror) {
 418     if (length (my $class = blessed($e) )) {
 419       carp_unique( sprintf(
 420         'External exception class %s implements partial (broken) overloading '
 421       . 'preventing its instances from being used in simple ($x eq $y) '
 422       . 'comparisons. Given Perl\'s "globally cooperative" exception '
 423       . 'handling this type of brokenness is extremely dangerous on '
 424       . 'exception objects, as it may (and often does) result in silent '
 425       . '"exception substitution". DBIx::Class tries to work around this '
 426       . 'as much as possible, but other parts of your software stack may '
 427       . 'not be even aware of this. Please submit a bugreport against the '
 428       . 'distribution containing %s and in the meantime apply a fix similar '
 429       . 'to the one shown at %s, in order to ensure your exception handling '
 430       . 'is saner application-wide. What follows is the actual error text '
 431       . "as generated by Perl itself:\n\n%s\n ",
 432         $class,
 433         $class,
 434         'http://v.gd/DBIC_overload_tempfix/',
 435         $suberror,
 436       ));
 437
 438       # workaround, keeps spice flowing
 439       $not_blank = !!( length $e );
 440     }
 441     else {
 442       # not blessed yet failed the 'ne'... this makes 0 sense...
 443       # just throw further
 444       die $suberror
 445     }
 446   }
 447   elsif (
 448     # a ref evaluating to '' is definitively a "null object"
 449     ( not $not_blank )
 450       and
 451     length( my $class = ref $e )
 452   ) {
 453     carp_unique( sprintf(
 454       "Objects of external exception class '%s' stringify to '' (the "
 455     . 'empty string), implementing the so called null-object-pattern. '
 456     . 'Given Perl\'s "globally cooperative" exception handling using this '
 457     . 'class of exceptions is extremely dangerous, as it may (and often '
 458     . 'does) result in silent discarding of errors. DBIx::Class tries to '
 459     . 'work around this as much as possible, but other parts of your '
 460     . 'software stack may not be even aware of the problem. Please submit '
 461     . 'a bugreport against the distribution containing %s',
 462
 463       ($class) x 2,
 464     ));
 465
 466     $not_blank = 1;
 467   }
 468
 469   return $not_blank;
 470 }
 471
 472 {
 473   my $callstack_state;
 474
 475   # Recreate the logic of try(), while reusing the catch()/finally() as-is
 476   #
 477   # FIXME: We need to move away from Try::Tiny entirely (way too heavy and
 478   # yes, shows up ON TOP of profiles) but this is a batle for another maint
 479   sub dbic_internal_try (&;@) {
 480
 481     my $try_cref = shift;
 482     my $catch_cref = undef;  # apparently this is a thing... https://rt.perl.org/Public/Bug/Display.html?id=119311
 483
 484     for my $arg (@_) {
 485
 486       if( ref($arg) eq 'Try::Tiny::Catch' ) {
 487
 488         croak 'dbic_internal_try() may not be followed by multiple catch() blocks'
 489           if $catch_cref;
 490
 491         $catch_cref = $$arg;
 492       }
 493       elsif ( ref($arg) eq 'Try::Tiny::Finally' ) {
 494         croak 'dbic_internal_try() does not support finally{}';
 495       }
 496       else {
 497         croak(
 498           'dbic_internal_try() encountered an unexpected argument '
 499         . "'@{[ defined $arg ? $arg : 'UNDEF' ]}' - perhaps "
 500         . 'a missing semi-colon before or ' # trailing space important
 501         );
 502       }
 503     }
 504
 505     my $wantarray = wantarray;
 506     my $preexisting_exception = $@;
 507
 508     my @ret;
 509     my $all_good = eval {
 510       $@ = $preexisting_exception;
 511
 512       local $callstack_state->{in_internal_try} = 1
 513         unless $callstack_state->{in_internal_try};
 514
 515       # always unset - someone may have snuck it in
 516       local $SIG{__DIE__} if $SIG{__DIE__};
 517
 518       if( $wantarray ) {
 519         @ret = $try_cref->();
 520       }
 521       elsif( defined $wantarray ) {
 522         $ret[0] = $try_cref->();
 523       }
 524       else {
 525         $try_cref->();
 526       }
 527
 528       1;
 529     };
 530
 531     my $exception = $@;
 532     $@ = $preexisting_exception;
 533
 534     if ( $all_good ) {
 535       return $wantarray ? @ret : $ret[0]
 536     }
 537     elsif ( $catch_cref ) {
 538       for ( $exception ) {
 539         return $catch_cref->($exception);
 540       }
 541     }
 542
 543     return;
 544   }
 545
 546   sub in_internal_try { !! $callstack_state->{in_internal_try} }
 547 }
 548
 549 {
 550   my $destruction_registry = {};
 551
 552   sub DBIx::Class::__Util_iThreads_handler__::CLONE {
 553     %$destruction_registry = map {
 554       (defined $_)
 555         ? ( refaddr($_) => $_ )
 556         : ()
 557     } values %$destruction_registry;
 558
 559     weaken($_) for values %$destruction_registry;
 560
 561     # Dummy NEXTSTATE ensuring the all temporaries on the stack are garbage
 562     # collected before leaving this scope. Depending on the code above, this
 563     # may very well be just a preventive measure guarding future modifications
 564     undef;
 565   }
 566
 567   # This is almost invariably invoked from within DESTROY
 568   # throwing exceptions won't work
 569   sub detected_reinvoked_destructor {
 570
 571     # quick "garbage collection" pass - prevents the registry
 572     # from slowly growing with a bunch of undef-valued keys
 573     defined $destruction_registry->{$_} or delete $destruction_registry->{$_}
 574       for keys %$destruction_registry;
 575
 576     if (! length ref $_[0]) {
 577       printf STDERR '%s() expects a blessed reference %s',
 578         (caller(0))[3],
 579         Carp::longmess,
 580       ;
 581       return undef; # don't know wtf to do
 582     }
 583     elsif (! defined $destruction_registry->{ my $addr = refaddr($_[0]) } ) {
 584       weaken( $destruction_registry->{$addr} = $_[0] );
 585       return 0;
 586     }
 587     else {
 588       carp_unique ( sprintf (
 589         'Preventing *MULTIPLE* DESTROY() invocations on %s - an *EXTREMELY '
 590       . 'DANGEROUS* condition which is *ALMOST CERTAINLY GLOBAL* within your '
 591       . 'application, affecting *ALL* classes without active protection against '
 592       . 'this. Diagnose and fix the root cause ASAP!!!%s',
 593       refdesc $_[0],
 594         ( ( $INC{'Devel/StackTrace.pm'} and ! do { local $@; eval { Devel::StackTrace->VERSION(2) } } )
 595           ? " (likely culprit Devel::StackTrace\@@{[ Devel::StackTrace->VERSION ]} found in %INC, http://is.gd/D_ST_refcap)"
 596           : ''
 597         )
 598       ));
 599
 600       return 1;
 601     }
 602   }
 603 }
 604
 605 my $module_name_rx = qr/ \A [A-Z_a-z] [0-9A-Z_a-z]* (?: :: [0-9A-Z_a-z]+ )* \z /x;
 606 my $ver_rx =         qr/ \A [0-9]+ (?: \. [0-9]+ )* (?: \_ [0-9]+ )*        \z /x;
 607
 608 sub modver_gt_or_eq ($$) {
 609   my ($mod, $ver) = @_;
 610
 611   croak "Nonsensical module name supplied"
 612     if ! defined $mod or $mod !~ $module_name_rx;
 613
 614   croak "Nonsensical minimum version supplied"
 615     if ! defined $ver or $ver !~ $ver_rx;
 616
 617   no strict 'refs';
 618   my $ver_cache = ${"${mod}::__DBIC_MODULE_VERSION_CHECKS__"} ||= ( $mod->VERSION
 619     ? {}
 620     : croak "$mod does not seem to provide a version (perhaps it never loaded)"
 621   );
 622
 623   ! defined $ver_cache->{$ver}
 624     and
 625   $ver_cache->{$ver} = do {
 626
 627     local $SIG{__WARN__} = sigwarn_silencer( qr/\Qisn't numeric in subroutine entry/ )
 628       if SPURIOUS_VERSION_CHECK_WARNINGS;
 629
 630     local $SIG{__DIE__} if $SIG{__DIE__};
 631     local $@;
 632     eval { $mod->VERSION($ver) } ? 1 : 0;
 633   };
 634
 635   $ver_cache->{$ver};
 636 }
 637
 638 sub modver_gt_or_eq_and_lt ($$$) {
 639   my ($mod, $v_ge, $v_lt) = @_;
 640
 641   croak "Nonsensical maximum version supplied"
 642     if ! defined $v_lt or $v_lt !~ $ver_rx;
 643
 644   return (
 645     modver_gt_or_eq($mod, $v_ge)
 646       and
 647     ! modver_gt_or_eq($mod, $v_lt)
 648   ) ? 1 : 0;
 649 }
 650
 651 {
 652   # FIXME - should be a private my(), but I'm too uncertain whether
 653   # all bases are covered
 654   our $describe_class_query_cache;
 655
 656   sub describe_class_methods {
 657     my ($class) = @_;
 658
 659     croak "Expecting a class name"
 660       if not defined $class or $class !~ $module_name_rx;
 661
 662     # use a cache on old MRO, since while we are recursing in this function
 663     # nothing can possibly change (the speedup is immense)
 664     # (yes, people could be tie()ing the stash and adding methods on access
 665     # but there is a limit to how much crazy can be supported here)
 666     #
 667     # we use the cache for linear_isa lookups on new MRO as well - it adds
 668     # a *tiny* speedup, and simplifies the code a lot
 669     #
 670     local $mro_recursor_stack->{cache} = {}
 671       unless $mro_recursor_stack->{cache};
 672
 673     my $my_gen = 0;
 674
 675     $my_gen += get_real_pkg_gen($_) for ( my @full_ISA = (
 676
 677       @{
 678         $mro_recursor_stack->{cache}{$class}{linear_isa}
 679           ||=
 680         mro::get_linear_isa($class)
 681       },
 682
 683       ((
 684         $mro_recursor_stack->{cache}{$class}{is_universal}
 685           ||=
 686         mro::is_universal($class)
 687       ) ? () : @{
 688         $mro_recursor_stack->{cache}{UNIVERSAL}{linear_isa}
 689           ||=
 690         mro::get_linear_isa("UNIVERSAL")
 691       }),
 692
 693     ));
 694
 695     my $slot = $describe_class_query_cache->{$class} ||= {};
 696
 697     unless ( ($slot->{cumulative_gen}||0) == $my_gen ) {
 698
 699       # remove ourselves from ISA
 700       shift @full_ISA;
 701
 702       # reset
 703       %$slot = (
 704         class => $class,
 705         isa => [
 706           @{ $mro_recursor_stack->{cache}{$class}{linear_isa} }
 707             [ 1 .. $#{$mro_recursor_stack->{cache}{$class}{linear_isa}} ]
 708         ],
 709         mro => {
 710           type => mro::get_mro($class),
 711         },
 712         cumulative_gen => $my_gen,
 713       );
 714       $slot->{mro}{is_c3} = ($slot->{mro}{type} eq 'c3') ? 1 : 0;
 715
 716       # ensure the cache is populated for the parents, code below can then
 717       # efficiently operate over the query_cache directly
 718       describe_class_methods($_) for reverse @full_ISA;
 719
 720       my ($methods_seen_via_ISA_on_old_mro, $current_node_refaddr);
 721       no strict 'refs';
 722
 723       # combine full ISA-order inherited and local method list into a
 724       # "shadowing stack"
 725
 726       (
 727         $current_node_refaddr = refaddr($_)
 728
 729           and
 730
 731         unshift @{ $slot->{methods}{$_->{name}} }, $_
 732
 733           and
 734
 735         (
 736           $_->{via_class} ne $class
 737             or
 738           $slot->{methods_defined_in_class}{$_->{name}} = $_
 739         )
 740
 741           and
 742
 743         @{ $slot->{methods}{$_->{name}} } > 1
 744
 745           and
 746
 747         $slot->{methods_with_supers}{$_->{name}} = $slot->{methods}{$_->{name}}
 748
 749       ) for (
 750
 751         # what describe_class_methods for @full_ISA produced above
 752         ( map { values %{
 753           $describe_class_query_cache->{$_}{methods_defined_in_class} || {}
 754         } } reverse @full_ISA ),
 755
 756         # our own non-cleaned subs + their attributes
 757         ( map {
 758           (
 759             # these 2 OR-ed checks are sufficient for 5.10+
 760             (
 761               ref(\ "${class}::"->{$_} ) ne 'GLOB'
 762                 or
 763               defined( *{ "${class}::"->{$_} }{CODE} )
 764             )
 765               and
 766             # need to account for dummy helper crefs under OLD_MRO
 767             (
 768               ! DBIx::Class::_ENV_::OLD_MRO
 769                 or
 770               (
 771                 $methods_seen_via_ISA_on_old_mro ||= do {
 772                   my $rv = {};
 773                   $rv->{$_->{name}}->{ refaddr( \&{ "$_->{via_class}::$_->{name}"} ) } = 1 for
 774                     map { @$_ } map
 775                       { values %{ $describe_class_query_cache->{$_}{methods} } }
 776                       @full_ISA;
 777                   $rv;
 778                 }
 779                   and
 780                 (
 781                   ! $methods_seen_via_ISA_on_old_mro->{$_}
 782                     or
 783                   ! $methods_seen_via_ISA_on_old_mro->{$_}{ refaddr( \&{"${class}::${_}"} ) }
 784                 )
 785               )
 786             )
 787           ) ? {
 788               via_class => $class,
 789               name => $_,
 790               attributes => {
 791                 map { $_ => 1 } attributes::get( \&{"${class}::${_}"} )
 792               },
 793             }
 794             : ()
 795         } keys %{"${class}::"} )
 796       );
 797
 798
 799       # recalculate the pkg_gen on newer perls under Taint mode,
 800       # because of shit like:
 801       # perl -T -Mmro -e 'package Foo; sub bar {}; defined( *{ "Foo::"->{bar}}{CODE} ) and warn mro::get_pkg_gen("Foo") for (1,2,3)'
 802       #
 803       if (
 804         ! DBIx::Class::_ENV_::OLD_MRO
 805           and
 806         ${^TAINT}
 807       ) {
 808
 809         $slot->{cumulative_gen} = 0;
 810         $slot->{cumulative_gen} += get_real_pkg_gen($_)
 811           for $class, @full_ISA;
 812       }
 813     }
 814
 815     # RV
 816     +{ %$slot };
 817   }
 818 }
 819
 820
 821 #
 822 # Why not just use some higher-level module or at least File::Spec here?
 823 # Because:
 824 # 1)  This is a *very* rarely used function, and the deptree is large
 825 #     enough already as it is
 826 #
 827 # 2)  (more importantly) Our tooling is utter shit in this area. There
 828 #     is no comprehensive support for UNC paths in PathTools and there
 829 #     are also various small bugs in representation across different
 830 #     path-manipulation CPAN offerings.
 831 #
 832 # Since this routine is strictly used for logical path processing (it
 833 # *must* be able to work with not-yet-existing paths), use this seemingly
 834 # simple but I *think* complete implementation to feed to other consumers
 835 #
 836 # If bugs are ever uncovered in this routine, *YOU ARE URGED TO RESIST*
 837 # the impulse to bring in an external dependency. During runtime there
 838 # is exactly one spot that could potentially maybe once in a blue moon
 839 # use this function. Keep it lean.
 840 #
 841 sub parent_dir ($) {
 842   ( $_[0] =~ m{  [\/\\]  ( \.{0,2} ) ( [\/\\]* ) \z }x )
 843     ? (
 844       $_[0]
 845         .
 846       ( ( length($1) and ! length($2) ) ? '/' : '' )
 847         .
 848       '../'
 849     )
 850     : (
 851       require File::Spec
 852         and
 853       File::Spec->catpath (
 854         ( File::Spec->splitpath( "$_[0]" ) )[0,1],
 855         '/',
 856       )
 857     )
 858   ;
 859 }
 860
 861 sub mkdir_p ($) {
 862   require File::Path;
 863   # do not ask for a recent version, use 1.x API calls
 864   File::Path::mkpath([ "$_[0]" ]);  # File::Path does not like objects
 865 }
 866
 867
 868 {
 869   my $list_ctx_ok_stack_marker;
 870
 871   sub fail_on_internal_wantarray () {
 872     return if $list_ctx_ok_stack_marker;
 873
 874     if (! defined wantarray) {
 875       croak('fail_on_internal_wantarray() needs a tempvar to save the stack marker guard');
 876     }
 877
 878     my $cf = 1;
 879     while ( ( (CORE::caller($cf+1))[3] || '' ) =~ / :: (?:
 880
 881       # these are public API parts that alter behavior on wantarray
 882       search | search_related | slice | search_literal
 883
 884         |
 885
 886       # these are explicitly prefixed, since we only recognize them as valid
 887       # escapes when they come from the guts of CDBICompat
 888       CDBICompat .*? :: (?: search_where | retrieve_from_sql | retrieve_all )
 889
 890     ) $/x ) {
 891       $cf++;
 892     }
 893
 894     my ($fr, $want, $argdesc);
 895     {
 896       package DB;
 897       $fr = [ CORE::caller($cf) ];
 898       $want = ( CORE::caller($cf-1) )[5];
 899       $argdesc = ref $DB::args[0]
 900         ? DBIx::Class::_Util::refdesc($DB::args[0])
 901         : 'non '
 902       ;
 903     };
 904
 905     if (
 906       $want and $fr->[0] =~ /^(?:DBIx::Class|DBICx::)/
 907     ) {
 908       DBIx::Class::Exception->throw( sprintf (
 909         "Improper use of %s instance in list context at %s line %d\n\n    Stacktrace starts",
 910         $argdesc, @{$fr}[1,2]
 911       ), 'with_stacktrace');
 912     }
 913
 914     weaken( $list_ctx_ok_stack_marker = my $mark = [] );
 915
 916     $mark;
 917   }
 918 }
 919
 920 sub fail_on_internal_call {
 921   my ($fr, $argdesc);
 922   {
 923     package DB;
 924     $fr = [ CORE::caller(1) ];
 925     $argdesc = ref $DB::args[0]
 926       ? DBIx::Class::_Util::refdesc($DB::args[0])
 927       : ( $DB::args[0] . '' )
 928     ;
 929   };
 930
 931   my @fr2;
 932   # need to make allowance for a proxy-yet-direct call
 933   my $check_fr = (
 934     $fr->[0] eq 'DBIx::Class::ResultSourceProxy'
 935       and
 936     @fr2 = (CORE::caller(2))
 937       and
 938     (
 939       ( $fr->[3] =~ /([^:])+$/ )[0]
 940         eq
 941       ( $fr2[3] =~ /([^:])+$/ )[0]
 942     )
 943   )
 944     ? \@fr2
 945     : $fr
 946   ;
 947
 948   if (
 949     $argdesc
 950       and
 951     $check_fr->[0] =~ /^(?:DBIx::Class|DBICx::)/
 952       and
 953     $check_fr->[1] !~ /\b(?:CDBICompat|ResultSetProxy)\b/  # no point touching there
 954   ) {
 955     DBIx::Class::Exception->throw( sprintf (
 956       "Illegal internal call of indirect proxy-method %s() with argument '%s': examine the last lines of the proxy method deparse below to determine what to call directly instead at %s on line %d\n\n%s\n\n    Stacktrace starts",
 957       $fr->[3], $argdesc, @{$fr}[1,2], ( $fr->[6] || do {
 958         require B::Deparse;
 959         no strict 'refs';
 960         B::Deparse->new->coderef2text(\&{$fr->[3]})
 961       }),
 962     ), 'with_stacktrace');
 963   }
 964 }
 965
 966 1;