1 package #hide from PAUSE
2 DBIx::Class::Storage::DBIHacks;
5 # This module contains code that should never have seen the light of day,
6 # does not belong in the Storage, or is otherwise unfit for public
7 # display. The arrival of SQLA2 should immediately oboslete 90% of this
13 use base 'DBIx::Class::Storage';
16 use Carp::Clan qw/^DBIx::Class/;
19 # This code will remove non-selecting/non-restricting joins from
20 # {from} specs, aiding the RDBMS query optimizer. It will leave any
21 # unused type-multi joins, if the amount of returned rows is
22 # important (i.e. count without collapse)
24 sub _prune_unused_joins {
28 if (ref $from ne 'ARRAY' || ref $from->[0] ne 'HASH' || ref $from->[1] ne 'ARRAY') {
29 return $from; # only standard {from} specs are supported
32 my $aliastypes = $self->_resolve_aliases_from_select_args($from, @_);
34 my @newfrom = $from->[0]; # FROM head is always present
36 my %need_joins = (map { %{$_||{}} } (values %$aliastypes) );
37 for my $j (@{$from}[1..$#$from]) {
38 push @newfrom, $j if $need_joins{$j->[0]{-alias}};
46 # This is the code producing joined subqueries like:
47 # SELECT me.*, other.* FROM ( SELECT me.* FROM ... ) JOIN other ON ...
49 sub _adjust_select_args_for_complex_prefetch {
50 my ($self, $from, $select, $where, $attrs) = @_;
52 $self->throw_exception ('Nothing to prefetch... how did we get here?!')
53 if not @{$attrs->{_prefetch_select}};
55 $self->throw_exception ('Complex prefetches are not supported on resultsets with a custom from attribute')
56 if (ref $from ne 'ARRAY' || ref $from->[0] ne 'HASH' || ref $from->[1] ne 'ARRAY');
59 # generate inner/outer attribute lists, remove stuff that doesn't apply
60 my $outer_attrs = { %$attrs };
61 delete $outer_attrs->{$_} for qw/where bind rows offset group_by having/;
63 my $inner_attrs = { %$attrs };
64 delete $inner_attrs->{$_} for qw/for collapse _prefetch_select _collapse_order_by select as/;
67 # bring over all non-collapse-induced order_by into the inner query (if any)
68 # the outer one will have to keep them all
69 delete $inner_attrs->{order_by};
70 if (my $ord_cnt = @{$outer_attrs->{order_by}} - @{$outer_attrs->{_collapse_order_by}} ) {
71 $inner_attrs->{order_by} = [
72 @{$outer_attrs->{order_by}}[ 0 .. $ord_cnt - 1]
76 # generate the inner/outer select lists
77 # for inside we consider only stuff *not* brought in by the prefetch
78 # on the outside we substitute any function for its alias
79 my $outer_select = [ @$select ];
80 my $inner_select = [];
81 for my $i (0 .. ( @$outer_select - @{$outer_attrs->{_prefetch_select}} - 1) ) {
82 my $sel = $outer_select->[$i];
84 if (ref $sel eq 'HASH' ) {
85 $sel->{-as} ||= $attrs->{as}[$i];
86 $outer_select->[$i] = join ('.', $attrs->{alias}, ($sel->{-as} || "inner_column_$i") );
89 push @$inner_select, $sel;
92 # construct the inner $from for the subquery
93 my $inner_from = $self->_prune_unused_joins ($from, $inner_select, $where, $inner_attrs);
95 # if a multi-type join was needed in the subquery ("multi" is indicated by
96 # presence in {collapse}) - add a group_by to simulate the collapse in the subq
97 unless ($inner_attrs->{group_by}) {
98 for my $alias (map { $_->[0]{-alias} } (@{$inner_from}[1 .. $#$inner_from]) ) {
100 # the dot comes from some weirdness in collapse
101 # remove after the rewrite
102 if ($attrs->{collapse}{".$alias"}) {
103 $inner_attrs->{group_by} ||= $inner_select;
109 # generate the subquery
110 my $subq = $self->_select_args_to_query (
117 my $subq_joinspec = {
118 -alias => $attrs->{alias},
119 -source_handle => $inner_from->[0]{-source_handle},
120 $attrs->{alias} => $subq,
123 # Generate the outer from - this is relatively easy (really just replace
124 # the join slot with the subquery), with a major caveat - we can not
125 # join anything that is non-selecting (not part of the prefetch), but at
126 # the same time is a multi-type relationship, as it will explode the result.
128 # There are two possibilities here
129 # - either the join is non-restricting, in which case we simply throw it away
130 # - it is part of the restrictions, in which case we need to collapse the outer
131 # result by tackling yet another group_by to the outside of the query
133 # normalize a copy of $from, so it will be easier to work with further
134 # down (i.e. promote the initial hashref to an AoH)
136 $from->[0] = [ $from->[0] ];
138 # so first generate the outer_from, up to the substitution point
140 while (my $j = shift @$from) {
141 if ($j->[0]{-alias} eq $attrs->{alias}) { # time to swap
146 last; # we'll take care of what's left in $from below
149 push @outer_from, $j;
153 # scan the from spec against different attributes, and see which joins are needed
155 my $outer_aliastypes =
156 $self->_resolve_aliases_from_select_args( $from, $outer_select, $where, $outer_attrs );
158 # see what's left - throw away if not selecting/restricting
159 # also throw in a group_by if restricting to guard against
160 # cross-join explosions
162 while (my $j = shift @$from) {
163 my $alias = $j->[0]{-alias};
165 if ($outer_aliastypes->{select}{$alias}) {
166 push @outer_from, $j;
168 elsif ($outer_aliastypes->{restrict}{$alias}) {
169 push @outer_from, $j;
171 # FIXME - this should be obviated by SQLA2, as I'll be able to
172 # have restrict_inner and restrict_outer... or something to that
173 # effect... I think...
175 # FIXME2 - I can't find a clean way to determine if a particular join
176 # is a multi - instead I am just treating everything as a potential
177 # explosive join (ribasushi)
179 # if (my $handle = $j->[0]{-source_handle}) {
180 # my $rsrc = $handle->resolve;
181 # ... need to bail out of the following if this is not a multi,
182 # as it will be much easier on the db ...
184 $outer_attrs->{group_by} ||= $outer_select;
189 # demote the outer_from head
190 $outer_from[0] = $outer_from[0][0];
192 # This is totally horrific - the $where ends up in both the inner and outer query
193 # Unfortunately not much can be done until SQLA2 introspection arrives, and even
194 # then if where conditions apply to the *right* side of the prefetch, you may have
195 # to both filter the inner select (e.g. to apply a limit) and then have to re-filter
196 # the outer select to exclude joins you didin't want in the first place
198 # OTOH it can be seen as a plus: <ash> (notes that this query would make a DBA cry ;)
199 return (\@outer_from, $outer_select, $where, $outer_attrs);
202 # Due to a lack of SQLA2 we fall back to crude scans of all the
203 # select/where/order/group attributes, in order to determine what
204 # aliases are neded to fulfill the query. This information is used
205 # throughout the code to prune unnecessary JOINs from the queries
206 # in an attempt to reduce the execution time.
207 # Although the method is pretty horrific, the worst thing that can
208 # happen is for it to fail due to an unqualified column, which in
209 # turn will result in a vocal exception. Qualifying the column will
210 # invariably solve the problem.
211 sub _resolve_aliases_from_select_args {
212 my ( $self, $from, $select, $where, $attrs ) = @_;
214 $self->throw_exception ('Unable to analyze custom {from}')
215 if ref $from ne 'ARRAY';
217 # what we will return
220 # see what aliases are there to work with
222 my @from = @$from; # if I don't copy weird shit happens
224 $j = $j->[0] if ref $j eq 'ARRAY';
225 $alias_list->{$j->{-alias}} = $j;
228 # set up a botched SQLA
229 my $sql_maker = $self->sql_maker;
230 my $sep = quotemeta ($self->_sql_maker_opts->{name_sep} || '.');
231 local $sql_maker->{quote_char}; # so that we can regex away
234 my $select_sql = $sql_maker->_recurse_fields ($select);
235 my $where_sql = $sql_maker->where ($where);
236 my $group_by_sql = $sql_maker->_order_by({
237 map { $_ => $attrs->{$_} } qw/group_by having/
239 my @order_by_chunks = (map
240 { ref $_ ? $_->[0] : $_ }
241 $sql_maker->_order_by_chunks ($attrs->{order_by})
244 # match every alias to the sql chunks above
245 for my $alias (keys %$alias_list) {
246 my $al_re = qr/\b $alias $sep/x;
248 for my $piece ($where_sql, $group_by_sql) {
249 $aliases_by_type->{restrict}{$alias} = 1 if ($piece =~ $al_re);
252 for my $piece ($select_sql, @order_by_chunks ) {
253 $aliases_by_type->{select}{$alias} = 1 if ($piece =~ $al_re);
257 # Add any non-left joins to the restriction list (such joins are indeed restrictions)
258 for my $j (values %$alias_list) {
259 my $alias = $j->{-alias} or next;
260 $aliases_by_type->{restrict}{$alias} = 1 if (
261 (not $j->{-join_type})
263 ($j->{-join_type} !~ /^left (?: \s+ outer)? $/xi)
267 # mark all join parents as mentioned
268 # (e.g. join => { cds => 'tracks' } - tracks will need to bring cds too )
269 for my $type (keys %$aliases_by_type) {
270 for my $alias (keys %{$aliases_by_type->{$type}}) {
271 $aliases_by_type->{$type}{$_} = 1
272 for (@{ $alias_list->{$alias}{-join_path} || [] });
276 return $aliases_by_type;
279 sub _resolve_ident_sources {
280 my ($self, $ident) = @_;
282 my $alias2source = {};
285 # the reason this is so contrived is that $ident may be a {from}
286 # structure, specifying multiple tables to join
287 if ( Scalar::Util::blessed($ident) && $ident->isa("DBIx::Class::ResultSource") ) {
288 # this is compat mode for insert/update/delete which do not deal with aliases
289 $alias2source->{me} = $ident;
292 elsif (ref $ident eq 'ARRAY') {
296 if (ref $_ eq 'HASH') {
298 $rs_alias = $tabinfo->{-alias};
300 if (ref $_ eq 'ARRAY' and ref $_->[0] eq 'HASH') {
304 $alias2source->{$tabinfo->{-alias}} = $tabinfo->{-source_handle}->resolve
305 if ($tabinfo->{-source_handle});
309 return ($alias2source, $rs_alias);
312 # Takes $ident, \@column_names
314 # returns { $column_name => \%column_info, ... }
315 # also note: this adds -result_source => $rsrc to the column info
317 # If no columns_names are supplied returns info about *all* columns
319 sub _resolve_column_info {
320 my ($self, $ident, $colnames) = @_;
321 my ($alias2src, $root_alias) = $self->_resolve_ident_sources($ident);
323 my $sep = $self->_sql_maker_opts->{name_sep} || '.';
324 my $qsep = quotemeta $sep;
326 my (%return, %seen_cols, @auto_colnames);
328 # compile a global list of column names, to be able to properly
329 # disambiguate unqualified column names (if at all possible)
330 for my $alias (keys %$alias2src) {
331 my $rsrc = $alias2src->{$alias};
332 for my $colname ($rsrc->columns) {
333 push @{$seen_cols{$colname}}, $alias;
334 push @auto_colnames, "$alias$sep$colname" unless $colnames;
340 grep { @{$seen_cols{$_}} == 1 } (keys %seen_cols),
344 foreach my $col (@$colnames) {
345 my ($alias, $colname) = $col =~ m/^ (?: ([^$qsep]+) $qsep)? (.+) $/x;
348 # see if the column was seen exactly once (so we know which rsrc it came from)
349 if ($seen_cols{$colname} and @{$seen_cols{$colname}} == 1) {
350 $alias = $seen_cols{$colname}[0];
357 my $rsrc = $alias2src->{$alias};
358 $return{$col} = $rsrc && {
359 %{$rsrc->column_info($colname)},
360 -result_source => $rsrc,
361 -source_alias => $alias,
368 # The DBIC relationship chaining implementation is pretty simple - every
369 # new related_relationship is pushed onto the {from} stack, and the {select}
370 # window simply slides further in. This means that when we count somewhere
371 # in the middle, we got to make sure that everything in the join chain is an
372 # actual inner join, otherwise the count will come back with unpredictable
373 # results (a resultset may be generated with _some_ rows regardless of if
374 # the relation which the $rs currently selects has rows or not). E.g.
375 # $artist_rs->cds->count - normally generates:
376 # SELECT COUNT( * ) FROM artist me LEFT JOIN cd cds ON cds.artist = me.artistid
377 # which actually returns the number of artists * (number of cds || 1)
379 # So what we do here is crawl {from}, determine if the current alias is at
380 # the top of the stack, and if not - make sure the chain is inner-joined down
383 sub _straight_join_to_node {
384 my ($self, $from, $alias) = @_;
386 # subqueries and other oddness are naturally not supported
392 ref $from->[0] ne 'HASH'
396 $from->[0]{-alias} eq $alias # this last bit means $alias is the head of $from - nothing to do
399 # find the current $alias in the $from structure
402 for my $j (@{$from}[1 .. $#$from]) {
403 if ($j->[0]{-alias} eq $alias) {
404 $switch_branch = $j->[0]{-join_path};
409 # something else went quite wrong
410 return $from unless $switch_branch;
412 # So it looks like we will have to switch some stuff around.
413 # local() is useless here as we will be leaving the scope
414 # anyway, and deep cloning is just too fucking expensive
415 # So replace the first hashref in the node arrayref manually
416 my @new_from = ($from->[0]);
417 my $sw_idx = { map { $_ => 1 } @$switch_branch };
419 for my $j (@{$from}[1 .. $#$from]) {
420 my $jalias = $j->[0]{-alias};
422 if ($sw_idx->{$jalias}) {
423 my %attrs = %{$j->[0]};
424 delete $attrs{-join_type};
438 # Most databases do not allow aliasing of tables in UPDATE/DELETE. Thus
439 # a condition containing 'me' or other table prefixes will not work
440 # at all. What this code tries to do (badly) is introspect the condition
441 # and remove all column qualifiers. If it bails out early (returns undef)
442 # the calling code should try another approach (e.g. a subquery)
443 sub _strip_cond_qualifiers {
444 my ($self, $where) = @_;
448 # No-op. No condition, we're updating/deleting everything
449 return $cond unless $where;
451 if (ref $where eq 'ARRAY') {
455 foreach my $key (keys %{$_}) {
457 $hash{$1} = $_->{$key};
463 elsif (ref $where eq 'HASH') {
464 if ( (keys %$where) == 1 && ( (keys %{$where})[0] eq '-and' )) {
466 my @cond = @{$where->{-and}};
467 for (my $i = 0; $i < @cond; $i++) {
468 my $entry = $cond[$i];
470 if (ref $entry eq 'HASH') {
471 $hash = $self->_strip_cond_qualifiers($entry);
474 $entry =~ /([^.]+)$/;
475 $hash->{$1} = $cond[++$i];
477 push @{$cond->{-and}}, $hash;
481 foreach my $key (keys %$where) {
483 $cond->{$1} = $where->{$key};