lib/DBIx/Class/Table.pm

   1 package DBIx::Class::Table;
   2
   3 use strict;
   4 use warnings;
   5
   6 use DBIx::Class::ResultSet;
   7 use Data::Page;
   8
   9 use base qw/Class::Data::Inheritable/;
  10
  11 __PACKAGE__->mk_classdata('_columns' => {});
  12
  13 __PACKAGE__->mk_classdata('_table_name');
  14
  15 __PACKAGE__->mk_classdata('table_alias'); # FIXME: Doesn't actually do anything yet!
  16
  17 __PACKAGE__->mk_classdata('_resultset_class' => 'DBIx::Class::ResultSet');
  18
  19 sub iterator_class { shift->_resultset_class(@_) }
  20
  21 =head1 NAME
  22
  23 DBIx::Class::Table - Basic table methods
  24
  25 =head1 SYNOPSIS
  26
  27 =head1 DESCRIPTION
  28
  29 This class is responsible for defining and doing basic operations on
  30 L<DBIx::Class> objects.
  31
  32 =head1 METHODS
  33
  34 =over 4
  35
  36 =cut
  37
  38 sub _register_columns {
  39   my ($class, @cols) = @_;
  40   my $names = { %{$class->_columns} };
  41   $names->{$_} ||= {} for @cols;
  42   $class->_columns($names);
  43 }
  44
  45 sub _mk_column_accessors {
  46   my ($class, @cols) = @_;
  47   $class->mk_group_accessors('column' => @cols);
  48 }
  49
  50 =item add_columns
  51
  52   __PACKAGE__->add_columns(qw/col1 col2 col3/);
  53
  54 Adds columns to the current package, and creates accessors for them
  55
  56 =cut
  57
  58 sub add_columns {
  59   my ($class, @cols) = @_;
  60   $class->_register_columns(@cols);
  61   $class->_mk_column_accessors(@cols);
  62 }
  63
  64 =item search_literal
  65
  66   my @obj    = $class->search_literal($literal_where_cond, @bind);
  67   my $cursor = $class->search_literal($literal_where_cond, @bind);
  68
  69 =cut
  70
  71 sub search_literal {
  72   my ($class, $cond, @vals) = @_;
  73   $cond =~ s/^\s*WHERE//i;
  74   my $attrs = (ref $vals[$#vals] eq 'HASH' ? { %{ pop(@vals) } } : {});
  75   $attrs->{bind} = \@vals;
  76   return $class->search(\$cond, $attrs);
  77 }
  78
  79 =item count_literal
  80
  81   my $count = $class->count_literal($literal_where_cond);
  82
  83 =cut
  84
  85 sub count_literal {
  86   my $class = shift;
  87   return $class->search_literal(@_)->count;
  88 }
  89
  90 =item count
  91
  92   my $count = $class->count({ foo => 3 });
  93
  94 =cut
  95
  96 sub count {
  97   my $class = shift;
  98   return $class->search(@_)->count;
  99 }
 100
 101 =item search
 102
 103   my @obj    = $class->search({ foo => 3 });
 104   my $cursor = $class->search({ foo => 3 });
 105
 106 =cut
 107
 108 sub search {
 109   my $class = shift;
 110   #warn "@_";
 111   my $attrs = { };
 112   if (@_ > 1 && ref $_[$#_] eq 'HASH') {
 113     $attrs = { %{ pop(@_) } };
 114   }
 115   $attrs->{where} = (@_ == 1 || ref $_[0] eq "HASH" ? shift: {@_});
 116
 117   my $rs = $class->resultset($attrs);
 118
 119   return (wantarray ? $rs->all : $rs);
 120 }
 121
 122 sub resultset {
 123   my $class = shift;
 124
 125   my $rs_class = $class->_resultset_class;
 126   eval "use $rs_class;";
 127   my $rs = $rs_class->new($class, @_);
 128 }
 129
 130 =item search_like
 131
 132 Identical to search except defaults to 'LIKE' instead of '=' in condition
 133
 134 =cut
 135
 136 sub search_like {
 137   my $class    = shift;
 138   my $attrs = { };
 139   if (@_ > 1 && ref $_[$#_] eq 'HASH') {
 140     $attrs = pop(@_);
 141   }
 142   my $query    = ref $_[0] eq "HASH" ? { %{shift()} }: {@_};
 143   $query->{$_} = { 'like' => $query->{$_} } for keys %$query;
 144   return $class->search($query, { %$attrs });
 145 }
 146
 147 sub _select_columns {
 148   return keys %{$_[0]->_columns};
 149 }
 150
 151 =item table
 152
 153   __PACKAGE__->table('tbl_name');
 154
 155 =cut
 156
 157 sub table {
 158   shift->_table_name(@_);
 159 }
 160
 161 =item find_or_create
 162
 163   $class->find_or_create({ key => $val, ... });
 164
 165 Searches for a record matching the search condition; if it doesn't find one,
 166 creates one and returns that instead
 167
 168 =cut
 169
 170 sub find_or_create {
 171   my $class    = shift;
 172   my $hash     = ref $_[0] eq "HASH" ? shift: {@_};
 173   my $exists = $class->find($hash);
 174   return defined($exists) ? $exists : $class->create($hash);
 175 }
 176
 177 sub columns { return keys %{shift->_columns}; }
 178
 179 1;
 180
 181 =back
 182
 183 =head1 AUTHORS
 184
 185 Matt S. Trout <mst@shadowcatsystems.co.uk>
 186
 187 =head1 LICENSE
 188
 189 You may distribute this code under the same terms as Perl itself.
 190
 191 =cut
 192