lib/DBIx/Class/Storage/DBI/Sybase/ASE.pm

   1 package DBIx::Class::Storage::DBI::Sybase::ASE;
   2
   3 use strict;
   4 use warnings;
   5
   6 use base qw/
   7     DBIx::Class::Storage::DBI::Sybase
   8     DBIx::Class::Storage::DBI::AutoCast
   9 /;
  10 use mro 'c3';
  11 use DBIx::Class::Carp;
  12 use Scalar::Util 'blessed';
  13 use List::Util 'first';
  14 use Sub::Name();
  15 use Data::Dumper::Concise 'Dumper';
  16 use Try::Tiny;
  17 use namespace::clean;
  18
  19 __PACKAGE__->sql_limit_dialect ('RowCountOrGenericSubQ');
  20 __PACKAGE__->sql_quote_char ([qw/[ ]/]);
  21 __PACKAGE__->datetime_parser_type('DateTime::Format::Sybase');
  22
  23 __PACKAGE__->mk_group_accessors('simple' =>
  24     qw/_identity _blob_log_on_update _writer_storage _is_extra_storage
  25        _bulk_storage _is_bulk_storage _began_bulk_work
  26        _bulk_disabled_due_to_coderef_connect_info_warned
  27        _identity_method/
  28 );
  29
  30 __PACKAGE__->datetime_parser_type(
  31   'DBIx::Class::Storage::DBI::Sybase::ASE::DateTime::Format'
  32 );
  33
  34 my @also_proxy_to_extra_storages = qw/
  35   connect_call_set_auto_cast auto_cast connect_call_blob_setup
  36   connect_call_datetime_setup
  37
  38   disconnect _connect_info _sql_maker _sql_maker_opts disable_sth_caching
  39   auto_savepoint unsafe cursor_class debug debugobj schema
  40 /;
  41
  42 =head1 NAME
  43
  44 DBIx::Class::Storage::DBI::Sybase::ASE - Sybase ASE SQL Server support for
  45 DBIx::Class
  46
  47 =head1 SYNOPSIS
  48
  49 This subclass supports L<DBD::Sybase> for real (non-Microsoft) Sybase databases.
  50
  51 =head1 DESCRIPTION
  52
  53 If your version of Sybase does not support placeholders, then your storage will
  54 be reblessed to L<DBIx::Class::Storage::DBI::Sybase::ASE::NoBindVars>.
  55 You can also enable that driver explicitly, see the documentation for more
  56 details.
  57
  58 With this driver there is unfortunately no way to get the C<last_insert_id>
  59 without doing a C<SELECT MAX(col)>. This is done safely in a transaction
  60 (locking the table.) See L</INSERTS WITH PLACEHOLDERS>.
  61
  62 A recommended L<connect_info|DBIx::Class::Storage::DBI/connect_info> setting:
  63
  64   on_connect_call => [['datetime_setup'], ['blob_setup', log_on_update => 0]]
  65
  66 =head1 METHODS
  67
  68 =cut
  69
  70 sub _rebless {
  71   my $self = shift;
  72
  73   my $no_bind_vars = __PACKAGE__ . '::NoBindVars';
  74
  75   if ($self->using_freetds) {
  76     carp_once <<'EOF' unless $ENV{DBIC_SYBASE_FREETDS_NOWARN};
  77
  78 You are using FreeTDS with Sybase.
  79
  80 We will do our best to support this configuration, but please consider this
  81 support experimental.
  82
  83 TEXT/IMAGE columns will definitely not work.
  84
  85 You are encouraged to recompile DBD::Sybase with the Sybase Open Client libraries
  86 instead.
  87
  88 See perldoc DBIx::Class::Storage::DBI::Sybase::ASE for more details.
  89
  90 To turn off this warning set the DBIC_SYBASE_FREETDS_NOWARN environment
  91 variable.
  92 EOF
  93
  94     if (not $self->_use_typeless_placeholders) {
  95       if ($self->_use_placeholders) {
  96         $self->auto_cast(1);
  97       }
  98       else {
  99         $self->ensure_class_loaded($no_bind_vars);
 100         bless $self, $no_bind_vars;
 101         $self->_rebless;
 102       }
 103     }
 104   }
 105
 106   elsif (not $self->_get_dbh->{syb_dynamic_supported}) {
 107     # not necessarily FreeTDS, but no placeholders nevertheless
 108     $self->ensure_class_loaded($no_bind_vars);
 109     bless $self, $no_bind_vars;
 110     $self->_rebless;
 111   }
 112   # this is highly unlikely, but we check just in case
 113   elsif (not $self->_use_typeless_placeholders) {
 114     $self->auto_cast(1);
 115   }
 116 }
 117
 118 sub _init {
 119   my $self = shift;
 120   $self->_set_max_connect(256);
 121
 122 # create storage for insert/(update blob) transactions,
 123 # unless this is that storage
 124   return if $self->_is_extra_storage;
 125
 126   my $writer_storage = (ref $self)->new;
 127
 128   $writer_storage->_is_extra_storage(1);
 129   $writer_storage->connect_info($self->connect_info);
 130   $writer_storage->auto_cast($self->auto_cast);
 131
 132   $self->_writer_storage($writer_storage);
 133
 134 # create a bulk storage unless connect_info is a coderef
 135   return if ref($self->_dbi_connect_info->[0]) eq 'CODE';
 136
 137   my $bulk_storage = (ref $self)->new;
 138
 139   $bulk_storage->_is_extra_storage(1);
 140   $bulk_storage->_is_bulk_storage(1); # for special ->disconnect acrobatics
 141   $bulk_storage->connect_info($self->connect_info);
 142
 143 # this is why
 144   $bulk_storage->_dbi_connect_info->[0] .= ';bulkLogin=1';
 145
 146   $self->_bulk_storage($bulk_storage);
 147 }
 148
 149 for my $method (@also_proxy_to_extra_storages) {
 150   no strict 'refs';
 151   no warnings 'redefine';
 152
 153   my $replaced = __PACKAGE__->can($method);
 154
 155   *{$method} = Sub::Name::subname $method => sub {
 156     my $self = shift;
 157     $self->_writer_storage->$replaced(@_) if $self->_writer_storage;
 158     $self->_bulk_storage->$replaced(@_)   if $self->_bulk_storage;
 159     return $self->$replaced(@_);
 160   };
 161 }
 162
 163 sub disconnect {
 164   my $self = shift;
 165
 166 # Even though we call $sth->finish for uses off the bulk API, there's still an
 167 # "active statement" warning on disconnect, which we throw away here.
 168 # This is due to the bug described in insert_bulk.
 169 # Currently a noop because 'prepare' is used instead of 'prepare_cached'.
 170   local $SIG{__WARN__} = sub {
 171     warn $_[0] unless $_[0] =~ /active statement/i;
 172   } if $self->_is_bulk_storage;
 173
 174 # so that next transaction gets a dbh
 175   $self->_began_bulk_work(0) if $self->_is_bulk_storage;
 176
 177   $self->next::method;
 178 }
 179
 180 # This is only invoked for FreeTDS drivers by ::Storage::DBI::Sybase::FreeTDS
 181 sub _set_autocommit_stmt {
 182   my ($self, $on) = @_;
 183
 184   return 'SET CHAINED ' . ($on ? 'OFF' : 'ON');
 185 }
 186
 187 # Set up session settings for Sybase databases for the connection.
 188 #
 189 # Make sure we have CHAINED mode turned on if AutoCommit is off in non-FreeTDS
 190 # DBD::Sybase (since we don't know how DBD::Sybase was compiled.) If however
 191 # we're using FreeTDS, CHAINED mode turns on an implicit transaction which we
 192 # only want when AutoCommit is off.
 193 sub _run_connection_actions {
 194   my $self = shift;
 195
 196   if ($self->_is_bulk_storage) {
 197     # this should be cleared on every reconnect
 198     $self->_began_bulk_work(0);
 199     return;
 200   }
 201
 202   $self->_dbh->{syb_chained_txn} = 1
 203     unless $self->using_freetds;
 204
 205   $self->next::method(@_);
 206 }
 207
 208 =head2 connect_call_blob_setup
 209
 210 Used as:
 211
 212   on_connect_call => [ [ 'blob_setup', log_on_update => 0 ] ]
 213
 214 Does C<< $dbh->{syb_binary_images} = 1; >> to return C<IMAGE> data as raw binary
 215 instead of as a hex string.
 216
 217 Recommended.
 218
 219 Also sets the C<log_on_update> value for blob write operations. The default is
 220 C<1>, but C<0> is better if your database is configured for it.
 221
 222 See
 223 L<DBD::Sybase/Handling_IMAGE/TEXT_data_with_syb_ct_get_data()/syb_ct_send_data()>.
 224
 225 =cut
 226
 227 sub connect_call_blob_setup {
 228   my $self = shift;
 229   my %args = @_;
 230   my $dbh = $self->_dbh;
 231   $dbh->{syb_binary_images} = 1;
 232
 233   $self->_blob_log_on_update($args{log_on_update})
 234     if exists $args{log_on_update};
 235 }
 236
 237 sub _is_lob_column {
 238   my ($self, $source, $column) = @_;
 239
 240   return $self->_is_lob_type($source->column_info($column)->{data_type});
 241 }
 242
 243 sub _prep_for_execute {
 244   my $self = shift;
 245   my ($op, $ident, $args) = @_;
 246
 247   my ($sql, $bind) = $self->next::method (@_);
 248
 249   my $table = blessed $ident ? $ident->from : $ident;
 250
 251   my $bind_info = $self->_resolve_column_info(
 252     $ident, [map { $_->[0]{dbic_colname} || () } @{$bind}]
 253   );
 254   my $bound_identity_col =
 255     first { $bind_info->{$_}{is_auto_increment} }
 256     keys %$bind_info
 257   ;
 258
 259   my $columns_info = blessed $ident && $ident->columns_info;
 260
 261   my $identity_col =
 262     $columns_info &&
 263     first { $columns_info->{$_}{is_auto_increment} }
 264       keys %$columns_info
 265   ;
 266
 267   if (($op eq 'insert' && $bound_identity_col) ||
 268       ($op eq 'update' && exists $args->[0]{$identity_col})) {
 269     $sql = join ("\n",
 270       $self->_set_table_identity_sql($op => $table, 'on'),
 271       $sql,
 272       $self->_set_table_identity_sql($op => $table, 'off'),
 273     );
 274   }
 275
 276   if ($op eq 'insert' && (not $bound_identity_col) && $identity_col &&
 277       (not $self->{insert_bulk})) {
 278     $sql =
 279       "$sql\n" .
 280       $self->_fetch_identity_sql($ident, $identity_col);
 281   }
 282
 283   return ($sql, $bind);
 284 }
 285
 286 sub _set_table_identity_sql {
 287   my ($self, $op, $table, $on_off) = @_;
 288
 289   return sprintf 'SET IDENTITY_%s %s %s',
 290     uc($op), $self->sql_maker->_quote($table), uc($on_off);
 291 }
 292
 293 # Stolen from SQLT, with some modifications. This is a makeshift
 294 # solution before a sane type-mapping library is available, thus
 295 # the 'our' for easy overrides.
 296 our %TYPE_MAPPING  = (
 297     number    => 'numeric',
 298     money     => 'money',
 299     varchar   => 'varchar',
 300     varchar2  => 'varchar',
 301     timestamp => 'datetime',
 302     text      => 'varchar',
 303     real      => 'double precision',
 304     comment   => 'text',
 305     bit       => 'bit',
 306     tinyint   => 'smallint',
 307     float     => 'double precision',
 308     serial    => 'numeric',
 309     bigserial => 'numeric',
 310     boolean   => 'varchar',
 311     long      => 'varchar',
 312 );
 313
 314 sub _native_data_type {
 315   my ($self, $type) = @_;
 316
 317   $type = lc $type;
 318   $type =~ s/\s* identity//x;
 319
 320   return uc($TYPE_MAPPING{$type} || $type);
 321 }
 322
 323 sub _fetch_identity_sql {
 324   my ($self, $source, $col) = @_;
 325
 326   return sprintf ("SELECT MAX(%s) FROM %s",
 327     map { $self->sql_maker->_quote ($_) } ($col, $source->from)
 328   );
 329 }
 330
 331 sub _execute {
 332   my $self = shift;
 333   my ($op) = @_;
 334
 335   my ($rv, $sth, @bind) = $self->next::method(@_);
 336
 337   if ($op eq 'insert') {
 338     $self->_identity($sth->fetchrow_array);
 339     $sth->finish;
 340   }
 341
 342   return wantarray ? ($rv, $sth, @bind) : $rv;
 343 }
 344
 345 sub last_insert_id { shift->_identity }
 346
 347 # handles TEXT/IMAGE and transaction for last_insert_id
 348 sub insert {
 349   my $self = shift;
 350   my ($source, $to_insert) = @_;
 351
 352   my $columns_info = $source->columns_info;
 353
 354   my $identity_col =
 355     (first { $columns_info->{$_}{is_auto_increment} }
 356       keys %$columns_info )
 357     || '';
 358
 359   # check for empty insert
 360   # INSERT INTO foo DEFAULT VALUES -- does not work with Sybase
 361   # try to insert explicit 'DEFAULT's instead (except for identity, timestamp
 362   # and computed columns)
 363   if (not %$to_insert) {
 364     for my $col ($source->columns) {
 365       next if $col eq $identity_col;
 366
 367       my $info = $source->column_info($col);
 368
 369       next if ref $info->{default_value} eq 'SCALAR'
 370         || (exists $info->{data_type} && (not defined $info->{data_type}));
 371
 372       next if $info->{data_type} && $info->{data_type} =~ /^timestamp\z/i;
 373
 374       $to_insert->{$col} = \'DEFAULT';
 375     }
 376   }
 377
 378   my $blob_cols = $self->_remove_blob_cols($source, $to_insert);
 379
 380   # do we need the horrific SELECT MAX(COL) hack?
 381   my $dumb_last_insert_id =
 382        $identity_col
 383     && (not exists $to_insert->{$identity_col})
 384     && ($self->_identity_method||'') ne '@@IDENTITY';
 385
 386   my $next = $self->next::can;
 387
 388   # we are already in a transaction, or there are no blobs
 389   # and we don't need the PK - just (try to) do it
 390   if ($self->{transaction_depth}
 391         || (!$blob_cols && !$dumb_last_insert_id)
 392   ) {
 393     return $self->_insert (
 394       $next, $source, $to_insert, $blob_cols, $identity_col
 395     );
 396   }
 397
 398   # otherwise use the _writer_storage to do the insert+transaction on another
 399   # connection
 400   my $guard = $self->_writer_storage->txn_scope_guard;
 401
 402   my $updated_cols = $self->_writer_storage->_insert (
 403     $next, $source, $to_insert, $blob_cols, $identity_col
 404   );
 405
 406   $self->_identity($self->_writer_storage->_identity);
 407
 408   $guard->commit;
 409
 410   return $updated_cols;
 411 }
 412
 413 sub _insert {
 414   my ($self, $next, $source, $to_insert, $blob_cols, $identity_col) = @_;
 415
 416   my $updated_cols = $self->$next ($source, $to_insert);
 417
 418   my $final_row = {
 419     ($identity_col ?
 420       ($identity_col => $self->last_insert_id($source, $identity_col)) : ()),
 421     %$to_insert,
 422     %$updated_cols,
 423   };
 424
 425   $self->_insert_blobs ($source, $blob_cols, $final_row) if $blob_cols;
 426
 427   return $updated_cols;
 428 }
 429
 430 sub update {
 431   my $self = shift;
 432   my ($source, $fields, $where, @rest) = @_;
 433
 434   my $blob_cols = $self->_remove_blob_cols($source, $fields);
 435
 436   my $table = $source->name;
 437
 438   my $columns_info = $source->columns_info;
 439
 440   my $identity_col =
 441     first { $columns_info->{$_}{is_auto_increment} }
 442       keys %$columns_info;
 443
 444   my $is_identity_update = $identity_col && defined $fields->{$identity_col};
 445
 446   return $self->next::method(@_) unless $blob_cols;
 447
 448 # If there are any blobs in $where, Sybase will return a descriptive error
 449 # message.
 450 # XXX blobs can still be used with a LIKE query, and this should be handled.
 451
 452 # update+blob update(s) done atomically on separate connection
 453   $self = $self->_writer_storage;
 454
 455   my $guard = $self->txn_scope_guard;
 456
 457 # First update the blob columns to be updated to '' (taken from $fields, where
 458 # it is originally put by _remove_blob_cols .)
 459   my %blobs_to_empty = map { ($_ => delete $fields->{$_}) } keys %$blob_cols;
 460
 461 # We can't only update NULL blobs, because blobs cannot be in the WHERE clause.
 462
 463   $self->next::method($source, \%blobs_to_empty, $where, @rest);
 464
 465 # Now update the blobs before the other columns in case the update of other
 466 # columns makes the search condition invalid.
 467   $self->_update_blobs($source, $blob_cols, $where);
 468
 469   my @res;
 470   if (%$fields) {
 471     if (wantarray) {
 472       @res    = $self->next::method(@_);
 473     }
 474     elsif (defined wantarray) {
 475       $res[0] = $self->next::method(@_);
 476     }
 477     else {
 478       $self->next::method(@_);
 479     }
 480   }
 481
 482   $guard->commit;
 483
 484   return wantarray ? @res : $res[0];
 485 }
 486
 487 sub insert_bulk {
 488   my $self = shift;
 489   my ($source, $cols, $data) = @_;
 490
 491   my $columns_info = $source->columns_info;
 492
 493   my $identity_col =
 494     first { $columns_info->{$_}{is_auto_increment} }
 495       keys %$columns_info;
 496
 497   my $is_identity_insert = (first { $_ eq $identity_col } @{$cols}) ? 1 : 0;
 498
 499   my @source_columns = $source->columns;
 500
 501   my $use_bulk_api =
 502     $self->_bulk_storage &&
 503     $self->_get_dbh->{syb_has_blk};
 504
 505   if ((not $use_bulk_api)
 506         &&
 507       (ref($self->_dbi_connect_info->[0]) eq 'CODE')
 508         &&
 509       (not $self->_bulk_disabled_due_to_coderef_connect_info_warned)) {
 510     carp <<'EOF';
 511 Bulk API support disabled due to use of a CODEREF connect_info. Reverting to
 512 regular array inserts.
 513 EOF
 514     $self->_bulk_disabled_due_to_coderef_connect_info_warned(1);
 515   }
 516
 517   if (not $use_bulk_api) {
 518     my $blob_cols = $self->_remove_blob_cols_array($source, $cols, $data);
 519
 520 # _execute_array uses a txn anyway, but it ends too early in case we need to
 521 # select max(col) to get the identity for inserting blobs.
 522     ($self, my $guard) = $self->{transaction_depth} == 0 ?
 523       ($self->_writer_storage, $self->_writer_storage->txn_scope_guard)
 524       :
 525       ($self, undef);
 526
 527     local $self->{insert_bulk} = 1;
 528
 529     $self->next::method(@_);
 530
 531     if ($blob_cols) {
 532       if ($is_identity_insert) {
 533         $self->_insert_blobs_array ($source, $blob_cols, $cols, $data);
 534       }
 535       else {
 536         my @cols_with_identities = (@$cols, $identity_col);
 537
 538         ## calculate identities
 539         # XXX This assumes identities always increase by 1, which may or may not
 540         # be true.
 541         my ($last_identity) =
 542           $self->_dbh->selectrow_array (
 543             $self->_fetch_identity_sql($source, $identity_col)
 544           );
 545         my @identities = (($last_identity - @$data + 1) .. $last_identity);
 546
 547         my @data_with_identities = map [@$_, shift @identities], @$data;
 548
 549         $self->_insert_blobs_array (
 550           $source, $blob_cols, \@cols_with_identities, \@data_with_identities
 551         );
 552       }
 553     }
 554
 555     $guard->commit if $guard;
 556
 557     return;
 558   }
 559
 560 # otherwise, use the bulk API
 561
 562 # rearrange @$data so that columns are in database order
 563   my %orig_idx;
 564   @orig_idx{@$cols} = 0..$#$cols;
 565
 566   my %new_idx;
 567   @new_idx{@source_columns} = 0..$#source_columns;
 568
 569   my @new_data;
 570   for my $datum (@$data) {
 571     my $new_datum = [];
 572     for my $col (@source_columns) {
 573 # identity data will be 'undef' if not $is_identity_insert
 574 # columns with defaults will also be 'undef'
 575       $new_datum->[ $new_idx{$col} ] =
 576         exists $orig_idx{$col} ? $datum->[ $orig_idx{$col} ] : undef;
 577     }
 578     push @new_data, $new_datum;
 579   }
 580
 581 # bcp identity index is 1-based
 582   my $identity_idx = exists $new_idx{$identity_col} ?
 583     $new_idx{$identity_col} + 1 : 0;
 584
 585 ## Set a client-side conversion error handler, straight from DBD::Sybase docs.
 586 # This ignores any data conversion errors detected by the client side libs, as
 587 # they are usually harmless.
 588   my $orig_cslib_cb = DBD::Sybase::set_cslib_cb(
 589     Sub::Name::subname insert_bulk => sub {
 590       my ($layer, $origin, $severity, $errno, $errmsg, $osmsg, $blkmsg) = @_;
 591
 592       return 1 if $errno == 36;
 593
 594       carp
 595         "Layer: $layer, Origin: $origin, Severity: $severity, Error: $errno" .
 596         ($errmsg ? "\n$errmsg" : '') .
 597         ($osmsg  ? "\n$osmsg"  : '')  .
 598         ($blkmsg ? "\n$blkmsg" : '');
 599
 600       return 0;
 601   });
 602
 603   my $exception = '';
 604   try {
 605     my $bulk = $self->_bulk_storage;
 606
 607     my $guard = $bulk->txn_scope_guard;
 608
 609 ## XXX get this to work instead of our own $sth
 610 ## will require SQLA or *Hacks changes for ordered columns
 611 #    $bulk->next::method($source, \@source_columns, \@new_data, {
 612 #      syb_bcp_attribs => {
 613 #        identity_flag   => $is_identity_insert,
 614 #        identity_column => $identity_idx,
 615 #      }
 616 #    });
 617     my $sql = 'INSERT INTO ' .
 618       $bulk->sql_maker->_quote($source->name) . ' (' .
 619 # colname list is ignored for BCP, but does no harm
 620       (join ', ', map $bulk->sql_maker->_quote($_), @source_columns) . ') '.
 621       ' VALUES ('.  (join ', ', ('?') x @source_columns) . ')';
 622
 623 ## XXX there's a bug in the DBD::Sybase bulk support that makes $sth->finish for
 624 ## a prepare_cached statement ineffective. Replace with ->sth when fixed, or
 625 ## better yet the version above. Should be fixed in DBD::Sybase .
 626     my $sth = $bulk->_get_dbh->prepare($sql,
 627 #      'insert', # op
 628       {
 629         syb_bcp_attribs => {
 630           identity_flag   => $is_identity_insert,
 631           identity_column => $identity_idx,
 632         }
 633       }
 634     );
 635
 636     my @bind = map { [ $source_columns[$_] => $_ ] } (0 .. $#source_columns);
 637
 638     $self->_execute_array(
 639       $source, $sth, \@bind, \@source_columns, \@new_data, sub {
 640         $guard->commit
 641       }
 642     );
 643
 644     $bulk->_query_end($sql);
 645   } catch {
 646     $exception = shift;
 647   };
 648
 649   DBD::Sybase::set_cslib_cb($orig_cslib_cb);
 650
 651   if ($exception =~ /-Y option/) {
 652     my $w = 'Sybase bulk API operation failed due to character set incompatibility, '
 653           . 'reverting to regular array inserts. Try unsetting the LANG environment variable'
 654     ;
 655     $w .= "\n$exception" if $self->debug;
 656     carp $w;
 657
 658     $self->_bulk_storage(undef);
 659     unshift @_, $self;
 660     goto \&insert_bulk;
 661   }
 662   elsif ($exception) {
 663 # rollback makes the bulkLogin connection unusable
 664     $self->_bulk_storage->disconnect;
 665     $self->throw_exception($exception);
 666   }
 667 }
 668
 669 sub _dbh_execute_array {
 670   my ($self, $sth, $tuple_status, $cb) = @_;
 671
 672   my $rv = $self->next::method($sth, $tuple_status);
 673   $cb->() if $cb;
 674
 675   return $rv;
 676 }
 677
 678 # Make sure blobs are not bound as placeholders, and return any non-empty ones
 679 # as a hash.
 680 sub _remove_blob_cols {
 681   my ($self, $source, $fields) = @_;
 682
 683   my %blob_cols;
 684
 685   for my $col (keys %$fields) {
 686     if ($self->_is_lob_column($source, $col)) {
 687       my $blob_val = delete $fields->{$col};
 688       if (not defined $blob_val) {
 689         $fields->{$col} = \'NULL';
 690       }
 691       else {
 692         $fields->{$col} = \"''";
 693         $blob_cols{$col} = $blob_val unless $blob_val eq '';
 694       }
 695     }
 696   }
 697
 698   return %blob_cols ? \%blob_cols : undef;
 699 }
 700
 701 # same for insert_bulk
 702 sub _remove_blob_cols_array {
 703   my ($self, $source, $cols, $data) = @_;
 704
 705   my @blob_cols;
 706
 707   for my $i (0..$#$cols) {
 708     my $col = $cols->[$i];
 709
 710     if ($self->_is_lob_column($source, $col)) {
 711       for my $j (0..$#$data) {
 712         my $blob_val = delete $data->[$j][$i];
 713         if (not defined $blob_val) {
 714           $data->[$j][$i] = \'NULL';
 715         }
 716         else {
 717           $data->[$j][$i] = \"''";
 718           $blob_cols[$j][$i] = $blob_val
 719             unless $blob_val eq '';
 720         }
 721       }
 722     }
 723   }
 724
 725   return @blob_cols ? \@blob_cols : undef;
 726 }
 727
 728 sub _update_blobs {
 729   my ($self, $source, $blob_cols, $where) = @_;
 730
 731   my @primary_cols = try
 732     { $source->_pri_cols }
 733     catch {
 734       $self->throw_exception("Cannot update TEXT/IMAGE column(s): $_")
 735     };
 736
 737   my @pks_to_update;
 738   if (
 739     ref $where eq 'HASH'
 740       and
 741     @primary_cols == grep { defined $where->{$_} } @primary_cols
 742   ) {
 743     my %row_to_update;
 744     @row_to_update{@primary_cols} = @{$where}{@primary_cols};
 745     @pks_to_update = \%row_to_update;
 746   }
 747   else {
 748     my $cursor = $self->select ($source, \@primary_cols, $where, {});
 749     @pks_to_update = map {
 750       my %row; @row{@primary_cols} = @$_; \%row
 751     } $cursor->all;
 752   }
 753
 754   for my $ident (@pks_to_update) {
 755     $self->_insert_blobs($source, $blob_cols, $ident);
 756   }
 757 }
 758
 759 sub _insert_blobs {
 760   my ($self, $source, $blob_cols, $row) = @_;
 761   my $dbh = $self->_get_dbh;
 762
 763   my $table = $source->name;
 764
 765   my %row = %$row;
 766   my @primary_cols = try
 767     { $source->_pri_cols }
 768     catch {
 769       $self->throw_exception("Cannot update TEXT/IMAGE column(s): $_")
 770     };
 771
 772   $self->throw_exception('Cannot update TEXT/IMAGE column(s) without primary key values')
 773     if ((grep { defined $row{$_} } @primary_cols) != @primary_cols);
 774
 775   for my $col (keys %$blob_cols) {
 776     my $blob = $blob_cols->{$col};
 777
 778     my %where = map { ($_, $row{$_}) } @primary_cols;
 779
 780     my $cursor = $self->select ($source, [$col], \%where, {});
 781     $cursor->next;
 782     my $sth = $cursor->sth;
 783
 784     if (not $sth) {
 785       $self->throw_exception(
 786           "Could not find row in table '$table' for blob update:\n"
 787         . (Dumper \%where)
 788       );
 789     }
 790
 791     try {
 792       do {
 793         $sth->func('CS_GET', 1, 'ct_data_info') or die $sth->errstr;
 794       } while $sth->fetch;
 795
 796       $sth->func('ct_prepare_send') or die $sth->errstr;
 797
 798       my $log_on_update = $self->_blob_log_on_update;
 799       $log_on_update    = 1 if not defined $log_on_update;
 800
 801       $sth->func('CS_SET', 1, {
 802         total_txtlen => length($blob),
 803         log_on_update => $log_on_update
 804       }, 'ct_data_info') or die $sth->errstr;
 805
 806       $sth->func($blob, length($blob), 'ct_send_data') or die $sth->errstr;
 807
 808       $sth->func('ct_finish_send') or die $sth->errstr;
 809     }
 810     catch {
 811       if ($self->using_freetds) {
 812         $self->throw_exception (
 813           "TEXT/IMAGE operation failed, probably because you are using FreeTDS: $_"
 814         );
 815       }
 816       else {
 817         $self->throw_exception($_);
 818       }
 819     }
 820     finally {
 821       $sth->finish if $sth;
 822     };
 823   }
 824 }
 825
 826 sub _insert_blobs_array {
 827   my ($self, $source, $blob_cols, $cols, $data) = @_;
 828
 829   for my $i (0..$#$data) {
 830     my $datum = $data->[$i];
 831
 832     my %row;
 833     @row{ @$cols } = @$datum;
 834
 835     my %blob_vals;
 836     for my $j (0..$#$cols) {
 837       if (exists $blob_cols->[$i][$j]) {
 838         $blob_vals{ $cols->[$j] } = $blob_cols->[$i][$j];
 839       }
 840     }
 841
 842     $self->_insert_blobs ($source, \%blob_vals, \%row);
 843   }
 844 }
 845
 846 =head2 connect_call_datetime_setup
 847
 848 Used as:
 849
 850   on_connect_call => 'datetime_setup'
 851
 852 In L<connect_info|DBIx::Class::Storage::DBI/connect_info> to set:
 853
 854   $dbh->syb_date_fmt('ISO_strict'); # output fmt: 2004-08-21T14:36:48.080Z
 855   $dbh->do('set dateformat mdy');   # input fmt:  08/13/1979 18:08:55.080
 856
 857 On connection for use with L<DBIx::Class::InflateColumn::DateTime>, using
 858 L<DateTime::Format::Sybase>, which you will need to install.
 859
 860 This works for both C<DATETIME> and C<SMALLDATETIME> columns, note that
 861 C<SMALLDATETIME> columns only have minute precision.
 862
 863 =cut
 864
 865 sub connect_call_datetime_setup {
 866   my $self = shift;
 867   my $dbh = $self->_get_dbh;
 868
 869   if ($dbh->can('syb_date_fmt')) {
 870     # amazingly, this works with FreeTDS
 871     $dbh->syb_date_fmt('ISO_strict');
 872   }
 873   else {
 874     carp_once
 875       'Your DBD::Sybase is too old to support '
 876      .'DBIx::Class::InflateColumn::DateTime, please upgrade!';
 877
 878     $dbh->do('SET DATEFORMAT mdy');
 879     1;
 880   }
 881 }
 882
 883
 884 sub _exec_txn_begin {
 885   my $self = shift;
 886
 887 # bulkLogin=1 connections are always in a transaction, and can only call BEGIN
 888 # TRAN once. However, we need to make sure there's a $dbh.
 889   return if $self->_is_bulk_storage && $self->_dbh && $self->_began_bulk_work;
 890
 891   $self->next::method(@_);
 892
 893   $self->_began_bulk_work(1) if $self->_is_bulk_storage;
 894 }
 895
 896 # savepoint support using ASE syntax
 897
 898 sub _exec_svp_begin {
 899   my ($self, $name) = @_;
 900
 901   $self->_dbh->do("SAVE TRANSACTION $name");
 902 }
 903
 904 # A new SAVE TRANSACTION with the same name releases the previous one.
 905 sub _exec_svp_release { 1 }
 906
 907 sub _exec_svp_rollback {
 908   my ($self, $name) = @_;
 909
 910   $self->_dbh->do("ROLLBACK TRANSACTION $name");
 911 }
 912
 913 package # hide from PAUSE
 914   DBIx::Class::Storage::DBI::Sybase::ASE::DateTime::Format;
 915
 916 my $datetime_parse_format  = '%Y-%m-%dT%H:%M:%S.%3NZ';
 917 my $datetime_format_format = '%m/%d/%Y %H:%M:%S.%3N';
 918
 919 my ($datetime_parser, $datetime_formatter);
 920
 921 sub parse_datetime {
 922   shift;
 923   require DateTime::Format::Strptime;
 924   $datetime_parser ||= DateTime::Format::Strptime->new(
 925     pattern  => $datetime_parse_format,
 926     on_error => 'croak',
 927   );
 928   return $datetime_parser->parse_datetime(shift);
 929 }
 930
 931 sub format_datetime {
 932   shift;
 933   require DateTime::Format::Strptime;
 934   $datetime_formatter ||= DateTime::Format::Strptime->new(
 935     pattern  => $datetime_format_format,
 936     on_error => 'croak',
 937   );
 938   return $datetime_formatter->format_datetime(shift);
 939 }
 940
 941 1;
 942
 943 =head1 Schema::Loader Support
 944
 945 As of version C<0.05000>, L<DBIx::Class::Schema::Loader> should work well with
 946 most versions of Sybase ASE.
 947
 948 =head1 FreeTDS
 949
 950 This driver supports L<DBD::Sybase> compiled against FreeTDS
 951 (L<http://www.freetds.org/>) to the best of our ability, however it is
 952 recommended that you recompile L<DBD::Sybase> against the Sybase Open Client
 953 libraries. They are a part of the Sybase ASE distribution:
 954
 955 The Open Client FAQ is here:
 956 L<http://www.isug.com/Sybase_FAQ/ASE/section7.html>.
 957
 958 Sybase ASE for Linux (which comes with the Open Client libraries) may be
 959 downloaded here: L<http://response.sybase.com/forms/ASE_Linux_Download>.
 960
 961 To see if you're using FreeTDS check C<< $schema->storage->using_freetds >>, or run:
 962
 963   perl -MDBI -le 'my $dbh = DBI->connect($dsn, $user, $pass); print $dbh->{syb_oc_version}'
 964
 965 It is recommended to set C<tds version> for your ASE server to C<5.0> in
 966 C</etc/freetds/freetds.conf>.
 967
 968 Some versions or configurations of the libraries involved will not support
 969 placeholders, in which case the storage will be reblessed to
 970 L<DBIx::Class::Storage::DBI::Sybase::ASE::NoBindVars>.
 971
 972 In some configurations, placeholders will work but will throw implicit type
 973 conversion errors for anything that's not expecting a string. In such a case,
 974 the C<auto_cast> option from L<DBIx::Class::Storage::DBI::AutoCast> is
 975 automatically set, which you may enable on connection with
 976 L<connect_call_set_auto_cast|DBIx::Class::Storage::DBI::AutoCast/connect_call_set_auto_cast>.
 977 The type info for the C<CAST>s is taken from the
 978 L<DBIx::Class::ResultSource/data_type> definitions in your Result classes, and
 979 are mapped to a Sybase type (if it isn't already) using a mapping based on
 980 L<SQL::Translator>.
 981
 982 In other configurations, placeholders will work just as they do with the Sybase
 983 Open Client libraries.
 984
 985 Inserts or updates of TEXT/IMAGE columns will B<NOT> work with FreeTDS.
 986
 987 =head1 INSERTS WITH PLACEHOLDERS
 988
 989 With placeholders enabled, inserts are done in a transaction so that there are
 990 no concurrency issues with getting the inserted identity value using
 991 C<SELECT MAX(col)>, which is the only way to get the C<IDENTITY> value in this
 992 mode.
 993
 994 In addition, they are done on a separate connection so that it's possible to
 995 have active cursors when doing an insert.
 996
 997 When using C<DBIx::Class::Storage::DBI::Sybase::ASE::NoBindVars> transactions
 998 are unnecessary and not used, as there are no concurrency issues with C<SELECT
 999 @@IDENTITY> which is a session variable.
1000
1001 =head1 TRANSACTIONS
1002
1003 Due to limitations of the TDS protocol and L<DBD::Sybase>, you cannot begin a
1004 transaction while there are active cursors, nor can you use multiple active
1005 cursors within a transaction. An active cursor is, for example, a
1006 L<ResultSet|DBIx::Class::ResultSet> that has been executed using C<next> or
1007 C<first> but has not been exhausted or L<reset|DBIx::Class::ResultSet/reset>.
1008
1009 For example, this will not work:
1010
1011   $schema->txn_do(sub {
1012     my $rs = $schema->resultset('Book');
1013     while (my $row = $rs->next) {
1014       $schema->resultset('MetaData')->create({
1015         book_id => $row->id,
1016         ...
1017       });
1018     }
1019   });
1020
1021 This won't either:
1022
1023   my $first_row = $large_rs->first;
1024   $schema->txn_do(sub { ... });
1025
1026 Transactions done for inserts in C<AutoCommit> mode when placeholders are in use
1027 are not affected, as they are done on an extra database handle.
1028
1029 Some workarounds:
1030
1031 =over 4
1032
1033 =item * use L<DBIx::Class::Storage::DBI::Replicated>
1034
1035 =item * L<connect|DBIx::Class::Schema/connect> another L<Schema|DBIx::Class::Schema>
1036
1037 =item * load the data from your cursor with L<DBIx::Class::ResultSet/all>
1038
1039 =back
1040
1041 =head1 MAXIMUM CONNECTIONS
1042
1043 The TDS protocol makes separate connections to the server for active statements
1044 in the background. By default the number of such connections is limited to 25,
1045 on both the client side and the server side.
1046
1047 This is a bit too low for a complex L<DBIx::Class> application, so on connection
1048 the client side setting is set to C<256> (see L<DBD::Sybase/maxConnect>.) You
1049 can override it to whatever setting you like in the DSN.
1050
1051 See
1052 L<http://infocenter.sybase.com/help/index.jsp?topic=/com.sybase.help.ase_15.0.sag1/html/sag1/sag1272.htm>
1053 for information on changing the setting on the server side.
1054
1055 =head1 DATES
1056
1057 See L</connect_call_datetime_setup> to setup date formats
1058 for L<DBIx::Class::InflateColumn::DateTime>.
1059
1060 =head1 TEXT/IMAGE COLUMNS
1061
1062 L<DBD::Sybase> compiled with FreeTDS will B<NOT> allow you to insert or update
1063 C<TEXT/IMAGE> columns.
1064
1065 Setting C<< $dbh->{LongReadLen} >> will also not work with FreeTDS use either:
1066
1067   $schema->storage->dbh->do("SET TEXTSIZE $bytes");
1068
1069 or
1070
1071   $schema->storage->set_textsize($bytes);
1072
1073 instead.
1074
1075 However, the C<LongReadLen> you pass in
1076 L<connect_info|DBIx::Class::Storage::DBI/connect_info> is used to execute the
1077 equivalent C<SET TEXTSIZE> command on connection.
1078
1079 See L</connect_call_blob_setup> for a
1080 L<connect_info|DBIx::Class::Storage::DBI/connect_info> setting you need to work
1081 with C<IMAGE> columns.
1082
1083 =head1 BULK API
1084
1085 The experimental L<DBD::Sybase> Bulk API support is used for
1086 L<populate|DBIx::Class::ResultSet/populate> in B<void> context, in a transaction
1087 on a separate connection.
1088
1089 To use this feature effectively, use a large number of rows for each
1090 L<populate|DBIx::Class::ResultSet/populate> call, eg.:
1091
1092   while (my $rows = $data_source->get_100_rows()) {
1093     $rs->populate($rows);
1094   }
1095
1096 B<NOTE:> the L<add_columns|DBIx::Class::ResultSource/add_columns>
1097 calls in your C<Result> classes B<must> list columns in database order for this
1098 to work. Also, you may have to unset the C<LANG> environment variable before
1099 loading your app, as C<BCP -Y> is not yet supported in DBD::Sybase .
1100
1101 When inserting IMAGE columns using this method, you'll need to use
1102 L</connect_call_blob_setup> as well.
1103
1104 =head1 COMPUTED COLUMNS
1105
1106 If you have columns such as:
1107
1108   created_dtm AS getdate()
1109
1110 represent them in your Result classes as:
1111
1112   created_dtm => {
1113     data_type => undef,
1114     default_value => \'getdate()',
1115     is_nullable => 0,
1116     inflate_datetime => 1,
1117   }
1118
1119 The C<data_type> must exist and must be C<undef>. Then empty inserts will work
1120 on tables with such columns.
1121
1122 =head1 TIMESTAMP COLUMNS
1123
1124 C<timestamp> columns in Sybase ASE are not really timestamps, see:
1125 L<http://dba.fyicenter.com/Interview-Questions/SYBASE/The_timestamp_datatype_in_Sybase_.html>.
1126
1127 They should be defined in your Result classes as:
1128
1129   ts => {
1130     data_type => 'timestamp',
1131     is_nullable => 0,
1132     inflate_datetime => 0,
1133   }
1134
1135 The C<<inflate_datetime => 0>> is necessary if you use
1136 L<DBIx::Class::InflateColumn::DateTime>, and most people do, and still want to
1137 be able to read these values.
1138
1139 The values will come back as hexadecimal.
1140
1141 =head1 TODO
1142
1143 =over
1144
1145 =item *
1146
1147 Transitions to AutoCommit=0 (starting a transaction) mode by exhausting
1148 any active cursors, using eager cursors.
1149
1150 =item *
1151
1152 Real limits and limited counts using stored procedures deployed on startup.
1153
1154 =item *
1155
1156 Blob update with a LIKE query on a blob, without invalidating the WHERE condition.
1157
1158 =item *
1159
1160 bulk_insert using prepare_cached (see comments.)
1161
1162 =back
1163
1164 =head1 AUTHOR
1165
1166 See L<DBIx::Class/AUTHOR> and L<DBIx::Class/CONTRIBUTORS>.
1167
1168 =head1 LICENSE
1169
1170 You may distribute this code under the same terms as Perl itself.
1171
1172 =cut
1173 # vim:sts=2 sw=2: