lib/DBIx/Class/Storage/DBIHacks.pm

   1 package   #hide from PAUSE
   2   DBIx::Class::Storage::DBIHacks;
   3
   4 #
   5 # This module contains code that should never have seen the light of day,
   6 # does not belong in the Storage, or is otherwise unfit for public
   7 # display. The arrival of SQLA2 should immediately oboslete 90% of this
   8 #
   9
  10 use strict;
  11 use warnings;
  12
  13 use base 'DBIx::Class::Storage';
  14 use mro 'c3';
  15
  16 use Carp::Clan qw/^DBIx::Class/;
  17
  18 #
  19 # This code will remove non-selecting/non-restricting joins from
  20 # {from} specs, aiding the RDBMS query optimizer
  21 #
  22 sub _prune_unused_joins {
  23   my ($self) = shift;
  24
  25   my ($from, $select, $where, $attrs) = @_;
  26
  27   if (ref $from ne 'ARRAY' || ref $from->[0] ne 'HASH' || ref $from->[1] ne 'ARRAY') {
  28     return $from;   # only standard {from} specs are supported
  29   }
  30
  31   my $aliastypes = $self->_resolve_aliastypes_from_select_args(@_);
  32
  33   # a grouped set will not be affected by amount of rows. Thus any
  34   # {multiplying} joins can go
  35   delete $aliastypes->{multiplying} if $attrs->{group_by};
  36
  37
  38   my @newfrom = $from->[0]; # FROM head is always present
  39
  40   my %need_joins = (map { %{$_||{}} } (values %$aliastypes) );
  41   for my $j (@{$from}[1..$#$from]) {
  42     push @newfrom, $j if (
  43       (! $j->[0]{-alias}) # legacy crap
  44         ||
  45       $need_joins{$j->[0]{-alias}}
  46     );
  47   }
  48
  49   return \@newfrom;
  50 }
  51
  52 #
  53 # This is the code producing joined subqueries like:
  54 # SELECT me.*, other.* FROM ( SELECT me.* FROM ... ) JOIN other ON ...
  55 #
  56 sub _adjust_select_args_for_complex_prefetch {
  57   my ($self, $from, $select, $where, $attrs) = @_;
  58
  59   $self->throw_exception ('Nothing to prefetch... how did we get here?!')
  60     if not @{$attrs->{_prefetch_select}};
  61
  62   $self->throw_exception ('Complex prefetches are not supported on resultsets with a custom from attribute')
  63     if (ref $from ne 'ARRAY' || ref $from->[0] ne 'HASH' || ref $from->[1] ne 'ARRAY');
  64
  65
  66   # generate inner/outer attribute lists, remove stuff that doesn't apply
  67   my $outer_attrs = { %$attrs };
  68   delete $outer_attrs->{$_} for qw/where bind rows offset group_by having/;
  69
  70   my $inner_attrs = { %$attrs };
  71   delete $inner_attrs->{$_} for qw/for collapse _prefetch_select _collapse_order_by select as/;
  72
  73
  74   # bring over all non-collapse-induced order_by into the inner query (if any)
  75   # the outer one will have to keep them all
  76   delete $inner_attrs->{order_by};
  77   if (my $ord_cnt = @{$outer_attrs->{order_by}} - @{$outer_attrs->{_collapse_order_by}} ) {
  78     $inner_attrs->{order_by} = [
  79       @{$outer_attrs->{order_by}}[ 0 .. $ord_cnt - 1]
  80     ];
  81   }
  82
  83   # generate the inner/outer select lists
  84   # for inside we consider only stuff *not* brought in by the prefetch
  85   # on the outside we substitute any function for its alias
  86   my $outer_select = [ @$select ];
  87   my $inner_select = [];
  88   for my $i (0 .. ( @$outer_select - @{$outer_attrs->{_prefetch_select}} - 1) ) {
  89     my $sel = $outer_select->[$i];
  90
  91     if (ref $sel eq 'HASH' ) {
  92       $sel->{-as} ||= $attrs->{as}[$i];
  93       $outer_select->[$i] = join ('.', $attrs->{alias}, ($sel->{-as} || "inner_column_$i") );
  94     }
  95
  96     push @$inner_select, $sel;
  97   }
  98
  99   # construct the inner $from for the subquery
 100   # we need to prune first, because this will determine if we need a group_by below
 101   my $inner_from = $self->_prune_unused_joins ($from, $inner_select, $where, $inner_attrs);
 102
 103   # if a multi-type join was needed in the subquery - add a group_by to simulate the
 104   # collapse in the subq
 105   $inner_attrs->{group_by} ||= $inner_select
 106     if List::Util::first
 107       { ! $_->[0]{-is_single} }
 108       (@{$inner_from}[1 .. $#$inner_from])
 109   ;
 110
 111   # generate the subquery
 112   my $subq = $self->_select_args_to_query (
 113     $inner_from,
 114     $inner_select,
 115     $where,
 116     $inner_attrs,
 117   );
 118
 119   my $subq_joinspec = {
 120     -alias => $attrs->{alias},
 121     -source_handle => $inner_from->[0]{-source_handle},
 122     $attrs->{alias} => $subq,
 123   };
 124
 125   # Generate the outer from - this is relatively easy (really just replace
 126   # the join slot with the subquery), with a major caveat - we can not
 127   # join anything that is non-selecting (not part of the prefetch), but at
 128   # the same time is a multi-type relationship, as it will explode the result.
 129   #
 130   # There are two possibilities here
 131   # - either the join is non-restricting, in which case we simply throw it away
 132   # - it is part of the restrictions, in which case we need to collapse the outer
 133   #   result by tackling yet another group_by to the outside of the query
 134
 135   # normalize a copy of $from, so it will be easier to work with further
 136   # down (i.e. promote the initial hashref to an AoH)
 137   $from = [ @$from ];
 138   $from->[0] = [ $from->[0] ];
 139
 140   # so first generate the outer_from, up to the substitution point
 141   my @outer_from;
 142   while (my $j = shift @$from) {
 143     if ($j->[0]{-alias} eq $attrs->{alias}) { # time to swap
 144       push @outer_from, [
 145         $subq_joinspec,
 146         @{$j}[1 .. $#$j],
 147       ];
 148       last; # we'll take care of what's left in $from below
 149     }
 150     else {
 151       push @outer_from, $j;
 152     }
 153   }
 154
 155   # scan the from spec against different attributes, and see which joins are needed
 156   # in what role
 157   my $outer_aliastypes =
 158     $self->_resolve_aliastypes_from_select_args( $from, $outer_select, $where, $outer_attrs );
 159
 160   # see what's left - throw away if not selecting/restricting
 161   # also throw in a group_by if restricting to guard against
 162   # cross-join explosions
 163   #
 164   while (my $j = shift @$from) {
 165     my $alias = $j->[0]{-alias};
 166
 167     if ($outer_aliastypes->{selecting}{$alias}) {
 168       push @outer_from, $j;
 169     }
 170     elsif ($outer_aliastypes->{restricting}{$alias}) {
 171       push @outer_from, $j;
 172       $outer_attrs->{group_by} ||= $outer_select unless $j->[0]{-is_single};
 173     }
 174   }
 175
 176   # demote the outer_from head
 177   $outer_from[0] = $outer_from[0][0];
 178
 179   # This is totally horrific - the $where ends up in both the inner and outer query
 180   # Unfortunately not much can be done until SQLA2 introspection arrives, and even
 181   # then if where conditions apply to the *right* side of the prefetch, you may have
 182   # to both filter the inner select (e.g. to apply a limit) and then have to re-filter
 183   # the outer select to exclude joins you didin't want in the first place
 184   #
 185   # OTOH it can be seen as a plus: <ash> (notes that this query would make a DBA cry ;)
 186   return (\@outer_from, $outer_select, $where, $outer_attrs);
 187 }
 188
 189 #
 190 # I KNOW THIS SUCKS! GET SQLA2 OUT THE DOOR SO THIS CAN DIE!
 191 #
 192 # Due to a lack of SQLA2 we fall back to crude scans of all the
 193 # select/where/order/group attributes, in order to determine what
 194 # aliases are neded to fulfill the query. This information is used
 195 # throughout the code to prune unnecessary JOINs from the queries
 196 # in an attempt to reduce the execution time.
 197 # Although the method is pretty horrific, the worst thing that can
 198 # happen is for it to fail due to some scalar SQL, which in turn will
 199 # result in a vocal exception.
 200 sub _resolve_aliastypes_from_select_args {
 201   my ( $self, $from, $select, $where, $attrs ) = @_;
 202
 203   $self->throw_exception ('Unable to analyze custom {from}')
 204     if ref $from ne 'ARRAY';
 205
 206   # what we will return
 207   my $aliases_by_type;
 208
 209   # see what aliases are there to work with
 210   my $alias_list;
 211   for (@$from) {
 212     my $j = $_;
 213     $j = $j->[0] if ref $j eq 'ARRAY';
 214     my $al = $j->{-alias}
 215       or next;
 216
 217     $alias_list->{$al} = $j;
 218     $aliases_by_type->{multiplying}{$al} = 1
 219       unless $j->{-is_single};
 220   }
 221
 222   # get a column to source/alias map (including unqualified ones)
 223   my $colinfo = $self->_resolve_column_info ($from);
 224
 225   # set up a botched SQLA
 226   my $sql_maker = $self->sql_maker;
 227   my $sep = quotemeta ($self->_sql_maker_opts->{name_sep} || '.');
 228
 229   my ($orig_lquote, $orig_rquote) = map { quotemeta $_ } (do {
 230     if (ref $sql_maker->{quote_char} eq 'ARRAY') {
 231       @{$sql_maker->{quote_char}}
 232     }
 233     else {
 234       ($sql_maker->{quote_char} || '') x 2;
 235     }
 236   });
 237
 238   local $sql_maker->{quote_char} = "\x00"; # so that we can regex away
 239
 240   # generate sql chunks
 241   my $to_scan = {
 242     restricting => [
 243       $sql_maker->_recurse_where ($where),
 244       $sql_maker->_order_by({
 245         map { $_ => $attrs->{$_} } (qw/group_by having/)
 246       }),
 247     ],
 248     selecting => [
 249       $self->_parse_order_by ($attrs->{order_by}, $sql_maker),
 250       $sql_maker->_recurse_fields ($select),
 251     ],
 252   };
 253
 254   # throw away empty chunks
 255   $_ = [ map { $_ || () } @$_ ] for values %$to_scan;
 256
 257   # first loop through all fully qualified columns and get the corresponding
 258   # alias (should work even if they are in scalarrefs)
 259   for my $alias (keys %$alias_list) {
 260     my $al_re = qr/
 261       \x00 $alias \x00 $sep
 262         |
 263       \b $alias $sep
 264     /x;
 265
 266     # add matching for possible quoted literal sql
 267     $al_re = qr/ $al_re | $orig_lquote $alias $orig_rquote /x
 268       if ($orig_lquote && $orig_rquote);
 269
 270
 271     for my $type (keys %$to_scan) {
 272       for my $piece (@{$to_scan->{$type}}) {
 273         $aliases_by_type->{$type}{$alias} = 1 if ($piece =~ $al_re);
 274       }
 275     }
 276
 277   }
 278
 279   # now loop through unqualified column names, and try to locate them within
 280   # the chunks
 281   for my $col (keys %$colinfo) {
 282     next if $col =~ $sep;   # if column is qualified it was caught by the above
 283
 284     my $col_re = qr/ \x00 $col \x00 /x;
 285
 286     $col_re = qr/ $col_re | $orig_lquote $col $orig_rquote /x
 287       if ($orig_lquote && $orig_rquote);
 288
 289     for my $type (keys %$to_scan) {
 290       for my $piece (@{$to_scan->{$type}}) {
 291         $aliases_by_type->{$type}{$colinfo->{$col}{-source_alias}} = 1 if ($piece =~ $col_re);
 292       }
 293     }
 294   }
 295
 296   # Add any non-left joins to the restriction list (such joins are indeed restrictions)
 297   for my $j (values %$alias_list) {
 298     my $alias = $j->{-alias} or next;
 299     $aliases_by_type->{restricting}{$alias} = 1 if (
 300       (not $j->{-join_type})
 301         or
 302       ($j->{-join_type} !~ /^left (?: \s+ outer)? $/xi)
 303     );
 304   }
 305
 306   # mark all join parents as mentioned
 307   # (e.g.  join => { cds => 'tracks' } - tracks will need to bring cds too )
 308   for my $type (keys %$aliases_by_type) {
 309     for my $alias (keys %{$aliases_by_type->{$type}}) {
 310       $aliases_by_type->{$type}{$_} = 1
 311         for (map { keys %$_ } @{ $alias_list->{$alias}{-join_path} || [] });
 312     }
 313   }
 314
 315   return $aliases_by_type;
 316 }
 317
 318 sub _resolve_ident_sources {
 319   my ($self, $ident) = @_;
 320
 321   my $alias2source = {};
 322   my $rs_alias;
 323
 324   # the reason this is so contrived is that $ident may be a {from}
 325   # structure, specifying multiple tables to join
 326   if ( Scalar::Util::blessed($ident) && $ident->isa("DBIx::Class::ResultSource") ) {
 327     # this is compat mode for insert/update/delete which do not deal with aliases
 328     $alias2source->{me} = $ident;
 329     $rs_alias = 'me';
 330   }
 331   elsif (ref $ident eq 'ARRAY') {
 332
 333     for (@$ident) {
 334       my $tabinfo;
 335       if (ref $_ eq 'HASH') {
 336         $tabinfo = $_;
 337         $rs_alias = $tabinfo->{-alias};
 338       }
 339       if (ref $_ eq 'ARRAY' and ref $_->[0] eq 'HASH') {
 340         $tabinfo = $_->[0];
 341       }
 342
 343       $alias2source->{$tabinfo->{-alias}} = $tabinfo->{-source_handle}->resolve
 344         if ($tabinfo->{-source_handle});
 345     }
 346   }
 347
 348   return ($alias2source, $rs_alias);
 349 }
 350
 351 # Takes $ident, \@column_names
 352 #
 353 # returns { $column_name => \%column_info, ... }
 354 # also note: this adds -result_source => $rsrc to the column info
 355 #
 356 # If no columns_names are supplied returns info about *all* columns
 357 # for all sources
 358 sub _resolve_column_info {
 359   my ($self, $ident, $colnames) = @_;
 360   my ($alias2src, $root_alias) = $self->_resolve_ident_sources($ident);
 361
 362   my $sep = $self->_sql_maker_opts->{name_sep} || '.';
 363   my $qsep = quotemeta $sep;
 364
 365   my (%return, %seen_cols, @auto_colnames);
 366
 367   # compile a global list of column names, to be able to properly
 368   # disambiguate unqualified column names (if at all possible)
 369   for my $alias (keys %$alias2src) {
 370     my $rsrc = $alias2src->{$alias};
 371     for my $colname ($rsrc->columns) {
 372       push @{$seen_cols{$colname}}, $alias;
 373       push @auto_colnames, "$alias$sep$colname" unless $colnames;
 374     }
 375   }
 376
 377   $colnames ||= [
 378     @auto_colnames,
 379     grep { @{$seen_cols{$_}} == 1 } (keys %seen_cols),
 380   ];
 381
 382   COLUMN:
 383   foreach my $col (@$colnames) {
 384     my ($alias, $colname) = $col =~ m/^ (?: ([^$qsep]+) $qsep)? (.+) $/x;
 385
 386     unless ($alias) {
 387       # see if the column was seen exactly once (so we know which rsrc it came from)
 388       if ($seen_cols{$colname} and @{$seen_cols{$colname}} == 1) {
 389         $alias = $seen_cols{$colname}[0];
 390       }
 391       else {
 392         next COLUMN;
 393       }
 394     }
 395
 396     my $rsrc = $alias2src->{$alias};
 397     $return{$col} = $rsrc && {
 398       %{$rsrc->column_info($colname)},
 399       -result_source => $rsrc,
 400       -source_alias => $alias,
 401     };
 402   }
 403
 404   return \%return;
 405 }
 406
 407 # The DBIC relationship chaining implementation is pretty simple - every
 408 # new related_relationship is pushed onto the {from} stack, and the {select}
 409 # window simply slides further in. This means that when we count somewhere
 410 # in the middle, we got to make sure that everything in the join chain is an
 411 # actual inner join, otherwise the count will come back with unpredictable
 412 # results (a resultset may be generated with _some_ rows regardless of if
 413 # the relation which the $rs currently selects has rows or not). E.g.
 414 # $artist_rs->cds->count - normally generates:
 415 # SELECT COUNT( * ) FROM artist me LEFT JOIN cd cds ON cds.artist = me.artistid
 416 # which actually returns the number of artists * (number of cds || 1)
 417 #
 418 # So what we do here is crawl {from}, determine if the current alias is at
 419 # the top of the stack, and if not - make sure the chain is inner-joined down
 420 # to the root.
 421 #
 422 sub _straight_join_to_node {
 423   my ($self, $from, $alias) = @_;
 424
 425   # subqueries and other oddness are naturally not supported
 426   return $from if (
 427     ref $from ne 'ARRAY'
 428       ||
 429     @$from <= 1
 430       ||
 431     ref $from->[0] ne 'HASH'
 432       ||
 433     ! $from->[0]{-alias}
 434       ||
 435     $from->[0]{-alias} eq $alias  # this last bit means $alias is the head of $from - nothing to do
 436   );
 437
 438   # find the current $alias in the $from structure
 439   my $switch_branch;
 440   JOINSCAN:
 441   for my $j (@{$from}[1 .. $#$from]) {
 442     if ($j->[0]{-alias} eq $alias) {
 443       $switch_branch = $j->[0]{-join_path};
 444       last JOINSCAN;
 445     }
 446   }
 447
 448   # something else went quite wrong
 449   return $from unless $switch_branch;
 450
 451   # So it looks like we will have to switch some stuff around.
 452   # local() is useless here as we will be leaving the scope
 453   # anyway, and deep cloning is just too fucking expensive
 454   # So replace the first hashref in the node arrayref manually
 455   my @new_from = ($from->[0]);
 456   my $sw_idx = { map { values %$_ => 1 } @$switch_branch };
 457
 458   for my $j (@{$from}[1 .. $#$from]) {
 459     my $jalias = $j->[0]{-alias};
 460
 461     if ($sw_idx->{$jalias}) {
 462       my %attrs = %{$j->[0]};
 463       delete $attrs{-join_type};
 464       push @new_from, [
 465         \%attrs,
 466         @{$j}[ 1 .. $#$j ],
 467       ];
 468     }
 469     else {
 470       push @new_from, $j;
 471     }
 472   }
 473
 474   return \@new_from;
 475 }
 476
 477 # Most databases do not allow aliasing of tables in UPDATE/DELETE. Thus
 478 # a condition containing 'me' or other table prefixes will not work
 479 # at all. What this code tries to do (badly) is introspect the condition
 480 # and remove all column qualifiers. If it bails out early (returns undef)
 481 # the calling code should try another approach (e.g. a subquery)
 482 sub _strip_cond_qualifiers {
 483   my ($self, $where) = @_;
 484
 485   my $cond = {};
 486
 487   # No-op. No condition, we're updating/deleting everything
 488   return $cond unless $where;
 489
 490   if (ref $where eq 'ARRAY') {
 491     $cond = [
 492       map {
 493         my %hash;
 494         foreach my $key (keys %{$_}) {
 495           $key =~ /([^.]+)$/;
 496           $hash{$1} = $_->{$key};
 497         }
 498         \%hash;
 499       } @$where
 500     ];
 501   }
 502   elsif (ref $where eq 'HASH') {
 503     if ( (keys %$where) == 1 && ( (keys %{$where})[0] eq '-and' )) {
 504       $cond->{-and} = [];
 505       my @cond = @{$where->{-and}};
 506        for (my $i = 0; $i < @cond; $i++) {
 507         my $entry = $cond[$i];
 508         my $hash;
 509         my $ref = ref $entry;
 510         if ($ref eq 'HASH' or $ref eq 'ARRAY') {
 511           $hash = $self->_strip_cond_qualifiers($entry);
 512         }
 513         elsif (! $ref) {
 514           $entry =~ /([^.]+)$/;
 515           $hash->{$1} = $cond[++$i];
 516         }
 517         else {
 518           $self->throw_exception ("_strip_cond_qualifiers() is unable to handle a condition reftype $ref");
 519         }
 520         push @{$cond->{-and}}, $hash;
 521       }
 522     }
 523     else {
 524       foreach my $key (keys %$where) {
 525         $key =~ /([^.]+)$/;
 526         $cond->{$1} = $where->{$key};
 527       }
 528     }
 529   }
 530   else {
 531     return undef;
 532   }
 533
 534   return $cond;
 535 }
 536
 537 sub _parse_order_by {
 538   my ($self, $order_by, $sql_maker) = @_;
 539
 540   my $parser = sub {
 541     my ($sql_maker, $order_by) = @_;
 542
 543     return scalar $sql_maker->_order_by_chunks ($order_by)
 544       unless wantarray;
 545
 546     my @chunks;
 547     for my $chunk (map { ref $_ ? @$_ : $_ } ($sql_maker->_order_by_chunks ($order_by) ) ) {
 548       $chunk =~ s/\s+ (?: ASC|DESC ) \s* $//ix;
 549       push @chunks, $chunk;
 550     }
 551
 552     return @chunks;
 553   };
 554
 555   if ($sql_maker) {
 556     return $parser->($sql_maker, $order_by);
 557   }
 558   else {
 559     $sql_maker = $self->sql_maker;
 560     local $sql_maker->{quote_char};
 561     return $parser->($sql_maker, $order_by);
 562   }
 563 }
 564
 565 1;