lib/DBIx/Class/Storage/DBI/Sybase/Microsoft_SQL_Server.pm

   1 package DBIx::Class::Storage::DBI::Sybase::Microsoft_SQL_Server;
   2
   3 use strict;
   4 use warnings;
   5
   6 use base qw/
   7   DBIx::Class::Storage::DBI::Sybase
   8   DBIx::Class::Storage::DBI::MSSQL
   9 /;
  10 use mro 'c3';
  11
  12 use DBIx::Class::Carp;
  13
  14 __PACKAGE__->datetime_parser_type(
  15   'DBIx::Class::Storage::DBI::Sybase::Microsoft_SQL_Server::DateTime::Format'
  16 );
  17
  18 sub _rebless {
  19   my $self = shift;
  20   my $dbh  = $self->_get_dbh;
  21
  22   return if ref $self ne __PACKAGE__;
  23   if (not $self->_use_typeless_placeholders) {
  24     require
  25       DBIx::Class::Storage::DBI::Sybase::Microsoft_SQL_Server::NoBindVars;
  26     bless $self,
  27       'DBIx::Class::Storage::DBI::Sybase::Microsoft_SQL_Server::NoBindVars';
  28     $self->_rebless;
  29   }
  30 }
  31
  32 sub _run_connection_actions {
  33   my $self = shift;
  34
  35   # LongReadLen doesn't work with MSSQL through DBD::Sybase, and the default is
  36   # huge on some versions of SQL server and can cause memory problems, so we
  37   # fix it up here (see ::DBI::Sybase.pm)
  38   $self->set_textsize;
  39
  40   $self->next::method(@_);
  41 }
  42
  43 sub _dbh_begin_work {
  44   my $self = shift;
  45
  46   $self->_get_dbh->do('BEGIN TRAN');
  47 }
  48
  49 sub _dbh_commit {
  50   my $self = shift;
  51   my $dbh  = $self->_dbh
  52     or $self->throw_exception('cannot COMMIT on a disconnected handle');
  53   $dbh->do('COMMIT');
  54 }
  55
  56 sub _dbh_rollback {
  57   my $self = shift;
  58   my $dbh  = $self->_dbh
  59     or $self->throw_exception('cannot ROLLBACK on a disconnected handle');
  60   $dbh->do('ROLLBACK');
  61 }
  62
  63 sub _get_server_version {
  64   my $self = shift;
  65
  66   my $product_version = $self->_get_dbh->selectrow_hashref('master.dbo.xp_msver ProductVersion');
  67
  68   if ((my $version = $product_version->{Character_Value}) =~ /^(\d+)\./) {
  69     return $version;
  70   }
  71   else {
  72     $self->throw_exception(
  73       "MSSQL Version Retrieval Failed, Your ProductVersion's Character_Value is missing or malformed!"
  74     );
  75   }
  76 }
  77
  78 =head2 connect_call_datetime_setup
  79
  80 Used as:
  81
  82   on_connect_call => 'datetime_setup'
  83
  84 In L<connect_info|DBIx::Class::Storage::DBI/connect_info> to set:
  85
  86   $dbh->syb_date_fmt('ISO_strict'); # output fmt: 2004-08-21T14:36:48.080Z
  87
  88 On connection for use with L<DBIx::Class::InflateColumn::DateTime>
  89
  90 This works for both C<DATETIME> and C<SMALLDATETIME> columns, although
  91 C<SMALLDATETIME> columns only have minute precision.
  92
  93 =cut
  94
  95 sub connect_call_datetime_setup {
  96   my $self = shift;
  97   my $dbh = $self->_get_dbh;
  98
  99   if ($dbh->can('syb_date_fmt')) {
 100     # amazingly, this works with FreeTDS
 101     $dbh->syb_date_fmt('ISO_strict');
 102   }
 103   else{
 104     carp_once
 105       'Your DBD::Sybase is too old to support '
 106     . 'DBIx::Class::InflateColumn::DateTime, please upgrade!';
 107   }
 108 }
 109
 110
 111 package # hide from PAUSE
 112   DBIx::Class::Storage::DBI::Sybase::Microsoft_SQL_Server::DateTime::Format;
 113
 114 my $datetime_parse_format  = '%Y-%m-%dT%H:%M:%S.%3NZ';
 115 my $datetime_format_format = '%Y-%m-%d %H:%M:%S.%3N'; # %F %T
 116
 117 my ($datetime_parser, $datetime_formatter);
 118
 119 sub parse_datetime {
 120   shift;
 121   require DateTime::Format::Strptime;
 122   $datetime_parser ||= DateTime::Format::Strptime->new(
 123     pattern  => $datetime_parse_format,
 124     on_error => 'croak',
 125   );
 126   return $datetime_parser->parse_datetime(shift);
 127 }
 128
 129 sub format_datetime {
 130   shift;
 131   require DateTime::Format::Strptime;
 132   $datetime_formatter ||= DateTime::Format::Strptime->new(
 133     pattern  => $datetime_format_format,
 134     on_error => 'croak',
 135   );
 136   return $datetime_formatter->format_datetime(shift);
 137 }
 138
 139 1;
 140
 141 =head1 NAME
 142
 143 DBIx::Class::Storage::DBI::Sybase::Microsoft_SQL_Server - Support for Microsoft
 144 SQL Server via DBD::Sybase
 145
 146 =head1 SYNOPSIS
 147
 148 This subclass supports MSSQL server connections via L<DBD::Sybase>.
 149
 150 =head1 DESCRIPTION
 151
 152 This driver tries to determine whether your version of L<DBD::Sybase> and
 153 supporting libraries (usually FreeTDS) support using placeholders, if not the
 154 storage will be reblessed to
 155 L<DBIx::Class::Storage::DBI::Sybase::Microsoft_SQL_Server::NoBindVars>.
 156
 157 The MSSQL specific functionality is provided by
 158 L<DBIx::Class::Storage::DBI::MSSQL>.
 159
 160 =head1 AUTHOR
 161
 162 See L<DBIx::Class/CONTRIBUTORS>.
 163
 164 =head1 LICENSE
 165
 166 You may distribute this code under the same terms as Perl itself.
 167
 168 =cut