lib/DBIx/Class/Storage/DBI/Sybase/ASE.pm

   1 package DBIx::Class::Storage::DBI::Sybase::ASE;
   2
   3 use strict;
   4 use warnings;
   5
   6 use base qw/
   7     DBIx::Class::Storage::DBI::Sybase
   8     DBIx::Class::Storage::DBI::AutoCast
   9 /;
  10 use mro 'c3';
  11 use Carp::Clan qw/^DBIx::Class/;
  12 use Scalar::Util 'blessed';
  13 use List::Util 'first';
  14 use Sub::Name();
  15 use Data::Dumper::Concise 'Dumper';
  16 use Try::Tiny;
  17 use namespace::clean;
  18
  19 __PACKAGE__->sql_limit_dialect ('RowCountOrGenericSubQ');
  20
  21 __PACKAGE__->mk_group_accessors('simple' =>
  22     qw/_identity _blob_log_on_update _writer_storage _is_extra_storage
  23        _bulk_storage _is_bulk_storage _began_bulk_work
  24        _bulk_disabled_due_to_coderef_connect_info_warned
  25        _identity_method/
  26 );
  27
  28 my @also_proxy_to_extra_storages = qw/
  29   connect_call_set_auto_cast auto_cast connect_call_blob_setup
  30   connect_call_datetime_setup
  31
  32   disconnect _connect_info _sql_maker _sql_maker_opts disable_sth_caching
  33   auto_savepoint unsafe cursor_class debug debugobj schema
  34 /;
  35
  36 =head1 NAME
  37
  38 DBIx::Class::Storage::DBI::Sybase::ASE - Sybase ASE SQL Server support for
  39 DBIx::Class
  40
  41 =head1 SYNOPSIS
  42
  43 This subclass supports L<DBD::Sybase> for real (non-Microsoft) Sybase databases.
  44
  45 =head1 DESCRIPTION
  46
  47 If your version of Sybase does not support placeholders, then your storage will
  48 be reblessed to L<DBIx::Class::Storage::DBI::Sybase::ASE::NoBindVars>.
  49 You can also enable that driver explicitly, see the documentation for more
  50 details.
  51
  52 With this driver there is unfortunately no way to get the C<last_insert_id>
  53 without doing a C<SELECT MAX(col)>. This is done safely in a transaction
  54 (locking the table.) See L</INSERTS WITH PLACEHOLDERS>.
  55
  56 A recommended L<connect_info|DBIx::Class::Storage::DBI/connect_info> setting:
  57
  58   on_connect_call => [['datetime_setup'], ['blob_setup', log_on_update => 0]]
  59
  60 =head1 METHODS
  61
  62 =cut
  63
  64 sub _rebless {
  65   my $self = shift;
  66
  67   my $no_bind_vars = __PACKAGE__ . '::NoBindVars';
  68
  69   if ($self->using_freetds) {
  70     carp <<'EOF' unless $ENV{DBIC_SYBASE_FREETDS_NOWARN};
  71
  72 You are using FreeTDS with Sybase.
  73
  74 We will do our best to support this configuration, but please consider this
  75 support experimental.
  76
  77 TEXT/IMAGE columns will definitely not work.
  78
  79 You are encouraged to recompile DBD::Sybase with the Sybase Open Client libraries
  80 instead.
  81
  82 See perldoc DBIx::Class::Storage::DBI::Sybase::ASE for more details.
  83
  84 To turn off this warning set the DBIC_SYBASE_FREETDS_NOWARN environment
  85 variable.
  86 EOF
  87
  88     if (not $self->_use_typeless_placeholders) {
  89       if ($self->_use_placeholders) {
  90         $self->auto_cast(1);
  91       }
  92       else {
  93         $self->ensure_class_loaded($no_bind_vars);
  94         bless $self, $no_bind_vars;
  95         $self->_rebless;
  96       }
  97     }
  98   }
  99
 100   elsif (not $self->_get_dbh->{syb_dynamic_supported}) {
 101     # not necessarily FreeTDS, but no placeholders nevertheless
 102     $self->ensure_class_loaded($no_bind_vars);
 103     bless $self, $no_bind_vars;
 104     $self->_rebless;
 105   }
 106   # this is highly unlikely, but we check just in case
 107   elsif (not $self->_use_typeless_placeholders) {
 108     $self->auto_cast(1);
 109   }
 110 }
 111
 112 sub _init {
 113   my $self = shift;
 114   $self->_set_max_connect(256);
 115
 116 # create storage for insert/(update blob) transactions,
 117 # unless this is that storage
 118   return if $self->_is_extra_storage;
 119
 120   my $writer_storage = (ref $self)->new;
 121
 122   $writer_storage->_is_extra_storage(1);
 123   $writer_storage->connect_info($self->connect_info);
 124   $writer_storage->auto_cast($self->auto_cast);
 125
 126   $self->_writer_storage($writer_storage);
 127
 128 # create a bulk storage unless connect_info is a coderef
 129   return if ref($self->_dbi_connect_info->[0]) eq 'CODE';
 130
 131   my $bulk_storage = (ref $self)->new;
 132
 133   $bulk_storage->_is_extra_storage(1);
 134   $bulk_storage->_is_bulk_storage(1); # for special ->disconnect acrobatics
 135   $bulk_storage->connect_info($self->connect_info);
 136
 137 # this is why
 138   $bulk_storage->_dbi_connect_info->[0] .= ';bulkLogin=1';
 139
 140   $self->_bulk_storage($bulk_storage);
 141 }
 142
 143 for my $method (@also_proxy_to_extra_storages) {
 144   no strict 'refs';
 145   no warnings 'redefine';
 146
 147   my $replaced = __PACKAGE__->can($method);
 148
 149   *{$method} = Sub::Name::subname $method => sub {
 150     my $self = shift;
 151     $self->_writer_storage->$replaced(@_) if $self->_writer_storage;
 152     $self->_bulk_storage->$replaced(@_)   if $self->_bulk_storage;
 153     return $self->$replaced(@_);
 154   };
 155 }
 156
 157 sub disconnect {
 158   my $self = shift;
 159
 160 # Even though we call $sth->finish for uses off the bulk API, there's still an
 161 # "active statement" warning on disconnect, which we throw away here.
 162 # This is due to the bug described in insert_bulk.
 163 # Currently a noop because 'prepare' is used instead of 'prepare_cached'.
 164   local $SIG{__WARN__} = sub {
 165     warn $_[0] unless $_[0] =~ /active statement/i;
 166   } if $self->_is_bulk_storage;
 167
 168 # so that next transaction gets a dbh
 169   $self->_began_bulk_work(0) if $self->_is_bulk_storage;
 170
 171   $self->next::method;
 172 }
 173
 174 # Set up session settings for Sybase databases for the connection.
 175 #
 176 # Make sure we have CHAINED mode turned on if AutoCommit is off in non-FreeTDS
 177 # DBD::Sybase (since we don't know how DBD::Sybase was compiled.) If however
 178 # we're using FreeTDS, CHAINED mode turns on an implicit transaction which we
 179 # only want when AutoCommit is off.
 180 #
 181 # Also SET TEXTSIZE for FreeTDS because LongReadLen doesn't work.
 182 sub _run_connection_actions {
 183   my $self = shift;
 184
 185   if ($self->_is_bulk_storage) {
 186 # this should be cleared on every reconnect
 187     $self->_began_bulk_work(0);
 188     return;
 189   }
 190
 191   if (not $self->using_freetds) {
 192     $self->_dbh->{syb_chained_txn} = 1;
 193   } else {
 194     # based on LongReadLen in connect_info
 195     $self->set_textsize;
 196
 197     if ($self->_dbh_autocommit) {
 198       $self->_dbh->do('SET CHAINED OFF');
 199     } else {
 200       $self->_dbh->do('SET CHAINED ON');
 201     }
 202   }
 203
 204   $self->next::method(@_);
 205 }
 206
 207 =head2 connect_call_blob_setup
 208
 209 Used as:
 210
 211   on_connect_call => [ [ 'blob_setup', log_on_update => 0 ] ]
 212
 213 Does C<< $dbh->{syb_binary_images} = 1; >> to return C<IMAGE> data as raw binary
 214 instead of as a hex string.
 215
 216 Recommended.
 217
 218 Also sets the C<log_on_update> value for blob write operations. The default is
 219 C<1>, but C<0> is better if your database is configured for it.
 220
 221 See
 222 L<DBD::Sybase/Handling_IMAGE/TEXT_data_with_syb_ct_get_data()/syb_ct_send_data()>.
 223
 224 =cut
 225
 226 sub connect_call_blob_setup {
 227   my $self = shift;
 228   my %args = @_;
 229   my $dbh = $self->_dbh;
 230   $dbh->{syb_binary_images} = 1;
 231
 232   $self->_blob_log_on_update($args{log_on_update})
 233     if exists $args{log_on_update};
 234 }
 235
 236 sub _is_lob_type {
 237   my $self = shift;
 238   my $type = shift;
 239   $type && $type =~ /(?:text|image|lob|bytea|binary|memo)/i;
 240 }
 241
 242 sub _is_lob_column {
 243   my ($self, $source, $column) = @_;
 244
 245   return $self->_is_lob_type($source->column_info($column)->{data_type});
 246 }
 247
 248 sub _prep_for_execute {
 249   my $self = shift;
 250   my ($op, $extra_bind, $ident, $args) = @_;
 251
 252   my ($sql, $bind) = $self->next::method (@_);
 253
 254   my $table = blessed $ident ? $ident->from : $ident;
 255
 256   my $bind_info = $self->_resolve_column_info(
 257     $ident, [map $_->[0], @{$bind}]
 258   );
 259   my $bound_identity_col =
 260     first { $bind_info->{$_}{is_auto_increment} }
 261     keys %$bind_info
 262   ;
 263
 264   my $columns_info = blessed $ident && $ident->columns_info;
 265
 266   my $identity_col =
 267     $columns_info &&
 268     first { $columns_info->{$_}{is_auto_increment} }
 269       keys %$columns_info
 270   ;
 271
 272   if (($op eq 'insert' && $bound_identity_col) ||
 273       ($op eq 'update' && exists $args->[0]{$identity_col})) {
 274     $sql = join ("\n",
 275       $self->_set_table_identity_sql($op => $table, 'on'),
 276       $sql,
 277       $self->_set_table_identity_sql($op => $table, 'off'),
 278     );
 279   }
 280
 281   if ($op eq 'insert' && (not $bound_identity_col) && $identity_col &&
 282       (not $self->{insert_bulk})) {
 283     $sql =
 284       "$sql\n" .
 285       $self->_fetch_identity_sql($ident, $identity_col);
 286   }
 287
 288   return ($sql, $bind);
 289 }
 290
 291 sub _set_table_identity_sql {
 292   my ($self, $op, $table, $on_off) = @_;
 293
 294   return sprintf 'SET IDENTITY_%s %s %s',
 295     uc($op), $self->sql_maker->_quote($table), uc($on_off);
 296 }
 297
 298 # Stolen from SQLT, with some modifications. This is a makeshift
 299 # solution before a sane type-mapping library is available, thus
 300 # the 'our' for easy overrides.
 301 our %TYPE_MAPPING  = (
 302     number    => 'numeric',
 303     money     => 'money',
 304     varchar   => 'varchar',
 305     varchar2  => 'varchar',
 306     timestamp => 'datetime',
 307     text      => 'varchar',
 308     real      => 'double precision',
 309     comment   => 'text',
 310     bit       => 'bit',
 311     tinyint   => 'smallint',
 312     float     => 'double precision',
 313     serial    => 'numeric',
 314     bigserial => 'numeric',
 315     boolean   => 'varchar',
 316     long      => 'varchar',
 317 );
 318
 319 sub _native_data_type {
 320   my ($self, $type) = @_;
 321
 322   $type = lc $type;
 323   $type =~ s/\s* identity//x;
 324
 325   return uc($TYPE_MAPPING{$type} || $type);
 326 }
 327
 328 sub _fetch_identity_sql {
 329   my ($self, $source, $col) = @_;
 330
 331   return sprintf ("SELECT MAX(%s) FROM %s",
 332     map { $self->sql_maker->_quote ($_) } ($col, $source->from)
 333   );
 334 }
 335
 336 sub _execute {
 337   my $self = shift;
 338   my ($op) = @_;
 339
 340   my ($rv, $sth, @bind) = $self->dbh_do($self->can('_dbh_execute'), @_);
 341
 342   if ($op eq 'insert') {
 343     $self->_identity($sth->fetchrow_array);
 344     $sth->finish;
 345   }
 346
 347   return wantarray ? ($rv, $sth, @bind) : $rv;
 348 }
 349
 350 sub last_insert_id { shift->_identity }
 351
 352 # handles TEXT/IMAGE and transaction for last_insert_id
 353 sub insert {
 354   my $self = shift;
 355   my ($source, $to_insert) = @_;
 356
 357   my $columns_info = $source->columns_info;
 358
 359   my $identity_col =
 360     (first { $columns_info->{$_}{is_auto_increment} }
 361       keys %$columns_info )
 362     || '';
 363
 364   # check for empty insert
 365   # INSERT INTO foo DEFAULT VALUES -- does not work with Sybase
 366   # try to insert explicit 'DEFAULT's instead (except for identity, timestamp
 367   # and computed columns)
 368   if (not %$to_insert) {
 369     for my $col ($source->columns) {
 370       next if $col eq $identity_col;
 371
 372       my $info = $source->column_info($col);
 373
 374       next if ref $info->{default_value} eq 'SCALAR'
 375         || (exists $info->{data_type} && (not defined $info->{data_type}));
 376
 377       next if $info->{data_type} && $info->{data_type} =~ /^timestamp\z/i;
 378
 379       $to_insert->{$col} = \'DEFAULT';
 380     }
 381   }
 382
 383   my $blob_cols = $self->_remove_blob_cols($source, $to_insert);
 384
 385   # do we need the horrific SELECT MAX(COL) hack?
 386   my $dumb_last_insert_id =
 387        $identity_col
 388     && (not exists $to_insert->{$identity_col})
 389     && ($self->_identity_method||'') ne '@@IDENTITY';
 390
 391   my $next = $self->next::can;
 392
 393   # we are already in a transaction, or there are no blobs
 394   # and we don't need the PK - just (try to) do it
 395   if ($self->{transaction_depth}
 396         || (!$blob_cols && !$dumb_last_insert_id)
 397   ) {
 398     return $self->_insert (
 399       $next, $source, $to_insert, $blob_cols, $identity_col
 400     );
 401   }
 402
 403   # otherwise use the _writer_storage to do the insert+transaction on another
 404   # connection
 405   my $guard = $self->_writer_storage->txn_scope_guard;
 406
 407   my $updated_cols = $self->_writer_storage->_insert (
 408     $next, $source, $to_insert, $blob_cols, $identity_col
 409   );
 410
 411   $self->_identity($self->_writer_storage->_identity);
 412
 413   $guard->commit;
 414
 415   return $updated_cols;
 416 }
 417
 418 sub _insert {
 419   my ($self, $next, $source, $to_insert, $blob_cols, $identity_col) = @_;
 420
 421   my $updated_cols = $self->$next ($source, $to_insert);
 422
 423   my $final_row = {
 424     ($identity_col ?
 425       ($identity_col => $self->last_insert_id($source, $identity_col)) : ()),
 426     %$to_insert,
 427     %$updated_cols,
 428   };
 429
 430   $self->_insert_blobs ($source, $blob_cols, $final_row) if $blob_cols;
 431
 432   return $updated_cols;
 433 }
 434
 435 sub update {
 436   my $self = shift;
 437   my ($source, $fields, $where, @rest) = @_;
 438
 439   my $blob_cols = $self->_remove_blob_cols($source, $fields);
 440
 441   my $table = $source->name;
 442
 443   my $columns_info = $source->columns_info;
 444
 445   my $identity_col =
 446     first { $columns_info->{$_}{is_auto_increment} }
 447       keys %$columns_info;
 448
 449   my $is_identity_update = $identity_col && defined $fields->{$identity_col};
 450
 451   return $self->next::method(@_) unless $blob_cols;
 452
 453 # If there are any blobs in $where, Sybase will return a descriptive error
 454 # message.
 455 # XXX blobs can still be used with a LIKE query, and this should be handled.
 456
 457 # update+blob update(s) done atomically on separate connection
 458   $self = $self->_writer_storage;
 459
 460   my $guard = $self->txn_scope_guard;
 461
 462 # First update the blob columns to be updated to '' (taken from $fields, where
 463 # it is originally put by _remove_blob_cols .)
 464   my %blobs_to_empty = map { ($_ => delete $fields->{$_}) } keys %$blob_cols;
 465
 466 # We can't only update NULL blobs, because blobs cannot be in the WHERE clause.
 467
 468   $self->next::method($source, \%blobs_to_empty, $where, @rest);
 469
 470 # Now update the blobs before the other columns in case the update of other
 471 # columns makes the search condition invalid.
 472   $self->_update_blobs($source, $blob_cols, $where);
 473
 474   my @res;
 475   if (%$fields) {
 476     if (wantarray) {
 477       @res    = $self->next::method(@_);
 478     }
 479     elsif (defined wantarray) {
 480       $res[0] = $self->next::method(@_);
 481     }
 482     else {
 483       $self->next::method(@_);
 484     }
 485   }
 486
 487   $guard->commit;
 488
 489   return wantarray ? @res : $res[0];
 490 }
 491
 492 sub insert_bulk {
 493   my $self = shift;
 494   my ($source, $cols, $data) = @_;
 495
 496   my $columns_info = $source->columns_info;
 497
 498   my $identity_col =
 499     first { $columns_info->{$_}{is_auto_increment} }
 500       keys %$columns_info;
 501
 502   my $is_identity_insert = (first { $_ eq $identity_col } @{$cols}) ? 1 : 0;
 503
 504   my @source_columns = $source->columns;
 505
 506   my $use_bulk_api =
 507     $self->_bulk_storage &&
 508     $self->_get_dbh->{syb_has_blk};
 509
 510   if ((not $use_bulk_api)
 511         &&
 512       (ref($self->_dbi_connect_info->[0]) eq 'CODE')
 513         &&
 514       (not $self->_bulk_disabled_due_to_coderef_connect_info_warned)) {
 515     carp <<'EOF';
 516 Bulk API support disabled due to use of a CODEREF connect_info. Reverting to
 517 regular array inserts.
 518 EOF
 519     $self->_bulk_disabled_due_to_coderef_connect_info_warned(1);
 520   }
 521
 522   if (not $use_bulk_api) {
 523     my $blob_cols = $self->_remove_blob_cols_array($source, $cols, $data);
 524
 525 # _execute_array uses a txn anyway, but it ends too early in case we need to
 526 # select max(col) to get the identity for inserting blobs.
 527     ($self, my $guard) = $self->{transaction_depth} == 0 ?
 528       ($self->_writer_storage, $self->_writer_storage->txn_scope_guard)
 529       :
 530       ($self, undef);
 531
 532     local $self->{insert_bulk} = 1;
 533
 534     $self->next::method(@_);
 535
 536     if ($blob_cols) {
 537       if ($is_identity_insert) {
 538         $self->_insert_blobs_array ($source, $blob_cols, $cols, $data);
 539       }
 540       else {
 541         my @cols_with_identities = (@$cols, $identity_col);
 542
 543         ## calculate identities
 544         # XXX This assumes identities always increase by 1, which may or may not
 545         # be true.
 546         my ($last_identity) =
 547           $self->_dbh->selectrow_array (
 548             $self->_fetch_identity_sql($source, $identity_col)
 549           );
 550         my @identities = (($last_identity - @$data + 1) .. $last_identity);
 551
 552         my @data_with_identities = map [@$_, shift @identities], @$data;
 553
 554         $self->_insert_blobs_array (
 555           $source, $blob_cols, \@cols_with_identities, \@data_with_identities
 556         );
 557       }
 558     }
 559
 560     $guard->commit if $guard;
 561
 562     return;
 563   }
 564
 565 # otherwise, use the bulk API
 566
 567 # rearrange @$data so that columns are in database order
 568   my %orig_idx;
 569   @orig_idx{@$cols} = 0..$#$cols;
 570
 571   my %new_idx;
 572   @new_idx{@source_columns} = 0..$#source_columns;
 573
 574   my @new_data;
 575   for my $datum (@$data) {
 576     my $new_datum = [];
 577     for my $col (@source_columns) {
 578 # identity data will be 'undef' if not $is_identity_insert
 579 # columns with defaults will also be 'undef'
 580       $new_datum->[ $new_idx{$col} ] =
 581         exists $orig_idx{$col} ? $datum->[ $orig_idx{$col} ] : undef;
 582     }
 583     push @new_data, $new_datum;
 584   }
 585
 586 # bcp identity index is 1-based
 587   my $identity_idx = exists $new_idx{$identity_col} ?
 588     $new_idx{$identity_col} + 1 : 0;
 589
 590 ## Set a client-side conversion error handler, straight from DBD::Sybase docs.
 591 # This ignores any data conversion errors detected by the client side libs, as
 592 # they are usually harmless.
 593   my $orig_cslib_cb = DBD::Sybase::set_cslib_cb(
 594     Sub::Name::subname insert_bulk => sub {
 595       my ($layer, $origin, $severity, $errno, $errmsg, $osmsg, $blkmsg) = @_;
 596
 597       return 1 if $errno == 36;
 598
 599       carp
 600         "Layer: $layer, Origin: $origin, Severity: $severity, Error: $errno" .
 601         ($errmsg ? "\n$errmsg" : '') .
 602         ($osmsg  ? "\n$osmsg"  : '')  .
 603         ($blkmsg ? "\n$blkmsg" : '');
 604
 605       return 0;
 606   });
 607
 608   my $exception = '';
 609   try {
 610     my $bulk = $self->_bulk_storage;
 611
 612     my $guard = $bulk->txn_scope_guard;
 613
 614 ## XXX get this to work instead of our own $sth
 615 ## will require SQLA or *Hacks changes for ordered columns
 616 #    $bulk->next::method($source, \@source_columns, \@new_data, {
 617 #      syb_bcp_attribs => {
 618 #        identity_flag   => $is_identity_insert,
 619 #        identity_column => $identity_idx,
 620 #      }
 621 #    });
 622     my $sql = 'INSERT INTO ' .
 623       $bulk->sql_maker->_quote($source->name) . ' (' .
 624 # colname list is ignored for BCP, but does no harm
 625       (join ', ', map $bulk->sql_maker->_quote($_), @source_columns) . ') '.
 626       ' VALUES ('.  (join ', ', ('?') x @source_columns) . ')';
 627
 628 ## XXX there's a bug in the DBD::Sybase bulk support that makes $sth->finish for
 629 ## a prepare_cached statement ineffective. Replace with ->sth when fixed, or
 630 ## better yet the version above. Should be fixed in DBD::Sybase .
 631     my $sth = $bulk->_get_dbh->prepare($sql,
 632 #      'insert', # op
 633       {
 634         syb_bcp_attribs => {
 635           identity_flag   => $is_identity_insert,
 636           identity_column => $identity_idx,
 637         }
 638       }
 639     );
 640
 641     my @bind = do {
 642       my $idx = 0;
 643       map [ $_, $idx++ ], @source_columns;
 644     };
 645
 646     $self->_execute_array(
 647       $source, $sth, \@bind, \@source_columns, \@new_data, sub {
 648         $guard->commit
 649       }
 650     );
 651
 652     $bulk->_query_end($sql);
 653   } catch {
 654     $exception = shift;
 655   };
 656
 657   DBD::Sybase::set_cslib_cb($orig_cslib_cb);
 658
 659   if ($exception =~ /-Y option/) {
 660     my $w = 'Sybase bulk API operation failed due to character set incompatibility, '
 661           . 'reverting to regular array inserts. Try unsetting the LANG environment variable'
 662     ;
 663     $w .= "\n$exception" if $self->debug;
 664     carp $w;
 665
 666     $self->_bulk_storage(undef);
 667     unshift @_, $self;
 668     goto \&insert_bulk;
 669   }
 670   elsif ($exception) {
 671 # rollback makes the bulkLogin connection unusable
 672     $self->_bulk_storage->disconnect;
 673     $self->throw_exception($exception);
 674   }
 675 }
 676
 677 sub _dbh_execute_array {
 678   my ($self, $sth, $tuple_status, $cb) = @_;
 679
 680   my $rv = $self->next::method($sth, $tuple_status);
 681   $cb->() if $cb;
 682
 683   return $rv;
 684 }
 685
 686 # Make sure blobs are not bound as placeholders, and return any non-empty ones
 687 # as a hash.
 688 sub _remove_blob_cols {
 689   my ($self, $source, $fields) = @_;
 690
 691   my %blob_cols;
 692
 693   for my $col (keys %$fields) {
 694     if ($self->_is_lob_column($source, $col)) {
 695       my $blob_val = delete $fields->{$col};
 696       if (not defined $blob_val) {
 697         $fields->{$col} = \'NULL';
 698       }
 699       else {
 700         $fields->{$col} = \"''";
 701         $blob_cols{$col} = $blob_val unless $blob_val eq '';
 702       }
 703     }
 704   }
 705
 706   return %blob_cols ? \%blob_cols : undef;
 707 }
 708
 709 # same for insert_bulk
 710 sub _remove_blob_cols_array {
 711   my ($self, $source, $cols, $data) = @_;
 712
 713   my @blob_cols;
 714
 715   for my $i (0..$#$cols) {
 716     my $col = $cols->[$i];
 717
 718     if ($self->_is_lob_column($source, $col)) {
 719       for my $j (0..$#$data) {
 720         my $blob_val = delete $data->[$j][$i];
 721         if (not defined $blob_val) {
 722           $data->[$j][$i] = \'NULL';
 723         }
 724         else {
 725           $data->[$j][$i] = \"''";
 726           $blob_cols[$j][$i] = $blob_val
 727             unless $blob_val eq '';
 728         }
 729       }
 730     }
 731   }
 732
 733   return @blob_cols ? \@blob_cols : undef;
 734 }
 735
 736 sub _update_blobs {
 737   my ($self, $source, $blob_cols, $where) = @_;
 738
 739   my @primary_cols = try
 740     { $source->_pri_cols }
 741     catch {
 742       $self->throw_exception("Cannot update TEXT/IMAGE column(s): $_")
 743     };
 744
 745 # check if we're updating a single row by PK
 746   my $pk_cols_in_where = 0;
 747   for my $col (@primary_cols) {
 748     $pk_cols_in_where++ if defined $where->{$col};
 749   }
 750   my @rows;
 751
 752   if ($pk_cols_in_where == @primary_cols) {
 753     my %row_to_update;
 754     @row_to_update{@primary_cols} = @{$where}{@primary_cols};
 755     @rows = \%row_to_update;
 756   } else {
 757     my $cursor = $self->select ($source, \@primary_cols, $where, {});
 758     @rows = map {
 759       my %row; @row{@primary_cols} = @$_; \%row
 760     } $cursor->all;
 761   }
 762
 763   for my $row (@rows) {
 764     $self->_insert_blobs($source, $blob_cols, $row);
 765   }
 766 }
 767
 768 sub _insert_blobs {
 769   my ($self, $source, $blob_cols, $row) = @_;
 770   my $dbh = $self->_get_dbh;
 771
 772   my $table = $source->name;
 773
 774   my %row = %$row;
 775   my @primary_cols = try
 776     { $source->_pri_cols }
 777     catch {
 778       $self->throw_exception("Cannot update TEXT/IMAGE column(s): $_")
 779     };
 780
 781   $self->throw_exception('Cannot update TEXT/IMAGE column(s) without primary key values')
 782     if ((grep { defined $row{$_} } @primary_cols) != @primary_cols);
 783
 784   for my $col (keys %$blob_cols) {
 785     my $blob = $blob_cols->{$col};
 786
 787     my %where = map { ($_, $row{$_}) } @primary_cols;
 788
 789     my $cursor = $self->select ($source, [$col], \%where, {});
 790     $cursor->next;
 791     my $sth = $cursor->sth;
 792
 793     if (not $sth) {
 794       $self->throw_exception(
 795           "Could not find row in table '$table' for blob update:\n"
 796         . (Dumper \%where)
 797       );
 798     }
 799
 800     try {
 801       do {
 802         $sth->func('CS_GET', 1, 'ct_data_info') or die $sth->errstr;
 803       } while $sth->fetch;
 804
 805       $sth->func('ct_prepare_send') or die $sth->errstr;
 806
 807       my $log_on_update = $self->_blob_log_on_update;
 808       $log_on_update    = 1 if not defined $log_on_update;
 809
 810       $sth->func('CS_SET', 1, {
 811         total_txtlen => length($blob),
 812         log_on_update => $log_on_update
 813       }, 'ct_data_info') or die $sth->errstr;
 814
 815       $sth->func($blob, length($blob), 'ct_send_data') or die $sth->errstr;
 816
 817       $sth->func('ct_finish_send') or die $sth->errstr;
 818     }
 819     catch {
 820       if ($self->using_freetds) {
 821         $self->throw_exception (
 822           "TEXT/IMAGE operation failed, probably because you are using FreeTDS: $_"
 823         );
 824       }
 825       else {
 826         $self->throw_exception($_);
 827       }
 828     }
 829     finally {
 830       $sth->finish if $sth;
 831     };
 832   }
 833 }
 834
 835 sub _insert_blobs_array {
 836   my ($self, $source, $blob_cols, $cols, $data) = @_;
 837
 838   for my $i (0..$#$data) {
 839     my $datum = $data->[$i];
 840
 841     my %row;
 842     @row{ @$cols } = @$datum;
 843
 844     my %blob_vals;
 845     for my $j (0..$#$cols) {
 846       if (exists $blob_cols->[$i][$j]) {
 847         $blob_vals{ $cols->[$j] } = $blob_cols->[$i][$j];
 848       }
 849     }
 850
 851     $self->_insert_blobs ($source, \%blob_vals, \%row);
 852   }
 853 }
 854
 855 =head2 connect_call_datetime_setup
 856
 857 Used as:
 858
 859   on_connect_call => 'datetime_setup'
 860
 861 In L<connect_info|DBIx::Class::Storage::DBI/connect_info> to set:
 862
 863   $dbh->syb_date_fmt('ISO_strict'); # output fmt: 2004-08-21T14:36:48.080Z
 864   $dbh->do('set dateformat mdy');   # input fmt:  08/13/1979 18:08:55.080
 865
 866 On connection for use with L<DBIx::Class::InflateColumn::DateTime>, using
 867 L<DateTime::Format::Sybase>, which you will need to install.
 868
 869 This works for both C<DATETIME> and C<SMALLDATETIME> columns, although
 870 C<SMALLDATETIME> columns only have minute precision.
 871
 872 =cut
 873
 874 {
 875   my $old_dbd_warned = 0;
 876
 877   sub connect_call_datetime_setup {
 878     my $self = shift;
 879     my $dbh = $self->_get_dbh;
 880
 881     if ($dbh->can('syb_date_fmt')) {
 882       # amazingly, this works with FreeTDS
 883       $dbh->syb_date_fmt('ISO_strict');
 884     } elsif (not $old_dbd_warned) {
 885       carp "Your DBD::Sybase is too old to support ".
 886       "DBIx::Class::InflateColumn::DateTime, please upgrade!";
 887       $old_dbd_warned = 1;
 888     }
 889
 890     $dbh->do('SET DATEFORMAT mdy');
 891
 892     1;
 893   }
 894 }
 895
 896 sub datetime_parser_type { "DateTime::Format::Sybase" }
 897
 898 # ->begin_work and such have no effect with FreeTDS but we run them anyway to
 899 # let the DBD keep any state it needs to.
 900 #
 901 # If they ever do start working, the extra statements will do no harm (because
 902 # Sybase supports nested transactions.)
 903
 904 sub _dbh_begin_work {
 905   my $self = shift;
 906
 907 # bulkLogin=1 connections are always in a transaction, and can only call BEGIN
 908 # TRAN once. However, we need to make sure there's a $dbh.
 909   return if $self->_is_bulk_storage && $self->_dbh && $self->_began_bulk_work;
 910
 911   $self->next::method(@_);
 912
 913   if ($self->using_freetds) {
 914     $self->_get_dbh->do('BEGIN TRAN');
 915   }
 916
 917   $self->_began_bulk_work(1) if $self->_is_bulk_storage;
 918 }
 919
 920 sub _dbh_commit {
 921   my $self = shift;
 922   if ($self->using_freetds) {
 923     $self->_dbh->do('COMMIT');
 924   }
 925   return $self->next::method(@_);
 926 }
 927
 928 sub _dbh_rollback {
 929   my $self = shift;
 930   if ($self->using_freetds) {
 931     $self->_dbh->do('ROLLBACK');
 932   }
 933   return $self->next::method(@_);
 934 }
 935
 936 # savepoint support using ASE syntax
 937
 938 sub _svp_begin {
 939   my ($self, $name) = @_;
 940
 941   $self->_get_dbh->do("SAVE TRANSACTION $name");
 942 }
 943
 944 # A new SAVE TRANSACTION with the same name releases the previous one.
 945 sub _svp_release { 1 }
 946
 947 sub _svp_rollback {
 948   my ($self, $name) = @_;
 949
 950   $self->_get_dbh->do("ROLLBACK TRANSACTION $name");
 951 }
 952
 953 1;
 954
 955 =head1 Schema::Loader Support
 956
 957 As of version C<0.05000>, L<DBIx::Class::Schema::Loader> should work well with
 958 most (if not all) versions of Sybase ASE.
 959
 960 =head1 FreeTDS
 961
 962 This driver supports L<DBD::Sybase> compiled against FreeTDS
 963 (L<http://www.freetds.org/>) to the best of our ability, however it is
 964 recommended that you recompile L<DBD::Sybase> against the Sybase Open Client
 965 libraries. They are a part of the Sybase ASE distribution:
 966
 967 The Open Client FAQ is here:
 968 L<http://www.isug.com/Sybase_FAQ/ASE/section7.html>.
 969
 970 Sybase ASE for Linux (which comes with the Open Client libraries) may be
 971 downloaded here: L<http://response.sybase.com/forms/ASE_Linux_Download>.
 972
 973 To see if you're using FreeTDS check C<< $schema->storage->using_freetds >>, or run:
 974
 975   perl -MDBI -le 'my $dbh = DBI->connect($dsn, $user, $pass); print $dbh->{syb_oc_version}'
 976
 977 Some versions of the libraries involved will not support placeholders, in which
 978 case the storage will be reblessed to
 979 L<DBIx::Class::Storage::DBI::Sybase::ASE::NoBindVars>.
 980
 981 In some configurations, placeholders will work but will throw implicit type
 982 conversion errors for anything that's not expecting a string. In such a case,
 983 the C<auto_cast> option from L<DBIx::Class::Storage::DBI::AutoCast> is
 984 automatically set, which you may enable on connection with
 985 L<DBIx::Class::Storage::DBI::AutoCast/connect_call_set_auto_cast>. The type info
 986 for the C<CAST>s is taken from the L<DBIx::Class::ResultSource/data_type>
 987 definitions in your Result classes, and are mapped to a Sybase type (if it isn't
 988 already) using a mapping based on L<SQL::Translator>.
 989
 990 In other configurations, placeholders will work just as they do with the Sybase
 991 Open Client libraries.
 992
 993 Inserts or updates of TEXT/IMAGE columns will B<NOT> work with FreeTDS.
 994
 995 =head1 INSERTS WITH PLACEHOLDERS
 996
 997 With placeholders enabled, inserts are done in a transaction so that there are
 998 no concurrency issues with getting the inserted identity value using
 999 C<SELECT MAX(col)>, which is the only way to get the C<IDENTITY> value in this
1000 mode.
1001
1002 In addition, they are done on a separate connection so that it's possible to
1003 have active cursors when doing an insert.
1004
1005 When using C<DBIx::Class::Storage::DBI::Sybase::ASE::NoBindVars> transactions
1006 are disabled, as there are no concurrency issues with C<SELECT @@IDENTITY> as
1007 it's a session variable.
1008
1009 =head1 TRANSACTIONS
1010
1011 Due to limitations of the TDS protocol, L<DBD::Sybase>, or both, you cannot
1012 begin a transaction while there are active cursors, nor can you use multiple
1013 active cursors within a transaction. An active cursor is, for example, a
1014 L<ResultSet|DBIx::Class::ResultSet> that has been executed using C<next> or
1015 C<first> but has not been exhausted or L<reset|DBIx::Class::ResultSet/reset>.
1016
1017 For example, this will not work:
1018
1019   $schema->txn_do(sub {
1020     my $rs = $schema->resultset('Book');
1021     while (my $row = $rs->next) {
1022       $schema->resultset('MetaData')->create({
1023         book_id => $row->id,
1024         ...
1025       });
1026     }
1027   });
1028
1029 This won't either:
1030
1031   my $first_row = $large_rs->first;
1032   $schema->txn_do(sub { ... });
1033
1034 Transactions done for inserts in C<AutoCommit> mode when placeholders are in use
1035 are not affected, as they are done on an extra database handle.
1036
1037 Some workarounds:
1038
1039 =over 4
1040
1041 =item * use L<DBIx::Class::Storage::DBI::Replicated>
1042
1043 =item * L<connect|DBIx::Class::Schema/connect> another L<Schema|DBIx::Class::Schema>
1044
1045 =item * load the data from your cursor with L<DBIx::Class::ResultSet/all>
1046
1047 =back
1048
1049 =head1 MAXIMUM CONNECTIONS
1050
1051 The TDS protocol makes separate connections to the server for active statements
1052 in the background. By default the number of such connections is limited to 25,
1053 on both the client side and the server side.
1054
1055 This is a bit too low for a complex L<DBIx::Class> application, so on connection
1056 the client side setting is set to C<256> (see L<DBD::Sybase/maxConnect>.) You
1057 can override it to whatever setting you like in the DSN.
1058
1059 See
1060 L<http://infocenter.sybase.com/help/index.jsp?topic=/com.sybase.help.ase_15.0.sag1/html/sag1/sag1272.htm>
1061 for information on changing the setting on the server side.
1062
1063 =head1 DATES
1064
1065 See L</connect_call_datetime_setup> to setup date formats
1066 for L<DBIx::Class::InflateColumn::DateTime>.
1067
1068 =head1 TEXT/IMAGE COLUMNS
1069
1070 L<DBD::Sybase> compiled with FreeTDS will B<NOT> allow you to insert or update
1071 C<TEXT/IMAGE> columns.
1072
1073 Setting C<< $dbh->{LongReadLen} >> will also not work with FreeTDS use either:
1074
1075   $schema->storage->dbh->do("SET TEXTSIZE $bytes");
1076
1077 or
1078
1079   $schema->storage->set_textsize($bytes);
1080
1081 instead.
1082
1083 However, the C<LongReadLen> you pass in
1084 L<connect_info|DBIx::Class::Storage::DBI/connect_info> is used to execute the
1085 equivalent C<SET TEXTSIZE> command on connection.
1086
1087 See L</connect_call_blob_setup> for a
1088 L<connect_info|DBIx::Class::Storage::DBI/connect_info> setting you need to work
1089 with C<IMAGE> columns.
1090
1091 =head1 BULK API
1092
1093 The experimental L<DBD::Sybase> Bulk API support is used for
1094 L<populate|DBIx::Class::ResultSet/populate> in B<void> context, in a transaction
1095 on a separate connection.
1096
1097 To use this feature effectively, use a large number of rows for each
1098 L<populate|DBIx::Class::ResultSet/populate> call, eg.:
1099
1100   while (my $rows = $data_source->get_100_rows()) {
1101     $rs->populate($rows);
1102   }
1103
1104 B<NOTE:> the L<add_columns|DBIx::Class::ResultSource/add_columns>
1105 calls in your C<Result> classes B<must> list columns in database order for this
1106 to work. Also, you may have to unset the C<LANG> environment variable before
1107 loading your app, if it doesn't match the character set of your database.
1108
1109 When inserting IMAGE columns using this method, you'll need to use
1110 L</connect_call_blob_setup> as well.
1111
1112 =head1 COMPUTED COLUMNS
1113
1114 If you have columns such as:
1115
1116   created_dtm AS getdate()
1117
1118 represent them in your Result classes as:
1119
1120   created_dtm => {
1121     data_type => undef,
1122     default_value => \'getdate()',
1123     is_nullable => 0,
1124   }
1125
1126 The C<data_type> must exist and must be C<undef>. Then empty inserts will work
1127 on tables with such columns.
1128
1129 =head1 TIMESTAMP COLUMNS
1130
1131 C<timestamp> columns in Sybase ASE are not really timestamps, see:
1132 L<http://dba.fyicenter.com/Interview-Questions/SYBASE/The_timestamp_datatype_in_Sybase_.html>.
1133
1134 They should be defined in your Result classes as:
1135
1136   ts => {
1137     data_type => 'timestamp',
1138     is_nullable => 0,
1139     inflate_datetime => 0,
1140   }
1141
1142 The C<<inflate_datetime => 0>> is necessary if you use
1143 L<DBIx::Class::InflateColumn::DateTime>, and most people do, and still want to
1144 be able to read these values.
1145
1146 The values will come back as hexadecimal.
1147
1148 =head1 TODO
1149
1150 =over
1151
1152 =item *
1153
1154 Transitions to AutoCommit=0 (starting a transaction) mode by exhausting
1155 any active cursors, using eager cursors.
1156
1157 =item *
1158
1159 Real limits and limited counts using stored procedures deployed on startup.
1160
1161 =item *
1162
1163 Adaptive Server Anywhere (ASA) support
1164
1165 =item *
1166
1167 Blob update with a LIKE query on a blob, without invalidating the WHERE condition.
1168
1169 =item *
1170
1171 bulk_insert using prepare_cached (see comments.)
1172
1173 =back
1174
1175 =head1 AUTHOR
1176
1177 See L<DBIx::Class/CONTRIBUTORS>.
1178
1179 =head1 LICENSE
1180
1181 You may distribute this code under the same terms as Perl itself.
1182
1183 =cut
1184 # vim:sts=2 sw=2: