lib/DBIx/Class/Storage/DBIHacks.pm

   1 package   #hide from PAUSE
   2   DBIx::Class::Storage::DBIHacks;
   3
   4 #
   5 # This module contains code that should never have seen the light of day,
   6 # does not belong in the Storage, or is otherwise unfit for public
   7 # display. The arrival of SQLA2 should immediately oboslete 90% of this
   8 #
   9
  10 use strict;
  11 use warnings;
  12
  13 use base 'DBIx::Class::Storage';
  14 use mro 'c3';
  15
  16 use Carp::Clan qw/^DBIx::Class/;
  17 use List::Util 'first';
  18 use Scalar::Util 'blessed';
  19 use namespace::clean;
  20
  21 #
  22 # This code will remove non-selecting/non-restricting joins from
  23 # {from} specs, aiding the RDBMS query optimizer
  24 #
  25 sub _prune_unused_joins {
  26   my $self = shift;
  27   my ($from, $select, $where, $attrs) = @_;
  28
  29   return $from unless $self->_use_join_optimizer;
  30
  31   if (ref $from ne 'ARRAY' || ref $from->[0] ne 'HASH' || ref $from->[1] ne 'ARRAY') {
  32     return $from;   # only standard {from} specs are supported
  33   }
  34
  35   my $aliastypes = $self->_resolve_aliastypes_from_select_args(@_);
  36
  37   # a grouped set will not be affected by amount of rows. Thus any
  38   # {multiplying} joins can go
  39   delete $aliastypes->{multiplying} if $attrs->{group_by};
  40
  41   my @newfrom = $from->[0]; # FROM head is always present
  42
  43   my %need_joins = (map { %{$_||{}} } (values %$aliastypes) );
  44   for my $j (@{$from}[1..$#$from]) {
  45     push @newfrom, $j if (
  46       (! $j->[0]{-alias}) # legacy crap
  47         ||
  48       $need_joins{$j->[0]{-alias}}
  49     );
  50   }
  51
  52   return \@newfrom;
  53 }
  54
  55 #
  56 # This is the code producing joined subqueries like:
  57 # SELECT me.*, other.* FROM ( SELECT me.* FROM ... ) JOIN other ON ...
  58 #
  59 sub _adjust_select_args_for_complex_prefetch {
  60   my ($self, $from, $select, $where, $attrs) = @_;
  61
  62   $self->throw_exception ('Nothing to prefetch... how did we get here?!')
  63     if not @{$attrs->{_prefetch_select}};
  64
  65   $self->throw_exception ('Complex prefetches are not supported on resultsets with a custom from attribute')
  66     if (ref $from ne 'ARRAY' || ref $from->[0] ne 'HASH' || ref $from->[1] ne 'ARRAY');
  67
  68
  69   # generate inner/outer attribute lists, remove stuff that doesn't apply
  70   my $outer_attrs = { %$attrs };
  71   delete $outer_attrs->{$_} for qw/where bind rows offset group_by having/;
  72
  73   my $inner_attrs = { %$attrs };
  74   delete $inner_attrs->{$_} for qw/for collapse _prefetch_select _collapse_order_by select as/;
  75
  76
  77   # bring over all non-collapse-induced order_by into the inner query (if any)
  78   # the outer one will have to keep them all
  79   delete $inner_attrs->{order_by};
  80   if (my $ord_cnt = @{$outer_attrs->{order_by}} - @{$outer_attrs->{_collapse_order_by}} ) {
  81     $inner_attrs->{order_by} = [
  82       @{$outer_attrs->{order_by}}[ 0 .. $ord_cnt - 1]
  83     ];
  84   }
  85
  86   # generate the inner/outer select lists
  87   # for inside we consider only stuff *not* brought in by the prefetch
  88   # on the outside we substitute any function for its alias
  89   my $outer_select = [ @$select ];
  90   my $inner_select = [];
  91   for my $i (0 .. ( @$outer_select - @{$outer_attrs->{_prefetch_select}} - 1) ) {
  92     my $sel = $outer_select->[$i];
  93
  94     if (ref $sel eq 'HASH' ) {
  95       $sel->{-as} ||= $attrs->{as}[$i];
  96       $outer_select->[$i] = join ('.', $attrs->{alias}, ($sel->{-as} || "inner_column_$i") );
  97     }
  98
  99     push @$inner_select, $sel;
 100
 101     push @{$inner_attrs->{as}}, $attrs->{as}[$i];
 102   }
 103
 104   # construct the inner $from and lock it in a subquery
 105   # we need to prune first, because this will determine if we need a group_by below
 106   # the fake group_by is so that the pruner throws away all non-selecting, non-restricting
 107   # multijoins (since we def. do not care about those inside the subquery)
 108
 109   my $subq_joinspec = do {
 110
 111     # must use it here regardless of user requests
 112     local $self->{_use_join_optimizer} = 1;
 113
 114     my $inner_from = $self->_prune_unused_joins ($from, $inner_select, $where, {
 115       group_by => ['dummy'], %$inner_attrs,
 116     });
 117
 118     # if a multi-type join was needed in the subquery - add a group_by to simulate the
 119     # collapse in the subq
 120     $inner_attrs->{group_by} ||= $inner_select
 121       if first { ! $_->[0]{-is_single} } (@{$inner_from}[1 .. $#$inner_from]);
 122
 123     # we already optimized $inner_from above
 124     local $self->{_use_join_optimizer} = 0;
 125
 126     # generate the subquery
 127     my $subq = $self->_select_args_to_query (
 128       $inner_from,
 129       $inner_select,
 130       $where,
 131       $inner_attrs,
 132     );
 133
 134     +{
 135       -alias => $attrs->{alias},
 136       -source_handle => $inner_from->[0]{-source_handle},
 137       $attrs->{alias} => $subq,
 138     };
 139   };
 140
 141   # Generate the outer from - this is relatively easy (really just replace
 142   # the join slot with the subquery), with a major caveat - we can not
 143   # join anything that is non-selecting (not part of the prefetch), but at
 144   # the same time is a multi-type relationship, as it will explode the result.
 145   #
 146   # There are two possibilities here
 147   # - either the join is non-restricting, in which case we simply throw it away
 148   # - it is part of the restrictions, in which case we need to collapse the outer
 149   #   result by tackling yet another group_by to the outside of the query
 150
 151   $from = [ @$from ];
 152
 153   # so first generate the outer_from, up to the substitution point
 154   my @outer_from;
 155   while (my $j = shift @$from) {
 156     $j = [ $j ] unless ref $j eq 'ARRAY'; # promote the head-from to an AoH
 157
 158     if ($j->[0]{-alias} eq $attrs->{alias}) { # time to swap
 159       push @outer_from, [
 160         $subq_joinspec,
 161         @{$j}[1 .. $#$j],
 162       ];
 163       last; # we'll take care of what's left in $from below
 164     }
 165     else {
 166       push @outer_from, $j;
 167     }
 168   }
 169
 170   # scan the *remaining* from spec against different attributes, and see which joins are needed
 171   # in what role
 172   my $outer_aliastypes =
 173     $self->_resolve_aliastypes_from_select_args( $from, $outer_select, $where, $outer_attrs );
 174
 175   # see what's left - throw away if not selecting/restricting
 176   # also throw in a group_by if restricting to guard against
 177   # cross-join explosions
 178   #
 179   while (my $j = shift @$from) {
 180     my $alias = $j->[0]{-alias};
 181
 182     if ($outer_aliastypes->{selecting}{$alias}) {
 183       push @outer_from, $j;
 184     }
 185     elsif ($outer_aliastypes->{restricting}{$alias}) {
 186       push @outer_from, $j;
 187       $outer_attrs->{group_by} ||= $outer_select unless $j->[0]{-is_single};
 188     }
 189   }
 190
 191   # demote the outer_from head
 192   $outer_from[0] = $outer_from[0][0];
 193
 194   # This is totally horrific - the $where ends up in both the inner and outer query
 195   # Unfortunately not much can be done until SQLA2 introspection arrives, and even
 196   # then if where conditions apply to the *right* side of the prefetch, you may have
 197   # to both filter the inner select (e.g. to apply a limit) and then have to re-filter
 198   # the outer select to exclude joins you didin't want in the first place
 199   #
 200   # OTOH it can be seen as a plus: <ash> (notes that this query would make a DBA cry ;)
 201   return (\@outer_from, $outer_select, $where, $outer_attrs);
 202 }
 203
 204 #
 205 # I KNOW THIS SUCKS! GET SQLA2 OUT THE DOOR SO THIS CAN DIE!
 206 #
 207 # Due to a lack of SQLA2 we fall back to crude scans of all the
 208 # select/where/order/group attributes, in order to determine what
 209 # aliases are neded to fulfill the query. This information is used
 210 # throughout the code to prune unnecessary JOINs from the queries
 211 # in an attempt to reduce the execution time.
 212 # Although the method is pretty horrific, the worst thing that can
 213 # happen is for it to fail due to some scalar SQL, which in turn will
 214 # result in a vocal exception.
 215 sub _resolve_aliastypes_from_select_args {
 216   my ( $self, $from, $select, $where, $attrs ) = @_;
 217
 218   $self->throw_exception ('Unable to analyze custom {from}')
 219     if ref $from ne 'ARRAY';
 220
 221   # what we will return
 222   my $aliases_by_type;
 223
 224   # see what aliases are there to work with
 225   my $alias_list;
 226   for (@$from) {
 227     my $j = $_;
 228     $j = $j->[0] if ref $j eq 'ARRAY';
 229     my $al = $j->{-alias}
 230       or next;
 231
 232     $alias_list->{$al} = $j;
 233     $aliases_by_type->{multiplying}{$al} = 1
 234       if ref($_) eq 'ARRAY' and ! $j->{-is_single}; # not array == {from} head == can't be multiplying
 235   }
 236
 237   # get a column to source/alias map (including unqualified ones)
 238   my $colinfo = $self->_resolve_column_info ($from);
 239
 240   # set up a botched SQLA
 241   my $sql_maker = $self->sql_maker;
 242
 243   local $sql_maker->{having_bind};  # these are throw away results
 244
 245   # we can't scan properly without any quoting (\b doesn't cut it
 246   # everywhere), so unless there is proper quoting set - use our
 247   # own weird impossible character.
 248   # Also in the case of no quoting, we need to explicitly disable
 249   # name_sep, otherwise sorry nasty legacy syntax like
 250   # { 'count(foo.id)' => { '>' => 3 } } will stop working >:(
 251   local $sql_maker->{quote_char} = $sql_maker->{quote_char};
 252   local $sql_maker->{name_sep} = $sql_maker->{name_sep};
 253
 254   unless (defined $sql_maker->{quote_char} and length $sql_maker->{quote_char}) {
 255     $sql_maker->{quote_char} = "\x00";
 256     $sql_maker->{name_sep} = '';
 257   }
 258
 259   my ($lquote, $rquote, $sep) = map { quotemeta $_ } ($sql_maker->_quote_chars, $sql_maker->name_sep);
 260
 261   # generate sql chunks
 262   my $to_scan = {
 263     restricting => [
 264       $sql_maker->_recurse_where ($where),
 265       $sql_maker->_parse_rs_attrs ({
 266         map { $_ => $attrs->{$_} } (qw/group_by having/)
 267       }),
 268     ],
 269     selecting => [
 270       $self->_extract_order_columns ($attrs->{order_by}, $sql_maker),
 271       $sql_maker->_recurse_fields ($select),
 272     ],
 273   };
 274
 275   # throw away empty chunks
 276   $_ = [ map { $_ || () } @$_ ] for values %$to_scan;
 277
 278   # first loop through all fully qualified columns and get the corresponding
 279   # alias (should work even if they are in scalarrefs)
 280   for my $alias (keys %$alias_list) {
 281     my $al_re = qr/
 282       $lquote $alias $rquote $sep
 283         |
 284       \b $alias \.
 285     /x;
 286
 287     for my $type (keys %$to_scan) {
 288       for my $piece (@{$to_scan->{$type}}) {
 289         $aliases_by_type->{$type}{$alias} = 1 if ($piece =~ $al_re);
 290       }
 291     }
 292   }
 293
 294   # now loop through unqualified column names, and try to locate them within
 295   # the chunks
 296   for my $col (keys %$colinfo) {
 297     next if $col =~ / \. /x;   # if column is qualified it was caught by the above
 298
 299     my $col_re = qr/ $lquote $col $rquote /x;
 300
 301     for my $type (keys %$to_scan) {
 302       for my $piece (@{$to_scan->{$type}}) {
 303         $aliases_by_type->{$type}{$colinfo->{$col}{-source_alias}} = 1 if ($piece =~ $col_re);
 304       }
 305     }
 306   }
 307
 308   # Add any non-left joins to the restriction list (such joins are indeed restrictions)
 309   for my $j (values %$alias_list) {
 310     my $alias = $j->{-alias} or next;
 311     $aliases_by_type->{restricting}{$alias} = 1 if (
 312       (not $j->{-join_type})
 313         or
 314       ($j->{-join_type} !~ /^left (?: \s+ outer)? $/xi)
 315     );
 316   }
 317
 318   # mark all restricting/selecting join parents as such
 319   # (e.g.  join => { cds => 'tracks' } - tracks will need to bring cds too )
 320   for my $type (qw/restricting selecting/) {
 321     for my $alias (keys %{$aliases_by_type->{$type}||{}}) {
 322       $aliases_by_type->{$type}{$_} = 1
 323         for (map { values %$_ } @{ $alias_list->{$alias}{-join_path} || [] });
 324     }
 325   }
 326
 327   return $aliases_by_type;
 328 }
 329
 330 sub _resolve_ident_sources {
 331   my ($self, $ident) = @_;
 332
 333   my $alias2source = {};
 334   my $rs_alias;
 335
 336   # the reason this is so contrived is that $ident may be a {from}
 337   # structure, specifying multiple tables to join
 338   if ( blessed $ident && $ident->isa("DBIx::Class::ResultSource") ) {
 339     # this is compat mode for insert/update/delete which do not deal with aliases
 340     $alias2source->{me} = $ident;
 341     $rs_alias = 'me';
 342   }
 343   elsif (ref $ident eq 'ARRAY') {
 344
 345     for (@$ident) {
 346       my $tabinfo;
 347       if (ref $_ eq 'HASH') {
 348         $tabinfo = $_;
 349         $rs_alias = $tabinfo->{-alias};
 350       }
 351       if (ref $_ eq 'ARRAY' and ref $_->[0] eq 'HASH') {
 352         $tabinfo = $_->[0];
 353       }
 354
 355       $alias2source->{$tabinfo->{-alias}} = $tabinfo->{-source_handle}->resolve
 356         if ($tabinfo->{-source_handle});
 357     }
 358   }
 359
 360   return ($alias2source, $rs_alias);
 361 }
 362
 363 # Takes $ident, \@column_names
 364 #
 365 # returns { $column_name => \%column_info, ... }
 366 # also note: this adds -result_source => $rsrc to the column info
 367 #
 368 # If no columns_names are supplied returns info about *all* columns
 369 # for all sources
 370 sub _resolve_column_info {
 371   my ($self, $ident, $colnames) = @_;
 372   my ($alias2src, $root_alias) = $self->_resolve_ident_sources($ident);
 373
 374   my (%return, %seen_cols, @auto_colnames);
 375
 376   # compile a global list of column names, to be able to properly
 377   # disambiguate unqualified column names (if at all possible)
 378   for my $alias (keys %$alias2src) {
 379     my $rsrc = $alias2src->{$alias};
 380     for my $colname ($rsrc->columns) {
 381       push @{$seen_cols{$colname}}, $alias;
 382       push @auto_colnames, "$alias.$colname" unless $colnames;
 383     }
 384   }
 385
 386   $colnames ||= [
 387     @auto_colnames,
 388     grep { @{$seen_cols{$_}} == 1 } (keys %seen_cols),
 389   ];
 390
 391   COLUMN:
 392   foreach my $col (@$colnames) {
 393     my ($alias, $colname) = $col =~ m/^ (?: ([^\.]+) \. )? (.+) $/x;
 394
 395     unless ($alias) {
 396       # see if the column was seen exactly once (so we know which rsrc it came from)
 397       if ($seen_cols{$colname} and @{$seen_cols{$colname}} == 1) {
 398         $alias = $seen_cols{$colname}[0];
 399       }
 400       else {
 401         next COLUMN;
 402       }
 403     }
 404
 405     my $rsrc = $alias2src->{$alias};
 406     $return{$col} = $rsrc && {
 407       %{$rsrc->column_info($colname)},
 408       -result_source => $rsrc,
 409       -source_alias => $alias,
 410     };
 411   }
 412
 413   return \%return;
 414 }
 415
 416 # The DBIC relationship chaining implementation is pretty simple - every
 417 # new related_relationship is pushed onto the {from} stack, and the {select}
 418 # window simply slides further in. This means that when we count somewhere
 419 # in the middle, we got to make sure that everything in the join chain is an
 420 # actual inner join, otherwise the count will come back with unpredictable
 421 # results (a resultset may be generated with _some_ rows regardless of if
 422 # the relation which the $rs currently selects has rows or not). E.g.
 423 # $artist_rs->cds->count - normally generates:
 424 # SELECT COUNT( * ) FROM artist me LEFT JOIN cd cds ON cds.artist = me.artistid
 425 # which actually returns the number of artists * (number of cds || 1)
 426 #
 427 # So what we do here is crawl {from}, determine if the current alias is at
 428 # the top of the stack, and if not - make sure the chain is inner-joined down
 429 # to the root.
 430 #
 431 sub _inner_join_to_node {
 432   my ($self, $from, $alias) = @_;
 433
 434   # subqueries and other oddness are naturally not supported
 435   return $from if (
 436     ref $from ne 'ARRAY'
 437       ||
 438     @$from <= 1
 439       ||
 440     ref $from->[0] ne 'HASH'
 441       ||
 442     ! $from->[0]{-alias}
 443       ||
 444     $from->[0]{-alias} eq $alias  # this last bit means $alias is the head of $from - nothing to do
 445   );
 446
 447   # find the current $alias in the $from structure
 448   my $switch_branch;
 449   JOINSCAN:
 450   for my $j (@{$from}[1 .. $#$from]) {
 451     if ($j->[0]{-alias} eq $alias) {
 452       $switch_branch = $j->[0]{-join_path};
 453       last JOINSCAN;
 454     }
 455   }
 456
 457   # something else went quite wrong
 458   return $from unless $switch_branch;
 459
 460   # So it looks like we will have to switch some stuff around.
 461   # local() is useless here as we will be leaving the scope
 462   # anyway, and deep cloning is just too fucking expensive
 463   # So replace the first hashref in the node arrayref manually
 464   my @new_from = ($from->[0]);
 465   my $sw_idx = { map { (values %$_), 1 } @$switch_branch }; #there's one k/v per join-path
 466
 467   for my $j (@{$from}[1 .. $#$from]) {
 468     my $jalias = $j->[0]{-alias};
 469
 470     if ($sw_idx->{$jalias}) {
 471       my %attrs = %{$j->[0]};
 472       delete $attrs{-join_type};
 473       push @new_from, [
 474         \%attrs,
 475         @{$j}[ 1 .. $#$j ],
 476       ];
 477     }
 478     else {
 479       push @new_from, $j;
 480     }
 481   }
 482
 483   return \@new_from;
 484 }
 485
 486 # Most databases do not allow aliasing of tables in UPDATE/DELETE. Thus
 487 # a condition containing 'me' or other table prefixes will not work
 488 # at all. What this code tries to do (badly) is introspect the condition
 489 # and remove all column qualifiers. If it bails out early (returns undef)
 490 # the calling code should try another approach (e.g. a subquery)
 491 sub _strip_cond_qualifiers {
 492   my ($self, $where) = @_;
 493
 494   my $cond = {};
 495
 496   # No-op. No condition, we're updating/deleting everything
 497   return $cond unless $where;
 498
 499   if (ref $where eq 'ARRAY') {
 500     $cond = [
 501       map {
 502         my %hash;
 503         foreach my $key (keys %{$_}) {
 504           $key =~ /([^.]+)$/;
 505           $hash{$1} = $_->{$key};
 506         }
 507         \%hash;
 508       } @$where
 509     ];
 510   }
 511   elsif (ref $where eq 'HASH') {
 512     if ( (keys %$where) == 1 && ( (keys %{$where})[0] eq '-and' )) {
 513       $cond->{-and} = [];
 514       my @cond = @{$where->{-and}};
 515        for (my $i = 0; $i < @cond; $i++) {
 516         my $entry = $cond[$i];
 517         my $hash;
 518         my $ref = ref $entry;
 519         if ($ref eq 'HASH' or $ref eq 'ARRAY') {
 520           $hash = $self->_strip_cond_qualifiers($entry);
 521         }
 522         elsif (! $ref) {
 523           $entry =~ /([^.]+)$/;
 524           $hash->{$1} = $cond[++$i];
 525         }
 526         else {
 527           $self->throw_exception ("_strip_cond_qualifiers() is unable to handle a condition reftype $ref");
 528         }
 529         push @{$cond->{-and}}, $hash;
 530       }
 531     }
 532     else {
 533       foreach my $key (keys %$where) {
 534         if ($key eq '-or' && ref $where->{$key} eq 'ARRAY') {
 535           $cond->{$key} = $self->_strip_cond_qualifiers($where->{$key});
 536         }
 537         else {
 538           $key =~ /([^.]+)$/;
 539           $cond->{$1} = $where->{$key};
 540         }
 541       }
 542     }
 543   }
 544   else {
 545     return undef;
 546   }
 547
 548   return $cond;
 549 }
 550
 551 sub _extract_order_columns {
 552   my ($self, $order_by, $sql_maker) = @_;
 553
 554   my $parser = sub {
 555     my ($sql_maker, $order_by) = @_;
 556
 557     return scalar $sql_maker->_order_by_chunks ($order_by)
 558       unless wantarray;
 559
 560     my @chunks;
 561     for my $chunk (map { ref $_ ? @$_ : $_ } ($sql_maker->_order_by_chunks ($order_by) ) ) {
 562       $chunk =~ s/\s+ (?: ASC|DESC ) \s* $//ix;
 563       push @chunks, $chunk;
 564     }
 565
 566     return @chunks;
 567   };
 568
 569   if ($sql_maker) {
 570     return $parser->($sql_maker, $order_by);
 571   }
 572   else {
 573     $sql_maker = $self->sql_maker;
 574     local $sql_maker->{quote_char};
 575     return $parser->($sql_maker, $order_by);
 576   }
 577 }
 578
 579 1;