lib/DBIx/Class/Storage/DBI/mysql.pm

   1 package DBIx::Class::Storage::DBI::mysql;
   2
   3 use strict;
   4 use warnings;
   5
   6 use base qw/
   7   DBIx::Class::Storage::DBI::MultiColumnIn
   8   DBIx::Class::Storage::DBI::AmbiguousGlob
   9   DBIx::Class::Storage::DBI
  10 /;
  11 use mro 'c3';
  12
  13 __PACKAGE__->sql_maker_class('DBIx::Class::SQLAHacks::MySQL');
  14
  15 sub with_deferred_fk_checks {
  16   my ($self, $sub) = @_;
  17
  18   $self->_do_query('SET FOREIGN_KEY_CHECKS = 0');
  19   $sub->();
  20   $self->_do_query('SET FOREIGN_KEY_CHECKS = 1');
  21 }
  22
  23 sub connect_call_set_strict_mode {
  24   my $self = shift;
  25
  26   # the @@sql_mode puts back what was previously set on the session handle
  27   $self->_do_query(q|SET SQL_MODE = CONCAT('ANSI,TRADITIONAL,ONLY_FULL_GROUP_BY,', @@sql_mode)|);
  28   $self->_do_query(q|SET SQL_AUTO_IS_NULL = 0|);
  29 }
  30
  31 sub _dbh_last_insert_id {
  32   my ($self, $dbh, $source, $col) = @_;
  33   $dbh->{mysql_insertid};
  34 }
  35
  36 # we need to figure out what mysql version we're running
  37 sub sql_maker {
  38   my $self = shift;
  39
  40   unless ($self->_sql_maker) {
  41     my $maker = $self->next::method (@_);
  42
  43     # mysql 3 does not understand a bare JOIN
  44     my $mysql_ver = $self->_get_dbh->get_info(18);
  45     $maker->{_default_jointype} = 'INNER' if $mysql_ver =~ /^3/;
  46   }
  47
  48   return $self->_sql_maker;
  49 }
  50
  51 sub sqlt_type {
  52   return 'MySQL';
  53 }
  54
  55 sub _svp_begin {
  56     my ($self, $name) = @_;
  57
  58     $self->_get_dbh->do("SAVEPOINT $name");
  59 }
  60
  61 sub _svp_release {
  62     my ($self, $name) = @_;
  63
  64     $self->_get_dbh->do("RELEASE SAVEPOINT $name");
  65 }
  66
  67 sub _svp_rollback {
  68     my ($self, $name) = @_;
  69
  70     $self->_get_dbh->do("ROLLBACK TO SAVEPOINT $name")
  71 }
  72
  73 sub is_replicating {
  74     my $status = shift->_get_dbh->selectrow_hashref('show slave status');
  75     return ($status->{Slave_IO_Running} eq 'Yes') && ($status->{Slave_SQL_Running} eq 'Yes');
  76 }
  77
  78 sub lag_behind_master {
  79     return shift->_get_dbh->selectrow_hashref('show slave status')->{Seconds_Behind_Master};
  80 }
  81
  82 # MySql can not do subquery update/deletes, only way is slow per-row operations.
  83 # This assumes you have set proper transaction isolation and use innodb.
  84 sub _subq_update_delete {
  85   return shift->_per_row_update_delete (@_);
  86 }
  87
  88 1;
  89
  90 =head1 NAME
  91
  92 DBIx::Class::Storage::DBI::mysql - Storage::DBI class implementing MySQL specifics
  93
  94 =head1 SYNOPSIS
  95
  96 Storage::DBI autodetects the underlying MySQL database, and re-blesses the
  97 C<$storage> object into this class.
  98
  99   my $schema = MyDb::Schema->connect( $dsn, $user, $pass, { on_connect_call => 'set_strict_mode' } );
 100
 101 =head1 DESCRIPTION
 102
 103 This class implements MySQL specific bits of L<DBIx::Class::Storage::DBI>.
 104
 105 It also provides a one-stop on-connect macro C<set_strict_mode> which sets
 106 session variables such that MySQL behaves more predictably as far as the
 107 SQL standard is concerned.
 108
 109 =head1 STORAGE OPTIONS
 110
 111 =head2 set_strict_mode
 112
 113 Enables session-wide strict options upon connecting. Equivalent to:
 114
 115   ->connect ( ... , {
 116     on_connect_do => [
 117       q|SET SQL_MODE = CONCAT('ANSI,TRADITIONAL,ONLY_FULL_GROUP_BY,', @@sql_mode)|,
 118       q|SET SQL_AUTO_IS_NULL = 0|,
 119     ]
 120   });
 121
 122 =head1 AUTHORS
 123
 124 See L<DBIx::Class/CONTRIBUTORS>
 125
 126 =head1 LICENSE
 127
 128 You may distribute this code under the same terms as Perl itself.
 129
 130 =cut