lib/DBIx/Class/Storage/DBI/Sybase/ASE.pm

   1 package DBIx::Class::Storage::DBI::Sybase::ASE;
   2
   3 use strict;
   4 use warnings;
   5
   6 use base qw/
   7     DBIx::Class::Storage::DBI::Sybase
   8     DBIx::Class::Storage::DBI::AutoCast
   9 /;
  10 use mro 'c3';
  11 use Carp::Clan qw/^DBIx::Class/;
  12 use Scalar::Util 'blessed';
  13 use List::Util 'first';
  14 use Sub::Name();
  15 use Data::Dumper::Concise 'Dumper';
  16 use Try::Tiny;
  17 use namespace::clean;
  18
  19 __PACKAGE__->mk_group_accessors('simple' =>
  20     qw/_identity _blob_log_on_update _writer_storage _is_extra_storage
  21        _bulk_storage _is_bulk_storage _began_bulk_work
  22        _bulk_disabled_due_to_coderef_connect_info_warned
  23        _identity_method/
  24 );
  25
  26 my @also_proxy_to_extra_storages = qw/
  27   connect_call_set_auto_cast auto_cast connect_call_blob_setup
  28   connect_call_datetime_setup
  29
  30   disconnect _connect_info _sql_maker _sql_maker_opts disable_sth_caching
  31   auto_savepoint unsafe cursor_class debug debugobj schema
  32 /;
  33
  34 =head1 NAME
  35
  36 DBIx::Class::Storage::DBI::Sybase::ASE - Sybase ASE SQL Server support for
  37 DBIx::Class
  38
  39 =head1 SYNOPSIS
  40
  41 This subclass supports L<DBD::Sybase> for real (non-Microsoft) Sybase databases.
  42
  43 =head1 DESCRIPTION
  44
  45 If your version of Sybase does not support placeholders, then your storage will
  46 be reblessed to L<DBIx::Class::Storage::DBI::Sybase::ASE::NoBindVars>.
  47 You can also enable that driver explicitly, see the documentation for more
  48 details.
  49
  50 With this driver there is unfortunately no way to get the C<last_insert_id>
  51 without doing a C<SELECT MAX(col)>. This is done safely in a transaction
  52 (locking the table.) See L</INSERTS WITH PLACEHOLDERS>.
  53
  54 A recommended L<connect_info|DBIx::Class::Storage::DBI/connect_info> setting:
  55
  56   on_connect_call => [['datetime_setup'], ['blob_setup', log_on_update => 0]]
  57
  58 =head1 METHODS
  59
  60 =cut
  61
  62 sub _rebless {
  63   my $self = shift;
  64
  65   my $no_bind_vars = __PACKAGE__ . '::NoBindVars';
  66
  67   if ($self->using_freetds) {
  68     carp <<'EOF' unless $ENV{DBIC_SYBASE_FREETDS_NOWARN};
  69
  70 You are using FreeTDS with Sybase.
  71
  72 We will do our best to support this configuration, but please consider this
  73 support experimental.
  74
  75 TEXT/IMAGE columns will definitely not work.
  76
  77 You are encouraged to recompile DBD::Sybase with the Sybase Open Client libraries
  78 instead.
  79
  80 See perldoc DBIx::Class::Storage::DBI::Sybase::ASE for more details.
  81
  82 To turn off this warning set the DBIC_SYBASE_FREETDS_NOWARN environment
  83 variable.
  84 EOF
  85
  86     if (not $self->_typeless_placeholders_supported) {
  87       if ($self->_placeholders_supported) {
  88         $self->auto_cast(1);
  89       }
  90       else {
  91         $self->ensure_class_loaded($no_bind_vars);
  92         bless $self, $no_bind_vars;
  93         $self->_rebless;
  94       }
  95     }
  96   }
  97
  98   elsif (not $self->_get_dbh->{syb_dynamic_supported}) {
  99     # not necessarily FreeTDS, but no placeholders nevertheless
 100     $self->ensure_class_loaded($no_bind_vars);
 101     bless $self, $no_bind_vars;
 102     $self->_rebless;
 103   }
 104   # this is highly unlikely, but we check just in case
 105   elsif (not $self->_typeless_placeholders_supported) {
 106     $self->auto_cast(1);
 107   }
 108 }
 109
 110 sub _init {
 111   my $self = shift;
 112   $self->_set_max_connect(256);
 113
 114 # create storage for insert/(update blob) transactions,
 115 # unless this is that storage
 116   return if $self->_is_extra_storage;
 117
 118   my $writer_storage = (ref $self)->new;
 119
 120   $writer_storage->_is_extra_storage(1);
 121   $writer_storage->connect_info($self->connect_info);
 122   $writer_storage->auto_cast($self->auto_cast);
 123
 124   $self->_writer_storage($writer_storage);
 125
 126 # create a bulk storage unless connect_info is a coderef
 127   return if ref($self->_dbi_connect_info->[0]) eq 'CODE';
 128
 129   my $bulk_storage = (ref $self)->new;
 130
 131   $bulk_storage->_is_extra_storage(1);
 132   $bulk_storage->_is_bulk_storage(1); # for special ->disconnect acrobatics
 133   $bulk_storage->connect_info($self->connect_info);
 134
 135 # this is why
 136   $bulk_storage->_dbi_connect_info->[0] .= ';bulkLogin=1';
 137
 138   $self->_bulk_storage($bulk_storage);
 139 }
 140
 141 for my $method (@also_proxy_to_extra_storages) {
 142   no strict 'refs';
 143   no warnings 'redefine';
 144
 145   my $replaced = __PACKAGE__->can($method);
 146
 147   *{$method} = Sub::Name::subname $method => sub {
 148     my $self = shift;
 149     $self->_writer_storage->$replaced(@_) if $self->_writer_storage;
 150     $self->_bulk_storage->$replaced(@_)   if $self->_bulk_storage;
 151     return $self->$replaced(@_);
 152   };
 153 }
 154
 155 sub disconnect {
 156   my $self = shift;
 157
 158 # Even though we call $sth->finish for uses off the bulk API, there's still an
 159 # "active statement" warning on disconnect, which we throw away here.
 160 # This is due to the bug described in insert_bulk.
 161 # Currently a noop because 'prepare' is used instead of 'prepare_cached'.
 162   local $SIG{__WARN__} = sub {
 163     warn $_[0] unless $_[0] =~ /active statement/i;
 164   } if $self->_is_bulk_storage;
 165
 166 # so that next transaction gets a dbh
 167   $self->_began_bulk_work(0) if $self->_is_bulk_storage;
 168
 169   $self->next::method;
 170 }
 171
 172 # Set up session settings for Sybase databases for the connection.
 173 #
 174 # Make sure we have CHAINED mode turned on if AutoCommit is off in non-FreeTDS
 175 # DBD::Sybase (since we don't know how DBD::Sybase was compiled.) If however
 176 # we're using FreeTDS, CHAINED mode turns on an implicit transaction which we
 177 # only want when AutoCommit is off.
 178 #
 179 # Also SET TEXTSIZE for FreeTDS because LongReadLen doesn't work.
 180 sub _run_connection_actions {
 181   my $self = shift;
 182
 183   if ($self->_is_bulk_storage) {
 184 # this should be cleared on every reconnect
 185     $self->_began_bulk_work(0);
 186     return;
 187   }
 188
 189   if (not $self->using_freetds) {
 190     $self->_dbh->{syb_chained_txn} = 1;
 191   } else {
 192     # based on LongReadLen in connect_info
 193     $self->set_textsize;
 194
 195     if ($self->_dbh_autocommit) {
 196       $self->_dbh->do('SET CHAINED OFF');
 197     } else {
 198       $self->_dbh->do('SET CHAINED ON');
 199     }
 200   }
 201
 202   $self->next::method(@_);
 203 }
 204
 205 =head2 connect_call_blob_setup
 206
 207 Used as:
 208
 209   on_connect_call => [ [ 'blob_setup', log_on_update => 0 ] ]
 210
 211 Does C<< $dbh->{syb_binary_images} = 1; >> to return C<IMAGE> data as raw binary
 212 instead of as a hex string.
 213
 214 Recommended.
 215
 216 Also sets the C<log_on_update> value for blob write operations. The default is
 217 C<1>, but C<0> is better if your database is configured for it.
 218
 219 See
 220 L<DBD::Sybase/Handling_IMAGE/TEXT_data_with_syb_ct_get_data()/syb_ct_send_data()>.
 221
 222 =cut
 223
 224 sub connect_call_blob_setup {
 225   my $self = shift;
 226   my %args = @_;
 227   my $dbh = $self->_dbh;
 228   $dbh->{syb_binary_images} = 1;
 229
 230   $self->_blob_log_on_update($args{log_on_update})
 231     if exists $args{log_on_update};
 232 }
 233
 234 sub _is_lob_type {
 235   my $self = shift;
 236   my $type = shift;
 237   $type && $type =~ /(?:text|image|lob|bytea|binary|memo)/i;
 238 }
 239
 240 sub _is_lob_column {
 241   my ($self, $source, $column) = @_;
 242
 243   return $self->_is_lob_type($source->column_info($column)->{data_type});
 244 }
 245
 246 sub _prep_for_execute {
 247   my $self = shift;
 248   my ($op, $extra_bind, $ident, $args) = @_;
 249
 250   my ($sql, $bind) = $self->next::method (@_);
 251
 252   my $table = blessed $ident ? $ident->from : $ident;
 253
 254   my $bind_info = $self->_resolve_column_info(
 255     $ident, [map $_->[0], @{$bind}]
 256   );
 257   my $bound_identity_col =
 258     first { $bind_info->{$_}{is_auto_increment} }
 259     keys %$bind_info
 260   ;
 261   my $identity_col =
 262     blessed $ident &&
 263     first { $ident->column_info($_)->{is_auto_increment} } $ident->columns
 264   ;
 265
 266   if (($op eq 'insert' && $bound_identity_col) ||
 267       ($op eq 'update' && exists $args->[0]{$identity_col})) {
 268     $sql = join ("\n",
 269       $self->_set_table_identity_sql($op => $table, 'on'),
 270       $sql,
 271       $self->_set_table_identity_sql($op => $table, 'off'),
 272     );
 273   }
 274
 275   if ($op eq 'insert' && (not $bound_identity_col) && $identity_col &&
 276       (not $self->{insert_bulk})) {
 277     $sql =
 278       "$sql\n" .
 279       $self->_fetch_identity_sql($ident, $identity_col);
 280   }
 281
 282   return ($sql, $bind);
 283 }
 284
 285 sub _set_table_identity_sql {
 286   my ($self, $op, $table, $on_off) = @_;
 287
 288   return sprintf 'SET IDENTITY_%s %s %s',
 289     uc($op), $self->sql_maker->_quote($table), uc($on_off);
 290 }
 291
 292 # Stolen from SQLT, with some modifications. This is a makeshift
 293 # solution before a sane type-mapping library is available, thus
 294 # the 'our' for easy overrides.
 295 our %TYPE_MAPPING  = (
 296     number    => 'numeric',
 297     money     => 'money',
 298     varchar   => 'varchar',
 299     varchar2  => 'varchar',
 300     timestamp => 'datetime',
 301     text      => 'varchar',
 302     real      => 'double precision',
 303     comment   => 'text',
 304     bit       => 'bit',
 305     tinyint   => 'smallint',
 306     float     => 'double precision',
 307     serial    => 'numeric',
 308     bigserial => 'numeric',
 309     boolean   => 'varchar',
 310     long      => 'varchar',
 311 );
 312
 313 sub _native_data_type {
 314   my ($self, $type) = @_;
 315
 316   $type = lc $type;
 317   $type =~ s/\s* identity//x;
 318
 319   return uc($TYPE_MAPPING{$type} || $type);
 320 }
 321
 322 sub _fetch_identity_sql {
 323   my ($self, $source, $col) = @_;
 324
 325   return sprintf ("SELECT MAX(%s) FROM %s",
 326     map { $self->sql_maker->_quote ($_) } ($col, $source->from)
 327   );
 328 }
 329
 330 sub _execute {
 331   my $self = shift;
 332   my ($op) = @_;
 333
 334   my ($rv, $sth, @bind) = $self->dbh_do($self->can('_dbh_execute'), @_);
 335
 336   if ($op eq 'insert') {
 337     $self->_identity($sth->fetchrow_array);
 338     $sth->finish;
 339   }
 340
 341   return wantarray ? ($rv, $sth, @bind) : $rv;
 342 }
 343
 344 sub last_insert_id { shift->_identity }
 345
 346 # handles TEXT/IMAGE and transaction for last_insert_id
 347 sub insert {
 348   my $self = shift;
 349   my ($source, $to_insert) = @_;
 350
 351   my $identity_col =
 352     (first { $source->column_info($_)->{is_auto_increment} } $source->columns)
 353     || '';
 354
 355   # check for empty insert
 356   # INSERT INTO foo DEFAULT VALUES -- does not work with Sybase
 357   # try to insert explicit 'DEFAULT's instead (except for identity, timestamp
 358   # and computed columns)
 359   if (not %$to_insert) {
 360     for my $col ($source->columns) {
 361       next if $col eq $identity_col;
 362
 363       my $info = $source->column_info($col);
 364
 365       next if ref $info->{default_value} eq 'SCALAR'
 366         || (exists $info->{data_type} && (not defined $info->{data_type}));
 367
 368       next if $info->{data_type} && $info->{data_type} =~ /^timestamp\z/i;
 369
 370       $to_insert->{$col} = \'DEFAULT';
 371     }
 372   }
 373
 374   my $blob_cols = $self->_remove_blob_cols($source, $to_insert);
 375
 376   # do we need the horrific SELECT MAX(COL) hack?
 377   my $dumb_last_insert_id =
 378        $identity_col
 379     && (not exists $to_insert->{$identity_col})
 380     && ($self->_identity_method||'') ne '@@IDENTITY';
 381
 382   my $next = $self->next::can;
 383
 384   # we are already in a transaction, or there are no blobs
 385   # and we don't need the PK - just (try to) do it
 386   if ($self->{transaction_depth}
 387         || (!$blob_cols && !$dumb_last_insert_id)
 388   ) {
 389     return $self->_insert (
 390       $next, $source, $to_insert, $blob_cols, $identity_col
 391     );
 392   }
 393
 394   # otherwise use the _writer_storage to do the insert+transaction on another
 395   # connection
 396   my $guard = $self->_writer_storage->txn_scope_guard;
 397
 398   my $updated_cols = $self->_writer_storage->_insert (
 399     $next, $source, $to_insert, $blob_cols, $identity_col
 400   );
 401
 402   $self->_identity($self->_writer_storage->_identity);
 403
 404   $guard->commit;
 405
 406   return $updated_cols;
 407 }
 408
 409 sub _insert {
 410   my ($self, $next, $source, $to_insert, $blob_cols, $identity_col) = @_;
 411
 412   my $updated_cols = $self->$next ($source, $to_insert);
 413
 414   my $final_row = {
 415     ($identity_col ?
 416       ($identity_col => $self->last_insert_id($source, $identity_col)) : ()),
 417     %$to_insert,
 418     %$updated_cols,
 419   };
 420
 421   $self->_insert_blobs ($source, $blob_cols, $final_row) if $blob_cols;
 422
 423   return $updated_cols;
 424 }
 425
 426 sub update {
 427   my $self = shift;
 428   my ($source, $fields, $where, @rest) = @_;
 429
 430   my $wantarray = wantarray;
 431
 432   my $blob_cols = $self->_remove_blob_cols($source, $fields);
 433
 434   my $table = $source->name;
 435
 436   my $identity_col =
 437     first { $source->column_info($_)->{is_auto_increment} } $source->columns;
 438
 439   my $is_identity_update = $identity_col && defined $fields->{$identity_col};
 440
 441   return $self->next::method(@_) unless $blob_cols;
 442
 443 # If there are any blobs in $where, Sybase will return a descriptive error
 444 # message.
 445 # XXX blobs can still be used with a LIKE query, and this should be handled.
 446
 447 # update+blob update(s) done atomically on separate connection
 448   $self = $self->_writer_storage;
 449
 450   my $guard = $self->txn_scope_guard;
 451
 452 # First update the blob columns to be updated to '' (taken from $fields, where
 453 # it is originally put by _remove_blob_cols .)
 454   my %blobs_to_empty = map { ($_ => delete $fields->{$_}) } keys %$blob_cols;
 455
 456 # We can't only update NULL blobs, because blobs cannot be in the WHERE clause.
 457
 458   $self->next::method($source, \%blobs_to_empty, $where, @rest);
 459
 460 # Now update the blobs before the other columns in case the update of other
 461 # columns makes the search condition invalid.
 462   $self->_update_blobs($source, $blob_cols, $where);
 463
 464   my @res;
 465   if (%$fields) {
 466     if ($wantarray) {
 467       @res    = $self->next::method(@_);
 468     }
 469     elsif (defined $wantarray) {
 470       $res[0] = $self->next::method(@_);
 471     }
 472     else {
 473       $self->next::method(@_);
 474     }
 475   }
 476
 477   $guard->commit;
 478
 479   return $wantarray ? @res : $res[0];
 480 }
 481
 482 sub insert_bulk {
 483   my $self = shift;
 484   my ($source, $cols, $data) = @_;
 485
 486   my $identity_col =
 487     first { $source->column_info($_)->{is_auto_increment} } $source->columns;
 488
 489   my $is_identity_insert = (first { $_ eq $identity_col } @{$cols}) ? 1 : 0;
 490
 491   my @source_columns = $source->columns;
 492
 493   my $use_bulk_api =
 494     $self->_bulk_storage &&
 495     $self->_get_dbh->{syb_has_blk};
 496
 497   if ((not $use_bulk_api)
 498         &&
 499       (ref($self->_dbi_connect_info->[0]) eq 'CODE')
 500         &&
 501       (not $self->_bulk_disabled_due_to_coderef_connect_info_warned)) {
 502     carp <<'EOF';
 503 Bulk API support disabled due to use of a CODEREF connect_info. Reverting to
 504 regular array inserts.
 505 EOF
 506     $self->_bulk_disabled_due_to_coderef_connect_info_warned(1);
 507   }
 508
 509   if (not $use_bulk_api) {
 510     my $blob_cols = $self->_remove_blob_cols_array($source, $cols, $data);
 511
 512 # _execute_array uses a txn anyway, but it ends too early in case we need to
 513 # select max(col) to get the identity for inserting blobs.
 514     ($self, my $guard) = $self->{transaction_depth} == 0 ?
 515       ($self->_writer_storage, $self->_writer_storage->txn_scope_guard)
 516       :
 517       ($self, undef);
 518
 519     local $self->{insert_bulk} = 1;
 520
 521     $self->next::method(@_);
 522
 523     if ($blob_cols) {
 524       if ($is_identity_insert) {
 525         $self->_insert_blobs_array ($source, $blob_cols, $cols, $data);
 526       }
 527       else {
 528         my @cols_with_identities = (@$cols, $identity_col);
 529
 530         ## calculate identities
 531         # XXX This assumes identities always increase by 1, which may or may not
 532         # be true.
 533         my ($last_identity) =
 534           $self->_dbh->selectrow_array (
 535             $self->_fetch_identity_sql($source, $identity_col)
 536           );
 537         my @identities = (($last_identity - @$data + 1) .. $last_identity);
 538
 539         my @data_with_identities = map [@$_, shift @identities], @$data;
 540
 541         $self->_insert_blobs_array (
 542           $source, $blob_cols, \@cols_with_identities, \@data_with_identities
 543         );
 544       }
 545     }
 546
 547     $guard->commit if $guard;
 548
 549     return;
 550   }
 551
 552 # otherwise, use the bulk API
 553
 554 # rearrange @$data so that columns are in database order
 555   my %orig_idx;
 556   @orig_idx{@$cols} = 0..$#$cols;
 557
 558   my %new_idx;
 559   @new_idx{@source_columns} = 0..$#source_columns;
 560
 561   my @new_data;
 562   for my $datum (@$data) {
 563     my $new_datum = [];
 564     for my $col (@source_columns) {
 565 # identity data will be 'undef' if not $is_identity_insert
 566 # columns with defaults will also be 'undef'
 567       $new_datum->[ $new_idx{$col} ] =
 568         exists $orig_idx{$col} ? $datum->[ $orig_idx{$col} ] : undef;
 569     }
 570     push @new_data, $new_datum;
 571   }
 572
 573 # bcp identity index is 1-based
 574   my $identity_idx = exists $new_idx{$identity_col} ?
 575     $new_idx{$identity_col} + 1 : 0;
 576
 577 ## Set a client-side conversion error handler, straight from DBD::Sybase docs.
 578 # This ignores any data conversion errors detected by the client side libs, as
 579 # they are usually harmless.
 580   my $orig_cslib_cb = DBD::Sybase::set_cslib_cb(
 581     Sub::Name::subname insert_bulk => sub {
 582       my ($layer, $origin, $severity, $errno, $errmsg, $osmsg, $blkmsg) = @_;
 583
 584       return 1 if $errno == 36;
 585
 586       carp
 587         "Layer: $layer, Origin: $origin, Severity: $severity, Error: $errno" .
 588         ($errmsg ? "\n$errmsg" : '') .
 589         ($osmsg  ? "\n$osmsg"  : '')  .
 590         ($blkmsg ? "\n$blkmsg" : '');
 591
 592       return 0;
 593   });
 594
 595   my $exception = '';
 596   try {
 597     my $bulk = $self->_bulk_storage;
 598
 599     my $guard = $bulk->txn_scope_guard;
 600
 601 ## XXX get this to work instead of our own $sth
 602 ## will require SQLA or *Hacks changes for ordered columns
 603 #    $bulk->next::method($source, \@source_columns, \@new_data, {
 604 #      syb_bcp_attribs => {
 605 #        identity_flag   => $is_identity_insert,
 606 #        identity_column => $identity_idx,
 607 #      }
 608 #    });
 609     my $sql = 'INSERT INTO ' .
 610       $bulk->sql_maker->_quote($source->name) . ' (' .
 611 # colname list is ignored for BCP, but does no harm
 612       (join ', ', map $bulk->sql_maker->_quote($_), @source_columns) . ') '.
 613       ' VALUES ('.  (join ', ', ('?') x @source_columns) . ')';
 614
 615 ## XXX there's a bug in the DBD::Sybase bulk support that makes $sth->finish for
 616 ## a prepare_cached statement ineffective. Replace with ->sth when fixed, or
 617 ## better yet the version above. Should be fixed in DBD::Sybase .
 618     my $sth = $bulk->_get_dbh->prepare($sql,
 619 #      'insert', # op
 620       {
 621         syb_bcp_attribs => {
 622           identity_flag   => $is_identity_insert,
 623           identity_column => $identity_idx,
 624         }
 625       }
 626     );
 627
 628     my @bind = do {
 629       my $idx = 0;
 630       map [ $_, $idx++ ], @source_columns;
 631     };
 632
 633     $self->_execute_array(
 634       $source, $sth, \@bind, \@source_columns, \@new_data, sub {
 635         $guard->commit
 636       }
 637     );
 638
 639     $bulk->_query_end($sql);
 640   } catch {
 641     $exception = shift;
 642   };
 643
 644   DBD::Sybase::set_cslib_cb($orig_cslib_cb);
 645
 646   if ($exception =~ /-Y option/) {
 647     carp <<"EOF";
 648
 649 Sybase bulk API operation failed due to character set incompatibility, reverting
 650 to regular array inserts:
 651
 652 *** Try unsetting the LANG environment variable.
 653
 654 $exception
 655 EOF
 656     $self->_bulk_storage(undef);
 657     unshift @_, $self;
 658     goto \&insert_bulk;
 659   }
 660   elsif ($exception) {
 661 # rollback makes the bulkLogin connection unusable
 662     $self->_bulk_storage->disconnect;
 663     $self->throw_exception($exception);
 664   }
 665 }
 666
 667 sub _dbh_execute_array {
 668   my ($self, $sth, $tuple_status, $cb) = @_;
 669
 670   my $rv = $self->next::method($sth, $tuple_status);
 671   $cb->() if $cb;
 672
 673   return $rv;
 674 }
 675
 676 # Make sure blobs are not bound as placeholders, and return any non-empty ones
 677 # as a hash.
 678 sub _remove_blob_cols {
 679   my ($self, $source, $fields) = @_;
 680
 681   my %blob_cols;
 682
 683   for my $col (keys %$fields) {
 684     if ($self->_is_lob_column($source, $col)) {
 685       my $blob_val = delete $fields->{$col};
 686       if (not defined $blob_val) {
 687         $fields->{$col} = \'NULL';
 688       }
 689       else {
 690         $fields->{$col} = \"''";
 691         $blob_cols{$col} = $blob_val unless $blob_val eq '';
 692       }
 693     }
 694   }
 695
 696   return %blob_cols ? \%blob_cols : undef;
 697 }
 698
 699 # same for insert_bulk
 700 sub _remove_blob_cols_array {
 701   my ($self, $source, $cols, $data) = @_;
 702
 703   my @blob_cols;
 704
 705   for my $i (0..$#$cols) {
 706     my $col = $cols->[$i];
 707
 708     if ($self->_is_lob_column($source, $col)) {
 709       for my $j (0..$#$data) {
 710         my $blob_val = delete $data->[$j][$i];
 711         if (not defined $blob_val) {
 712           $data->[$j][$i] = \'NULL';
 713         }
 714         else {
 715           $data->[$j][$i] = \"''";
 716           $blob_cols[$j][$i] = $blob_val
 717             unless $blob_val eq '';
 718         }
 719       }
 720     }
 721   }
 722
 723   return @blob_cols ? \@blob_cols : undef;
 724 }
 725
 726 sub _update_blobs {
 727   my ($self, $source, $blob_cols, $where) = @_;
 728
 729   my @primary_cols = try
 730     { $source->_pri_cols }
 731     catch {
 732       $self->throw_exception("Cannot update TEXT/IMAGE column(s): $_")
 733     };
 734
 735 # check if we're updating a single row by PK
 736   my $pk_cols_in_where = 0;
 737   for my $col (@primary_cols) {
 738     $pk_cols_in_where++ if defined $where->{$col};
 739   }
 740   my @rows;
 741
 742   if ($pk_cols_in_where == @primary_cols) {
 743     my %row_to_update;
 744     @row_to_update{@primary_cols} = @{$where}{@primary_cols};
 745     @rows = \%row_to_update;
 746   } else {
 747     my $cursor = $self->select ($source, \@primary_cols, $where, {});
 748     @rows = map {
 749       my %row; @row{@primary_cols} = @$_; \%row
 750     } $cursor->all;
 751   }
 752
 753   for my $row (@rows) {
 754     $self->_insert_blobs($source, $blob_cols, $row);
 755   }
 756 }
 757
 758 sub _insert_blobs {
 759   my ($self, $source, $blob_cols, $row) = @_;
 760   my $dbh = $self->_get_dbh;
 761
 762   my $table = $source->name;
 763
 764   my %row = %$row;
 765   my @primary_cols = try
 766     { $source->_pri_cols }
 767     catch {
 768       $self->throw_exception("Cannot update TEXT/IMAGE column(s): $_")
 769     };
 770
 771   $self->throw_exception('Cannot update TEXT/IMAGE column(s) without primary key values')
 772     if ((grep { defined $row{$_} } @primary_cols) != @primary_cols);
 773
 774   for my $col (keys %$blob_cols) {
 775     my $blob = $blob_cols->{$col};
 776
 777     my %where = map { ($_, $row{$_}) } @primary_cols;
 778
 779     my $cursor = $self->select ($source, [$col], \%where, {});
 780     $cursor->next;
 781     my $sth = $cursor->sth;
 782
 783     if (not $sth) {
 784       $self->throw_exception(
 785           "Could not find row in table '$table' for blob update:\n"
 786         . (Dumper \%where)
 787       );
 788     }
 789
 790     try {
 791       do {
 792         $sth->func('CS_GET', 1, 'ct_data_info') or die $sth->errstr;
 793       } while $sth->fetch;
 794
 795       $sth->func('ct_prepare_send') or die $sth->errstr;
 796
 797       my $log_on_update = $self->_blob_log_on_update;
 798       $log_on_update    = 1 if not defined $log_on_update;
 799
 800       $sth->func('CS_SET', 1, {
 801         total_txtlen => length($blob),
 802         log_on_update => $log_on_update
 803       }, 'ct_data_info') or die $sth->errstr;
 804
 805       $sth->func($blob, length($blob), 'ct_send_data') or die $sth->errstr;
 806
 807       $sth->func('ct_finish_send') or die $sth->errstr;
 808     }
 809     catch {
 810       if ($self->using_freetds) {
 811         $self->throw_exception (
 812           "TEXT/IMAGE operation failed, probably because you are using FreeTDS: $_"
 813         );
 814       }
 815       else {
 816         $self->throw_exception($_);
 817       }
 818     }
 819     finally {
 820       $sth->finish if $sth;
 821     };
 822   }
 823 }
 824
 825 sub _insert_blobs_array {
 826   my ($self, $source, $blob_cols, $cols, $data) = @_;
 827
 828   for my $i (0..$#$data) {
 829     my $datum = $data->[$i];
 830
 831     my %row;
 832     @row{ @$cols } = @$datum;
 833
 834     my %blob_vals;
 835     for my $j (0..$#$cols) {
 836       if (exists $blob_cols->[$i][$j]) {
 837         $blob_vals{ $cols->[$j] } = $blob_cols->[$i][$j];
 838       }
 839     }
 840
 841     $self->_insert_blobs ($source, \%blob_vals, \%row);
 842   }
 843 }
 844
 845 =head2 connect_call_datetime_setup
 846
 847 Used as:
 848
 849   on_connect_call => 'datetime_setup'
 850
 851 In L<connect_info|DBIx::Class::Storage::DBI/connect_info> to set:
 852
 853   $dbh->syb_date_fmt('ISO_strict'); # output fmt: 2004-08-21T14:36:48.080Z
 854   $dbh->do('set dateformat mdy');   # input fmt:  08/13/1979 18:08:55.080
 855
 856 On connection for use with L<DBIx::Class::InflateColumn::DateTime>, using
 857 L<DateTime::Format::Sybase>, which you will need to install.
 858
 859 This works for both C<DATETIME> and C<SMALLDATETIME> columns, although
 860 C<SMALLDATETIME> columns only have minute precision.
 861
 862 =cut
 863
 864 {
 865   my $old_dbd_warned = 0;
 866
 867   sub connect_call_datetime_setup {
 868     my $self = shift;
 869     my $dbh = $self->_get_dbh;
 870
 871     if ($dbh->can('syb_date_fmt')) {
 872       # amazingly, this works with FreeTDS
 873       $dbh->syb_date_fmt('ISO_strict');
 874     } elsif (not $old_dbd_warned) {
 875       carp "Your DBD::Sybase is too old to support ".
 876       "DBIx::Class::InflateColumn::DateTime, please upgrade!";
 877       $old_dbd_warned = 1;
 878     }
 879
 880     $dbh->do('SET DATEFORMAT mdy');
 881
 882     1;
 883   }
 884 }
 885
 886 sub datetime_parser_type { "DateTime::Format::Sybase" }
 887
 888 # ->begin_work and such have no effect with FreeTDS but we run them anyway to
 889 # let the DBD keep any state it needs to.
 890 #
 891 # If they ever do start working, the extra statements will do no harm (because
 892 # Sybase supports nested transactions.)
 893
 894 sub _dbh_begin_work {
 895   my $self = shift;
 896
 897 # bulkLogin=1 connections are always in a transaction, and can only call BEGIN
 898 # TRAN once. However, we need to make sure there's a $dbh.
 899   return if $self->_is_bulk_storage && $self->_dbh && $self->_began_bulk_work;
 900
 901   $self->next::method(@_);
 902
 903   if ($self->using_freetds) {
 904     $self->_get_dbh->do('BEGIN TRAN');
 905   }
 906
 907   $self->_began_bulk_work(1) if $self->_is_bulk_storage;
 908 }
 909
 910 sub _dbh_commit {
 911   my $self = shift;
 912   if ($self->using_freetds) {
 913     $self->_dbh->do('COMMIT');
 914   }
 915   return $self->next::method(@_);
 916 }
 917
 918 sub _dbh_rollback {
 919   my $self = shift;
 920   if ($self->using_freetds) {
 921     $self->_dbh->do('ROLLBACK');
 922   }
 923   return $self->next::method(@_);
 924 }
 925
 926 # savepoint support using ASE syntax
 927
 928 sub _svp_begin {
 929   my ($self, $name) = @_;
 930
 931   $self->_get_dbh->do("SAVE TRANSACTION $name");
 932 }
 933
 934 # A new SAVE TRANSACTION with the same name releases the previous one.
 935 sub _svp_release { 1 }
 936
 937 sub _svp_rollback {
 938   my ($self, $name) = @_;
 939
 940   $self->_get_dbh->do("ROLLBACK TRANSACTION $name");
 941 }
 942
 943 1;
 944
 945 =head1 Schema::Loader Support
 946
 947 As of version C<0.05000>, L<DBIx::Class::Schema::Loader> should work well with
 948 most (if not all) versions of Sybase ASE.
 949
 950 =head1 FreeTDS
 951
 952 This driver supports L<DBD::Sybase> compiled against FreeTDS
 953 (L<http://www.freetds.org/>) to the best of our ability, however it is
 954 recommended that you recompile L<DBD::Sybase> against the Sybase Open Client
 955 libraries. They are a part of the Sybase ASE distribution:
 956
 957 The Open Client FAQ is here:
 958 L<http://www.isug.com/Sybase_FAQ/ASE/section7.html>.
 959
 960 Sybase ASE for Linux (which comes with the Open Client libraries) may be
 961 downloaded here: L<http://response.sybase.com/forms/ASE_Linux_Download>.
 962
 963 To see if you're using FreeTDS check C<< $schema->storage->using_freetds >>, or run:
 964
 965   perl -MDBI -le 'my $dbh = DBI->connect($dsn, $user, $pass); print $dbh->{syb_oc_version}'
 966
 967 Some versions of the libraries involved will not support placeholders, in which
 968 case the storage will be reblessed to
 969 L<DBIx::Class::Storage::DBI::Sybase::ASE::NoBindVars>.
 970
 971 In some configurations, placeholders will work but will throw implicit type
 972 conversion errors for anything that's not expecting a string. In such a case,
 973 the C<auto_cast> option from L<DBIx::Class::Storage::DBI::AutoCast> is
 974 automatically set, which you may enable on connection with
 975 L<DBIx::Class::Storage::DBI::AutoCast/connect_call_set_auto_cast>. The type info
 976 for the C<CAST>s is taken from the L<DBIx::Class::ResultSource/data_type>
 977 definitions in your Result classes, and are mapped to a Sybase type (if it isn't
 978 already) using a mapping based on L<SQL::Translator>.
 979
 980 In other configurations, placeholders will work just as they do with the Sybase
 981 Open Client libraries.
 982
 983 Inserts or updates of TEXT/IMAGE columns will B<NOT> work with FreeTDS.
 984
 985 =head1 INSERTS WITH PLACEHOLDERS
 986
 987 With placeholders enabled, inserts are done in a transaction so that there are
 988 no concurrency issues with getting the inserted identity value using
 989 C<SELECT MAX(col)>, which is the only way to get the C<IDENTITY> value in this
 990 mode.
 991
 992 In addition, they are done on a separate connection so that it's possible to
 993 have active cursors when doing an insert.
 994
 995 When using C<DBIx::Class::Storage::DBI::Sybase::ASE::NoBindVars> transactions
 996 are disabled, as there are no concurrency issues with C<SELECT @@IDENTITY> as
 997 it's a session variable.
 998
 999 =head1 TRANSACTIONS
1000
1001 Due to limitations of the TDS protocol, L<DBD::Sybase>, or both, you cannot
1002 begin a transaction while there are active cursors, nor can you use multiple
1003 active cursors within a transaction. An active cursor is, for example, a
1004 L<ResultSet|DBIx::Class::ResultSet> that has been executed using C<next> or
1005 C<first> but has not been exhausted or L<reset|DBIx::Class::ResultSet/reset>.
1006
1007 For example, this will not work:
1008
1009   $schema->txn_do(sub {
1010     my $rs = $schema->resultset('Book');
1011     while (my $row = $rs->next) {
1012       $schema->resultset('MetaData')->create({
1013         book_id => $row->id,
1014         ...
1015       });
1016     }
1017   });
1018
1019 This won't either:
1020
1021   my $first_row = $large_rs->first;
1022   $schema->txn_do(sub { ... });
1023
1024 Transactions done for inserts in C<AutoCommit> mode when placeholders are in use
1025 are not affected, as they are done on an extra database handle.
1026
1027 Some workarounds:
1028
1029 =over 4
1030
1031 =item * use L<DBIx::Class::Storage::DBI::Replicated>
1032
1033 =item * L<connect|DBIx::Class::Schema/connect> another L<Schema|DBIx::Class::Schema>
1034
1035 =item * load the data from your cursor with L<DBIx::Class::ResultSet/all>
1036
1037 =back
1038
1039 =head1 MAXIMUM CONNECTIONS
1040
1041 The TDS protocol makes separate connections to the server for active statements
1042 in the background. By default the number of such connections is limited to 25,
1043 on both the client side and the server side.
1044
1045 This is a bit too low for a complex L<DBIx::Class> application, so on connection
1046 the client side setting is set to C<256> (see L<DBD::Sybase/maxConnect>.) You
1047 can override it to whatever setting you like in the DSN.
1048
1049 See
1050 L<http://infocenter.sybase.com/help/index.jsp?topic=/com.sybase.help.ase_15.0.sag1/html/sag1/sag1272.htm>
1051 for information on changing the setting on the server side.
1052
1053 =head1 DATES
1054
1055 See L</connect_call_datetime_setup> to setup date formats
1056 for L<DBIx::Class::InflateColumn::DateTime>.
1057
1058 =head1 TEXT/IMAGE COLUMNS
1059
1060 L<DBD::Sybase> compiled with FreeTDS will B<NOT> allow you to insert or update
1061 C<TEXT/IMAGE> columns.
1062
1063 Setting C<< $dbh->{LongReadLen} >> will also not work with FreeTDS use either:
1064
1065   $schema->storage->dbh->do("SET TEXTSIZE $bytes");
1066
1067 or
1068
1069   $schema->storage->set_textsize($bytes);
1070
1071 instead.
1072
1073 However, the C<LongReadLen> you pass in
1074 L<connect_info|DBIx::Class::Storage::DBI/connect_info> is used to execute the
1075 equivalent C<SET TEXTSIZE> command on connection.
1076
1077 See L</connect_call_blob_setup> for a
1078 L<connect_info|DBIx::Class::Storage::DBI/connect_info> setting you need to work
1079 with C<IMAGE> columns.
1080
1081 =head1 BULK API
1082
1083 The experimental L<DBD::Sybase> Bulk API support is used for
1084 L<populate|DBIx::Class::ResultSet/populate> in B<void> context, in a transaction
1085 on a separate connection.
1086
1087 To use this feature effectively, use a large number of rows for each
1088 L<populate|DBIx::Class::ResultSet/populate> call, eg.:
1089
1090   while (my $rows = $data_source->get_100_rows()) {
1091     $rs->populate($rows);
1092   }
1093
1094 B<NOTE:> the L<add_columns|DBIx::Class::ResultSource/add_columns>
1095 calls in your C<Result> classes B<must> list columns in database order for this
1096 to work. Also, you may have to unset the C<LANG> environment variable before
1097 loading your app, if it doesn't match the character set of your database.
1098
1099 When inserting IMAGE columns using this method, you'll need to use
1100 L</connect_call_blob_setup> as well.
1101
1102 =head1 COMPUTED COLUMNS
1103
1104 If you have columns such as:
1105
1106   created_dtm AS getdate()
1107
1108 represent them in your Result classes as:
1109
1110   created_dtm => {
1111     data_type => undef,
1112     default_value => \'getdate()',
1113     is_nullable => 0,
1114   }
1115
1116 The C<data_type> must exist and must be C<undef>. Then empty inserts will work
1117 on tables with such columns.
1118
1119 =head1 TIMESTAMP COLUMNS
1120
1121 C<timestamp> columns in Sybase ASE are not really timestamps, see:
1122 L<http://dba.fyicenter.com/Interview-Questions/SYBASE/The_timestamp_datatype_in_Sybase_.html>.
1123
1124 They should be defined in your Result classes as:
1125
1126   ts => {
1127     data_type => 'timestamp',
1128     is_nullable => 0,
1129     inflate_datetime => 0,
1130   }
1131
1132 The C<<inflate_datetime => 0>> is necessary if you use
1133 L<DBIx::Class::InflateColumn::DateTime>, and most people do, and still want to
1134 be able to read these values.
1135
1136 The values will come back as hexadecimal.
1137
1138 =head1 TODO
1139
1140 =over
1141
1142 =item *
1143
1144 Transitions to AutoCommit=0 (starting a transaction) mode by exhausting
1145 any active cursors, using eager cursors.
1146
1147 =item *
1148
1149 Real limits and limited counts using stored procedures deployed on startup.
1150
1151 =item *
1152
1153 Adaptive Server Anywhere (ASA) support, with possible SQLA::Limit support.
1154
1155 =item *
1156
1157 Blob update with a LIKE query on a blob, without invalidating the WHERE condition.
1158
1159 =item *
1160
1161 bulk_insert using prepare_cached (see comments.)
1162
1163 =back
1164
1165 =head1 AUTHOR
1166
1167 See L<DBIx::Class/CONTRIBUTORS>.
1168
1169 =head1 LICENSE
1170
1171 You may distribute this code under the same terms as Perl itself.
1172
1173 =cut
1174 # vim:sts=2 sw=2: