lib/DBIx/Class/Storage/DBIHacks.pm

   1 package   #hide from PAUSE
   2   DBIx::Class::Storage::DBIHacks;
   3
   4 #
   5 # This module contains code that should never have seen the light of day,
   6 # does not belong in the Storage, or is otherwise unfit for public
   7 # display. The arrival of SQLA2 should immediately oboslete 90% of this
   8 #
   9
  10 use strict;
  11 use warnings;
  12
  13 use base 'DBIx::Class::Storage';
  14 use mro 'c3';
  15
  16 use Carp::Clan qw/^DBIx::Class/;
  17
  18 #
  19 # This code will remove non-selecting/non-restricting joins from
  20 # {from} specs, aiding the RDBMS query optimizer
  21 #
  22 sub _prune_unused_joins {
  23   my ($self) = shift;
  24
  25   my ($from, $select, $where, $attrs) = @_;
  26
  27   if (ref $from ne 'ARRAY' || ref $from->[0] ne 'HASH' || ref $from->[1] ne 'ARRAY') {
  28     return $from;   # only standard {from} specs are supported
  29   }
  30
  31   my $aliastypes = $self->_resolve_aliastypes_from_select_args(@_);
  32
  33   # a grouped set will not be affected by amount of rows. Thus any
  34   # {multiplying} joins can go
  35   delete $aliastypes->{multiplying} if $attrs->{group_by};
  36
  37
  38   my @newfrom = $from->[0]; # FROM head is always present
  39
  40   my %need_joins = (map { %{$_||{}} } (values %$aliastypes) );
  41   for my $j (@{$from}[1..$#$from]) {
  42     push @newfrom, $j if (
  43       (! $j->[0]{-alias}) # legacy crap
  44         ||
  45       $need_joins{$j->[0]{-alias}}
  46     );
  47   }
  48
  49   return \@newfrom;
  50 }
  51
  52 #
  53 # This is the code producing joined subqueries like:
  54 # SELECT me.*, other.* FROM ( SELECT me.* FROM ... ) JOIN other ON ...
  55 #
  56 sub _adjust_select_args_for_complex_prefetch {
  57   my ($self, $from, $select, $where, $attrs) = @_;
  58
  59   $self->throw_exception ('Nothing to prefetch... how did we get here?!')
  60     if not @{$attrs->{_prefetch_select}};
  61
  62   $self->throw_exception ('Complex prefetches are not supported on resultsets with a custom from attribute')
  63     if (ref $from ne 'ARRAY' || ref $from->[0] ne 'HASH' || ref $from->[1] ne 'ARRAY');
  64
  65
  66   # generate inner/outer attribute lists, remove stuff that doesn't apply
  67   my $outer_attrs = { %$attrs };
  68   delete $outer_attrs->{$_} for qw/where bind rows offset group_by having/;
  69
  70   my $inner_attrs = { %$attrs };
  71   delete $inner_attrs->{$_} for qw/for collapse _prefetch_select _collapse_order_by select as/;
  72
  73
  74   # bring over all non-collapse-induced order_by into the inner query (if any)
  75   # the outer one will have to keep them all
  76   delete $inner_attrs->{order_by};
  77   if (my $ord_cnt = @{$outer_attrs->{order_by}} - @{$outer_attrs->{_collapse_order_by}} ) {
  78     $inner_attrs->{order_by} = [
  79       @{$outer_attrs->{order_by}}[ 0 .. $ord_cnt - 1]
  80     ];
  81   }
  82
  83   # generate the inner/outer select lists
  84   # for inside we consider only stuff *not* brought in by the prefetch
  85   # on the outside we substitute any function for its alias
  86   my $outer_select = [ @$select ];
  87   my $inner_select = [];
  88   for my $i (0 .. ( @$outer_select - @{$outer_attrs->{_prefetch_select}} - 1) ) {
  89     my $sel = $outer_select->[$i];
  90
  91     if (ref $sel eq 'HASH' ) {
  92       $sel->{-as} ||= $attrs->{as}[$i];
  93       $outer_select->[$i] = join ('.', $attrs->{alias}, ($sel->{-as} || "inner_column_$i") );
  94     }
  95
  96     push @$inner_select, $sel;
  97   }
  98
  99   # construct the inner $from for the subquery
 100   # we need to prune first, because this will determine if we need a group_by below
 101   my $inner_from = $self->_prune_unused_joins ($from, $inner_select, $where, $inner_attrs);
 102
 103   # if a multi-type join was needed in the subquery - add a group_by to simulate the
 104   # collapse in the subq
 105   $inner_attrs->{group_by} ||= $inner_select
 106     if List::Util::first
 107       { ! $_->[0]{-is_single} }
 108       (@{$inner_from}[1 .. $#$inner_from])
 109   ;
 110
 111   # generate the subquery
 112   my $subq = $self->_select_args_to_query (
 113     $inner_from,
 114     $inner_select,
 115     $where,
 116     $inner_attrs,
 117   );
 118
 119   my $subq_joinspec = {
 120     -alias => $attrs->{alias},
 121     -source_handle => $inner_from->[0]{-source_handle},
 122     $attrs->{alias} => $subq,
 123   };
 124
 125   # Generate the outer from - this is relatively easy (really just replace
 126   # the join slot with the subquery), with a major caveat - we can not
 127   # join anything that is non-selecting (not part of the prefetch), but at
 128   # the same time is a multi-type relationship, as it will explode the result.
 129   #
 130   # There are two possibilities here
 131   # - either the join is non-restricting, in which case we simply throw it away
 132   # - it is part of the restrictions, in which case we need to collapse the outer
 133   #   result by tackling yet another group_by to the outside of the query
 134
 135   # normalize a copy of $from, so it will be easier to work with further
 136   # down (i.e. promote the initial hashref to an AoH)
 137   $from = [ @$from ];
 138   $from->[0] = [ $from->[0] ];
 139
 140   # so first generate the outer_from, up to the substitution point
 141   my @outer_from;
 142   while (my $j = shift @$from) {
 143     if ($j->[0]{-alias} eq $attrs->{alias}) { # time to swap
 144       push @outer_from, [
 145         $subq_joinspec,
 146         @{$j}[1 .. $#$j],
 147       ];
 148       last; # we'll take care of what's left in $from below
 149     }
 150     else {
 151       push @outer_from, $j;
 152     }
 153   }
 154
 155   # scan the from spec against different attributes, and see which joins are needed
 156   # in what role
 157   my $outer_aliastypes =
 158     $self->_resolve_aliastypes_from_select_args( $from, $outer_select, $where, $outer_attrs );
 159
 160   # see what's left - throw away if not selecting/restricting
 161   # also throw in a group_by if restricting to guard against
 162   # cross-join explosions
 163   #
 164   while (my $j = shift @$from) {
 165     my $alias = $j->[0]{-alias};
 166
 167     if ($outer_aliastypes->{select}{$alias}) {
 168       push @outer_from, $j;
 169     }
 170     elsif ($outer_aliastypes->{restrict}{$alias}) {
 171       push @outer_from, $j;
 172       $outer_attrs->{group_by} ||= $outer_select unless $j->[0]{-is_single};
 173     }
 174   }
 175
 176   # demote the outer_from head
 177   $outer_from[0] = $outer_from[0][0];
 178
 179   # This is totally horrific - the $where ends up in both the inner and outer query
 180   # Unfortunately not much can be done until SQLA2 introspection arrives, and even
 181   # then if where conditions apply to the *right* side of the prefetch, you may have
 182   # to both filter the inner select (e.g. to apply a limit) and then have to re-filter
 183   # the outer select to exclude joins you didin't want in the first place
 184   #
 185   # OTOH it can be seen as a plus: <ash> (notes that this query would make a DBA cry ;)
 186   return (\@outer_from, $outer_select, $where, $outer_attrs);
 187 }
 188
 189 # Due to a lack of SQLA2 we fall back to crude scans of all the
 190 # select/where/order/group attributes, in order to determine what
 191 # aliases are neded to fulfill the query. This information is used
 192 # throughout the code to prune unnecessary JOINs from the queries
 193 # in an attempt to reduce the execution time.
 194 # Although the method is pretty horrific, the worst thing that can
 195 # happen is for it to fail due to an unqualified column, which in
 196 # turn will result in a vocal exception. Qualifying the column will
 197 # invariably solve the problem.
 198 sub _resolve_aliastypes_from_select_args {
 199   my ( $self, $from, $select, $where, $attrs ) = @_;
 200
 201   $self->throw_exception ('Unable to analyze custom {from}')
 202     if ref $from ne 'ARRAY';
 203
 204   # what we will return
 205   my $aliases_by_type;
 206
 207   # see what aliases are there to work with
 208   my $alias_list;
 209   for (@$from) {
 210     my $j = $_;
 211     $j = $j->[0] if ref $j eq 'ARRAY';
 212     my $al = $j->{-alias}
 213       or next;
 214
 215     $alias_list->{$al} = $j;
 216     $aliases_by_type->{multiplying}{$al} = 1
 217       unless $j->{-is_single};
 218   }
 219
 220   # set up a botched SQLA
 221   my $sql_maker = $self->sql_maker;
 222   my $sep = quotemeta ($self->_sql_maker_opts->{name_sep} || '.');
 223   local $sql_maker->{quote_char}; # so that we can regex away
 224
 225
 226   my $select_sql = $sql_maker->_recurse_fields ($select);
 227   my $where_sql = $sql_maker->where ($where);
 228   my $group_by_sql = $sql_maker->_order_by({
 229     map { $_ => $attrs->{$_} } qw/group_by having/
 230   });
 231   my @order_by_chunks = ($self->_parse_order_by ($attrs->{order_by}) );
 232
 233   # match every alias to the sql chunks above
 234   for my $alias (keys %$alias_list) {
 235     my $al_re = qr/\b $alias $sep/x;
 236
 237     for my $piece ($where_sql, $group_by_sql) {
 238       $aliases_by_type->{restrict}{$alias} = 1 if ($piece =~ $al_re);
 239     }
 240
 241     for my $piece ($select_sql, @order_by_chunks ) {
 242       $aliases_by_type->{select}{$alias} = 1 if ($piece =~ $al_re);
 243     }
 244   }
 245
 246   # Add any non-left joins to the restriction list (such joins are indeed restrictions)
 247   for my $j (values %$alias_list) {
 248     my $alias = $j->{-alias} or next;
 249     $aliases_by_type->{restrict}{$alias} = 1 if (
 250       (not $j->{-join_type})
 251         or
 252       ($j->{-join_type} !~ /^left (?: \s+ outer)? $/xi)
 253     );
 254   }
 255
 256   # mark all join parents as mentioned
 257   # (e.g.  join => { cds => 'tracks' } - tracks will need to bring cds too )
 258   for my $type (keys %$aliases_by_type) {
 259     for my $alias (keys %{$aliases_by_type->{$type}}) {
 260       $aliases_by_type->{$type}{$_} = 1
 261         for (map { keys %$_ } @{ $alias_list->{$alias}{-join_path} || [] });
 262     }
 263   }
 264
 265   return $aliases_by_type;
 266 }
 267
 268 sub _resolve_ident_sources {
 269   my ($self, $ident) = @_;
 270
 271   my $alias2source = {};
 272   my $rs_alias;
 273
 274   # the reason this is so contrived is that $ident may be a {from}
 275   # structure, specifying multiple tables to join
 276   if ( Scalar::Util::blessed($ident) && $ident->isa("DBIx::Class::ResultSource") ) {
 277     # this is compat mode for insert/update/delete which do not deal with aliases
 278     $alias2source->{me} = $ident;
 279     $rs_alias = 'me';
 280   }
 281   elsif (ref $ident eq 'ARRAY') {
 282
 283     for (@$ident) {
 284       my $tabinfo;
 285       if (ref $_ eq 'HASH') {
 286         $tabinfo = $_;
 287         $rs_alias = $tabinfo->{-alias};
 288       }
 289       if (ref $_ eq 'ARRAY' and ref $_->[0] eq 'HASH') {
 290         $tabinfo = $_->[0];
 291       }
 292
 293       $alias2source->{$tabinfo->{-alias}} = $tabinfo->{-source_handle}->resolve
 294         if ($tabinfo->{-source_handle});
 295     }
 296   }
 297
 298   return ($alias2source, $rs_alias);
 299 }
 300
 301 # Takes $ident, \@column_names
 302 #
 303 # returns { $column_name => \%column_info, ... }
 304 # also note: this adds -result_source => $rsrc to the column info
 305 #
 306 # If no columns_names are supplied returns info about *all* columns
 307 # for all sources
 308 sub _resolve_column_info {
 309   my ($self, $ident, $colnames) = @_;
 310   my ($alias2src, $root_alias) = $self->_resolve_ident_sources($ident);
 311
 312   my $sep = $self->_sql_maker_opts->{name_sep} || '.';
 313   my $qsep = quotemeta $sep;
 314
 315   my (%return, %seen_cols, @auto_colnames);
 316
 317   # compile a global list of column names, to be able to properly
 318   # disambiguate unqualified column names (if at all possible)
 319   for my $alias (keys %$alias2src) {
 320     my $rsrc = $alias2src->{$alias};
 321     for my $colname ($rsrc->columns) {
 322       push @{$seen_cols{$colname}}, $alias;
 323       push @auto_colnames, "$alias$sep$colname" unless $colnames;
 324     }
 325   }
 326
 327   $colnames ||= [
 328     @auto_colnames,
 329     grep { @{$seen_cols{$_}} == 1 } (keys %seen_cols),
 330   ];
 331
 332   COLUMN:
 333   foreach my $col (@$colnames) {
 334     my ($alias, $colname) = $col =~ m/^ (?: ([^$qsep]+) $qsep)? (.+) $/x;
 335
 336     unless ($alias) {
 337       # see if the column was seen exactly once (so we know which rsrc it came from)
 338       if ($seen_cols{$colname} and @{$seen_cols{$colname}} == 1) {
 339         $alias = $seen_cols{$colname}[0];
 340       }
 341       else {
 342         next COLUMN;
 343       }
 344     }
 345
 346     my $rsrc = $alias2src->{$alias};
 347     $return{$col} = $rsrc && {
 348       %{$rsrc->column_info($colname)},
 349       -result_source => $rsrc,
 350       -source_alias => $alias,
 351     };
 352   }
 353
 354   return \%return;
 355 }
 356
 357 # The DBIC relationship chaining implementation is pretty simple - every
 358 # new related_relationship is pushed onto the {from} stack, and the {select}
 359 # window simply slides further in. This means that when we count somewhere
 360 # in the middle, we got to make sure that everything in the join chain is an
 361 # actual inner join, otherwise the count will come back with unpredictable
 362 # results (a resultset may be generated with _some_ rows regardless of if
 363 # the relation which the $rs currently selects has rows or not). E.g.
 364 # $artist_rs->cds->count - normally generates:
 365 # SELECT COUNT( * ) FROM artist me LEFT JOIN cd cds ON cds.artist = me.artistid
 366 # which actually returns the number of artists * (number of cds || 1)
 367 #
 368 # So what we do here is crawl {from}, determine if the current alias is at
 369 # the top of the stack, and if not - make sure the chain is inner-joined down
 370 # to the root.
 371 #
 372 sub _straight_join_to_node {
 373   my ($self, $from, $alias) = @_;
 374
 375   # subqueries and other oddness are naturally not supported
 376   return $from if (
 377     ref $from ne 'ARRAY'
 378       ||
 379     @$from <= 1
 380       ||
 381     ref $from->[0] ne 'HASH'
 382       ||
 383     ! $from->[0]{-alias}
 384       ||
 385     $from->[0]{-alias} eq $alias  # this last bit means $alias is the head of $from - nothing to do
 386   );
 387
 388   # find the current $alias in the $from structure
 389   my $switch_branch;
 390   JOINSCAN:
 391   for my $j (@{$from}[1 .. $#$from]) {
 392     if ($j->[0]{-alias} eq $alias) {
 393       $switch_branch = $j->[0]{-join_path};
 394       last JOINSCAN;
 395     }
 396   }
 397
 398   # something else went quite wrong
 399   return $from unless $switch_branch;
 400
 401   # So it looks like we will have to switch some stuff around.
 402   # local() is useless here as we will be leaving the scope
 403   # anyway, and deep cloning is just too fucking expensive
 404   # So replace the first hashref in the node arrayref manually
 405   my @new_from = ($from->[0]);
 406   my $sw_idx = { map { values %$_ => 1 } @$switch_branch };
 407
 408   for my $j (@{$from}[1 .. $#$from]) {
 409     my $jalias = $j->[0]{-alias};
 410
 411     if ($sw_idx->{$jalias}) {
 412       my %attrs = %{$j->[0]};
 413       delete $attrs{-join_type};
 414       push @new_from, [
 415         \%attrs,
 416         @{$j}[ 1 .. $#$j ],
 417       ];
 418     }
 419     else {
 420       push @new_from, $j;
 421     }
 422   }
 423
 424   return \@new_from;
 425 }
 426
 427 # Most databases do not allow aliasing of tables in UPDATE/DELETE. Thus
 428 # a condition containing 'me' or other table prefixes will not work
 429 # at all. What this code tries to do (badly) is introspect the condition
 430 # and remove all column qualifiers. If it bails out early (returns undef)
 431 # the calling code should try another approach (e.g. a subquery)
 432 sub _strip_cond_qualifiers {
 433   my ($self, $where) = @_;
 434
 435   my $cond = {};
 436
 437   # No-op. No condition, we're updating/deleting everything
 438   return $cond unless $where;
 439
 440   if (ref $where eq 'ARRAY') {
 441     $cond = [
 442       map {
 443         my %hash;
 444         foreach my $key (keys %{$_}) {
 445           $key =~ /([^.]+)$/;
 446           $hash{$1} = $_->{$key};
 447         }
 448         \%hash;
 449       } @$where
 450     ];
 451   }
 452   elsif (ref $where eq 'HASH') {
 453     if ( (keys %$where) == 1 && ( (keys %{$where})[0] eq '-and' )) {
 454       $cond->{-and} = [];
 455       my @cond = @{$where->{-and}};
 456        for (my $i = 0; $i < @cond; $i++) {
 457         my $entry = $cond[$i];
 458         my $hash;
 459         my $ref = ref $entry;
 460         if ($ref eq 'HASH' or $ref eq 'ARRAY') {
 461           $hash = $self->_strip_cond_qualifiers($entry);
 462         }
 463         elsif (! $ref) {
 464           $entry =~ /([^.]+)$/;
 465           $hash->{$1} = $cond[++$i];
 466         }
 467         else {
 468           $self->throw_exception ("_strip_cond_qualifiers() is unable to handle a condition reftype $ref");
 469         }
 470         push @{$cond->{-and}}, $hash;
 471       }
 472     }
 473     else {
 474       foreach my $key (keys %$where) {
 475         $key =~ /([^.]+)$/;
 476         $cond->{$1} = $where->{$key};
 477       }
 478     }
 479   }
 480   else {
 481     return undef;
 482   }
 483
 484   return $cond;
 485 }
 486
 487 sub _parse_order_by {
 488   my ($self, $order_by) = @_;
 489
 490   return scalar $self->sql_maker->_order_by_chunks ($order_by)
 491     unless wantarray;
 492
 493   my $sql_maker = $self->sql_maker;
 494   local $sql_maker->{quote_char}; #disable quoting
 495   my @chunks;
 496   for my $chunk (map { ref $_ ? @$_ : $_ } ($sql_maker->_order_by_chunks ($order_by) ) ) {
 497     $chunk =~ s/\s+ (?: ASC|DESC ) \s* $//ix;
 498     push @chunks, $chunk;
 499   }
 500
 501   return @chunks;
 502 }
 503
 504 1;