lib/DBIx/Class/Storage/TxnScopeGuard.pm

   1 package DBIx::Class::Storage::TxnScopeGuard;
   2
   3 use strict;
   4 use warnings;
   5 use Scalar::Util qw(weaken blessed refaddr);
   6 use DBIx::Class;
   7 use DBIx::Class::_Util qw(is_exception detected_reinvoked_destructor);
   8 use DBIx::Class::Carp;
   9 use namespace::clean;
  10
  11 sub new {
  12   my ($class, $storage) = @_;
  13
  14   my $guard = {
  15     inactivated => 0,
  16     storage => $storage,
  17   };
  18
  19   # we are starting with an already set $@ - in order for things to work we need to
  20   # be able to recognize it upon destruction - store its weakref
  21   # recording it before doing the txn_begin stuff
  22   #
  23   # FIXME FRAGILE - any eval that fails but *does not* rethrow between here
  24   # and the unwind will trample over $@ and invalidate the entire mechanism
  25   # There got to be a saner way of doing this...
  26   #
  27   # Deliberately *NOT* using is_exception - if someone left a misbehaving
  28   # antipattern value in $@, it's not our business to whine about it
  29   if( defined $@ and length $@ ) {
  30     weaken(
  31       $guard->{existing_exception_ref} = (length ref $@) ? $@ : \$@
  32     );
  33   }
  34
  35   $storage->txn_begin;
  36
  37   weaken( $guard->{dbh} = $storage->_dbh );
  38
  39   bless $guard, ref $class || $class;
  40
  41   $guard;
  42 }
  43
  44 sub commit {
  45   my $self = shift;
  46
  47   $self->{storage}->throw_exception("Refusing to execute multiple commits on scope guard $self")
  48     if $self->{inactivated};
  49
  50   # FIXME - this assumption may be premature: a commit may fail and a rollback
  51   # *still* be necessary. Currently I am not aware of such scenarious, but I
  52   # also know the deferred constraint handling is *severely* undertested.
  53   # Making the change of "fire txn and never come back to this" in order to
  54   # address RT#107159, but this *MUST* be reevaluated later.
  55   $self->{inactivated} = 1;
  56   $self->{storage}->txn_commit;
  57 }
  58
  59 sub DESTROY {
  60   return if &detected_reinvoked_destructor;
  61
  62   return if $_[0]->{inactivated};
  63
  64   # if our dbh is not ours anymore, the $dbh weakref will go undef
  65   $_[0]->{storage}->_verify_pid unless DBIx::Class::_ENV_::BROKEN_FORK;
  66   return unless $_[0]->{dbh};
  67
  68   my $current_exception = (
  69     is_exception $@
  70       and
  71     (
  72       ! defined $_[0]->{existing_exception_ref}
  73         or
  74       refaddr( (length ref $@) ? $@ : \$@ ) != refaddr($_[0]->{existing_exception_ref})
  75     )
  76   )
  77     ? $@
  78     : undef
  79   ;
  80
  81   {
  82     local $@;
  83
  84     carp 'A DBIx::Class::Storage::TxnScopeGuard went out of scope without explicit commit or error. Rolling back.'
  85       unless defined $current_exception;
  86
  87     my $rollback_exception;
  88     # do minimal connectivity check due to weird shit like
  89     # https://rt.cpan.org/Public/Bug/Display.html?id=62370
  90     eval {
  91       $_[0]->{storage}->_seems_connected && $_[0]->{storage}->txn_rollback;
  92       1;
  93     } or $rollback_exception = $@;
  94
  95     if ( $rollback_exception and (
  96       ! defined blessed $rollback_exception
  97           or
  98       ! $rollback_exception->isa('DBIx::Class::Storage::NESTED_ROLLBACK_EXCEPTION')
  99     ) ) {
 100       # append our text - THIS IS A TEMPORARY FIXUP!
 101       # a real stackable exception object is in the works
 102       if (ref $current_exception eq 'DBIx::Class::Exception') {
 103         $current_exception->{msg} = "Transaction aborted: $current_exception->{msg} "
 104           ."Rollback failed: ${rollback_exception}";
 105       }
 106       elsif ($current_exception) {
 107         $current_exception = "Transaction aborted: ${current_exception} "
 108           ."Rollback failed: ${rollback_exception}";
 109       }
 110       else {
 111         carp (join ' ',
 112           "********************* ROLLBACK FAILED!!! ********************",
 113           "\nA rollback operation failed after the guard went out of scope.",
 114           'This is potentially a disastrous situation, check your data for',
 115           "consistency: $rollback_exception"
 116         );
 117       }
 118     }
 119   }
 120
 121   $@ = $current_exception;
 122 }
 123
 124 1;
 125
 126 __END__
 127
 128 =head1 NAME
 129
 130 DBIx::Class::Storage::TxnScopeGuard - Scope-based transaction handling
 131
 132 =head1 SYNOPSIS
 133
 134  sub foo {
 135    my ($self, $schema) = @_;
 136
 137    my $guard = $schema->txn_scope_guard;
 138
 139    # Multiple database operations here
 140
 141    $guard->commit;
 142  }
 143
 144 =head1 DESCRIPTION
 145
 146 An object that behaves much like L<Scope::Guard>, but hardcoded to do the
 147 right thing with transactions in DBIx::Class.
 148
 149 =head1 METHODS
 150
 151 =head2 new
 152
 153 Creating an instance of this class will start a new transaction (by
 154 implicitly calling L<DBIx::Class::Storage/txn_begin>. Expects a
 155 L<DBIx::Class::Storage> object as its only argument.
 156
 157 =head2 commit
 158
 159 Commit the transaction, and stop guarding the scope. If this method is not
 160 called and this object goes out of scope (e.g. an exception is thrown) then
 161 the transaction is rolled back, via L<DBIx::Class::Storage/txn_rollback>
 162
 163 =cut
 164
 165 =head1 SEE ALSO
 166
 167 L<DBIx::Class::Schema/txn_scope_guard>.
 168
 169 L<Scope::Guard> by chocolateboy (inspiration for this module)
 170
 171 =head1 FURTHER QUESTIONS?
 172
 173 Check the list of L<additional DBIC resources|DBIx::Class/GETTING HELP/SUPPORT>.
 174
 175 =head1 COPYRIGHT AND LICENSE
 176
 177 This module is free software L<copyright|DBIx::Class/COPYRIGHT AND LICENSE>
 178 by the L<DBIx::Class (DBIC) authors|DBIx::Class/AUTHORS>. You can
 179 redistribute it and/or modify it under the same terms as the
 180 L<DBIx::Class library|DBIx::Class/COPYRIGHT AND LICENSE>.