lib/DBIx/Class/Storage/DBI/Sybase/ASE/NoBindVars.pm

   1 package DBIx::Class::Storage::DBI::Sybase::ASE::NoBindVars;
   2
   3 use warnings;
   4 use strict;
   5
   6 use base qw/
   7   DBIx::Class::Storage::DBI::NoBindVars
   8   DBIx::Class::Storage::DBI::Sybase::ASE
   9 /;
  10 use mro 'c3';
  11 use List::Util 'first';
  12 use Scalar::Util 'looks_like_number';
  13 use namespace::clean;
  14
  15 sub _init {
  16   my $self = shift;
  17   $self->disable_sth_caching(1);
  18   $self->_identity_method('@@IDENTITY');
  19   $self->next::method (@_);
  20 }
  21
  22 sub _fetch_identity_sql { 'SELECT ' . $_[0]->_identity_method }
  23
  24 my $number = sub { looks_like_number $_[0] };
  25
  26 my $decimal = sub { $_[0] =~ /^ [-+]? \d+ (?:\.\d*)? \z/x };
  27
  28 my %noquote = (
  29     int => sub { $_[0] =~ /^ [-+]? \d+ \z/x },
  30     bit => => sub { $_[0] =~ /^[01]\z/ },
  31     money => sub { $_[0] =~ /^\$ \d+ (?:\.\d*)? \z/x },
  32     float => $number,
  33     real => $number,
  34     double => $number,
  35     decimal => $decimal,
  36     numeric => $decimal,
  37 );
  38
  39 sub interpolate_unquoted {
  40   my $self = shift;
  41   my ($type, $value) = @_;
  42
  43   return $self->next::method(@_) if not defined $value or not defined $type;
  44
  45   if (my $key = first { $type =~ /$_/i } keys %noquote) {
  46     return 1 if $noquote{$key}->($value);
  47   }
  48   elsif ($self->is_datatype_numeric($type) && $number->($value)) {
  49     return 1;
  50   }
  51
  52   return $self->next::method(@_);
  53 }
  54
  55 sub _prep_interpolated_value {
  56   my ($self, $type, $value) = @_;
  57
  58   if ($type =~ /money/i && defined $value) {
  59     # change a ^ not followed by \$ to a \$
  60     $value =~ s/^ (?! \$) /\$/x;
  61   }
  62
  63   return $value;
  64 }
  65
  66 1;
  67
  68 =head1 NAME
  69
  70 DBIx::Class::Storage::DBI::Sybase::ASE::NoBindVars - Storage::DBI subclass for
  71 Sybase ASE without placeholder support
  72
  73 =head1 DESCRIPTION
  74
  75 If you're using this driver then your version of Sybase or the libraries you
  76 use to connect to it do not support placeholders.
  77
  78 You can also enable this driver explicitly using:
  79
  80   my $schema = SchemaClass->clone;
  81   $schema->storage_type('::DBI::Sybase::ASE::NoBindVars');
  82   $schema->connect($dsn, $user, $pass, \%opts);
  83
  84 See the discussion in
  85 L<< DBD::Sybase/Using ? Placeholders & bind parameters to $sth->execute >>
  86 for details on the pros and cons of using placeholders with this particular
  87 driver.
  88
  89 One advantage of not using placeholders is that C<select @@identity> will work
  90 for obtaining the last insert id of an C<IDENTITY> column, instead of having to
  91 do C<select max(col)> in a transaction as the base Sybase driver does.
  92
  93 When using this driver, bind variables will be interpolated (properly quoted of
  94 course) into the SQL query itself, without using placeholders.
  95
  96 The caching of prepared statements is also explicitly disabled, as the
  97 interpolation renders it useless.
  98
  99 =head1 AUTHORS
 100
 101 See L<DBIx::Class/CONTRIBUTORS>.
 102
 103 =head1 LICENSE
 104
 105 You may distribute this code under the same terms as Perl itself.
 106
 107 =cut
 108 # vim:sts=2 sw=2: