lib/DBIx/Class/Storage/DBIHacks.pm

   1 package   #hide from PAUSE
   2   DBIx::Class::Storage::DBIHacks;
   3
   4 #
   5 # This module contains code that should never have seen the light of day,
   6 # does not belong in the Storage, or is otherwise unfit for public
   7 # display. The arrival of SQLA2 should immediately oboslete 90% of this
   8 #
   9
  10 use strict;
  11 use warnings;
  12
  13 use base 'DBIx::Class::Storage';
  14 use mro 'c3';
  15
  16 use Carp::Clan qw/^DBIx::Class/;
  17 use List::Util 'first';
  18 use Scalar::Util 'blessed';
  19 use namespace::clean;
  20
  21 #
  22 # This code will remove non-selecting/non-restricting joins from
  23 # {from} specs, aiding the RDBMS query optimizer
  24 #
  25 sub _prune_unused_joins {
  26   my ($self) = shift;
  27
  28   my ($from, $select, $where, $attrs) = @_;
  29
  30   if (ref $from ne 'ARRAY' || ref $from->[0] ne 'HASH' || ref $from->[1] ne 'ARRAY') {
  31     return $from;   # only standard {from} specs are supported
  32   }
  33
  34   my $aliastypes = $self->_resolve_aliastypes_from_select_args(@_);
  35
  36   # a grouped set will not be affected by amount of rows. Thus any
  37   # {multiplying} joins can go
  38   delete $aliastypes->{multiplying} if $attrs->{group_by};
  39
  40
  41   my @newfrom = $from->[0]; # FROM head is always present
  42
  43   my %need_joins = (map { %{$_||{}} } (values %$aliastypes) );
  44   for my $j (@{$from}[1..$#$from]) {
  45     push @newfrom, $j if (
  46       (! $j->[0]{-alias}) # legacy crap
  47         ||
  48       $need_joins{$j->[0]{-alias}}
  49     );
  50   }
  51
  52   return \@newfrom;
  53 }
  54
  55 #
  56 # This is the code producing joined subqueries like:
  57 # SELECT me.*, other.* FROM ( SELECT me.* FROM ... ) JOIN other ON ...
  58 #
  59 sub _adjust_select_args_for_complex_prefetch {
  60   my ($self, $from, $select, $where, $attrs) = @_;
  61
  62   $self->throw_exception ('Nothing to prefetch... how did we get here?!')
  63     if not @{$attrs->{_prefetch_select}};
  64
  65   $self->throw_exception ('Complex prefetches are not supported on resultsets with a custom from attribute')
  66     if (ref $from ne 'ARRAY' || ref $from->[0] ne 'HASH' || ref $from->[1] ne 'ARRAY');
  67
  68
  69   # generate inner/outer attribute lists, remove stuff that doesn't apply
  70   my $outer_attrs = { %$attrs };
  71   delete $outer_attrs->{$_} for qw/where bind rows offset group_by having/;
  72
  73   my $inner_attrs = { %$attrs };
  74   delete $inner_attrs->{$_} for qw/for collapse _prefetch_select _collapse_order_by select as/;
  75
  76
  77   # bring over all non-collapse-induced order_by into the inner query (if any)
  78   # the outer one will have to keep them all
  79   delete $inner_attrs->{order_by};
  80   if (my $ord_cnt = @{$outer_attrs->{order_by}} - @{$outer_attrs->{_collapse_order_by}} ) {
  81     $inner_attrs->{order_by} = [
  82       @{$outer_attrs->{order_by}}[ 0 .. $ord_cnt - 1]
  83     ];
  84   }
  85
  86   # generate the inner/outer select lists
  87   # for inside we consider only stuff *not* brought in by the prefetch
  88   # on the outside we substitute any function for its alias
  89   my $outer_select = [ @$select ];
  90   my $inner_select = [];
  91   for my $i (0 .. ( @$outer_select - @{$outer_attrs->{_prefetch_select}} - 1) ) {
  92     my $sel = $outer_select->[$i];
  93
  94     if (ref $sel eq 'HASH' ) {
  95       $sel->{-as} ||= $attrs->{as}[$i];
  96       $outer_select->[$i] = join ('.', $attrs->{alias}, ($sel->{-as} || "inner_column_$i") );
  97     }
  98
  99     push @$inner_select, $sel;
 100
 101     push @{$inner_attrs->{as}}, $attrs->{as}[$i];
 102   }
 103
 104   # construct the inner $from for the subquery
 105   # we need to prune first, because this will determine if we need a group_by below
 106   my $inner_from = $self->_prune_unused_joins ($from, $inner_select, $where, $inner_attrs);
 107
 108   # if a multi-type join was needed in the subquery - add a group_by to simulate the
 109   # collapse in the subq
 110   $inner_attrs->{group_by} ||= $inner_select
 111     if first { ! $_->[0]{-is_single} } (@{$inner_from}[1 .. $#$inner_from]);
 112
 113   # generate the subquery
 114   my $subq = $self->_select_args_to_query (
 115     $inner_from,
 116     $inner_select,
 117     $where,
 118     $inner_attrs,
 119   );
 120
 121   my $subq_joinspec = {
 122     -alias => $attrs->{alias},
 123     -source_handle => $inner_from->[0]{-source_handle},
 124     $attrs->{alias} => $subq,
 125   };
 126
 127   # Generate the outer from - this is relatively easy (really just replace
 128   # the join slot with the subquery), with a major caveat - we can not
 129   # join anything that is non-selecting (not part of the prefetch), but at
 130   # the same time is a multi-type relationship, as it will explode the result.
 131   #
 132   # There are two possibilities here
 133   # - either the join is non-restricting, in which case we simply throw it away
 134   # - it is part of the restrictions, in which case we need to collapse the outer
 135   #   result by tackling yet another group_by to the outside of the query
 136
 137   # normalize a copy of $from, so it will be easier to work with further
 138   # down (i.e. promote the initial hashref to an AoH)
 139   $from = [ @$from ];
 140   $from->[0] = [ $from->[0] ];
 141
 142   # so first generate the outer_from, up to the substitution point
 143   my @outer_from;
 144   while (my $j = shift @$from) {
 145     if ($j->[0]{-alias} eq $attrs->{alias}) { # time to swap
 146       push @outer_from, [
 147         $subq_joinspec,
 148         @{$j}[1 .. $#$j],
 149       ];
 150       last; # we'll take care of what's left in $from below
 151     }
 152     else {
 153       push @outer_from, $j;
 154     }
 155   }
 156
 157   # scan the from spec against different attributes, and see which joins are needed
 158   # in what role
 159   my $outer_aliastypes =
 160     $self->_resolve_aliastypes_from_select_args( $from, $outer_select, $where, $outer_attrs );
 161
 162   # see what's left - throw away if not selecting/restricting
 163   # also throw in a group_by if restricting to guard against
 164   # cross-join explosions
 165   #
 166   while (my $j = shift @$from) {
 167     my $alias = $j->[0]{-alias};
 168
 169     if ($outer_aliastypes->{selecting}{$alias}) {
 170       push @outer_from, $j;
 171     }
 172     elsif ($outer_aliastypes->{restricting}{$alias}) {
 173       push @outer_from, $j;
 174       $outer_attrs->{group_by} ||= $outer_select unless $j->[0]{-is_single};
 175     }
 176   }
 177
 178   # demote the outer_from head
 179   $outer_from[0] = $outer_from[0][0];
 180
 181   # This is totally horrific - the $where ends up in both the inner and outer query
 182   # Unfortunately not much can be done until SQLA2 introspection arrives, and even
 183   # then if where conditions apply to the *right* side of the prefetch, you may have
 184   # to both filter the inner select (e.g. to apply a limit) and then have to re-filter
 185   # the outer select to exclude joins you didin't want in the first place
 186   #
 187   # OTOH it can be seen as a plus: <ash> (notes that this query would make a DBA cry ;)
 188   return (\@outer_from, $outer_select, $where, $outer_attrs);
 189 }
 190
 191 #
 192 # I KNOW THIS SUCKS! GET SQLA2 OUT THE DOOR SO THIS CAN DIE!
 193 #
 194 # Due to a lack of SQLA2 we fall back to crude scans of all the
 195 # select/where/order/group attributes, in order to determine what
 196 # aliases are neded to fulfill the query. This information is used
 197 # throughout the code to prune unnecessary JOINs from the queries
 198 # in an attempt to reduce the execution time.
 199 # Although the method is pretty horrific, the worst thing that can
 200 # happen is for it to fail due to some scalar SQL, which in turn will
 201 # result in a vocal exception.
 202 sub _resolve_aliastypes_from_select_args {
 203   my ( $self, $from, $select, $where, $attrs ) = @_;
 204
 205   $self->throw_exception ('Unable to analyze custom {from}')
 206     if ref $from ne 'ARRAY';
 207
 208   # what we will return
 209   my $aliases_by_type;
 210
 211   # see what aliases are there to work with
 212   my $alias_list;
 213   for (@$from) {
 214     my $j = $_;
 215     $j = $j->[0] if ref $j eq 'ARRAY';
 216     my $al = $j->{-alias}
 217       or next;
 218
 219     $alias_list->{$al} = $j;
 220     $aliases_by_type->{multiplying}{$al} = 1
 221       unless $j->{-is_single};
 222   }
 223
 224   # get a column to source/alias map (including unqualified ones)
 225   my $colinfo = $self->_resolve_column_info ($from);
 226
 227   # set up a botched SQLA
 228   my $sql_maker = $self->sql_maker;
 229
 230   local $sql_maker->{having_bind};  # these are throw away results
 231
 232   # we can't scan properly without any quoting (\b doesn't cut it
 233   # everywhere), so unless there is proper quoting set - use our
 234   # own weird impossible character.
 235   # Also in the case of no quoting, we need to explicitly disable
 236   # name_sep, otherwise sorry nasty legacy syntax like
 237   # { 'count(foo.id)' => { '>' => 3 } } will stop working >:(
 238   local $sql_maker->{quote_char} = $sql_maker->{quote_char};
 239   local $sql_maker->{name_sep} = $sql_maker->{name_sep};
 240
 241   unless (defined $sql_maker->{quote_char} and length $sql_maker->{quote_char}) {
 242     $sql_maker->{quote_char} = "\x00";
 243     $sql_maker->{name_sep} = '';
 244   }
 245
 246   my ($lquote, $rquote, $sep) = map { quotemeta $_ } ($sql_maker->_quote_chars, $sql_maker->name_sep);
 247
 248
 249   # generate sql chunks
 250   my $to_scan = {
 251     restricting => [
 252       $sql_maker->_recurse_where ($where),
 253       $sql_maker->_parse_rs_attrs ({
 254         map { $_ => $attrs->{$_} } (qw/group_by having/)
 255       }),
 256     ],
 257     selecting => [
 258       $self->_extract_order_columns ($attrs->{order_by}, $sql_maker),
 259       $sql_maker->_recurse_fields ($select),
 260     ],
 261   };
 262
 263   # throw away empty chunks
 264   $_ = [ map { $_ || () } @$_ ] for values %$to_scan;
 265
 266   # first loop through all fully qualified columns and get the corresponding
 267   # alias (should work even if they are in scalarrefs)
 268   for my $alias (keys %$alias_list) {
 269     my $al_re = qr/
 270       $lquote $alias $rquote $sep
 271         |
 272       \b $alias \.
 273     /x;
 274
 275     for my $type (keys %$to_scan) {
 276       for my $piece (@{$to_scan->{$type}}) {
 277         $aliases_by_type->{$type}{$alias} = 1 if ($piece =~ $al_re);
 278       }
 279     }
 280   }
 281
 282   # now loop through unqualified column names, and try to locate them within
 283   # the chunks
 284   for my $col (keys %$colinfo) {
 285     next if $col =~ / \. /x;   # if column is qualified it was caught by the above
 286
 287     my $col_re = qr/ $lquote $col $rquote /x;
 288
 289     for my $type (keys %$to_scan) {
 290       for my $piece (@{$to_scan->{$type}}) {
 291         $aliases_by_type->{$type}{$colinfo->{$col}{-source_alias}} = 1 if ($piece =~ $col_re);
 292       }
 293     }
 294   }
 295
 296   # Add any non-left joins to the restriction list (such joins are indeed restrictions)
 297   for my $j (values %$alias_list) {
 298     my $alias = $j->{-alias} or next;
 299     $aliases_by_type->{restricting}{$alias} = 1 if (
 300       (not $j->{-join_type})
 301         or
 302       ($j->{-join_type} !~ /^left (?: \s+ outer)? $/xi)
 303     );
 304   }
 305
 306   # mark all join parents as mentioned
 307   # (e.g.  join => { cds => 'tracks' } - tracks will need to bring cds too )
 308   for my $type (keys %$aliases_by_type) {
 309     for my $alias (keys %{$aliases_by_type->{$type}}) {
 310       $aliases_by_type->{$type}{$_} = 1
 311         for (map { values %$_ } @{ $alias_list->{$alias}{-join_path} || [] });
 312     }
 313   }
 314
 315   return $aliases_by_type;
 316 }
 317
 318 sub _resolve_ident_sources {
 319   my ($self, $ident) = @_;
 320
 321   my $alias2source = {};
 322   my $rs_alias;
 323
 324   # the reason this is so contrived is that $ident may be a {from}
 325   # structure, specifying multiple tables to join
 326   if ( blessed $ident && $ident->isa("DBIx::Class::ResultSource") ) {
 327     # this is compat mode for insert/update/delete which do not deal with aliases
 328     $alias2source->{me} = $ident;
 329     $rs_alias = 'me';
 330   }
 331   elsif (ref $ident eq 'ARRAY') {
 332
 333     for (@$ident) {
 334       my $tabinfo;
 335       if (ref $_ eq 'HASH') {
 336         $tabinfo = $_;
 337         $rs_alias = $tabinfo->{-alias};
 338       }
 339       if (ref $_ eq 'ARRAY' and ref $_->[0] eq 'HASH') {
 340         $tabinfo = $_->[0];
 341       }
 342
 343       $alias2source->{$tabinfo->{-alias}} = $tabinfo->{-source_handle}->resolve
 344         if ($tabinfo->{-source_handle});
 345     }
 346   }
 347
 348   return ($alias2source, $rs_alias);
 349 }
 350
 351 # Takes $ident, \@column_names
 352 #
 353 # returns { $column_name => \%column_info, ... }
 354 # also note: this adds -result_source => $rsrc to the column info
 355 #
 356 # If no columns_names are supplied returns info about *all* columns
 357 # for all sources
 358 sub _resolve_column_info {
 359   my ($self, $ident, $colnames) = @_;
 360   my ($alias2src, $root_alias) = $self->_resolve_ident_sources($ident);
 361
 362   my (%return, %seen_cols, @auto_colnames);
 363
 364   # compile a global list of column names, to be able to properly
 365   # disambiguate unqualified column names (if at all possible)
 366   for my $alias (keys %$alias2src) {
 367     my $rsrc = $alias2src->{$alias};
 368     for my $colname ($rsrc->columns) {
 369       push @{$seen_cols{$colname}}, $alias;
 370       push @auto_colnames, "$alias.$colname" unless $colnames;
 371     }
 372   }
 373
 374   $colnames ||= [
 375     @auto_colnames,
 376     grep { @{$seen_cols{$_}} == 1 } (keys %seen_cols),
 377   ];
 378
 379   COLUMN:
 380   foreach my $col (@$colnames) {
 381     my ($alias, $colname) = $col =~ m/^ (?: ([^\.]+) \. )? (.+) $/x;
 382
 383     unless ($alias) {
 384       # see if the column was seen exactly once (so we know which rsrc it came from)
 385       if ($seen_cols{$colname} and @{$seen_cols{$colname}} == 1) {
 386         $alias = $seen_cols{$colname}[0];
 387       }
 388       else {
 389         next COLUMN;
 390       }
 391     }
 392
 393     my $rsrc = $alias2src->{$alias};
 394     $return{$col} = $rsrc && {
 395       %{$rsrc->column_info($colname)},
 396       -result_source => $rsrc,
 397       -source_alias => $alias,
 398     };
 399   }
 400
 401   return \%return;
 402 }
 403
 404 # The DBIC relationship chaining implementation is pretty simple - every
 405 # new related_relationship is pushed onto the {from} stack, and the {select}
 406 # window simply slides further in. This means that when we count somewhere
 407 # in the middle, we got to make sure that everything in the join chain is an
 408 # actual inner join, otherwise the count will come back with unpredictable
 409 # results (a resultset may be generated with _some_ rows regardless of if
 410 # the relation which the $rs currently selects has rows or not). E.g.
 411 # $artist_rs->cds->count - normally generates:
 412 # SELECT COUNT( * ) FROM artist me LEFT JOIN cd cds ON cds.artist = me.artistid
 413 # which actually returns the number of artists * (number of cds || 1)
 414 #
 415 # So what we do here is crawl {from}, determine if the current alias is at
 416 # the top of the stack, and if not - make sure the chain is inner-joined down
 417 # to the root.
 418 #
 419 sub _inner_join_to_node {
 420   my ($self, $from, $alias) = @_;
 421
 422   # subqueries and other oddness are naturally not supported
 423   return $from if (
 424     ref $from ne 'ARRAY'
 425       ||
 426     @$from <= 1
 427       ||
 428     ref $from->[0] ne 'HASH'
 429       ||
 430     ! $from->[0]{-alias}
 431       ||
 432     $from->[0]{-alias} eq $alias  # this last bit means $alias is the head of $from - nothing to do
 433   );
 434
 435   # find the current $alias in the $from structure
 436   my $switch_branch;
 437   JOINSCAN:
 438   for my $j (@{$from}[1 .. $#$from]) {
 439     if ($j->[0]{-alias} eq $alias) {
 440       $switch_branch = $j->[0]{-join_path};
 441       last JOINSCAN;
 442     }
 443   }
 444
 445   # something else went quite wrong
 446   return $from unless $switch_branch;
 447
 448   # So it looks like we will have to switch some stuff around.
 449   # local() is useless here as we will be leaving the scope
 450   # anyway, and deep cloning is just too fucking expensive
 451   # So replace the first hashref in the node arrayref manually
 452   my @new_from = ($from->[0]);
 453   my $sw_idx = { map { (values %$_), 1 } @$switch_branch }; #there's one k/v per join-path
 454
 455   for my $j (@{$from}[1 .. $#$from]) {
 456     my $jalias = $j->[0]{-alias};
 457
 458     if ($sw_idx->{$jalias}) {
 459       my %attrs = %{$j->[0]};
 460       delete $attrs{-join_type};
 461       push @new_from, [
 462         \%attrs,
 463         @{$j}[ 1 .. $#$j ],
 464       ];
 465     }
 466     else {
 467       push @new_from, $j;
 468     }
 469   }
 470
 471   return \@new_from;
 472 }
 473
 474 # Most databases do not allow aliasing of tables in UPDATE/DELETE. Thus
 475 # a condition containing 'me' or other table prefixes will not work
 476 # at all. What this code tries to do (badly) is introspect the condition
 477 # and remove all column qualifiers. If it bails out early (returns undef)
 478 # the calling code should try another approach (e.g. a subquery)
 479 sub _strip_cond_qualifiers {
 480   my ($self, $where) = @_;
 481
 482   my $cond = {};
 483
 484   # No-op. No condition, we're updating/deleting everything
 485   return $cond unless $where;
 486
 487   if (ref $where eq 'ARRAY') {
 488     $cond = [
 489       map {
 490         my %hash;
 491         foreach my $key (keys %{$_}) {
 492           $key =~ /([^.]+)$/;
 493           $hash{$1} = $_->{$key};
 494         }
 495         \%hash;
 496       } @$where
 497     ];
 498   }
 499   elsif (ref $where eq 'HASH') {
 500     if ( (keys %$where) == 1 && ( (keys %{$where})[0] eq '-and' )) {
 501       $cond->{-and} = [];
 502       my @cond = @{$where->{-and}};
 503        for (my $i = 0; $i < @cond; $i++) {
 504         my $entry = $cond[$i];
 505         my $hash;
 506         my $ref = ref $entry;
 507         if ($ref eq 'HASH' or $ref eq 'ARRAY') {
 508           $hash = $self->_strip_cond_qualifiers($entry);
 509         }
 510         elsif (! $ref) {
 511           $entry =~ /([^.]+)$/;
 512           $hash->{$1} = $cond[++$i];
 513         }
 514         else {
 515           $self->throw_exception ("_strip_cond_qualifiers() is unable to handle a condition reftype $ref");
 516         }
 517         push @{$cond->{-and}}, $hash;
 518       }
 519     }
 520     else {
 521       foreach my $key (keys %$where) {
 522         $key =~ /([^.]+)$/;
 523         $cond->{$1} = $where->{$key};
 524       }
 525     }
 526   }
 527   else {
 528     return undef;
 529   }
 530
 531   return $cond;
 532 }
 533
 534 sub _extract_order_columns {
 535   my ($self, $order_by, $sql_maker) = @_;
 536
 537   my $parser = sub {
 538     my ($sql_maker, $order_by) = @_;
 539
 540     return scalar $sql_maker->_order_by_chunks ($order_by)
 541       unless wantarray;
 542
 543     my @chunks;
 544     for my $chunk (map { ref $_ ? @$_ : $_ } ($sql_maker->_order_by_chunks ($order_by) ) ) {
 545       $chunk =~ s/\s+ (?: ASC|DESC ) \s* $//ix;
 546       push @chunks, $chunk;
 547     }
 548
 549     return @chunks;
 550   };
 551
 552   if ($sql_maker) {
 553     return $parser->($sql_maker, $order_by);
 554   }
 555   else {
 556     $sql_maker = $self->sql_maker;
 557     local $sql_maker->{quote_char};
 558     return $parser->($sql_maker, $order_by);
 559   }
 560 }
 561
 562 1;