lib/DBIx/Class/Storage/DBI/Sybase/ASE.pm

   1 package DBIx::Class::Storage::DBI::Sybase::ASE;
   2
   3 use strict;
   4 use warnings;
   5
   6 use base qw/
   7   DBIx::Class::Storage::DBI::Sybase
   8   DBIx::Class::Storage::DBI::AutoCast
   9   DBIx::Class::Storage::DBI::IdentityInsert
  10 /;
  11 use mro 'c3';
  12 use DBIx::Class::Carp;
  13 use Scalar::Util qw/blessed weaken/;
  14 use List::Util 'first';
  15 use Sub::Name();
  16 use Data::Dumper::Concise 'Dumper';
  17 use Try::Tiny;
  18 use Context::Preserve 'preserve_context';
  19 use DBIx::Class::_Util 'sigwarn_silencer';
  20 use namespace::clean;
  21
  22 __PACKAGE__->sql_limit_dialect ('GenericSubQ');
  23 __PACKAGE__->sql_quote_char ([qw/[ ]/]);
  24 __PACKAGE__->datetime_parser_type(
  25   'DBIx::Class::Storage::DBI::Sybase::ASE::DateTime::Format'
  26 );
  27
  28 __PACKAGE__->mk_group_accessors('simple' =>
  29     qw/_identity _identity_method _blob_log_on_update _parent_storage
  30        _writer_storage _is_writer_storage
  31        _bulk_storage _is_bulk_storage _began_bulk_work
  32     /
  33 );
  34
  35
  36 my @also_proxy_to_extra_storages = qw/
  37   connect_call_set_auto_cast auto_cast connect_call_blob_setup
  38   connect_call_datetime_setup
  39
  40   disconnect _connect_info _sql_maker _sql_maker_opts disable_sth_caching
  41   auto_savepoint unsafe cursor_class debug debugobj schema
  42 /;
  43
  44 =head1 NAME
  45
  46 DBIx::Class::Storage::DBI::Sybase::ASE - Sybase ASE SQL Server support for
  47 DBIx::Class
  48
  49 =head1 SYNOPSIS
  50
  51 This subclass supports L<DBD::Sybase> for real (non-Microsoft) Sybase databases.
  52
  53 =head1 DESCRIPTION
  54
  55 If your version of Sybase does not support placeholders, then your storage will
  56 be reblessed to L<DBIx::Class::Storage::DBI::Sybase::ASE::NoBindVars>.
  57 You can also enable that driver explicitly, see the documentation for more
  58 details.
  59
  60 With this driver there is unfortunately no way to get the C<last_insert_id>
  61 without doing a C<SELECT MAX(col)>. This is done safely in a transaction
  62 (locking the table.) See L</INSERTS WITH PLACEHOLDERS>.
  63
  64 A recommended L<connect_info|DBIx::Class::Storage::DBI/connect_info> setting:
  65
  66   on_connect_call => [['datetime_setup'], ['blob_setup', log_on_update => 0]]
  67
  68 =head1 METHODS
  69
  70 =cut
  71
  72 sub _rebless {
  73   my $self = shift;
  74
  75   my $no_bind_vars = __PACKAGE__ . '::NoBindVars';
  76
  77   if ($self->_using_freetds) {
  78     carp_once <<'EOF' unless $ENV{DBIC_SYBASE_FREETDS_NOWARN};
  79
  80 You are using FreeTDS with Sybase.
  81
  82 We will do our best to support this configuration, but please consider this
  83 support experimental.
  84
  85 TEXT/IMAGE columns will definitely not work.
  86
  87 You are encouraged to recompile DBD::Sybase with the Sybase Open Client libraries
  88 instead.
  89
  90 See perldoc DBIx::Class::Storage::DBI::Sybase::ASE for more details.
  91
  92 To turn off this warning set the DBIC_SYBASE_FREETDS_NOWARN environment
  93 variable.
  94 EOF
  95
  96     if (not $self->_use_typeless_placeholders) {
  97       if ($self->_use_placeholders) {
  98         $self->auto_cast(1);
  99       }
 100       else {
 101         $self->ensure_class_loaded($no_bind_vars);
 102         bless $self, $no_bind_vars;
 103         $self->_rebless;
 104       }
 105     }
 106   }
 107
 108   elsif (not $self->_get_dbh->{syb_dynamic_supported}) {
 109     # not necessarily FreeTDS, but no placeholders nevertheless
 110     $self->ensure_class_loaded($no_bind_vars);
 111     bless $self, $no_bind_vars;
 112     $self->_rebless;
 113   }
 114   # this is highly unlikely, but we check just in case
 115   elsif (not $self->_use_typeless_placeholders) {
 116     $self->auto_cast(1);
 117   }
 118 }
 119
 120 sub _init {
 121   my $self = shift;
 122
 123   $self->next::method(@_);
 124
 125   if ($self->_using_freetds && (my $ver = $self->_using_freetds_version||999) > 0.82) {
 126     carp_once(
 127       "Buggy FreeTDS version $ver detected, statement caching will not work and "
 128     . 'will be disabled.'
 129     );
 130     $self->disable_sth_caching(1);
 131   }
 132
 133   $self->_set_max_connect(256);
 134
 135 # create storage for insert/(update blob) transactions,
 136 # unless this is that storage
 137   return if $self->_parent_storage;
 138
 139   my $writer_storage = (ref $self)->new;
 140
 141   $writer_storage->_is_writer_storage(1); # just info
 142   $writer_storage->connect_info($self->connect_info);
 143   $writer_storage->auto_cast($self->auto_cast);
 144
 145   weaken ($writer_storage->{_parent_storage} = $self);
 146   $self->_writer_storage($writer_storage);
 147
 148 # create a bulk storage unless connect_info is a coderef
 149   return if ref($self->_dbi_connect_info->[0]) eq 'CODE';
 150
 151   my $bulk_storage = (ref $self)->new;
 152
 153   $bulk_storage->_is_bulk_storage(1); # for special ->disconnect acrobatics
 154   $bulk_storage->connect_info($self->connect_info);
 155
 156 # this is why
 157   $bulk_storage->_dbi_connect_info->[0] .= ';bulkLogin=1';
 158
 159   weaken ($bulk_storage->{_parent_storage} = $self);
 160   $self->_bulk_storage($bulk_storage);
 161 }
 162
 163 for my $method (@also_proxy_to_extra_storages) {
 164   no strict 'refs';
 165   no warnings 'redefine';
 166
 167   my $replaced = __PACKAGE__->can($method);
 168
 169   *{$method} = Sub::Name::subname $method => sub {
 170     my $self = shift;
 171     $self->_writer_storage->$replaced(@_) if $self->_writer_storage;
 172     $self->_bulk_storage->$replaced(@_)   if $self->_bulk_storage;
 173     return $self->$replaced(@_);
 174   };
 175 }
 176
 177 sub disconnect {
 178   my $self = shift;
 179
 180 # Even though we call $sth->finish for uses off the bulk API, there's still an
 181 # "active statement" warning on disconnect, which we throw away here.
 182 # This is due to the bug described in _insert_bulk.
 183 # Currently a noop because 'prepare' is used instead of 'prepare_cached'.
 184   local $SIG{__WARN__} = sigwarn_silencer(qr/active statement/i)
 185     if $self->_is_bulk_storage;
 186
 187 # so that next transaction gets a dbh
 188   $self->_began_bulk_work(0) if $self->_is_bulk_storage;
 189
 190   $self->next::method;
 191 }
 192
 193 # This is only invoked for FreeTDS drivers by ::Storage::DBI::Sybase::FreeTDS
 194 sub _set_autocommit_stmt {
 195   my ($self, $on) = @_;
 196
 197   return 'SET CHAINED ' . ($on ? 'OFF' : 'ON');
 198 }
 199
 200 # Set up session settings for Sybase databases for the connection.
 201 #
 202 # Make sure we have CHAINED mode turned on if AutoCommit is off in non-FreeTDS
 203 # DBD::Sybase (since we don't know how DBD::Sybase was compiled.) If however
 204 # we're using FreeTDS, CHAINED mode turns on an implicit transaction which we
 205 # only want when AutoCommit is off.
 206 sub _run_connection_actions {
 207   my $self = shift;
 208
 209   if ($self->_is_bulk_storage) {
 210     # this should be cleared on every reconnect
 211     $self->_began_bulk_work(0);
 212     return;
 213   }
 214
 215   $self->_dbh->{syb_chained_txn} = 1
 216     unless $self->_using_freetds;
 217
 218   $self->next::method(@_);
 219 }
 220
 221 =head2 connect_call_blob_setup
 222
 223 Used as:
 224
 225   on_connect_call => [ [ 'blob_setup', log_on_update => 0 ] ]
 226
 227 Does C<< $dbh->{syb_binary_images} = 1; >> to return C<IMAGE> data as raw binary
 228 instead of as a hex string.
 229
 230 Recommended.
 231
 232 Also sets the C<log_on_update> value for blob write operations. The default is
 233 C<1>, but C<0> is better if your database is configured for it.
 234
 235 See
 236 L<DBD::Sybase/Handling IMAGE/TEXT data with syb_ct_get_data()/syb_ct_send_data()>.
 237
 238 =cut
 239
 240 sub connect_call_blob_setup {
 241   my $self = shift;
 242   my %args = @_;
 243   my $dbh = $self->_dbh;
 244   $dbh->{syb_binary_images} = 1;
 245
 246   $self->_blob_log_on_update($args{log_on_update})
 247     if exists $args{log_on_update};
 248 }
 249
 250 sub _is_lob_column {
 251   my ($self, $source, $column) = @_;
 252
 253   return $self->_is_lob_type($source->column_info($column)->{data_type});
 254 }
 255
 256 sub _prep_for_execute {
 257   my ($self, $op, $ident, $args) = @_;
 258
 259   my $limit;  # extract and use shortcut on limit without offset
 260   if ($op eq 'select' and ! $args->[4] and $limit = $args->[3]) {
 261     $args = [ @$args ];
 262     $args->[3] = undef;
 263   }
 264
 265   my ($sql, $bind) = $self->next::method($op, $ident, $args);
 266
 267   # $limit is already sanitized by now
 268   $sql = join( "\n",
 269     "SET ROWCOUNT $limit",
 270     $sql,
 271     "SET ROWCOUNT 0",
 272   ) if $limit;
 273
 274   if (my $identity_col = $self->_perform_autoinc_retrieval) {
 275     $sql .= "\n" . $self->_fetch_identity_sql($ident, $identity_col)
 276   }
 277
 278   return ($sql, $bind);
 279 }
 280
 281 sub _fetch_identity_sql {
 282   my ($self, $source, $col) = @_;
 283
 284   return sprintf ("SELECT MAX(%s) FROM %s",
 285     map { $self->sql_maker->_quote ($_) } ($col, $source->from)
 286   );
 287 }
 288
 289 # Stolen from SQLT, with some modifications. This is a makeshift
 290 # solution before a sane type-mapping library is available, thus
 291 # the 'our' for easy overrides.
 292 our %TYPE_MAPPING  = (
 293     number    => 'numeric',
 294     money     => 'money',
 295     varchar   => 'varchar',
 296     varchar2  => 'varchar',
 297     timestamp => 'datetime',
 298     text      => 'varchar',
 299     real      => 'double precision',
 300     comment   => 'text',
 301     bit       => 'bit',
 302     tinyint   => 'smallint',
 303     float     => 'double precision',
 304     serial    => 'numeric',
 305     bigserial => 'numeric',
 306     boolean   => 'varchar',
 307     long      => 'varchar',
 308 );
 309
 310 sub _native_data_type {
 311   my ($self, $type) = @_;
 312
 313   $type = lc $type;
 314   $type =~ s/\s* identity//x;
 315
 316   return uc($TYPE_MAPPING{$type} || $type);
 317 }
 318
 319
 320 sub _execute {
 321   my $self = shift;
 322   my ($rv, $sth, @bind) = $self->next::method(@_);
 323
 324   $self->_identity( ($sth->fetchall_arrayref)->[0][0] )
 325     if $self->_perform_autoinc_retrieval;
 326
 327   return wantarray ? ($rv, $sth, @bind) : $rv;
 328 }
 329
 330 sub last_insert_id { shift->_identity }
 331
 332 # handles TEXT/IMAGE and transaction for last_insert_id
 333 sub insert {
 334   my $self = shift;
 335   my ($source, $to_insert) = @_;
 336
 337   my $columns_info = $source->columns_info;
 338
 339   my ($identity_col) = grep
 340     { $columns_info->{$_}{is_auto_increment} }
 341     keys %$columns_info
 342   ;
 343
 344   $identity_col = '' if ! defined $identity_col;
 345
 346   # FIXME - this is duplication from DBI.pm. When refactored towards
 347   # the LobWriter this can be folded back where it belongs.
 348   local $self->{_autoinc_supplied_for_op} = exists $to_insert->{$identity_col}
 349     ? 1
 350     : 0
 351   ;
 352
 353   local $self->{_perform_autoinc_retrieval} = $self->{_autoinc_supplied_for_op}
 354     ? undef
 355     : $identity_col
 356   ;
 357
 358   # check for empty insert
 359   # INSERT INTO foo DEFAULT VALUES -- does not work with Sybase
 360   # try to insert explicit 'DEFAULT's instead (except for identity, timestamp
 361   # and computed columns)
 362   if (not %$to_insert) {
 363     for my $col ($source->columns) {
 364       next if $col eq $identity_col;
 365
 366       my $info = $source->column_info($col);
 367
 368       next if ref $info->{default_value} eq 'SCALAR'
 369         || (exists $info->{data_type} && (not defined $info->{data_type}));
 370
 371       next if $info->{data_type} && $info->{data_type} =~ /^timestamp\z/i;
 372
 373       $to_insert->{$col} = \'DEFAULT';
 374     }
 375   }
 376
 377   my $blob_cols = $self->_remove_blob_cols($source, $to_insert);
 378
 379   # do we need the horrific SELECT MAX(COL) hack?
 380   my $need_dumb_last_insert_id = (
 381     $self->_perform_autoinc_retrieval
 382       and
 383     ( ($self->_identity_method||'') ne '@@IDENTITY' )
 384   );
 385
 386   my $next = $self->next::can;
 387
 388   # we are already in a transaction, or there are no blobs
 389   # and we don't need the PK - just (try to) do it
 390   if (
 391     ( !$blob_cols and !$need_dumb_last_insert_id )
 392       or
 393     $self->transaction_depth
 394   ) {
 395     $self->_insert (
 396       $next, $source, $to_insert, $blob_cols, $identity_col
 397     );
 398   }
 399   # otherwise use the _writer_storage to do the insert+transaction on another
 400   # connection
 401   else {
 402     my $guard = $self->_writer_storage->txn_scope_guard;
 403
 404     my $updated_cols = $self->_writer_storage->_insert (
 405       $next, $source, $to_insert, $blob_cols, $identity_col
 406     );
 407
 408     $self->_identity($self->_writer_storage->_identity);
 409
 410     $guard->commit;
 411
 412     $updated_cols;
 413   }
 414 }
 415
 416 sub _insert {
 417   my ($self, $next, $source, $to_insert, $blob_cols, $identity_col) = @_;
 418
 419   my $updated_cols = $self->$next ($source, $to_insert);
 420
 421   $self->_insert_blobs (
 422     $source,
 423     $blob_cols,
 424     {
 425       ( $identity_col
 426         ? ( $identity_col => $self->last_insert_id($source, $identity_col) )
 427         : ()
 428       ),
 429       %$to_insert,
 430       %$updated_cols,
 431     },
 432   ) if $blob_cols;
 433
 434   return $updated_cols;
 435 }
 436
 437 sub update {
 438   my $self = shift;
 439   my ($source, $fields, $where, @rest) = @_;
 440
 441   #
 442   # When *updating* identities, ASE requires SET IDENTITY_UPDATE called
 443   #
 444   if (my $blob_cols = $self->_remove_blob_cols($source, $fields)) {
 445
 446     # If there are any blobs in $where, Sybase will return a descriptive error
 447     # message.
 448     # XXX blobs can still be used with a LIKE query, and this should be handled.
 449
 450     # update+blob update(s) done atomically on separate connection
 451     $self = $self->_writer_storage;
 452
 453     my $guard = $self->txn_scope_guard;
 454
 455     # First update the blob columns to be updated to '' (taken from $fields, where
 456     # it is originally put by _remove_blob_cols .)
 457     my %blobs_to_empty = map { ($_ => delete $fields->{$_}) } keys %$blob_cols;
 458
 459     # We can't only update NULL blobs, because blobs cannot be in the WHERE clause.
 460     $self->next::method($source, \%blobs_to_empty, $where, @rest);
 461
 462     # Now update the blobs before the other columns in case the update of other
 463     # columns makes the search condition invalid.
 464     my $rv = $self->_update_blobs($source, $blob_cols, $where);
 465
 466     if (keys %$fields) {
 467
 468       # Now set the identity update flags for the actual update
 469       local $self->{_autoinc_supplied_for_op} = (first
 470         { $_->{is_auto_increment} }
 471         values %{ $source->columns_info([ keys %$fields ]) }
 472       ) ? 1 : 0;
 473
 474       my $next = $self->next::can;
 475       my $args = \@_;
 476       return preserve_context {
 477         $self->$next(@$args);
 478       } after => sub { $guard->commit };
 479     }
 480     else {
 481       $guard->commit;
 482       return $rv;
 483     }
 484   }
 485   else {
 486     # Set the identity update flags for the actual update
 487     local $self->{_autoinc_supplied_for_op} = (first
 488       { $_->{is_auto_increment} }
 489       values %{ $source->columns_info([ keys %$fields ]) }
 490     ) ? 1 : 0;
 491
 492     return $self->next::method(@_);
 493   }
 494 }
 495
 496 sub _insert_bulk {
 497   my $self = shift;
 498   my ($source, $cols, $data) = @_;
 499
 500   my $columns_info = $source->columns_info;
 501
 502   my $identity_col =
 503     first { $columns_info->{$_}{is_auto_increment} }
 504       keys %$columns_info;
 505
 506   # FIXME - this is duplication from DBI.pm. When refactored towards
 507   # the LobWriter this can be folded back where it belongs.
 508   local $self->{_autoinc_supplied_for_op} =
 509     (first { $_ eq $identity_col } @$cols)
 510       ? 1
 511       : 0
 512   ;
 513
 514   my $use_bulk_api =
 515     $self->_bulk_storage &&
 516     $self->_get_dbh->{syb_has_blk};
 517
 518   if (! $use_bulk_api and ref($self->_dbi_connect_info->[0]) eq 'CODE') {
 519     carp_unique( join ' ',
 520       'Bulk API support disabled due to use of a CODEREF connect_info.',
 521       'Reverting to regular array inserts.',
 522     );
 523   }
 524
 525   if (not $use_bulk_api) {
 526     my $blob_cols = $self->_remove_blob_cols_array($source, $cols, $data);
 527
 528 # next::method uses a txn anyway, but it ends too early in case we need to
 529 # select max(col) to get the identity for inserting blobs.
 530     ($self, my $guard) = $self->transaction_depth
 531       ? ($self, undef)
 532       : ($self->_writer_storage, $self->_writer_storage->txn_scope_guard)
 533     ;
 534
 535     $self->next::method(@_);
 536
 537     if ($blob_cols) {
 538       if ($self->_autoinc_supplied_for_op) {
 539         $self->_insert_blobs_array ($source, $blob_cols, $cols, $data);
 540       }
 541       else {
 542         my @cols_with_identities = (@$cols, $identity_col);
 543
 544         ## calculate identities
 545         # XXX This assumes identities always increase by 1, which may or may not
 546         # be true.
 547         my ($last_identity) =
 548           $self->_dbh->selectrow_array (
 549             $self->_fetch_identity_sql($source, $identity_col)
 550           );
 551         my @identities = (($last_identity - @$data + 1) .. $last_identity);
 552
 553         my @data_with_identities = map [@$_, shift @identities], @$data;
 554
 555         $self->_insert_blobs_array (
 556           $source, $blob_cols, \@cols_with_identities, \@data_with_identities
 557         );
 558       }
 559     }
 560
 561     $guard->commit if $guard;
 562
 563     return;
 564   }
 565
 566 # otherwise, use the bulk API
 567
 568 # rearrange @$data so that columns are in database order
 569 # and so we submit a full column list
 570   my %orig_order = map { $cols->[$_] => $_ } 0..$#$cols;
 571
 572   my @source_columns = $source->columns;
 573
 574   # bcp identity index is 1-based
 575   my $identity_idx = first { $source_columns[$_] eq $identity_col } (0..$#source_columns);
 576   $identity_idx = defined $identity_idx ? $identity_idx + 1 : 0;
 577
 578   my @new_data;
 579   for my $slice_idx (0..$#$data) {
 580     push @new_data, [map {
 581       # identity data will be 'undef' if not _autoinc_supplied_for_op()
 582       # columns with defaults will also be 'undef'
 583       exists $orig_order{$_}
 584         ? $data->[$slice_idx][$orig_order{$_}]
 585         : undef
 586     } @source_columns];
 587   }
 588
 589   my $proto_bind = $self->_resolve_bindattrs(
 590     $source,
 591     [map {
 592       [ { dbic_colname => $source_columns[$_], _bind_data_slice_idx => $_ }
 593         => $new_data[0][$_] ]
 594     } (0 ..$#source_columns) ],
 595     $columns_info
 596   );
 597
 598 ## Set a client-side conversion error handler, straight from DBD::Sybase docs.
 599 # This ignores any data conversion errors detected by the client side libs, as
 600 # they are usually harmless.
 601   my $orig_cslib_cb = DBD::Sybase::set_cslib_cb(
 602     Sub::Name::subname _insert_bulk_cslib_errhandler => sub {
 603       my ($layer, $origin, $severity, $errno, $errmsg, $osmsg, $blkmsg) = @_;
 604
 605       return 1 if $errno == 36;
 606
 607       carp
 608         "Layer: $layer, Origin: $origin, Severity: $severity, Error: $errno" .
 609         ($errmsg ? "\n$errmsg" : '') .
 610         ($osmsg  ? "\n$osmsg"  : '')  .
 611         ($blkmsg ? "\n$blkmsg" : '');
 612
 613       return 0;
 614   });
 615
 616   my $exception = '';
 617   try {
 618     my $bulk = $self->_bulk_storage;
 619
 620     my $guard = $bulk->txn_scope_guard;
 621
 622 ## FIXME - once this is done - address the FIXME on finish() below
 623 ## XXX get this to work instead of our own $sth
 624 ## will require SQLA or *Hacks changes for ordered columns
 625 #    $bulk->next::method($source, \@source_columns, \@new_data, {
 626 #      syb_bcp_attribs => {
 627 #        identity_flag   => $self->_autoinc_supplied_for_op ? 1 : 0,
 628 #        identity_column => $identity_idx,
 629 #      }
 630 #    });
 631     my $sql = 'INSERT INTO ' .
 632       $bulk->sql_maker->_quote($source->name) . ' (' .
 633 # colname list is ignored for BCP, but does no harm
 634       (join ', ', map $bulk->sql_maker->_quote($_), @source_columns) . ') '.
 635       ' VALUES ('.  (join ', ', ('?') x @source_columns) . ')';
 636
 637 ## XXX there's a bug in the DBD::Sybase bulk support that makes $sth->finish for
 638 ## a prepare_cached statement ineffective. Replace with ->sth when fixed, or
 639 ## better yet the version above. Should be fixed in DBD::Sybase .
 640     my $sth = $bulk->_get_dbh->prepare($sql,
 641 #      'insert', # op
 642       {
 643         syb_bcp_attribs => {
 644           identity_flag   => $self->_autoinc_supplied_for_op ? 1 : 0,
 645           identity_column => $identity_idx,
 646         }
 647       }
 648     );
 649
 650     {
 651       # FIXME the $sth->finish in _execute_array does a rollback for some
 652       # reason. Disable it temporarily until we fix the SQLMaker thing above
 653       no warnings 'redefine';
 654       no strict 'refs';
 655       local *{ref($sth).'::finish'} = sub {};
 656
 657       $self->_dbh_execute_for_fetch(
 658         $source, $sth, $proto_bind, \@source_columns, \@new_data
 659       );
 660     }
 661
 662     $guard->commit;
 663
 664     $bulk->_query_end($sql);
 665   } catch {
 666     $exception = shift;
 667   };
 668
 669   DBD::Sybase::set_cslib_cb($orig_cslib_cb);
 670
 671   if ($exception =~ /-Y option/) {
 672     my $w = 'Sybase bulk API operation failed due to character set incompatibility, '
 673           . 'reverting to regular array inserts. Try unsetting the LC_ALL environment variable'
 674     ;
 675     $w .= "\n$exception" if $self->debug;
 676     carp $w;
 677
 678     $self->_bulk_storage(undef);
 679     unshift @_, $self;
 680     goto \&_insert_bulk;
 681   }
 682   elsif ($exception) {
 683 # rollback makes the bulkLogin connection unusable
 684     $self->_bulk_storage->disconnect;
 685     $self->throw_exception($exception);
 686   }
 687 }
 688
 689 # Make sure blobs are not bound as placeholders, and return any non-empty ones
 690 # as a hash.
 691 sub _remove_blob_cols {
 692   my ($self, $source, $fields) = @_;
 693
 694   my %blob_cols;
 695
 696   for my $col (keys %$fields) {
 697     if ($self->_is_lob_column($source, $col)) {
 698       my $blob_val = delete $fields->{$col};
 699       if (not defined $blob_val) {
 700         $fields->{$col} = \'NULL';
 701       }
 702       else {
 703         $fields->{$col} = \"''";
 704         $blob_cols{$col} = $blob_val unless $blob_val eq '';
 705       }
 706     }
 707   }
 708
 709   return %blob_cols ? \%blob_cols : undef;
 710 }
 711
 712 # same for _insert_bulk
 713 sub _remove_blob_cols_array {
 714   my ($self, $source, $cols, $data) = @_;
 715
 716   my @blob_cols;
 717
 718   for my $i (0..$#$cols) {
 719     my $col = $cols->[$i];
 720
 721     if ($self->_is_lob_column($source, $col)) {
 722       for my $j (0..$#$data) {
 723         my $blob_val = delete $data->[$j][$i];
 724         if (not defined $blob_val) {
 725           $data->[$j][$i] = \'NULL';
 726         }
 727         else {
 728           $data->[$j][$i] = \"''";
 729           $blob_cols[$j][$i] = $blob_val
 730             unless $blob_val eq '';
 731         }
 732       }
 733     }
 734   }
 735
 736   return @blob_cols ? \@blob_cols : undef;
 737 }
 738
 739 sub _update_blobs {
 740   my ($self, $source, $blob_cols, $where) = @_;
 741
 742   my @primary_cols = try
 743     { $source->_pri_cols_or_die }
 744     catch {
 745       $self->throw_exception("Cannot update TEXT/IMAGE column(s): $_")
 746     };
 747
 748   my @pks_to_update;
 749   if (
 750     ref $where eq 'HASH'
 751       and
 752     ! grep { ! defined $where->{$_} } @primary_cols
 753   ) {
 754     my %row_to_update;
 755     @row_to_update{@primary_cols} = @{$where}{@primary_cols};
 756     @pks_to_update = \%row_to_update;
 757   }
 758   else {
 759     my $cursor = $self->select ($source, \@primary_cols, $where, {});
 760     @pks_to_update = map {
 761       my %row; @row{@primary_cols} = @$_; \%row
 762     } $cursor->all;
 763   }
 764
 765   for my $ident (@pks_to_update) {
 766     $self->_insert_blobs($source, $blob_cols, $ident);
 767   }
 768 }
 769
 770 sub _insert_blobs {
 771   my ($self, $source, $blob_cols, $row_data) = @_;
 772
 773   my $table = $source->name;
 774
 775   my @primary_cols = try
 776     { $source->_pri_cols_or_die }
 777     catch {
 778       $self->throw_exception("Cannot update TEXT/IMAGE column(s): $_")
 779     };
 780
 781   $self->throw_exception('Cannot update TEXT/IMAGE column(s) without primary key values')
 782     if grep { ! defined $row_data->{$_} } @primary_cols;
 783
 784   my %where = map {( $_ => $row_data->{$_} )} @primary_cols;
 785
 786   for my $col (keys %$blob_cols) {
 787     my $blob = $blob_cols->{$col};
 788
 789     my $cursor = $self->select ($source, [$col], \%where, {});
 790     $cursor->next;
 791     my $sth = $cursor->sth;
 792
 793     if (not $sth) {
 794       $self->throw_exception(
 795           "Could not find row in table '$table' for blob update:\n"
 796         . (Dumper \%where)
 797       );
 798     }
 799
 800     try {
 801       do {
 802         $sth->func('CS_GET', 1, 'ct_data_info') or die $sth->errstr;
 803       } while $sth->fetch;
 804
 805       $sth->func('ct_prepare_send') or die $sth->errstr;
 806
 807       my $log_on_update = $self->_blob_log_on_update;
 808       $log_on_update    = 1 if not defined $log_on_update;
 809
 810       $sth->func('CS_SET', 1, {
 811         total_txtlen => length($blob),
 812         log_on_update => $log_on_update
 813       }, 'ct_data_info') or die $sth->errstr;
 814
 815       $sth->func($blob, length($blob), 'ct_send_data') or die $sth->errstr;
 816
 817       $sth->func('ct_finish_send') or die $sth->errstr;
 818     }
 819     catch {
 820       if ($self->_using_freetds) {
 821         $self->throw_exception (
 822           "TEXT/IMAGE operation failed, probably because you are using FreeTDS: $_"
 823         );
 824       }
 825       else {
 826         $self->throw_exception($_);
 827       }
 828     }
 829     finally {
 830       $sth->finish if $sth;
 831     };
 832   }
 833 }
 834
 835 sub _insert_blobs_array {
 836   my ($self, $source, $blob_cols, $cols, $data) = @_;
 837
 838   for my $i (0..$#$data) {
 839     my $datum = $data->[$i];
 840
 841     my %row;
 842     @row{ @$cols } = @$datum;
 843
 844     my %blob_vals;
 845     for my $j (0..$#$cols) {
 846       if (exists $blob_cols->[$i][$j]) {
 847         $blob_vals{ $cols->[$j] } = $blob_cols->[$i][$j];
 848       }
 849     }
 850
 851     $self->_insert_blobs ($source, \%blob_vals, \%row);
 852   }
 853 }
 854
 855 =head2 connect_call_datetime_setup
 856
 857 Used as:
 858
 859   on_connect_call => 'datetime_setup'
 860
 861 In L<connect_info|DBIx::Class::Storage::DBI/connect_info> to set:
 862
 863   $dbh->syb_date_fmt('ISO_strict'); # output fmt: 2004-08-21T14:36:48.080Z
 864   $dbh->do('set dateformat mdy');   # input fmt:  08/13/1979 18:08:55.080
 865
 866 This works for both C<DATETIME> and C<SMALLDATETIME> columns, note that
 867 C<SMALLDATETIME> columns only have minute precision.
 868
 869 =cut
 870
 871 sub connect_call_datetime_setup {
 872   my $self = shift;
 873   my $dbh = $self->_get_dbh;
 874
 875   if ($dbh->can('syb_date_fmt')) {
 876     # amazingly, this works with FreeTDS
 877     $dbh->syb_date_fmt('ISO_strict');
 878   }
 879   else {
 880     carp_once
 881       'Your DBD::Sybase is too old to support '
 882      .'DBIx::Class::InflateColumn::DateTime, please upgrade!';
 883
 884     # FIXME - in retrospect this is a rather bad US-centric choice
 885     # of format. Not changing as a bugwards compat, though in reality
 886     # the only piece that sees the results of $dt object formatting
 887     # (as opposed to parsing) is the database itself, so theoretically
 888     # changing both this SET command and the formatter definition of
 889     # ::S::D::Sybase::ASE::DateTime::Format below should be safe and
 890     # transparent
 891
 892     $dbh->do('SET DATEFORMAT mdy');
 893   }
 894 }
 895
 896
 897 sub _exec_txn_begin {
 898   my $self = shift;
 899
 900 # bulkLogin=1 connections are always in a transaction, and can only call BEGIN
 901 # TRAN once. However, we need to make sure there's a $dbh.
 902   return if $self->_is_bulk_storage && $self->_dbh && $self->_began_bulk_work;
 903
 904   $self->next::method(@_);
 905
 906   $self->_began_bulk_work(1) if $self->_is_bulk_storage;
 907 }
 908
 909 # savepoint support using ASE syntax
 910
 911 sub _exec_svp_begin {
 912   my ($self, $name) = @_;
 913
 914   $self->_dbh->do("SAVE TRANSACTION $name");
 915 }
 916
 917 # A new SAVE TRANSACTION with the same name releases the previous one.
 918 sub _exec_svp_release { 1 }
 919
 920 sub _exec_svp_rollback {
 921   my ($self, $name) = @_;
 922
 923   $self->_dbh->do("ROLLBACK TRANSACTION $name");
 924 }
 925
 926 package # hide from PAUSE
 927   DBIx::Class::Storage::DBI::Sybase::ASE::DateTime::Format;
 928
 929 my $datetime_parse_format  = '%Y-%m-%dT%H:%M:%S.%3NZ';
 930 my $datetime_format_format = '%m/%d/%Y %H:%M:%S.%3N';
 931
 932 my ($datetime_parser, $datetime_formatter);
 933
 934 sub parse_datetime {
 935   shift;
 936   require DateTime::Format::Strptime;
 937   $datetime_parser ||= DateTime::Format::Strptime->new(
 938     pattern  => $datetime_parse_format,
 939     on_error => 'croak',
 940   );
 941   return $datetime_parser->parse_datetime(shift);
 942 }
 943
 944 sub format_datetime {
 945   shift;
 946   require DateTime::Format::Strptime;
 947   $datetime_formatter ||= DateTime::Format::Strptime->new(
 948     pattern  => $datetime_format_format,
 949     on_error => 'croak',
 950   );
 951   return $datetime_formatter->format_datetime(shift);
 952 }
 953
 954 1;
 955
 956 =head1 Schema::Loader Support
 957
 958 As of version C<0.05000>, L<DBIx::Class::Schema::Loader> should work well with
 959 most versions of Sybase ASE.
 960
 961 =head1 FreeTDS
 962
 963 This driver supports L<DBD::Sybase> compiled against FreeTDS
 964 (L<http://www.freetds.org/>) to the best of our ability, however it is
 965 recommended that you recompile L<DBD::Sybase> against the Sybase Open Client
 966 libraries. They are a part of the Sybase ASE distribution:
 967
 968 The Open Client FAQ is here:
 969 L<http://www.isug.com/Sybase_FAQ/ASE/section7.html>.
 970
 971 Sybase ASE for Linux (which comes with the Open Client libraries) may be
 972 downloaded here: L<http://response.sybase.com/forms/ASE_Linux_Download>.
 973
 974 To see if you're using FreeTDS run:
 975
 976   perl -MDBI -le 'my $dbh = DBI->connect($dsn, $user, $pass); print $dbh->{syb_oc_version}'
 977
 978 It is recommended to set C<tds version> for your ASE server to C<5.0> in
 979 C</etc/freetds/freetds.conf>.
 980
 981 Some versions or configurations of the libraries involved will not support
 982 placeholders, in which case the storage will be reblessed to
 983 L<DBIx::Class::Storage::DBI::Sybase::ASE::NoBindVars>.
 984
 985 In some configurations, placeholders will work but will throw implicit type
 986 conversion errors for anything that's not expecting a string. In such a case,
 987 the C<auto_cast> option from L<DBIx::Class::Storage::DBI::AutoCast> is
 988 automatically set, which you may enable on connection with
 989 L<connect_call_set_auto_cast|DBIx::Class::Storage::DBI::AutoCast/connect_call_set_auto_cast>.
 990 The type info for the C<CAST>s is taken from the
 991 L<DBIx::Class::ResultSource/data_type> definitions in your Result classes, and
 992 are mapped to a Sybase type (if it isn't already) using a mapping based on
 993 L<SQL::Translator>.
 994
 995 In other configurations, placeholders will work just as they do with the Sybase
 996 Open Client libraries.
 997
 998 Inserts or updates of TEXT/IMAGE columns will B<NOT> work with FreeTDS.
 999
1000 =head1 INSERTS WITH PLACEHOLDERS
1001
1002 With placeholders enabled, inserts are done in a transaction so that there are
1003 no concurrency issues with getting the inserted identity value using
1004 C<SELECT MAX(col)>, which is the only way to get the C<IDENTITY> value in this
1005 mode.
1006
1007 In addition, they are done on a separate connection so that it's possible to
1008 have active cursors when doing an insert.
1009
1010 When using C<DBIx::Class::Storage::DBI::Sybase::ASE::NoBindVars> transactions
1011 are unnecessary and not used, as there are no concurrency issues with C<SELECT
1012 @@IDENTITY> which is a session variable.
1013
1014 =head1 TRANSACTIONS
1015
1016 Due to limitations of the TDS protocol and L<DBD::Sybase>, you cannot begin a
1017 transaction while there are active cursors, nor can you use multiple active
1018 cursors within a transaction. An active cursor is, for example, a
1019 L<ResultSet|DBIx::Class::ResultSet> that has been executed using C<next> or
1020 C<first> but has not been exhausted or L<reset|DBIx::Class::ResultSet/reset>.
1021
1022 For example, this will not work:
1023
1024   $schema->txn_do(sub {
1025     my $rs = $schema->resultset('Book');
1026     while (my $result = $rs->next) {
1027       $schema->resultset('MetaData')->create({
1028         book_id => $result->id,
1029         ...
1030       });
1031     }
1032   });
1033
1034 This won't either:
1035
1036   my $first_row = $large_rs->first;
1037   $schema->txn_do(sub { ... });
1038
1039 Transactions done for inserts in C<AutoCommit> mode when placeholders are in use
1040 are not affected, as they are done on an extra database handle.
1041
1042 Some workarounds:
1043
1044 =over 4
1045
1046 =item * use L<DBIx::Class::Storage::DBI::Replicated>
1047
1048 =item * L<connect|DBIx::Class::Schema/connect> another L<Schema|DBIx::Class::Schema>
1049
1050 =item * load the data from your cursor with L<DBIx::Class::ResultSet/all>
1051
1052 =back
1053
1054 =head1 MAXIMUM CONNECTIONS
1055
1056 The TDS protocol makes separate connections to the server for active statements
1057 in the background. By default the number of such connections is limited to 25,
1058 on both the client side and the server side.
1059
1060 This is a bit too low for a complex L<DBIx::Class> application, so on connection
1061 the client side setting is set to C<256> (see L<DBD::Sybase/maxConnect>.) You
1062 can override it to whatever setting you like in the DSN.
1063
1064 See
1065 L<http://infocenter.sybase.com/help/index.jsp?topic=/com.sybase.help.ase_15.0.sag1/html/sag1/sag1272.htm>
1066 for information on changing the setting on the server side.
1067
1068 =head1 DATES
1069
1070 See L</connect_call_datetime_setup> to setup date formats
1071 for L<DBIx::Class::InflateColumn::DateTime>.
1072
1073 =head1 LIMITED QUERIES
1074
1075 Because ASE does not have a good way to limit results in SQL that works for
1076 all types of queries, the limit dialect is set to
1077 L<GenericSubQ|DBIx::Class::SQLMaker::LimitDialects/GenericSubQ>.
1078
1079 Fortunately, ASE and L<DBD::Sybase> support cursors properly, so when
1080 L<GenericSubQ|DBIx::Class::SQLMaker::LimitDialects/GenericSubQ> is too slow
1081 you can use the L<software_limit|DBIx::Class::ResultSet/software_limit>
1082 L<DBIx::Class::ResultSet> attribute to simulate limited queries by skipping
1083 over records.
1084
1085 =head1 TEXT/IMAGE COLUMNS
1086
1087 L<DBD::Sybase> compiled with FreeTDS will B<NOT> allow you to insert or update
1088 C<TEXT/IMAGE> columns.
1089
1090 Setting C<< $dbh->{LongReadLen} >> will also not work with FreeTDS use either:
1091
1092   $schema->storage->dbh->do("SET TEXTSIZE $bytes");
1093
1094 or
1095
1096   $schema->storage->set_textsize($bytes);
1097
1098 instead.
1099
1100 However, the C<LongReadLen> you pass in
1101 L<connect_info|DBIx::Class::Storage::DBI/connect_info> is used to execute the
1102 equivalent C<SET TEXTSIZE> command on connection.
1103
1104 See L</connect_call_blob_setup> for a
1105 L<connect_info|DBIx::Class::Storage::DBI/connect_info> setting you need to work
1106 with C<IMAGE> columns.
1107
1108 =head1 BULK API
1109
1110 The experimental L<DBD::Sybase> Bulk API support is used for
1111 L<populate|DBIx::Class::ResultSet/populate> in B<void> context, in a transaction
1112 on a separate connection.
1113
1114 To use this feature effectively, use a large number of rows for each
1115 L<populate|DBIx::Class::ResultSet/populate> call, eg.:
1116
1117   while (my $rows = $data_source->get_100_rows()) {
1118     $rs->populate($rows);
1119   }
1120
1121 B<NOTE:> the L<add_columns|DBIx::Class::ResultSource/add_columns>
1122 calls in your C<Result> classes B<must> list columns in database order for this
1123 to work. Also, you may have to unset the C<LC_ALL> environment variable before
1124 loading your app, as C<BCP -Y> is not yet supported in DBD::Sybase .
1125
1126 When inserting IMAGE columns using this method, you'll need to use
1127 L</connect_call_blob_setup> as well.
1128
1129 =head1 COMPUTED COLUMNS
1130
1131 If you have columns such as:
1132
1133   created_dtm AS getdate()
1134
1135 represent them in your Result classes as:
1136
1137   created_dtm => {
1138     data_type => undef,
1139     default_value => \'getdate()',
1140     is_nullable => 0,
1141     inflate_datetime => 1,
1142   }
1143
1144 The C<data_type> must exist and must be C<undef>. Then empty inserts will work
1145 on tables with such columns.
1146
1147 =head1 TIMESTAMP COLUMNS
1148
1149 C<timestamp> columns in Sybase ASE are not really timestamps, see:
1150 L<http://dba.fyicenter.com/Interview-Questions/SYBASE/The_timestamp_datatype_in_Sybase_.html>.
1151
1152 They should be defined in your Result classes as:
1153
1154   ts => {
1155     data_type => 'timestamp',
1156     is_nullable => 0,
1157     inflate_datetime => 0,
1158   }
1159
1160 The C<<inflate_datetime => 0>> is necessary if you use
1161 L<DBIx::Class::InflateColumn::DateTime>, and most people do, and still want to
1162 be able to read these values.
1163
1164 The values will come back as hexadecimal.
1165
1166 =head1 TODO
1167
1168 =over
1169
1170 =item *
1171
1172 Transitions to AutoCommit=0 (starting a transaction) mode by exhausting
1173 any active cursors, using eager cursors.
1174
1175 =item *
1176
1177 Real limits and limited counts using stored procedures deployed on startup.
1178
1179 =item *
1180
1181 Blob update with a LIKE query on a blob, without invalidating the WHERE condition.
1182
1183 =item *
1184
1185 bulk_insert using prepare_cached (see comments.)
1186
1187 =back
1188
1189 =head1 FURTHER QUESTIONS?
1190
1191 Check the list of L<additional DBIC resources|DBIx::Class/GETTING HELP/SUPPORT>.
1192
1193 =head1 COPYRIGHT AND LICENSE
1194
1195 This module is free software L<copyright|DBIx::Class/COPYRIGHT AND LICENSE>
1196 by the L<DBIx::Class (DBIC) authors|DBIx::Class/AUTHORS>. You can
1197 redistribute it and/or modify it under the same terms as the
1198 L<DBIx::Class library|DBIx::Class/COPYRIGHT AND LICENSE>.