lib/DBIx/Class/Table.pm

   1 package DBIx::Class::Table;
   2
   3 use strict;
   4 use warnings;
   5
   6 use DBIx::Class::ResultSet;
   7
   8 use base qw/Class::Data::Inheritable/;
   9
  10 __PACKAGE__->mk_classdata('_columns' => {});
  11
  12 __PACKAGE__->mk_classdata('_table_name');
  13
  14 __PACKAGE__->mk_classdata('table_alias'); # FIXME: Doesn't actually do anything yet!
  15
  16 __PACKAGE__->mk_classdata('_resultset_class' => 'DBIx::Class::ResultSet');
  17
  18 sub iterator_class { shift->_resultset_class(@_) }
  19
  20 =head1 NAME
  21
  22 DBIx::Class::Table - Basic table methods
  23
  24 =head1 SYNOPSIS
  25
  26 =head1 DESCRIPTION
  27
  28 This class is responsible for defining and doing basic operations on
  29 L<DBIx::Class> objects.
  30
  31 =head1 METHODS
  32
  33 =over 4
  34
  35 =cut
  36
  37 sub _register_columns {
  38   my ($class, @cols) = @_;
  39   my $names = { %{$class->_columns} };
  40   $names->{$_} ||= {} for @cols;
  41   $class->_columns($names);
  42 }
  43
  44 sub _mk_column_accessors {
  45   my ($class, @cols) = @_;
  46   $class->mk_group_accessors('column' => @cols);
  47 }
  48
  49 =item add_columns
  50
  51   __PACKAGE__->add_columns(qw/col1 col2 col3/);
  52
  53 Adds columns to the current package, and creates accessors for them
  54
  55 =cut
  56
  57 sub add_columns {
  58   my ($class, @cols) = @_;
  59   $class->_register_columns(@cols);
  60   $class->_mk_column_accessors(@cols);
  61 }
  62
  63 =item search_literal
  64
  65   my @obj    = $class->search_literal($literal_where_cond, @bind);
  66   my $cursor = $class->search_literal($literal_where_cond, @bind);
  67
  68 =cut
  69
  70 sub search_literal {
  71   my ($class, $cond, @vals) = @_;
  72   $cond =~ s/^\s*WHERE//i;
  73   my $attrs = (ref $vals[$#vals] eq 'HASH' ? { %{ pop(@vals) } } : {});
  74   $attrs->{bind} = \@vals;
  75   return $class->search(\$cond, $attrs);
  76 }
  77
  78 =item count_literal
  79
  80   my $count = $class->count_literal($literal_where_cond);
  81
  82 =cut
  83
  84 sub count_literal {
  85   my $class = shift;
  86   return $class->search_literal(@_)->count;
  87 }
  88
  89 =item count
  90
  91   my $count = $class->count({ foo => 3 });
  92
  93 =cut
  94
  95 sub count {
  96   my $class = shift;
  97   return $class->search(@_)->count;
  98 }
  99
 100 =item search
 101
 102   my @obj    = $class->search({ foo => 3 });
 103   my $cursor = $class->search({ foo => 3 });
 104
 105 =cut
 106
 107 sub search {
 108   my $class = shift;
 109   #warn "@_";
 110   my $attrs = { };
 111   if (@_ > 1 && ref $_[$#_] eq 'HASH') {
 112     $attrs = { %{ pop(@_) } };
 113   }
 114   $attrs->{where} = (@_ == 1 || ref $_[0] eq "HASH" ? shift: {@_});
 115
 116   my $rs = $class->resultset($attrs);
 117
 118   return (wantarray ? $rs->all : $rs);
 119 }
 120
 121 sub resultset {
 122   my $class = shift;
 123
 124   my $rs_class = $class->_resultset_class;
 125   eval "use $rs_class;";
 126   my $rs = $rs_class->new($class, @_);
 127 }
 128
 129 =item search_like
 130
 131 Identical to search except defaults to 'LIKE' instead of '=' in condition
 132
 133 =cut
 134
 135 sub search_like {
 136   my $class    = shift;
 137   my $attrs = { };
 138   if (@_ > 1 && ref $_[$#_] eq 'HASH') {
 139     $attrs = pop(@_);
 140   }
 141   my $query    = ref $_[0] eq "HASH" ? { %{shift()} }: {@_};
 142   $query->{$_} = { 'like' => $query->{$_} } for keys %$query;
 143   return $class->search($query, { %$attrs });
 144 }
 145
 146 sub _select_columns {
 147   return keys %{$_[0]->_columns};
 148 }
 149
 150 =item table
 151
 152   __PACKAGE__->table('tbl_name');
 153
 154 =cut
 155
 156 sub table {
 157   shift->_table_name(@_);
 158 }
 159
 160 =item find_or_create
 161
 162   $class->find_or_create({ key => $val, ... });
 163
 164 Searches for a record matching the search condition; if it doesn't find one,
 165 creates one and returns that instead
 166
 167 =cut
 168
 169 sub find_or_create {
 170   my $class    = shift;
 171   my $hash     = ref $_[0] eq "HASH" ? shift: {@_};
 172   my $exists = $class->find($hash);
 173   return defined($exists) ? $exists : $class->create($hash);
 174 }
 175
 176 sub columns { return keys %{shift->_columns}; }
 177
 178 1;
 179
 180 =back
 181
 182 =head1 AUTHORS
 183
 184 Matt S. Trout <mst@shadowcatsystems.co.uk>
 185
 186 =head1 LICENSE
 187
 188 You may distribute this code under the same terms as Perl itself.
 189
 190 =cut
 191