lib/DBIx/Class/Storage/DBIHacks.pm

   1 package   #hide from PAUSE
   2   DBIx::Class::Storage::DBIHacks;
   3
   4 #
   5 # This module contains code that should never have seen the light of day,
   6 # does not belong in the Storage, or is otherwise unfit for public
   7 # display. The arrival of SQLA2 should immediately oboslete 90% of this
   8 #
   9
  10 use strict;
  11 use warnings;
  12
  13 use base 'DBIx::Class::Storage';
  14 use mro 'c3';
  15
  16 use Carp::Clan qw/^DBIx::Class/;
  17 use List::Util 'first';
  18 use Scalar::Util 'blessed';
  19 use namespace::clean;
  20
  21 #
  22 # This code will remove non-selecting/non-restricting joins from
  23 # {from} specs, aiding the RDBMS query optimizer
  24 #
  25 sub _prune_unused_joins {
  26   my $self = shift;
  27   my ($from, $select, $where, $attrs) = @_;
  28
  29   return $from unless $self->_use_join_optimizer;
  30
  31   if (ref $from ne 'ARRAY' || ref $from->[0] ne 'HASH' || ref $from->[1] ne 'ARRAY') {
  32     return $from;   # only standard {from} specs are supported
  33   }
  34
  35   my $aliastypes = $self->_resolve_aliastypes_from_select_args(@_);
  36
  37   # a grouped set will not be affected by amount of rows. Thus any
  38   # {multiplying} joins can go
  39   delete $aliastypes->{multiplying} if $attrs->{group_by};
  40
  41   my @newfrom = $from->[0]; # FROM head is always present
  42
  43   my %need_joins = (map { %{$_||{}} } (values %$aliastypes) );
  44   for my $j (@{$from}[1..$#$from]) {
  45     push @newfrom, $j if (
  46       (! $j->[0]{-alias}) # legacy crap
  47         ||
  48       $need_joins{$j->[0]{-alias}}
  49     );
  50   }
  51
  52   return \@newfrom;
  53 }
  54
  55 #
  56 # This is the code producing joined subqueries like:
  57 # SELECT me.*, other.* FROM ( SELECT me.* FROM ... ) JOIN other ON ...
  58 #
  59 sub _adjust_select_args_for_complex_prefetch {
  60   my ($self, $from, $select, $where, $attrs) = @_;
  61
  62   $self->throw_exception ('Nothing to prefetch... how did we get here?!')
  63     if not @{$attrs->{_prefetch_select}};
  64
  65   $self->throw_exception ('Complex prefetches are not supported on resultsets with a custom from attribute')
  66     if (ref $from ne 'ARRAY' || ref $from->[0] ne 'HASH' || ref $from->[1] ne 'ARRAY');
  67
  68
  69   # generate inner/outer attribute lists, remove stuff that doesn't apply
  70   my $outer_attrs = { %$attrs };
  71   delete $outer_attrs->{$_} for qw/where bind rows offset group_by having/;
  72
  73   my $inner_attrs = { %$attrs };
  74   delete $inner_attrs->{$_} for qw/for collapse _prefetch_select _collapse_order_by select as/;
  75
  76
  77   # bring over all non-collapse-induced order_by into the inner query (if any)
  78   # the outer one will have to keep them all
  79   delete $inner_attrs->{order_by};
  80   if (my $ord_cnt = @{$outer_attrs->{order_by}} - @{$outer_attrs->{_collapse_order_by}} ) {
  81     $inner_attrs->{order_by} = [
  82       @{$outer_attrs->{order_by}}[ 0 .. $ord_cnt - 1]
  83     ];
  84   }
  85
  86   # generate the inner/outer select lists
  87   # for inside we consider only stuff *not* brought in by the prefetch
  88   # on the outside we substitute any function for its alias
  89   my $outer_select = [ @$select ];
  90   my $inner_select = [];
  91   for my $i (0 .. ( @$outer_select - @{$outer_attrs->{_prefetch_select}} - 1) ) {
  92     my $sel = $outer_select->[$i];
  93
  94     if (ref $sel eq 'HASH' ) {
  95       $sel->{-as} ||= $attrs->{as}[$i];
  96       $outer_select->[$i] = join ('.', $attrs->{alias}, ($sel->{-as} || "inner_column_$i") );
  97     }
  98
  99     push @$inner_select, $sel;
 100
 101     push @{$inner_attrs->{as}}, $attrs->{as}[$i];
 102   }
 103
 104   # construct the inner $from and lock it in a subquery
 105   # we need to prune first, because this will determine if we need a group_by below
 106   # the fake group_by is so that the pruner throws away all non-selecting, non-restricting
 107   # multijoins (since we def. do not care about those inside the subquery)
 108
 109   my $subq_joinspec = do {
 110
 111     # must use it here regardless of user requests
 112     local $self->{_use_join_optimizer} = 1;
 113
 114     my $inner_from = $self->_prune_unused_joins ($from, $inner_select, $where, {
 115       group_by => ['dummy'], %$inner_attrs,
 116     });
 117
 118     # if a multi-type join was needed in the subquery - add a group_by to simulate the
 119     # collapse in the subq
 120     if (
 121       ! $inner_attrs->{group_by}
 122         and
 123       first { ! $_->[0]{-is_single} } (@{$inner_from}[1 .. $#$inner_from])
 124     ) {
 125       $inner_attrs->{group_by} = $self->_group_over_selection (
 126         $inner_from, $inner_select, $inner_attrs->{order_by}
 127       );
 128     }
 129
 130     # we already optimized $inner_from above
 131     local $self->{_use_join_optimizer} = 0;
 132
 133     # generate the subquery
 134     my $subq = $self->_select_args_to_query (
 135       $inner_from,
 136       $inner_select,
 137       $where,
 138       $inner_attrs,
 139     );
 140
 141     +{
 142       -alias => $attrs->{alias},
 143       -source_handle => $inner_from->[0]{-source_handle},
 144       $attrs->{alias} => $subq,
 145     };
 146   };
 147
 148   # Generate the outer from - this is relatively easy (really just replace
 149   # the join slot with the subquery), with a major caveat - we can not
 150   # join anything that is non-selecting (not part of the prefetch), but at
 151   # the same time is a multi-type relationship, as it will explode the result.
 152   #
 153   # There are two possibilities here
 154   # - either the join is non-restricting, in which case we simply throw it away
 155   # - it is part of the restrictions, in which case we need to collapse the outer
 156   #   result by tackling yet another group_by to the outside of the query
 157
 158   $from = [ @$from ];
 159
 160   # so first generate the outer_from, up to the substitution point
 161   my @outer_from;
 162   while (my $j = shift @$from) {
 163     $j = [ $j ] unless ref $j eq 'ARRAY'; # promote the head-from to an AoH
 164
 165     if ($j->[0]{-alias} eq $attrs->{alias}) { # time to swap
 166       push @outer_from, [
 167         $subq_joinspec,
 168         @{$j}[1 .. $#$j],
 169       ];
 170       last; # we'll take care of what's left in $from below
 171     }
 172     else {
 173       push @outer_from, $j;
 174     }
 175   }
 176
 177   # scan the *remaining* from spec against different attributes, and see which joins are needed
 178   # in what role
 179   my $outer_aliastypes =
 180     $self->_resolve_aliastypes_from_select_args( $from, $outer_select, $where, $outer_attrs );
 181
 182   # see what's left - throw away if not selecting/restricting
 183   # also throw in a group_by if restricting to guard against
 184   # cross-join explosions
 185   #
 186   while (my $j = shift @$from) {
 187     my $alias = $j->[0]{-alias};
 188
 189     if ($outer_aliastypes->{selecting}{$alias}) {
 190       push @outer_from, $j;
 191     }
 192     elsif ($outer_aliastypes->{restricting}{$alias}) {
 193       push @outer_from, $j;
 194       $outer_attrs->{group_by} ||= $outer_select unless $j->[0]{-is_single};
 195     }
 196   }
 197
 198   # demote the outer_from head
 199   $outer_from[0] = $outer_from[0][0];
 200
 201   # This is totally horrific - the $where ends up in both the inner and outer query
 202   # Unfortunately not much can be done until SQLA2 introspection arrives, and even
 203   # then if where conditions apply to the *right* side of the prefetch, you may have
 204   # to both filter the inner select (e.g. to apply a limit) and then have to re-filter
 205   # the outer select to exclude joins you didin't want in the first place
 206   #
 207   # OTOH it can be seen as a plus: <ash> (notes that this query would make a DBA cry ;)
 208   return (\@outer_from, $outer_select, $where, $outer_attrs);
 209 }
 210
 211 #
 212 # I KNOW THIS SUCKS! GET SQLA2 OUT THE DOOR SO THIS CAN DIE!
 213 #
 214 # Due to a lack of SQLA2 we fall back to crude scans of all the
 215 # select/where/order/group attributes, in order to determine what
 216 # aliases are neded to fulfill the query. This information is used
 217 # throughout the code to prune unnecessary JOINs from the queries
 218 # in an attempt to reduce the execution time.
 219 # Although the method is pretty horrific, the worst thing that can
 220 # happen is for it to fail due to some scalar SQL, which in turn will
 221 # result in a vocal exception.
 222 sub _resolve_aliastypes_from_select_args {
 223   my ( $self, $from, $select, $where, $attrs ) = @_;
 224
 225   $self->throw_exception ('Unable to analyze custom {from}')
 226     if ref $from ne 'ARRAY';
 227
 228   # what we will return
 229   my $aliases_by_type;
 230
 231   # see what aliases are there to work with
 232   my $alias_list;
 233   for (@$from) {
 234     my $j = $_;
 235     $j = $j->[0] if ref $j eq 'ARRAY';
 236     my $al = $j->{-alias}
 237       or next;
 238
 239     $alias_list->{$al} = $j;
 240     $aliases_by_type->{multiplying}{$al} = 1
 241       if ref($_) eq 'ARRAY' and ! $j->{-is_single}; # not array == {from} head == can't be multiplying
 242   }
 243
 244   # get a column to source/alias map (including unqualified ones)
 245   my $colinfo = $self->_resolve_column_info ($from);
 246
 247   # set up a botched SQLA
 248   my $sql_maker = $self->sql_maker;
 249
 250   # these are throw away results, do not pollute the bind stack
 251   local $sql_maker->{having_bind};
 252   local $sql_maker->{select_bind};
 253
 254   # we can't scan properly without any quoting (\b doesn't cut it
 255   # everywhere), so unless there is proper quoting set - use our
 256   # own weird impossible character.
 257   # Also in the case of no quoting, we need to explicitly disable
 258   # name_sep, otherwise sorry nasty legacy syntax like
 259   # { 'count(foo.id)' => { '>' => 3 } } will stop working >:(
 260   local $sql_maker->{quote_char} = $sql_maker->{quote_char};
 261   local $sql_maker->{name_sep} = $sql_maker->{name_sep};
 262
 263   unless (defined $sql_maker->{quote_char} and length $sql_maker->{quote_char}) {
 264     $sql_maker->{quote_char} = ["\x00", "\xFF"];
 265     # if we don't unset it we screw up retarded but unfortunately working
 266     # 'MAX(foo.bar)' => { '>', 3 }
 267     $sql_maker->{name_sep} = '';
 268   }
 269
 270   my ($lquote, $rquote, $sep) = map { quotemeta $_ } ($sql_maker->_quote_chars, $sql_maker->name_sep);
 271
 272   # generate sql chunks
 273   my $to_scan = {
 274     restricting => [
 275       $sql_maker->_recurse_where ($where),
 276       $sql_maker->_parse_rs_attrs ({
 277         map { $_ => $attrs->{$_} } (qw/group_by having/)
 278       }),
 279     ],
 280     selecting => [
 281       $sql_maker->_recurse_fields ($select),
 282       ( map { $_->[0] } $self->_extract_order_criteria ($attrs->{order_by}, $sql_maker) ),
 283     ],
 284   };
 285
 286   # throw away empty chunks
 287   $_ = [ map { $_ || () } @$_ ] for values %$to_scan;
 288
 289   # first loop through all fully qualified columns and get the corresponding
 290   # alias (should work even if they are in scalarrefs)
 291   for my $alias (keys %$alias_list) {
 292     my $al_re = qr/
 293       $lquote $alias $rquote $sep
 294         |
 295       \b $alias \.
 296     /x;
 297
 298     for my $type (keys %$to_scan) {
 299       for my $piece (@{$to_scan->{$type}}) {
 300         $aliases_by_type->{$type}{$alias} = 1 if ($piece =~ $al_re);
 301       }
 302     }
 303   }
 304
 305   # now loop through unqualified column names, and try to locate them within
 306   # the chunks
 307   for my $col (keys %$colinfo) {
 308     next if $col =~ / \. /x;   # if column is qualified it was caught by the above
 309
 310     my $col_re = qr/ $lquote $col $rquote /x;
 311
 312     for my $type (keys %$to_scan) {
 313       for my $piece (@{$to_scan->{$type}}) {
 314         $aliases_by_type->{$type}{$colinfo->{$col}{-source_alias}} = 1 if ($piece =~ $col_re);
 315       }
 316     }
 317   }
 318
 319   # Add any non-left joins to the restriction list (such joins are indeed restrictions)
 320   for my $j (values %$alias_list) {
 321     my $alias = $j->{-alias} or next;
 322     $aliases_by_type->{restricting}{$alias} = 1 if (
 323       (not $j->{-join_type})
 324         or
 325       ($j->{-join_type} !~ /^left (?: \s+ outer)? $/xi)
 326     );
 327   }
 328
 329   # mark all restricting/selecting join parents as such
 330   # (e.g.  join => { cds => 'tracks' } - tracks will need to bring cds too )
 331   for my $type (qw/restricting selecting/) {
 332     for my $alias (keys %{$aliases_by_type->{$type}||{}}) {
 333       $aliases_by_type->{$type}{$_} = 1
 334         for (map { values %$_ } @{ $alias_list->{$alias}{-join_path} || [] });
 335     }
 336   }
 337
 338   return $aliases_by_type;
 339 }
 340
 341 # This is the engine behind { distinct => 1 }
 342 sub _group_over_selection {
 343   my ($self, $from, $select, $order_by) = @_;
 344
 345   my $rs_column_list = $self->_resolve_column_info ($from);
 346
 347   my (@group_by, %group_index);
 348
 349   for (@$select) {
 350     if (! ref($_) or ref ($_) ne 'HASH' ) {
 351       push @group_by, $_;
 352       $group_index{$_}++;
 353       if ($rs_column_list->{$_} and $_ !~ /\./ ) {
 354         # add a fully qualified version as well
 355         $group_index{"$rs_column_list->{$_}{-source_alias}.$_"}++;
 356       }
 357     }
 358   }
 359
 360   # add any order_by parts that are not already present in the group_by
 361   # we need to be careful not to add any named functions/aggregates
 362   # i.e. order_by => [ ... { count => 'foo' } ... ]
 363   for ($self->_extract_order_criteria($order_by)) {
 364     # only consider real columns (for functions the user got to do an explicit group_by)
 365     next if @$_ != 1;
 366     my $chunk = $_->[0];
 367     my $colinfo = $rs_column_list->{$chunk} or next;
 368
 369     $chunk = "$colinfo->{-source_alias}.$chunk" if $chunk !~ /\./;
 370     push @group_by, $chunk unless $group_index{$chunk}++;
 371   }
 372
 373   return \@group_by;
 374 }
 375
 376 sub _resolve_ident_sources {
 377   my ($self, $ident) = @_;
 378
 379   my $alias2source = {};
 380   my $rs_alias;
 381
 382   # the reason this is so contrived is that $ident may be a {from}
 383   # structure, specifying multiple tables to join
 384   if ( blessed $ident && $ident->isa("DBIx::Class::ResultSource") ) {
 385     # this is compat mode for insert/update/delete which do not deal with aliases
 386     $alias2source->{me} = $ident;
 387     $rs_alias = 'me';
 388   }
 389   elsif (ref $ident eq 'ARRAY') {
 390
 391     for (@$ident) {
 392       my $tabinfo;
 393       if (ref $_ eq 'HASH') {
 394         $tabinfo = $_;
 395         $rs_alias = $tabinfo->{-alias};
 396       }
 397       if (ref $_ eq 'ARRAY' and ref $_->[0] eq 'HASH') {
 398         $tabinfo = $_->[0];
 399       }
 400
 401       $alias2source->{$tabinfo->{-alias}} = $tabinfo->{-source_handle}->resolve
 402         if ($tabinfo->{-source_handle});
 403     }
 404   }
 405
 406   return ($alias2source, $rs_alias);
 407 }
 408
 409 # Takes $ident, \@column_names
 410 #
 411 # returns { $column_name => \%column_info, ... }
 412 # also note: this adds -result_source => $rsrc to the column info
 413 #
 414 # If no columns_names are supplied returns info about *all* columns
 415 # for all sources
 416 sub _resolve_column_info {
 417   my ($self, $ident, $colnames) = @_;
 418   my ($alias2src, $root_alias) = $self->_resolve_ident_sources($ident);
 419
 420   my (%seen_cols, @auto_colnames);
 421
 422   # compile a global list of column names, to be able to properly
 423   # disambiguate unqualified column names (if at all possible)
 424   for my $alias (keys %$alias2src) {
 425     my $rsrc = $alias2src->{$alias};
 426     for my $colname ($rsrc->columns) {
 427       push @{$seen_cols{$colname}}, $alias;
 428       push @auto_colnames, "$alias.$colname" unless $colnames;
 429     }
 430   }
 431
 432   $colnames ||= [
 433     @auto_colnames,
 434     grep { @{$seen_cols{$_}} == 1 } (keys %seen_cols),
 435   ];
 436
 437   my (%return, $colinfos);
 438   foreach my $col (@$colnames) {
 439     my ($source_alias, $colname) = $col =~ m/^ (?: ([^\.]+) \. )? (.+) $/x;
 440
 441     # if the column was seen exactly once - we know which rsrc it came from
 442     $source_alias ||= $seen_cols{$colname}[0]
 443       if ($seen_cols{$colname} and @{$seen_cols{$colname}} == 1);
 444
 445     next unless $source_alias;
 446
 447     my $rsrc = $alias2src->{$source_alias}
 448       or next;
 449
 450     $return{$col} = {
 451       %{ ( $colinfos->{$source_alias} ||= $rsrc->columns_info )->{$colname} },
 452       -result_source => $rsrc,
 453       -source_alias => $source_alias,
 454     };
 455   }
 456
 457   return \%return;
 458 }
 459
 460 # The DBIC relationship chaining implementation is pretty simple - every
 461 # new related_relationship is pushed onto the {from} stack, and the {select}
 462 # window simply slides further in. This means that when we count somewhere
 463 # in the middle, we got to make sure that everything in the join chain is an
 464 # actual inner join, otherwise the count will come back with unpredictable
 465 # results (a resultset may be generated with _some_ rows regardless of if
 466 # the relation which the $rs currently selects has rows or not). E.g.
 467 # $artist_rs->cds->count - normally generates:
 468 # SELECT COUNT( * ) FROM artist me LEFT JOIN cd cds ON cds.artist = me.artistid
 469 # which actually returns the number of artists * (number of cds || 1)
 470 #
 471 # So what we do here is crawl {from}, determine if the current alias is at
 472 # the top of the stack, and if not - make sure the chain is inner-joined down
 473 # to the root.
 474 #
 475 sub _inner_join_to_node {
 476   my ($self, $from, $alias) = @_;
 477
 478   # subqueries and other oddness are naturally not supported
 479   return $from if (
 480     ref $from ne 'ARRAY'
 481       ||
 482     @$from <= 1
 483       ||
 484     ref $from->[0] ne 'HASH'
 485       ||
 486     ! $from->[0]{-alias}
 487       ||
 488     $from->[0]{-alias} eq $alias  # this last bit means $alias is the head of $from - nothing to do
 489   );
 490
 491   # find the current $alias in the $from structure
 492   my $switch_branch;
 493   JOINSCAN:
 494   for my $j (@{$from}[1 .. $#$from]) {
 495     if ($j->[0]{-alias} eq $alias) {
 496       $switch_branch = $j->[0]{-join_path};
 497       last JOINSCAN;
 498     }
 499   }
 500
 501   # something else went quite wrong
 502   return $from unless $switch_branch;
 503
 504   # So it looks like we will have to switch some stuff around.
 505   # local() is useless here as we will be leaving the scope
 506   # anyway, and deep cloning is just too fucking expensive
 507   # So replace the first hashref in the node arrayref manually
 508   my @new_from = ($from->[0]);
 509   my $sw_idx = { map { (values %$_), 1 } @$switch_branch }; #there's one k/v per join-path
 510
 511   for my $j (@{$from}[1 .. $#$from]) {
 512     my $jalias = $j->[0]{-alias};
 513
 514     if ($sw_idx->{$jalias}) {
 515       my %attrs = %{$j->[0]};
 516       delete $attrs{-join_type};
 517       push @new_from, [
 518         \%attrs,
 519         @{$j}[ 1 .. $#$j ],
 520       ];
 521     }
 522     else {
 523       push @new_from, $j;
 524     }
 525   }
 526
 527   return \@new_from;
 528 }
 529
 530 # Most databases do not allow aliasing of tables in UPDATE/DELETE. Thus
 531 # a condition containing 'me' or other table prefixes will not work
 532 # at all. What this code tries to do (badly) is introspect the condition
 533 # and remove all column qualifiers. If it bails out early (returns undef)
 534 # the calling code should try another approach (e.g. a subquery)
 535 sub _strip_cond_qualifiers {
 536   my ($self, $where) = @_;
 537
 538   my $cond = {};
 539
 540   # No-op. No condition, we're updating/deleting everything
 541   return $cond unless $where;
 542
 543   if (ref $where eq 'ARRAY') {
 544     $cond = [
 545       map {
 546         my %hash;
 547         foreach my $key (keys %{$_}) {
 548           $key =~ /([^.]+)$/;
 549           $hash{$1} = $_->{$key};
 550         }
 551         \%hash;
 552       } @$where
 553     ];
 554   }
 555   elsif (ref $where eq 'HASH') {
 556     if ( (keys %$where) == 1 && ( (keys %{$where})[0] eq '-and' )) {
 557       $cond->{-and} = [];
 558       my @cond = @{$where->{-and}};
 559        for (my $i = 0; $i < @cond; $i++) {
 560         my $entry = $cond[$i];
 561         my $hash;
 562         my $ref = ref $entry;
 563         if ($ref eq 'HASH' or $ref eq 'ARRAY') {
 564           $hash = $self->_strip_cond_qualifiers($entry);
 565         }
 566         elsif (! $ref) {
 567           $entry =~ /([^.]+)$/;
 568           $hash->{$1} = $cond[++$i];
 569         }
 570         else {
 571           $self->throw_exception ("_strip_cond_qualifiers() is unable to handle a condition reftype $ref");
 572         }
 573         push @{$cond->{-and}}, $hash;
 574       }
 575     }
 576     else {
 577       foreach my $key (keys %$where) {
 578         if ($key eq '-or' && ref $where->{$key} eq 'ARRAY') {
 579           $cond->{$key} = $self->_strip_cond_qualifiers($where->{$key});
 580         }
 581         else {
 582           $key =~ /([^.]+)$/;
 583           $cond->{$1} = $where->{$key};
 584         }
 585       }
 586     }
 587   }
 588   else {
 589     return undef;
 590   }
 591
 592   return $cond;
 593 }
 594
 595 sub _extract_order_criteria {
 596   my ($self, $order_by, $sql_maker) = @_;
 597
 598   my $parser = sub {
 599     my ($sql_maker, $order_by) = @_;
 600
 601     return scalar $sql_maker->_order_by_chunks ($order_by)
 602       unless wantarray;
 603
 604     my @chunks;
 605     for ($sql_maker->_order_by_chunks ($order_by) ) {
 606       my $chunk = ref $_ ? $_ : [ $_ ];
 607       $chunk->[0] =~ s/\s+ (?: ASC|DESC ) \s* $//ix;
 608       push @chunks, $chunk;
 609     }
 610
 611     return @chunks;
 612   };
 613
 614   if ($sql_maker) {
 615     return $parser->($sql_maker, $order_by);
 616   }
 617   else {
 618     $sql_maker = $self->sql_maker;
 619     local $sql_maker->{quote_char};
 620     return $parser->($sql_maker, $order_by);
 621   }
 622 }
 623
 624 1;