lib/DBIx/Class/Storage/DBI/Sybase/ASE.pm

   1 package DBIx::Class::Storage::DBI::Sybase::ASE;
   2
   3 use strict;
   4 use warnings;
   5
   6 use base qw/
   7     DBIx::Class::Storage::DBI::Sybase
   8     DBIx::Class::Storage::DBI::AutoCast
   9 /;
  10 use mro 'c3';
  11 use Carp::Clan qw/^DBIx::Class/;
  12 use Scalar::Util 'blessed';
  13 use List::Util 'first';
  14 use Sub::Name();
  15 use Data::Dumper::Concise 'Dumper';
  16 use Try::Tiny;
  17 use namespace::clean;
  18
  19 __PACKAGE__->sql_limit_dialect ('RowCountOrGenericSubQ');
  20
  21 __PACKAGE__->mk_group_accessors('simple' =>
  22     qw/_identity _blob_log_on_update _writer_storage _is_extra_storage
  23        _bulk_storage _is_bulk_storage _began_bulk_work
  24        _bulk_disabled_due_to_coderef_connect_info_warned
  25        _identity_method/
  26 );
  27
  28 my @also_proxy_to_extra_storages = qw/
  29   connect_call_set_auto_cast auto_cast connect_call_blob_setup
  30   connect_call_datetime_setup
  31
  32   disconnect _connect_info _sql_maker _sql_maker_opts disable_sth_caching
  33   auto_savepoint unsafe cursor_class debug debugobj schema
  34 /;
  35
  36 =head1 NAME
  37
  38 DBIx::Class::Storage::DBI::Sybase::ASE - Sybase ASE SQL Server support for
  39 DBIx::Class
  40
  41 =head1 SYNOPSIS
  42
  43 This subclass supports L<DBD::Sybase> for real (non-Microsoft) Sybase databases.
  44
  45 =head1 DESCRIPTION
  46
  47 If your version of Sybase does not support placeholders, then your storage will
  48 be reblessed to L<DBIx::Class::Storage::DBI::Sybase::ASE::NoBindVars>.
  49 You can also enable that driver explicitly, see the documentation for more
  50 details.
  51
  52 With this driver there is unfortunately no way to get the C<last_insert_id>
  53 without doing a C<SELECT MAX(col)>. This is done safely in a transaction
  54 (locking the table.) See L</INSERTS WITH PLACEHOLDERS>.
  55
  56 A recommended L<connect_info|DBIx::Class::Storage::DBI/connect_info> setting:
  57
  58   on_connect_call => [['datetime_setup'], ['blob_setup', log_on_update => 0]]
  59
  60 =head1 METHODS
  61
  62 =cut
  63
  64 sub _rebless {
  65   my $self = shift;
  66
  67   my $no_bind_vars = __PACKAGE__ . '::NoBindVars';
  68
  69   if ($self->using_freetds) {
  70     carp <<'EOF' unless $ENV{DBIC_SYBASE_FREETDS_NOWARN};
  71
  72 You are using FreeTDS with Sybase.
  73
  74 We will do our best to support this configuration, but please consider this
  75 support experimental.
  76
  77 TEXT/IMAGE columns will definitely not work.
  78
  79 You are encouraged to recompile DBD::Sybase with the Sybase Open Client libraries
  80 instead.
  81
  82 See perldoc DBIx::Class::Storage::DBI::Sybase::ASE for more details.
  83
  84 To turn off this warning set the DBIC_SYBASE_FREETDS_NOWARN environment
  85 variable.
  86 EOF
  87
  88     if (not $self->_use_typeless_placeholders) {
  89       if ($self->_use_placeholders) {
  90         $self->auto_cast(1);
  91       }
  92       else {
  93         $self->ensure_class_loaded($no_bind_vars);
  94         bless $self, $no_bind_vars;
  95         $self->_rebless;
  96       }
  97     }
  98   }
  99
 100   elsif (not $self->_get_dbh->{syb_dynamic_supported}) {
 101     # not necessarily FreeTDS, but no placeholders nevertheless
 102     $self->ensure_class_loaded($no_bind_vars);
 103     bless $self, $no_bind_vars;
 104     $self->_rebless;
 105   }
 106   # this is highly unlikely, but we check just in case
 107   elsif (not $self->_use_typeless_placeholders) {
 108     $self->auto_cast(1);
 109   }
 110 }
 111
 112 sub _init {
 113   my $self = shift;
 114   $self->_set_max_connect(256);
 115
 116 # create storage for insert/(update blob) transactions,
 117 # unless this is that storage
 118   return if $self->_is_extra_storage;
 119
 120   my $writer_storage = (ref $self)->new;
 121
 122   $writer_storage->_is_extra_storage(1);
 123   $writer_storage->connect_info($self->connect_info);
 124   $writer_storage->auto_cast($self->auto_cast);
 125
 126   $self->_writer_storage($writer_storage);
 127
 128 # create a bulk storage unless connect_info is a coderef
 129   return if ref($self->_dbi_connect_info->[0]) eq 'CODE';
 130
 131   my $bulk_storage = (ref $self)->new;
 132
 133   $bulk_storage->_is_extra_storage(1);
 134   $bulk_storage->_is_bulk_storage(1); # for special ->disconnect acrobatics
 135   $bulk_storage->connect_info($self->connect_info);
 136
 137 # this is why
 138   $bulk_storage->_dbi_connect_info->[0] .= ';bulkLogin=1';
 139
 140   $self->_bulk_storage($bulk_storage);
 141 }
 142
 143 for my $method (@also_proxy_to_extra_storages) {
 144   no strict 'refs';
 145   no warnings 'redefine';
 146
 147   my $replaced = __PACKAGE__->can($method);
 148
 149   *{$method} = Sub::Name::subname $method => sub {
 150     my $self = shift;
 151     $self->_writer_storage->$replaced(@_) if $self->_writer_storage;
 152     $self->_bulk_storage->$replaced(@_)   if $self->_bulk_storage;
 153     return $self->$replaced(@_);
 154   };
 155 }
 156
 157 sub disconnect {
 158   my $self = shift;
 159
 160 # Even though we call $sth->finish for uses off the bulk API, there's still an
 161 # "active statement" warning on disconnect, which we throw away here.
 162 # This is due to the bug described in insert_bulk.
 163 # Currently a noop because 'prepare' is used instead of 'prepare_cached'.
 164   local $SIG{__WARN__} = sub {
 165     warn $_[0] unless $_[0] =~ /active statement/i;
 166   } if $self->_is_bulk_storage;
 167
 168 # so that next transaction gets a dbh
 169   $self->_began_bulk_work(0) if $self->_is_bulk_storage;
 170
 171   $self->next::method;
 172 }
 173
 174 # Set up session settings for Sybase databases for the connection.
 175 #
 176 # Make sure we have CHAINED mode turned on if AutoCommit is off in non-FreeTDS
 177 # DBD::Sybase (since we don't know how DBD::Sybase was compiled.) If however
 178 # we're using FreeTDS, CHAINED mode turns on an implicit transaction which we
 179 # only want when AutoCommit is off.
 180 #
 181 # Also SET TEXTSIZE for FreeTDS because LongReadLen doesn't work.
 182 sub _run_connection_actions {
 183   my $self = shift;
 184
 185   if ($self->_is_bulk_storage) {
 186 # this should be cleared on every reconnect
 187     $self->_began_bulk_work(0);
 188     return;
 189   }
 190
 191   if (not $self->using_freetds) {
 192     $self->_dbh->{syb_chained_txn} = 1;
 193   } else {
 194     # based on LongReadLen in connect_info
 195     $self->set_textsize;
 196
 197     if ($self->_dbh_autocommit) {
 198       $self->_dbh->do('SET CHAINED OFF');
 199     } else {
 200       $self->_dbh->do('SET CHAINED ON');
 201     }
 202   }
 203
 204   $self->next::method(@_);
 205 }
 206
 207 =head2 connect_call_blob_setup
 208
 209 Used as:
 210
 211   on_connect_call => [ [ 'blob_setup', log_on_update => 0 ] ]
 212
 213 Does C<< $dbh->{syb_binary_images} = 1; >> to return C<IMAGE> data as raw binary
 214 instead of as a hex string.
 215
 216 Recommended.
 217
 218 Also sets the C<log_on_update> value for blob write operations. The default is
 219 C<1>, but C<0> is better if your database is configured for it.
 220
 221 See
 222 L<DBD::Sybase/Handling_IMAGE/TEXT_data_with_syb_ct_get_data()/syb_ct_send_data()>.
 223
 224 =cut
 225
 226 sub connect_call_blob_setup {
 227   my $self = shift;
 228   my %args = @_;
 229   my $dbh = $self->_dbh;
 230   $dbh->{syb_binary_images} = 1;
 231
 232   $self->_blob_log_on_update($args{log_on_update})
 233     if exists $args{log_on_update};
 234 }
 235
 236 sub _is_lob_type {
 237   my $self = shift;
 238   my $type = shift;
 239   $type && $type =~ /(?:text|image|lob|bytea|binary|memo)/i;
 240 }
 241
 242 sub _is_lob_column {
 243   my ($self, $source, $column) = @_;
 244
 245   return $self->_is_lob_type($source->column_info($column)->{data_type});
 246 }
 247
 248 sub _prep_for_execute {
 249   my $self = shift;
 250   my ($op, $extra_bind, $ident, $args) = @_;
 251
 252   my ($sql, $bind) = $self->next::method (@_);
 253
 254   my $table = blessed $ident ? $ident->from : $ident;
 255
 256   my $bind_info = $self->_resolve_column_info(
 257     $ident, [map $_->[0], @{$bind}]
 258   );
 259   my $bound_identity_col =
 260     first { $bind_info->{$_}{is_auto_increment} }
 261     keys %$bind_info
 262   ;
 263
 264   my $columns_info = blessed $ident && $ident->columns_info;
 265
 266   my $identity_col =
 267     $columns_info &&
 268     first { $columns_info->{$_}{is_auto_increment} }
 269       keys %$columns_info
 270   ;
 271
 272   if (($op eq 'insert' && $bound_identity_col) ||
 273       ($op eq 'update' && exists $args->[0]{$identity_col})) {
 274     $sql = join ("\n",
 275       $self->_set_table_identity_sql($op => $table, 'on'),
 276       $sql,
 277       $self->_set_table_identity_sql($op => $table, 'off'),
 278     );
 279   }
 280
 281   if ($op eq 'insert' && (not $bound_identity_col) && $identity_col &&
 282       (not $self->{insert_bulk})) {
 283     $sql =
 284       "$sql\n" .
 285       $self->_fetch_identity_sql($ident, $identity_col);
 286   }
 287
 288   return ($sql, $bind);
 289 }
 290
 291 sub _set_table_identity_sql {
 292   my ($self, $op, $table, $on_off) = @_;
 293
 294   return sprintf 'SET IDENTITY_%s %s %s',
 295     uc($op), $self->sql_maker->_quote($table), uc($on_off);
 296 }
 297
 298 # Stolen from SQLT, with some modifications. This is a makeshift
 299 # solution before a sane type-mapping library is available, thus
 300 # the 'our' for easy overrides.
 301 our %TYPE_MAPPING  = (
 302     number    => 'numeric',
 303     money     => 'money',
 304     varchar   => 'varchar',
 305     varchar2  => 'varchar',
 306     timestamp => 'datetime',
 307     text      => 'varchar',
 308     real      => 'double precision',
 309     comment   => 'text',
 310     bit       => 'bit',
 311     tinyint   => 'smallint',
 312     float     => 'double precision',
 313     serial    => 'numeric',
 314     bigserial => 'numeric',
 315     boolean   => 'varchar',
 316     long      => 'varchar',
 317 );
 318
 319 sub _native_data_type {
 320   my ($self, $type) = @_;
 321
 322   $type = lc $type;
 323   $type =~ s/\s* identity//x;
 324
 325   return uc($TYPE_MAPPING{$type} || $type);
 326 }
 327
 328 sub _fetch_identity_sql {
 329   my ($self, $source, $col) = @_;
 330
 331   return sprintf ("SELECT MAX(%s) FROM %s",
 332     map { $self->sql_maker->_quote ($_) } ($col, $source->from)
 333   );
 334 }
 335
 336 sub _execute {
 337   my $self = shift;
 338   my ($op) = @_;
 339
 340   my ($rv, $sth, @bind) = $self->dbh_do($self->can('_dbh_execute'), @_);
 341
 342   if ($op eq 'insert') {
 343     $self->_identity($sth->fetchrow_array);
 344     $sth->finish;
 345   }
 346
 347   return wantarray ? ($rv, $sth, @bind) : $rv;
 348 }
 349
 350 sub last_insert_id { shift->_identity }
 351
 352 # handles TEXT/IMAGE and transaction for last_insert_id
 353 sub insert {
 354   my $self = shift;
 355   my ($source, $to_insert) = @_;
 356
 357   my $columns_info = $source->columns_info;
 358
 359   my $identity_col =
 360     (first { $columns_info->{$_}{is_auto_increment} }
 361       keys %$columns_info )
 362     || '';
 363
 364   # check for empty insert
 365   # INSERT INTO foo DEFAULT VALUES -- does not work with Sybase
 366   # try to insert explicit 'DEFAULT's instead (except for identity, timestamp
 367   # and computed columns)
 368   if (not %$to_insert) {
 369     for my $col ($source->columns) {
 370       next if $col eq $identity_col;
 371
 372       my $info = $source->column_info($col);
 373
 374       next if ref $info->{default_value} eq 'SCALAR'
 375         || (exists $info->{data_type} && (not defined $info->{data_type}));
 376
 377       next if $info->{data_type} && $info->{data_type} =~ /^timestamp\z/i;
 378
 379       $to_insert->{$col} = \'DEFAULT';
 380     }
 381   }
 382
 383   my $blob_cols = $self->_remove_blob_cols($source, $to_insert);
 384
 385   # do we need the horrific SELECT MAX(COL) hack?
 386   my $dumb_last_insert_id =
 387        $identity_col
 388     && (not exists $to_insert->{$identity_col})
 389     && ($self->_identity_method||'') ne '@@IDENTITY';
 390
 391   my $next = $self->next::can;
 392
 393   # we are already in a transaction, or there are no blobs
 394   # and we don't need the PK - just (try to) do it
 395   if ($self->{transaction_depth}
 396         || (!$blob_cols && !$dumb_last_insert_id)
 397   ) {
 398     return $self->_insert (
 399       $next, $source, $to_insert, $blob_cols, $identity_col
 400     );
 401   }
 402
 403   # otherwise use the _writer_storage to do the insert+transaction on another
 404   # connection
 405   my $guard = $self->_writer_storage->txn_scope_guard;
 406
 407   my $updated_cols = $self->_writer_storage->_insert (
 408     $next, $source, $to_insert, $blob_cols, $identity_col
 409   );
 410
 411   $self->_identity($self->_writer_storage->_identity);
 412
 413   $guard->commit;
 414
 415   return $updated_cols;
 416 }
 417
 418 sub _insert {
 419   my ($self, $next, $source, $to_insert, $blob_cols, $identity_col) = @_;
 420
 421   my $updated_cols = $self->$next ($source, $to_insert);
 422
 423   my $final_row = {
 424     ($identity_col ?
 425       ($identity_col => $self->last_insert_id($source, $identity_col)) : ()),
 426     %$to_insert,
 427     %$updated_cols,
 428   };
 429
 430   $self->_insert_blobs ($source, $blob_cols, $final_row) if $blob_cols;
 431
 432   return $updated_cols;
 433 }
 434
 435 sub update {
 436   my $self = shift;
 437   my ($source, $fields, $where, @rest) = @_;
 438
 439   my $wantarray = wantarray;
 440
 441   my $blob_cols = $self->_remove_blob_cols($source, $fields);
 442
 443   my $table = $source->name;
 444
 445   my $columns_info = $source->columns_info;
 446
 447   my $identity_col =
 448     first { $columns_info->{$_}{is_auto_increment} }
 449       keys %$columns_info;
 450
 451   my $is_identity_update = $identity_col && defined $fields->{$identity_col};
 452
 453   return $self->next::method(@_) unless $blob_cols;
 454
 455 # If there are any blobs in $where, Sybase will return a descriptive error
 456 # message.
 457 # XXX blobs can still be used with a LIKE query, and this should be handled.
 458
 459 # update+blob update(s) done atomically on separate connection
 460   $self = $self->_writer_storage;
 461
 462   my $guard = $self->txn_scope_guard;
 463
 464 # First update the blob columns to be updated to '' (taken from $fields, where
 465 # it is originally put by _remove_blob_cols .)
 466   my %blobs_to_empty = map { ($_ => delete $fields->{$_}) } keys %$blob_cols;
 467
 468 # We can't only update NULL blobs, because blobs cannot be in the WHERE clause.
 469
 470   $self->next::method($source, \%blobs_to_empty, $where, @rest);
 471
 472 # Now update the blobs before the other columns in case the update of other
 473 # columns makes the search condition invalid.
 474   $self->_update_blobs($source, $blob_cols, $where);
 475
 476   my @res;
 477   if (%$fields) {
 478     if ($wantarray) {
 479       @res    = $self->next::method(@_);
 480     }
 481     elsif (defined $wantarray) {
 482       $res[0] = $self->next::method(@_);
 483     }
 484     else {
 485       $self->next::method(@_);
 486     }
 487   }
 488
 489   $guard->commit;
 490
 491   return $wantarray ? @res : $res[0];
 492 }
 493
 494 sub insert_bulk {
 495   my $self = shift;
 496   my ($source, $cols, $data) = @_;
 497
 498   my $columns_info = $source->columns_info;
 499
 500   my $identity_col =
 501     first { $columns_info->{$_}{is_auto_increment} }
 502       keys %$columns_info;
 503
 504   my $is_identity_insert = (first { $_ eq $identity_col } @{$cols}) ? 1 : 0;
 505
 506   my @source_columns = $source->columns;
 507
 508   my $use_bulk_api =
 509     $self->_bulk_storage &&
 510     $self->_get_dbh->{syb_has_blk};
 511
 512   if ((not $use_bulk_api)
 513         &&
 514       (ref($self->_dbi_connect_info->[0]) eq 'CODE')
 515         &&
 516       (not $self->_bulk_disabled_due_to_coderef_connect_info_warned)) {
 517     carp <<'EOF';
 518 Bulk API support disabled due to use of a CODEREF connect_info. Reverting to
 519 regular array inserts.
 520 EOF
 521     $self->_bulk_disabled_due_to_coderef_connect_info_warned(1);
 522   }
 523
 524   if (not $use_bulk_api) {
 525     my $blob_cols = $self->_remove_blob_cols_array($source, $cols, $data);
 526
 527 # _execute_array uses a txn anyway, but it ends too early in case we need to
 528 # select max(col) to get the identity for inserting blobs.
 529     ($self, my $guard) = $self->{transaction_depth} == 0 ?
 530       ($self->_writer_storage, $self->_writer_storage->txn_scope_guard)
 531       :
 532       ($self, undef);
 533
 534     local $self->{insert_bulk} = 1;
 535
 536     $self->next::method(@_);
 537
 538     if ($blob_cols) {
 539       if ($is_identity_insert) {
 540         $self->_insert_blobs_array ($source, $blob_cols, $cols, $data);
 541       }
 542       else {
 543         my @cols_with_identities = (@$cols, $identity_col);
 544
 545         ## calculate identities
 546         # XXX This assumes identities always increase by 1, which may or may not
 547         # be true.
 548         my ($last_identity) =
 549           $self->_dbh->selectrow_array (
 550             $self->_fetch_identity_sql($source, $identity_col)
 551           );
 552         my @identities = (($last_identity - @$data + 1) .. $last_identity);
 553
 554         my @data_with_identities = map [@$_, shift @identities], @$data;
 555
 556         $self->_insert_blobs_array (
 557           $source, $blob_cols, \@cols_with_identities, \@data_with_identities
 558         );
 559       }
 560     }
 561
 562     $guard->commit if $guard;
 563
 564     return;
 565   }
 566
 567 # otherwise, use the bulk API
 568
 569 # rearrange @$data so that columns are in database order
 570   my %orig_idx;
 571   @orig_idx{@$cols} = 0..$#$cols;
 572
 573   my %new_idx;
 574   @new_idx{@source_columns} = 0..$#source_columns;
 575
 576   my @new_data;
 577   for my $datum (@$data) {
 578     my $new_datum = [];
 579     for my $col (@source_columns) {
 580 # identity data will be 'undef' if not $is_identity_insert
 581 # columns with defaults will also be 'undef'
 582       $new_datum->[ $new_idx{$col} ] =
 583         exists $orig_idx{$col} ? $datum->[ $orig_idx{$col} ] : undef;
 584     }
 585     push @new_data, $new_datum;
 586   }
 587
 588 # bcp identity index is 1-based
 589   my $identity_idx = exists $new_idx{$identity_col} ?
 590     $new_idx{$identity_col} + 1 : 0;
 591
 592 ## Set a client-side conversion error handler, straight from DBD::Sybase docs.
 593 # This ignores any data conversion errors detected by the client side libs, as
 594 # they are usually harmless.
 595   my $orig_cslib_cb = DBD::Sybase::set_cslib_cb(
 596     Sub::Name::subname insert_bulk => sub {
 597       my ($layer, $origin, $severity, $errno, $errmsg, $osmsg, $blkmsg) = @_;
 598
 599       return 1 if $errno == 36;
 600
 601       carp
 602         "Layer: $layer, Origin: $origin, Severity: $severity, Error: $errno" .
 603         ($errmsg ? "\n$errmsg" : '') .
 604         ($osmsg  ? "\n$osmsg"  : '')  .
 605         ($blkmsg ? "\n$blkmsg" : '');
 606
 607       return 0;
 608   });
 609
 610   my $exception = '';
 611   try {
 612     my $bulk = $self->_bulk_storage;
 613
 614     my $guard = $bulk->txn_scope_guard;
 615
 616 ## XXX get this to work instead of our own $sth
 617 ## will require SQLA or *Hacks changes for ordered columns
 618 #    $bulk->next::method($source, \@source_columns, \@new_data, {
 619 #      syb_bcp_attribs => {
 620 #        identity_flag   => $is_identity_insert,
 621 #        identity_column => $identity_idx,
 622 #      }
 623 #    });
 624     my $sql = 'INSERT INTO ' .
 625       $bulk->sql_maker->_quote($source->name) . ' (' .
 626 # colname list is ignored for BCP, but does no harm
 627       (join ', ', map $bulk->sql_maker->_quote($_), @source_columns) . ') '.
 628       ' VALUES ('.  (join ', ', ('?') x @source_columns) . ')';
 629
 630 ## XXX there's a bug in the DBD::Sybase bulk support that makes $sth->finish for
 631 ## a prepare_cached statement ineffective. Replace with ->sth when fixed, or
 632 ## better yet the version above. Should be fixed in DBD::Sybase .
 633     my $sth = $bulk->_get_dbh->prepare($sql,
 634 #      'insert', # op
 635       {
 636         syb_bcp_attribs => {
 637           identity_flag   => $is_identity_insert,
 638           identity_column => $identity_idx,
 639         }
 640       }
 641     );
 642
 643     my @bind = do {
 644       my $idx = 0;
 645       map [ $_, $idx++ ], @source_columns;
 646     };
 647
 648     $self->_execute_array(
 649       $source, $sth, \@bind, \@source_columns, \@new_data, sub {
 650         $guard->commit
 651       }
 652     );
 653
 654     $bulk->_query_end($sql);
 655   } catch {
 656     $exception = shift;
 657   };
 658
 659   DBD::Sybase::set_cslib_cb($orig_cslib_cb);
 660
 661   if ($exception =~ /-Y option/) {
 662     carp <<"EOF";
 663
 664 Sybase bulk API operation failed due to character set incompatibility, reverting
 665 to regular array inserts:
 666
 667 *** Try unsetting the LANG environment variable.
 668
 669 $exception
 670 EOF
 671     $self->_bulk_storage(undef);
 672     unshift @_, $self;
 673     goto \&insert_bulk;
 674   }
 675   elsif ($exception) {
 676 # rollback makes the bulkLogin connection unusable
 677     $self->_bulk_storage->disconnect;
 678     $self->throw_exception($exception);
 679   }
 680 }
 681
 682 sub _dbh_execute_array {
 683   my ($self, $sth, $tuple_status, $cb) = @_;
 684
 685   my $rv = $self->next::method($sth, $tuple_status);
 686   $cb->() if $cb;
 687
 688   return $rv;
 689 }
 690
 691 # Make sure blobs are not bound as placeholders, and return any non-empty ones
 692 # as a hash.
 693 sub _remove_blob_cols {
 694   my ($self, $source, $fields) = @_;
 695
 696   my %blob_cols;
 697
 698   for my $col (keys %$fields) {
 699     if ($self->_is_lob_column($source, $col)) {
 700       my $blob_val = delete $fields->{$col};
 701       if (not defined $blob_val) {
 702         $fields->{$col} = \'NULL';
 703       }
 704       else {
 705         $fields->{$col} = \"''";
 706         $blob_cols{$col} = $blob_val unless $blob_val eq '';
 707       }
 708     }
 709   }
 710
 711   return %blob_cols ? \%blob_cols : undef;
 712 }
 713
 714 # same for insert_bulk
 715 sub _remove_blob_cols_array {
 716   my ($self, $source, $cols, $data) = @_;
 717
 718   my @blob_cols;
 719
 720   for my $i (0..$#$cols) {
 721     my $col = $cols->[$i];
 722
 723     if ($self->_is_lob_column($source, $col)) {
 724       for my $j (0..$#$data) {
 725         my $blob_val = delete $data->[$j][$i];
 726         if (not defined $blob_val) {
 727           $data->[$j][$i] = \'NULL';
 728         }
 729         else {
 730           $data->[$j][$i] = \"''";
 731           $blob_cols[$j][$i] = $blob_val
 732             unless $blob_val eq '';
 733         }
 734       }
 735     }
 736   }
 737
 738   return @blob_cols ? \@blob_cols : undef;
 739 }
 740
 741 sub _update_blobs {
 742   my ($self, $source, $blob_cols, $where) = @_;
 743
 744   my @primary_cols = try
 745     { $source->_pri_cols }
 746     catch {
 747       $self->throw_exception("Cannot update TEXT/IMAGE column(s): $_")
 748     };
 749
 750 # check if we're updating a single row by PK
 751   my $pk_cols_in_where = 0;
 752   for my $col (@primary_cols) {
 753     $pk_cols_in_where++ if defined $where->{$col};
 754   }
 755   my @rows;
 756
 757   if ($pk_cols_in_where == @primary_cols) {
 758     my %row_to_update;
 759     @row_to_update{@primary_cols} = @{$where}{@primary_cols};
 760     @rows = \%row_to_update;
 761   } else {
 762     my $cursor = $self->select ($source, \@primary_cols, $where, {});
 763     @rows = map {
 764       my %row; @row{@primary_cols} = @$_; \%row
 765     } $cursor->all;
 766   }
 767
 768   for my $row (@rows) {
 769     $self->_insert_blobs($source, $blob_cols, $row);
 770   }
 771 }
 772
 773 sub _insert_blobs {
 774   my ($self, $source, $blob_cols, $row) = @_;
 775   my $dbh = $self->_get_dbh;
 776
 777   my $table = $source->name;
 778
 779   my %row = %$row;
 780   my @primary_cols = try
 781     { $source->_pri_cols }
 782     catch {
 783       $self->throw_exception("Cannot update TEXT/IMAGE column(s): $_")
 784     };
 785
 786   $self->throw_exception('Cannot update TEXT/IMAGE column(s) without primary key values')
 787     if ((grep { defined $row{$_} } @primary_cols) != @primary_cols);
 788
 789   for my $col (keys %$blob_cols) {
 790     my $blob = $blob_cols->{$col};
 791
 792     my %where = map { ($_, $row{$_}) } @primary_cols;
 793
 794     my $cursor = $self->select ($source, [$col], \%where, {});
 795     $cursor->next;
 796     my $sth = $cursor->sth;
 797
 798     if (not $sth) {
 799       $self->throw_exception(
 800           "Could not find row in table '$table' for blob update:\n"
 801         . (Dumper \%where)
 802       );
 803     }
 804
 805     try {
 806       do {
 807         $sth->func('CS_GET', 1, 'ct_data_info') or die $sth->errstr;
 808       } while $sth->fetch;
 809
 810       $sth->func('ct_prepare_send') or die $sth->errstr;
 811
 812       my $log_on_update = $self->_blob_log_on_update;
 813       $log_on_update    = 1 if not defined $log_on_update;
 814
 815       $sth->func('CS_SET', 1, {
 816         total_txtlen => length($blob),
 817         log_on_update => $log_on_update
 818       }, 'ct_data_info') or die $sth->errstr;
 819
 820       $sth->func($blob, length($blob), 'ct_send_data') or die $sth->errstr;
 821
 822       $sth->func('ct_finish_send') or die $sth->errstr;
 823     }
 824     catch {
 825       if ($self->using_freetds) {
 826         $self->throw_exception (
 827           "TEXT/IMAGE operation failed, probably because you are using FreeTDS: $_"
 828         );
 829       }
 830       else {
 831         $self->throw_exception($_);
 832       }
 833     }
 834     finally {
 835       $sth->finish if $sth;
 836     };
 837   }
 838 }
 839
 840 sub _insert_blobs_array {
 841   my ($self, $source, $blob_cols, $cols, $data) = @_;
 842
 843   for my $i (0..$#$data) {
 844     my $datum = $data->[$i];
 845
 846     my %row;
 847     @row{ @$cols } = @$datum;
 848
 849     my %blob_vals;
 850     for my $j (0..$#$cols) {
 851       if (exists $blob_cols->[$i][$j]) {
 852         $blob_vals{ $cols->[$j] } = $blob_cols->[$i][$j];
 853       }
 854     }
 855
 856     $self->_insert_blobs ($source, \%blob_vals, \%row);
 857   }
 858 }
 859
 860 =head2 connect_call_datetime_setup
 861
 862 Used as:
 863
 864   on_connect_call => 'datetime_setup'
 865
 866 In L<connect_info|DBIx::Class::Storage::DBI/connect_info> to set:
 867
 868   $dbh->syb_date_fmt('ISO_strict'); # output fmt: 2004-08-21T14:36:48.080Z
 869   $dbh->do('set dateformat mdy');   # input fmt:  08/13/1979 18:08:55.080
 870
 871 On connection for use with L<DBIx::Class::InflateColumn::DateTime>, using
 872 L<DateTime::Format::Sybase>, which you will need to install.
 873
 874 This works for both C<DATETIME> and C<SMALLDATETIME> columns, although
 875 C<SMALLDATETIME> columns only have minute precision.
 876
 877 =cut
 878
 879 {
 880   my $old_dbd_warned = 0;
 881
 882   sub connect_call_datetime_setup {
 883     my $self = shift;
 884     my $dbh = $self->_get_dbh;
 885
 886     if ($dbh->can('syb_date_fmt')) {
 887       # amazingly, this works with FreeTDS
 888       $dbh->syb_date_fmt('ISO_strict');
 889     } elsif (not $old_dbd_warned) {
 890       carp "Your DBD::Sybase is too old to support ".
 891       "DBIx::Class::InflateColumn::DateTime, please upgrade!";
 892       $old_dbd_warned = 1;
 893     }
 894
 895     $dbh->do('SET DATEFORMAT mdy');
 896
 897     1;
 898   }
 899 }
 900
 901 sub datetime_parser_type { "DateTime::Format::Sybase" }
 902
 903 # ->begin_work and such have no effect with FreeTDS but we run them anyway to
 904 # let the DBD keep any state it needs to.
 905 #
 906 # If they ever do start working, the extra statements will do no harm (because
 907 # Sybase supports nested transactions.)
 908
 909 sub _dbh_begin_work {
 910   my $self = shift;
 911
 912 # bulkLogin=1 connections are always in a transaction, and can only call BEGIN
 913 # TRAN once. However, we need to make sure there's a $dbh.
 914   return if $self->_is_bulk_storage && $self->_dbh && $self->_began_bulk_work;
 915
 916   $self->next::method(@_);
 917
 918   if ($self->using_freetds) {
 919     $self->_get_dbh->do('BEGIN TRAN');
 920   }
 921
 922   $self->_began_bulk_work(1) if $self->_is_bulk_storage;
 923 }
 924
 925 sub _dbh_commit {
 926   my $self = shift;
 927   if ($self->using_freetds) {
 928     $self->_dbh->do('COMMIT');
 929   }
 930   return $self->next::method(@_);
 931 }
 932
 933 sub _dbh_rollback {
 934   my $self = shift;
 935   if ($self->using_freetds) {
 936     $self->_dbh->do('ROLLBACK');
 937   }
 938   return $self->next::method(@_);
 939 }
 940
 941 # savepoint support using ASE syntax
 942
 943 sub _svp_begin {
 944   my ($self, $name) = @_;
 945
 946   $self->_get_dbh->do("SAVE TRANSACTION $name");
 947 }
 948
 949 # A new SAVE TRANSACTION with the same name releases the previous one.
 950 sub _svp_release { 1 }
 951
 952 sub _svp_rollback {
 953   my ($self, $name) = @_;
 954
 955   $self->_get_dbh->do("ROLLBACK TRANSACTION $name");
 956 }
 957
 958 1;
 959
 960 =head1 Schema::Loader Support
 961
 962 As of version C<0.05000>, L<DBIx::Class::Schema::Loader> should work well with
 963 most (if not all) versions of Sybase ASE.
 964
 965 =head1 FreeTDS
 966
 967 This driver supports L<DBD::Sybase> compiled against FreeTDS
 968 (L<http://www.freetds.org/>) to the best of our ability, however it is
 969 recommended that you recompile L<DBD::Sybase> against the Sybase Open Client
 970 libraries. They are a part of the Sybase ASE distribution:
 971
 972 The Open Client FAQ is here:
 973 L<http://www.isug.com/Sybase_FAQ/ASE/section7.html>.
 974
 975 Sybase ASE for Linux (which comes with the Open Client libraries) may be
 976 downloaded here: L<http://response.sybase.com/forms/ASE_Linux_Download>.
 977
 978 To see if you're using FreeTDS check C<< $schema->storage->using_freetds >>, or run:
 979
 980   perl -MDBI -le 'my $dbh = DBI->connect($dsn, $user, $pass); print $dbh->{syb_oc_version}'
 981
 982 Some versions of the libraries involved will not support placeholders, in which
 983 case the storage will be reblessed to
 984 L<DBIx::Class::Storage::DBI::Sybase::ASE::NoBindVars>.
 985
 986 In some configurations, placeholders will work but will throw implicit type
 987 conversion errors for anything that's not expecting a string. In such a case,
 988 the C<auto_cast> option from L<DBIx::Class::Storage::DBI::AutoCast> is
 989 automatically set, which you may enable on connection with
 990 L<DBIx::Class::Storage::DBI::AutoCast/connect_call_set_auto_cast>. The type info
 991 for the C<CAST>s is taken from the L<DBIx::Class::ResultSource/data_type>
 992 definitions in your Result classes, and are mapped to a Sybase type (if it isn't
 993 already) using a mapping based on L<SQL::Translator>.
 994
 995 In other configurations, placeholders will work just as they do with the Sybase
 996 Open Client libraries.
 997
 998 Inserts or updates of TEXT/IMAGE columns will B<NOT> work with FreeTDS.
 999
1000 =head1 INSERTS WITH PLACEHOLDERS
1001
1002 With placeholders enabled, inserts are done in a transaction so that there are
1003 no concurrency issues with getting the inserted identity value using
1004 C<SELECT MAX(col)>, which is the only way to get the C<IDENTITY> value in this
1005 mode.
1006
1007 In addition, they are done on a separate connection so that it's possible to
1008 have active cursors when doing an insert.
1009
1010 When using C<DBIx::Class::Storage::DBI::Sybase::ASE::NoBindVars> transactions
1011 are disabled, as there are no concurrency issues with C<SELECT @@IDENTITY> as
1012 it's a session variable.
1013
1014 =head1 TRANSACTIONS
1015
1016 Due to limitations of the TDS protocol, L<DBD::Sybase>, or both, you cannot
1017 begin a transaction while there are active cursors, nor can you use multiple
1018 active cursors within a transaction. An active cursor is, for example, a
1019 L<ResultSet|DBIx::Class::ResultSet> that has been executed using C<next> or
1020 C<first> but has not been exhausted or L<reset|DBIx::Class::ResultSet/reset>.
1021
1022 For example, this will not work:
1023
1024   $schema->txn_do(sub {
1025     my $rs = $schema->resultset('Book');
1026     while (my $row = $rs->next) {
1027       $schema->resultset('MetaData')->create({
1028         book_id => $row->id,
1029         ...
1030       });
1031     }
1032   });
1033
1034 This won't either:
1035
1036   my $first_row = $large_rs->first;
1037   $schema->txn_do(sub { ... });
1038
1039 Transactions done for inserts in C<AutoCommit> mode when placeholders are in use
1040 are not affected, as they are done on an extra database handle.
1041
1042 Some workarounds:
1043
1044 =over 4
1045
1046 =item * use L<DBIx::Class::Storage::DBI::Replicated>
1047
1048 =item * L<connect|DBIx::Class::Schema/connect> another L<Schema|DBIx::Class::Schema>
1049
1050 =item * load the data from your cursor with L<DBIx::Class::ResultSet/all>
1051
1052 =back
1053
1054 =head1 MAXIMUM CONNECTIONS
1055
1056 The TDS protocol makes separate connections to the server for active statements
1057 in the background. By default the number of such connections is limited to 25,
1058 on both the client side and the server side.
1059
1060 This is a bit too low for a complex L<DBIx::Class> application, so on connection
1061 the client side setting is set to C<256> (see L<DBD::Sybase/maxConnect>.) You
1062 can override it to whatever setting you like in the DSN.
1063
1064 See
1065 L<http://infocenter.sybase.com/help/index.jsp?topic=/com.sybase.help.ase_15.0.sag1/html/sag1/sag1272.htm>
1066 for information on changing the setting on the server side.
1067
1068 =head1 DATES
1069
1070 See L</connect_call_datetime_setup> to setup date formats
1071 for L<DBIx::Class::InflateColumn::DateTime>.
1072
1073 =head1 TEXT/IMAGE COLUMNS
1074
1075 L<DBD::Sybase> compiled with FreeTDS will B<NOT> allow you to insert or update
1076 C<TEXT/IMAGE> columns.
1077
1078 Setting C<< $dbh->{LongReadLen} >> will also not work with FreeTDS use either:
1079
1080   $schema->storage->dbh->do("SET TEXTSIZE $bytes");
1081
1082 or
1083
1084   $schema->storage->set_textsize($bytes);
1085
1086 instead.
1087
1088 However, the C<LongReadLen> you pass in
1089 L<connect_info|DBIx::Class::Storage::DBI/connect_info> is used to execute the
1090 equivalent C<SET TEXTSIZE> command on connection.
1091
1092 See L</connect_call_blob_setup> for a
1093 L<connect_info|DBIx::Class::Storage::DBI/connect_info> setting you need to work
1094 with C<IMAGE> columns.
1095
1096 =head1 BULK API
1097
1098 The experimental L<DBD::Sybase> Bulk API support is used for
1099 L<populate|DBIx::Class::ResultSet/populate> in B<void> context, in a transaction
1100 on a separate connection.
1101
1102 To use this feature effectively, use a large number of rows for each
1103 L<populate|DBIx::Class::ResultSet/populate> call, eg.:
1104
1105   while (my $rows = $data_source->get_100_rows()) {
1106     $rs->populate($rows);
1107   }
1108
1109 B<NOTE:> the L<add_columns|DBIx::Class::ResultSource/add_columns>
1110 calls in your C<Result> classes B<must> list columns in database order for this
1111 to work. Also, you may have to unset the C<LANG> environment variable before
1112 loading your app, if it doesn't match the character set of your database.
1113
1114 When inserting IMAGE columns using this method, you'll need to use
1115 L</connect_call_blob_setup> as well.
1116
1117 =head1 COMPUTED COLUMNS
1118
1119 If you have columns such as:
1120
1121   created_dtm AS getdate()
1122
1123 represent them in your Result classes as:
1124
1125   created_dtm => {
1126     data_type => undef,
1127     default_value => \'getdate()',
1128     is_nullable => 0,
1129   }
1130
1131 The C<data_type> must exist and must be C<undef>. Then empty inserts will work
1132 on tables with such columns.
1133
1134 =head1 TIMESTAMP COLUMNS
1135
1136 C<timestamp> columns in Sybase ASE are not really timestamps, see:
1137 L<http://dba.fyicenter.com/Interview-Questions/SYBASE/The_timestamp_datatype_in_Sybase_.html>.
1138
1139 They should be defined in your Result classes as:
1140
1141   ts => {
1142     data_type => 'timestamp',
1143     is_nullable => 0,
1144     inflate_datetime => 0,
1145   }
1146
1147 The C<<inflate_datetime => 0>> is necessary if you use
1148 L<DBIx::Class::InflateColumn::DateTime>, and most people do, and still want to
1149 be able to read these values.
1150
1151 The values will come back as hexadecimal.
1152
1153 =head1 TODO
1154
1155 =over
1156
1157 =item *
1158
1159 Transitions to AutoCommit=0 (starting a transaction) mode by exhausting
1160 any active cursors, using eager cursors.
1161
1162 =item *
1163
1164 Real limits and limited counts using stored procedures deployed on startup.
1165
1166 =item *
1167
1168 Adaptive Server Anywhere (ASA) support
1169
1170 =item *
1171
1172 Blob update with a LIKE query on a blob, without invalidating the WHERE condition.
1173
1174 =item *
1175
1176 bulk_insert using prepare_cached (see comments.)
1177
1178 =back
1179
1180 =head1 AUTHOR
1181
1182 See L<DBIx::Class/CONTRIBUTORS>.
1183
1184 =head1 LICENSE
1185
1186 You may distribute this code under the same terms as Perl itself.
1187
1188 =cut
1189 # vim:sts=2 sw=2: