lib/DBIx/Class/Storage/DBIHacks.pm

   1 package   #hide from PAUSE
   2   DBIx::Class::Storage::DBIHacks;
   3
   4 #
   5 # This module contains code that should never have seen the light of day,
   6 # does not belong in the Storage, or is otherwise unfit for public
   7 # display. The arrival of SQLA2 should immediately oboslete 90% of this
   8 #
   9
  10 use strict;
  11 use warnings;
  12
  13 use base 'DBIx::Class::Storage';
  14 use mro 'c3';
  15
  16 use Carp::Clan qw/^DBIx::Class/;
  17
  18 #
  19 # This code will remove non-selecting/non-restricting joins from
  20 # {from} specs, aiding the RDBMS query optimizer
  21 #
  22 sub _prune_unused_joins {
  23   my ($self) = shift;
  24
  25   my ($from, $select, $where, $attrs) = @_;
  26
  27   if (ref $from ne 'ARRAY' || ref $from->[0] ne 'HASH' || ref $from->[1] ne 'ARRAY') {
  28     return $from;   # only standard {from} specs are supported
  29   }
  30
  31   my $aliastypes = $self->_resolve_aliastypes_from_select_args(@_);
  32
  33   # a grouped set will not be affected by amount of rows. Thus any
  34   # {multiplying} joins can go
  35   delete $aliastypes->{multiplying} if $attrs->{group_by};
  36
  37
  38   my @newfrom = $from->[0]; # FROM head is always present
  39
  40   my %need_joins = (map { %{$_||{}} } (values %$aliastypes) );
  41   for my $j (@{$from}[1..$#$from]) {
  42     push @newfrom, $j if (
  43       (! $j->[0]{-alias}) # legacy crap
  44         ||
  45       $need_joins{$j->[0]{-alias}}
  46     );
  47   }
  48
  49   return \@newfrom;
  50 }
  51
  52 #
  53 # This is the code producing joined subqueries like:
  54 # SELECT me.*, other.* FROM ( SELECT me.* FROM ... ) JOIN other ON ...
  55 #
  56 sub _adjust_select_args_for_complex_prefetch {
  57   my ($self, $from, $select, $where, $attrs) = @_;
  58
  59   $self->throw_exception ('Nothing to prefetch... how did we get here?!')
  60     if not @{$attrs->{_prefetch_select}};
  61
  62   $self->throw_exception ('Complex prefetches are not supported on resultsets with a custom from attribute')
  63     if (ref $from ne 'ARRAY' || ref $from->[0] ne 'HASH' || ref $from->[1] ne 'ARRAY');
  64
  65
  66   # generate inner/outer attribute lists, remove stuff that doesn't apply
  67   my $outer_attrs = { %$attrs };
  68   delete $outer_attrs->{$_} for qw/where bind rows offset group_by having/;
  69
  70   my $inner_attrs = { %$attrs };
  71   delete $inner_attrs->{$_} for qw/for collapse _prefetch_select _collapse_order_by select as/;
  72
  73
  74   # bring over all non-collapse-induced order_by into the inner query (if any)
  75   # the outer one will have to keep them all
  76   delete $inner_attrs->{order_by};
  77   if (my $ord_cnt = @{$outer_attrs->{order_by}} - @{$outer_attrs->{_collapse_order_by}} ) {
  78     $inner_attrs->{order_by} = [
  79       @{$outer_attrs->{order_by}}[ 0 .. $ord_cnt - 1]
  80     ];
  81   }
  82
  83   # generate the inner/outer select lists
  84   # for inside we consider only stuff *not* brought in by the prefetch
  85   # on the outside we substitute any function for its alias
  86   my $outer_select = [ @$select ];
  87   my $inner_select = [];
  88   for my $i (0 .. ( @$outer_select - @{$outer_attrs->{_prefetch_select}} - 1) ) {
  89     my $sel = $outer_select->[$i];
  90
  91     if (ref $sel eq 'HASH' ) {
  92       $sel->{-as} ||= $attrs->{as}[$i];
  93       $outer_select->[$i] = join ('.', $attrs->{alias}, ($sel->{-as} || "inner_column_$i") );
  94     }
  95
  96     push @$inner_select, $sel;
  97
  98     push @{$inner_attrs->{as}}, $attrs->{as}[$i];
  99   }
 100
 101   # construct the inner $from for the subquery
 102   # we need to prune first, because this will determine if we need a group_by below
 103   my $inner_from = $self->_prune_unused_joins ($from, $inner_select, $where, $inner_attrs);
 104
 105   # if a multi-type join was needed in the subquery - add a group_by to simulate the
 106   # collapse in the subq
 107   $inner_attrs->{group_by} ||= $inner_select
 108     if List::Util::first
 109       { ! $_->[0]{-is_single} }
 110       (@{$inner_from}[1 .. $#$inner_from])
 111   ;
 112
 113   # generate the subquery
 114   my $subq = $self->_select_args_to_query (
 115     $inner_from,
 116     $inner_select,
 117     $where,
 118     $inner_attrs,
 119   );
 120
 121   my $subq_joinspec = {
 122     -alias => $attrs->{alias},
 123     -source_handle => $inner_from->[0]{-source_handle},
 124     $attrs->{alias} => $subq,
 125   };
 126
 127   # Generate the outer from - this is relatively easy (really just replace
 128   # the join slot with the subquery), with a major caveat - we can not
 129   # join anything that is non-selecting (not part of the prefetch), but at
 130   # the same time is a multi-type relationship, as it will explode the result.
 131   #
 132   # There are two possibilities here
 133   # - either the join is non-restricting, in which case we simply throw it away
 134   # - it is part of the restrictions, in which case we need to collapse the outer
 135   #   result by tackling yet another group_by to the outside of the query
 136
 137   # normalize a copy of $from, so it will be easier to work with further
 138   # down (i.e. promote the initial hashref to an AoH)
 139   $from = [ @$from ];
 140   $from->[0] = [ $from->[0] ];
 141
 142   # so first generate the outer_from, up to the substitution point
 143   my @outer_from;
 144   while (my $j = shift @$from) {
 145     if ($j->[0]{-alias} eq $attrs->{alias}) { # time to swap
 146       push @outer_from, [
 147         $subq_joinspec,
 148         @{$j}[1 .. $#$j],
 149       ];
 150       last; # we'll take care of what's left in $from below
 151     }
 152     else {
 153       push @outer_from, $j;
 154     }
 155   }
 156
 157   # scan the from spec against different attributes, and see which joins are needed
 158   # in what role
 159   my $outer_aliastypes =
 160     $self->_resolve_aliastypes_from_select_args( $from, $outer_select, $where, $outer_attrs );
 161
 162   # see what's left - throw away if not selecting/restricting
 163   # also throw in a group_by if restricting to guard against
 164   # cross-join explosions
 165   #
 166   while (my $j = shift @$from) {
 167     my $alias = $j->[0]{-alias};
 168
 169     if ($outer_aliastypes->{selecting}{$alias}) {
 170       push @outer_from, $j;
 171     }
 172     elsif ($outer_aliastypes->{restricting}{$alias}) {
 173       push @outer_from, $j;
 174       $outer_attrs->{group_by} ||= $outer_select unless $j->[0]{-is_single};
 175     }
 176   }
 177
 178   # demote the outer_from head
 179   $outer_from[0] = $outer_from[0][0];
 180
 181   # This is totally horrific - the $where ends up in both the inner and outer query
 182   # Unfortunately not much can be done until SQLA2 introspection arrives, and even
 183   # then if where conditions apply to the *right* side of the prefetch, you may have
 184   # to both filter the inner select (e.g. to apply a limit) and then have to re-filter
 185   # the outer select to exclude joins you didin't want in the first place
 186   #
 187   # OTOH it can be seen as a plus: <ash> (notes that this query would make a DBA cry ;)
 188   return (\@outer_from, $outer_select, $where, $outer_attrs);
 189 }
 190
 191 #
 192 # I KNOW THIS SUCKS! GET SQLA2 OUT THE DOOR SO THIS CAN DIE!
 193 #
 194 # Due to a lack of SQLA2 we fall back to crude scans of all the
 195 # select/where/order/group attributes, in order to determine what
 196 # aliases are neded to fulfill the query. This information is used
 197 # throughout the code to prune unnecessary JOINs from the queries
 198 # in an attempt to reduce the execution time.
 199 # Although the method is pretty horrific, the worst thing that can
 200 # happen is for it to fail due to some scalar SQL, which in turn will
 201 # result in a vocal exception.
 202 sub _resolve_aliastypes_from_select_args {
 203   my ( $self, $from, $select, $where, $attrs ) = @_;
 204
 205   $self->throw_exception ('Unable to analyze custom {from}')
 206     if ref $from ne 'ARRAY';
 207
 208   # what we will return
 209   my $aliases_by_type;
 210
 211   # see what aliases are there to work with
 212   my $alias_list;
 213   for (@$from) {
 214     my $j = $_;
 215     $j = $j->[0] if ref $j eq 'ARRAY';
 216     my $al = $j->{-alias}
 217       or next;
 218
 219     $alias_list->{$al} = $j;
 220     $aliases_by_type->{multiplying}{$al} = 1
 221       unless $j->{-is_single};
 222   }
 223
 224   # get a column to source/alias map (including unqualified ones)
 225   my $colinfo = $self->_resolve_column_info ($from);
 226
 227   # set up a botched SQLA
 228   my $sql_maker = $self->sql_maker;
 229   my $sep = quotemeta ($self->_sql_maker_opts->{name_sep} || '.');
 230
 231   my ($orig_lquote, $orig_rquote) = map { quotemeta $_ } (do {
 232     if (ref $sql_maker->{quote_char} eq 'ARRAY') {
 233       @{$sql_maker->{quote_char}}
 234     }
 235     else {
 236       ($sql_maker->{quote_char} || '') x 2;
 237     }
 238   });
 239
 240   local $sql_maker->{quote_char} = "\x00"; # so that we can regex away
 241
 242   # generate sql chunks
 243   my $to_scan = {
 244     restricting => [
 245       $sql_maker->_recurse_where ($where),
 246       $sql_maker->_order_by({
 247         map { $_ => $attrs->{$_} } (qw/group_by having/)
 248       }),
 249     ],
 250     selecting => [
 251       $self->_parse_order_by ($attrs->{order_by}, $sql_maker),
 252       $sql_maker->_recurse_fields ($select),
 253     ],
 254   };
 255
 256   # throw away empty chunks
 257   $_ = [ map { $_ || () } @$_ ] for values %$to_scan;
 258
 259   # first loop through all fully qualified columns and get the corresponding
 260   # alias (should work even if they are in scalarrefs)
 261   for my $alias (keys %$alias_list) {
 262     my $al_re = qr/
 263       \x00 $alias \x00 $sep
 264         |
 265       \b $alias $sep
 266     /x;
 267
 268     # add matching for possible quoted literal sql
 269     $al_re = qr/ $al_re | $orig_lquote $alias $orig_rquote /x
 270       if ($orig_lquote && $orig_rquote);
 271
 272
 273     for my $type (keys %$to_scan) {
 274       for my $piece (@{$to_scan->{$type}}) {
 275         $aliases_by_type->{$type}{$alias} = 1 if ($piece =~ $al_re);
 276       }
 277     }
 278   }
 279
 280   # now loop through unqualified column names, and try to locate them within
 281   # the chunks
 282   for my $col (keys %$colinfo) {
 283     next if $col =~ $sep;   # if column is qualified it was caught by the above
 284
 285     my $col_re = qr/ \x00 $col \x00 /x;
 286
 287     $col_re = qr/ $col_re | $orig_lquote $col $orig_rquote /x
 288       if ($orig_lquote && $orig_rquote);
 289
 290     for my $type (keys %$to_scan) {
 291       for my $piece (@{$to_scan->{$type}}) {
 292         $aliases_by_type->{$type}{$colinfo->{$col}{-source_alias}} = 1 if ($piece =~ $col_re);
 293       }
 294     }
 295   }
 296
 297   # Add any non-left joins to the restriction list (such joins are indeed restrictions)
 298   for my $j (values %$alias_list) {
 299     my $alias = $j->{-alias} or next;
 300     $aliases_by_type->{restricting}{$alias} = 1 if (
 301       (not $j->{-join_type})
 302         or
 303       ($j->{-join_type} !~ /^left (?: \s+ outer)? $/xi)
 304     );
 305   }
 306
 307   # mark all join parents as mentioned
 308   # (e.g.  join => { cds => 'tracks' } - tracks will need to bring cds too )
 309   for my $type (keys %$aliases_by_type) {
 310     for my $alias (keys %{$aliases_by_type->{$type}}) {
 311       $aliases_by_type->{$type}{$_} = 1
 312         for (map { values %$_ } @{ $alias_list->{$alias}{-join_path} || [] });
 313     }
 314   }
 315
 316   return $aliases_by_type;
 317 }
 318
 319 sub _resolve_ident_sources {
 320   my ($self, $ident) = @_;
 321
 322   my $alias2source = {};
 323   my $rs_alias;
 324
 325   # the reason this is so contrived is that $ident may be a {from}
 326   # structure, specifying multiple tables to join
 327   if ( Scalar::Util::blessed($ident) && $ident->isa("DBIx::Class::ResultSource") ) {
 328     # this is compat mode for insert/update/delete which do not deal with aliases
 329     $alias2source->{me} = $ident;
 330     $rs_alias = 'me';
 331   }
 332   elsif (ref $ident eq 'ARRAY') {
 333
 334     for (@$ident) {
 335       my $tabinfo;
 336       if (ref $_ eq 'HASH') {
 337         $tabinfo = $_;
 338         $rs_alias = $tabinfo->{-alias};
 339       }
 340       if (ref $_ eq 'ARRAY' and ref $_->[0] eq 'HASH') {
 341         $tabinfo = $_->[0];
 342       }
 343
 344       $alias2source->{$tabinfo->{-alias}} = $tabinfo->{-source_handle}->resolve
 345         if ($tabinfo->{-source_handle});
 346     }
 347   }
 348
 349   return ($alias2source, $rs_alias);
 350 }
 351
 352 # Takes $ident, \@column_names
 353 #
 354 # returns { $column_name => \%column_info, ... }
 355 # also note: this adds -result_source => $rsrc to the column info
 356 #
 357 # If no columns_names are supplied returns info about *all* columns
 358 # for all sources
 359 sub _resolve_column_info {
 360   my ($self, $ident, $colnames) = @_;
 361   my ($alias2src, $root_alias) = $self->_resolve_ident_sources($ident);
 362
 363   my $sep = $self->_sql_maker_opts->{name_sep} || '.';
 364   my $qsep = quotemeta $sep;
 365
 366   my (%return, %seen_cols, @auto_colnames);
 367
 368   # compile a global list of column names, to be able to properly
 369   # disambiguate unqualified column names (if at all possible)
 370   for my $alias (keys %$alias2src) {
 371     my $rsrc = $alias2src->{$alias};
 372     for my $colname ($rsrc->columns) {
 373       push @{$seen_cols{$colname}}, $alias;
 374       push @auto_colnames, "$alias$sep$colname" unless $colnames;
 375     }
 376   }
 377
 378   $colnames ||= [
 379     @auto_colnames,
 380     grep { @{$seen_cols{$_}} == 1 } (keys %seen_cols),
 381   ];
 382
 383   COLUMN:
 384   foreach my $col (@$colnames) {
 385     my ($alias, $colname) = $col =~ m/^ (?: ([^$qsep]+) $qsep)? (.+) $/x;
 386
 387     unless ($alias) {
 388       # see if the column was seen exactly once (so we know which rsrc it came from)
 389       if ($seen_cols{$colname} and @{$seen_cols{$colname}} == 1) {
 390         $alias = $seen_cols{$colname}[0];
 391       }
 392       else {
 393         next COLUMN;
 394       }
 395     }
 396
 397     my $rsrc = $alias2src->{$alias};
 398     $return{$col} = $rsrc && {
 399       %{$rsrc->column_info($colname)},
 400       -result_source => $rsrc,
 401       -source_alias => $alias,
 402     };
 403   }
 404
 405   return \%return;
 406 }
 407
 408 # The DBIC relationship chaining implementation is pretty simple - every
 409 # new related_relationship is pushed onto the {from} stack, and the {select}
 410 # window simply slides further in. This means that when we count somewhere
 411 # in the middle, we got to make sure that everything in the join chain is an
 412 # actual inner join, otherwise the count will come back with unpredictable
 413 # results (a resultset may be generated with _some_ rows regardless of if
 414 # the relation which the $rs currently selects has rows or not). E.g.
 415 # $artist_rs->cds->count - normally generates:
 416 # SELECT COUNT( * ) FROM artist me LEFT JOIN cd cds ON cds.artist = me.artistid
 417 # which actually returns the number of artists * (number of cds || 1)
 418 #
 419 # So what we do here is crawl {from}, determine if the current alias is at
 420 # the top of the stack, and if not - make sure the chain is inner-joined down
 421 # to the root.
 422 #
 423 sub _straight_join_to_node {
 424   my ($self, $from, $alias) = @_;
 425
 426   # subqueries and other oddness are naturally not supported
 427   return $from if (
 428     ref $from ne 'ARRAY'
 429       ||
 430     @$from <= 1
 431       ||
 432     ref $from->[0] ne 'HASH'
 433       ||
 434     ! $from->[0]{-alias}
 435       ||
 436     $from->[0]{-alias} eq $alias  # this last bit means $alias is the head of $from - nothing to do
 437   );
 438
 439   # find the current $alias in the $from structure
 440   my $switch_branch;
 441   JOINSCAN:
 442   for my $j (@{$from}[1 .. $#$from]) {
 443     if ($j->[0]{-alias} eq $alias) {
 444       $switch_branch = $j->[0]{-join_path};
 445       last JOINSCAN;
 446     }
 447   }
 448
 449   # something else went quite wrong
 450   return $from unless $switch_branch;
 451
 452   # So it looks like we will have to switch some stuff around.
 453   # local() is useless here as we will be leaving the scope
 454   # anyway, and deep cloning is just too fucking expensive
 455   # So replace the first hashref in the node arrayref manually
 456   my @new_from = ($from->[0]);
 457   my $sw_idx = { map { (values %$_), 1 } @$switch_branch }; #there's one k/v per join-path
 458
 459   for my $j (@{$from}[1 .. $#$from]) {
 460     my $jalias = $j->[0]{-alias};
 461
 462     if ($sw_idx->{$jalias}) {
 463       my %attrs = %{$j->[0]};
 464       delete $attrs{-join_type};
 465       push @new_from, [
 466         \%attrs,
 467         @{$j}[ 1 .. $#$j ],
 468       ];
 469     }
 470     else {
 471       push @new_from, $j;
 472     }
 473   }
 474
 475   return \@new_from;
 476 }
 477
 478 # Most databases do not allow aliasing of tables in UPDATE/DELETE. Thus
 479 # a condition containing 'me' or other table prefixes will not work
 480 # at all. What this code tries to do (badly) is introspect the condition
 481 # and remove all column qualifiers. If it bails out early (returns undef)
 482 # the calling code should try another approach (e.g. a subquery)
 483 sub _strip_cond_qualifiers {
 484   my ($self, $where) = @_;
 485
 486   my $cond = {};
 487
 488   # No-op. No condition, we're updating/deleting everything
 489   return $cond unless $where;
 490
 491   if (ref $where eq 'ARRAY') {
 492     $cond = [
 493       map {
 494         my %hash;
 495         foreach my $key (keys %{$_}) {
 496           $key =~ /([^.]+)$/;
 497           $hash{$1} = $_->{$key};
 498         }
 499         \%hash;
 500       } @$where
 501     ];
 502   }
 503   elsif (ref $where eq 'HASH') {
 504     if ( (keys %$where) == 1 && ( (keys %{$where})[0] eq '-and' )) {
 505       $cond->{-and} = [];
 506       my @cond = @{$where->{-and}};
 507        for (my $i = 0; $i < @cond; $i++) {
 508         my $entry = $cond[$i];
 509         my $hash;
 510         my $ref = ref $entry;
 511         if ($ref eq 'HASH' or $ref eq 'ARRAY') {
 512           $hash = $self->_strip_cond_qualifiers($entry);
 513         }
 514         elsif (! $ref) {
 515           $entry =~ /([^.]+)$/;
 516           $hash->{$1} = $cond[++$i];
 517         }
 518         else {
 519           $self->throw_exception ("_strip_cond_qualifiers() is unable to handle a condition reftype $ref");
 520         }
 521         push @{$cond->{-and}}, $hash;
 522       }
 523     }
 524     else {
 525       foreach my $key (keys %$where) {
 526         $key =~ /([^.]+)$/;
 527         $cond->{$1} = $where->{$key};
 528       }
 529     }
 530   }
 531   else {
 532     return undef;
 533   }
 534
 535   return $cond;
 536 }
 537
 538 sub _parse_order_by {
 539   my ($self, $order_by, $sql_maker) = @_;
 540
 541   my $parser = sub {
 542     my ($sql_maker, $order_by) = @_;
 543
 544     return scalar $sql_maker->_order_by_chunks ($order_by)
 545       unless wantarray;
 546
 547     my @chunks;
 548     for my $chunk (map { ref $_ ? @$_ : $_ } ($sql_maker->_order_by_chunks ($order_by) ) ) {
 549       $chunk =~ s/\s+ (?: ASC|DESC ) \s* $//ix;
 550       push @chunks, $chunk;
 551     }
 552
 553     return @chunks;
 554   };
 555
 556   if ($sql_maker) {
 557     return $parser->($sql_maker, $order_by);
 558   }
 559   else {
 560     $sql_maker = $self->sql_maker;
 561     local $sql_maker->{quote_char};
 562     return $parser->($sql_maker, $order_by);
 563   }
 564 }
 565
 566 1;