lib/DBIx/Class/Storage/DBI/Sybase/ASE.pm

   1 package DBIx::Class::Storage::DBI::Sybase::ASE;
   2
   3 use strict;
   4 use warnings;
   5
   6 use base qw/
   7     DBIx::Class::Storage::DBI::Sybase
   8     DBIx::Class::Storage::DBI::AutoCast
   9 /;
  10 use mro 'c3';
  11 use Carp::Clan qw/^DBIx::Class/;
  12 use Scalar::Util();
  13 use List::Util();
  14 use Sub::Name();
  15 use Data::Dumper::Concise();
  16 use Try::Tiny;
  17
  18 __PACKAGE__->mk_group_accessors('simple' =>
  19     qw/_identity _blob_log_on_update _writer_storage _is_extra_storage
  20        _bulk_storage _is_bulk_storage _began_bulk_work
  21        _bulk_disabled_due_to_coderef_connect_info_warned
  22        _identity_method/
  23 );
  24
  25 my @also_proxy_to_extra_storages = qw/
  26   connect_call_set_auto_cast auto_cast connect_call_blob_setup
  27   connect_call_datetime_setup
  28
  29   disconnect _connect_info _sql_maker _sql_maker_opts disable_sth_caching
  30   auto_savepoint unsafe cursor_class debug debugobj schema
  31 /;
  32
  33 =head1 NAME
  34
  35 DBIx::Class::Storage::DBI::Sybase::ASE - Sybase ASE SQL Server support for
  36 DBIx::Class
  37
  38 =head1 SYNOPSIS
  39
  40 This subclass supports L<DBD::Sybase> for real (non-Microsoft) Sybase databases.
  41
  42 =head1 DESCRIPTION
  43
  44 If your version of Sybase does not support placeholders, then your storage will
  45 be reblessed to L<DBIx::Class::Storage::DBI::Sybase::ASE::NoBindVars>.
  46 You can also enable that driver explicitly, see the documentation for more
  47 details.
  48
  49 With this driver there is unfortunately no way to get the C<last_insert_id>
  50 without doing a C<SELECT MAX(col)>. This is done safely in a transaction
  51 (locking the table.) See L</INSERTS WITH PLACEHOLDERS>.
  52
  53 A recommended L<connect_info|DBIx::Class::Storage::DBI/connect_info> setting:
  54
  55   on_connect_call => [['datetime_setup'], ['blob_setup', log_on_update => 0]]
  56
  57 =head1 METHODS
  58
  59 =cut
  60
  61 sub _rebless {
  62   my $self = shift;
  63
  64   my $no_bind_vars = __PACKAGE__ . '::NoBindVars';
  65
  66   if ($self->using_freetds) {
  67     carp <<'EOF' unless $ENV{DBIC_SYBASE_FREETDS_NOWARN};
  68
  69 You are using FreeTDS with Sybase.
  70
  71 We will do our best to support this configuration, but please consider this
  72 support experimental.
  73
  74 TEXT/IMAGE columns will definitely not work.
  75
  76 You are encouraged to recompile DBD::Sybase with the Sybase Open Client libraries
  77 instead.
  78
  79 See perldoc DBIx::Class::Storage::DBI::Sybase::ASE for more details.
  80
  81 To turn off this warning set the DBIC_SYBASE_FREETDS_NOWARN environment
  82 variable.
  83 EOF
  84
  85     if (not $self->_typeless_placeholders_supported) {
  86       if ($self->_placeholders_supported) {
  87         $self->auto_cast(1);
  88       }
  89       else {
  90         $self->ensure_class_loaded($no_bind_vars);
  91         bless $self, $no_bind_vars;
  92         $self->_rebless;
  93       }
  94     }
  95   }
  96
  97   elsif (not $self->_get_dbh->{syb_dynamic_supported}) {
  98     # not necessarily FreeTDS, but no placeholders nevertheless
  99     $self->ensure_class_loaded($no_bind_vars);
 100     bless $self, $no_bind_vars;
 101     $self->_rebless;
 102   }
 103   # this is highly unlikely, but we check just in case
 104   elsif (not $self->_typeless_placeholders_supported) {
 105     $self->auto_cast(1);
 106   }
 107 }
 108
 109 sub _init {
 110   my $self = shift;
 111   $self->_set_max_connect(256);
 112
 113 # create storage for insert/(update blob) transactions,
 114 # unless this is that storage
 115   return if $self->_is_extra_storage;
 116
 117   my $writer_storage = (ref $self)->new;
 118
 119   $writer_storage->_is_extra_storage(1);
 120   $writer_storage->connect_info($self->connect_info);
 121   $writer_storage->auto_cast($self->auto_cast);
 122
 123   $self->_writer_storage($writer_storage);
 124
 125 # create a bulk storage unless connect_info is a coderef
 126   return if ref($self->_dbi_connect_info->[0]) eq 'CODE';
 127
 128   my $bulk_storage = (ref $self)->new;
 129
 130   $bulk_storage->_is_extra_storage(1);
 131   $bulk_storage->_is_bulk_storage(1); # for special ->disconnect acrobatics
 132   $bulk_storage->connect_info($self->connect_info);
 133
 134 # this is why
 135   $bulk_storage->_dbi_connect_info->[0] .= ';bulkLogin=1';
 136
 137   $self->_bulk_storage($bulk_storage);
 138 }
 139
 140 for my $method (@also_proxy_to_extra_storages) {
 141   no strict 'refs';
 142   no warnings 'redefine';
 143
 144   my $replaced = __PACKAGE__->can($method);
 145
 146   *{$method} = Sub::Name::subname $method => sub {
 147     my $self = shift;
 148     $self->_writer_storage->$replaced(@_) if $self->_writer_storage;
 149     $self->_bulk_storage->$replaced(@_)   if $self->_bulk_storage;
 150     return $self->$replaced(@_);
 151   };
 152 }
 153
 154 sub disconnect {
 155   my $self = shift;
 156
 157 # Even though we call $sth->finish for uses off the bulk API, there's still an
 158 # "active statement" warning on disconnect, which we throw away here.
 159 # This is due to the bug described in insert_bulk.
 160 # Currently a noop because 'prepare' is used instead of 'prepare_cached'.
 161   local $SIG{__WARN__} = sub {
 162     warn $_[0] unless $_[0] =~ /active statement/i;
 163   } if $self->_is_bulk_storage;
 164
 165 # so that next transaction gets a dbh
 166   $self->_began_bulk_work(0) if $self->_is_bulk_storage;
 167
 168   $self->next::method;
 169 }
 170
 171 # Set up session settings for Sybase databases for the connection.
 172 #
 173 # Make sure we have CHAINED mode turned on if AutoCommit is off in non-FreeTDS
 174 # DBD::Sybase (since we don't know how DBD::Sybase was compiled.) If however
 175 # we're using FreeTDS, CHAINED mode turns on an implicit transaction which we
 176 # only want when AutoCommit is off.
 177 #
 178 # Also SET TEXTSIZE for FreeTDS because LongReadLen doesn't work.
 179 sub _run_connection_actions {
 180   my $self = shift;
 181
 182   if ($self->_is_bulk_storage) {
 183 # this should be cleared on every reconnect
 184     $self->_began_bulk_work(0);
 185     return;
 186   }
 187
 188   if (not $self->using_freetds) {
 189     $self->_dbh->{syb_chained_txn} = 1;
 190   } else {
 191     # based on LongReadLen in connect_info
 192     $self->set_textsize;
 193
 194     if ($self->_dbh_autocommit) {
 195       $self->_dbh->do('SET CHAINED OFF');
 196     } else {
 197       $self->_dbh->do('SET CHAINED ON');
 198     }
 199   }
 200
 201   $self->next::method(@_);
 202 }
 203
 204 =head2 connect_call_blob_setup
 205
 206 Used as:
 207
 208   on_connect_call => [ [ 'blob_setup', log_on_update => 0 ] ]
 209
 210 Does C<< $dbh->{syb_binary_images} = 1; >> to return C<IMAGE> data as raw binary
 211 instead of as a hex string.
 212
 213 Recommended.
 214
 215 Also sets the C<log_on_update> value for blob write operations. The default is
 216 C<1>, but C<0> is better if your database is configured for it.
 217
 218 See
 219 L<DBD::Sybase/Handling_IMAGE/TEXT_data_with_syb_ct_get_data()/syb_ct_send_data()>.
 220
 221 =cut
 222
 223 sub connect_call_blob_setup {
 224   my $self = shift;
 225   my %args = @_;
 226   my $dbh = $self->_dbh;
 227   $dbh->{syb_binary_images} = 1;
 228
 229   $self->_blob_log_on_update($args{log_on_update})
 230     if exists $args{log_on_update};
 231 }
 232
 233 sub _is_lob_type {
 234   my $self = shift;
 235   my $type = shift;
 236   $type && $type =~ /(?:text|image|lob|bytea|binary|memo)/i;
 237 }
 238
 239 sub _is_lob_column {
 240   my ($self, $source, $column) = @_;
 241
 242   return $self->_is_lob_type($source->column_info($column)->{data_type});
 243 }
 244
 245 sub _prep_for_execute {
 246   my $self = shift;
 247   my ($op, $extra_bind, $ident, $args) = @_;
 248
 249   my ($sql, $bind) = $self->next::method (@_);
 250
 251   my $table = Scalar::Util::blessed($ident) ? $ident->from : $ident;
 252
 253   my $bind_info = $self->_resolve_column_info(
 254     $ident, [map $_->[0], @{$bind}]
 255   );
 256   my $bound_identity_col = List::Util::first
 257     { $bind_info->{$_}{is_auto_increment} }
 258     (keys %$bind_info)
 259   ;
 260   my $identity_col = Scalar::Util::blessed($ident) &&
 261     List::Util::first
 262     { $ident->column_info($_)->{is_auto_increment} }
 263     $ident->columns
 264   ;
 265
 266   if (($op eq 'insert' && $bound_identity_col) ||
 267       ($op eq 'update' && exists $args->[0]{$identity_col})) {
 268     $sql = join ("\n",
 269       $self->_set_table_identity_sql($op => $table, 'on'),
 270       $sql,
 271       $self->_set_table_identity_sql($op => $table, 'off'),
 272     );
 273   }
 274
 275   if ($op eq 'insert' && (not $bound_identity_col) && $identity_col &&
 276       (not $self->{insert_bulk})) {
 277     $sql =
 278       "$sql\n" .
 279       $self->_fetch_identity_sql($ident, $identity_col);
 280   }
 281
 282   return ($sql, $bind);
 283 }
 284
 285 sub _set_table_identity_sql {
 286   my ($self, $op, $table, $on_off) = @_;
 287
 288   return sprintf 'SET IDENTITY_%s %s %s',
 289     uc($op), $self->sql_maker->_quote($table), uc($on_off);
 290 }
 291
 292 # Stolen from SQLT, with some modifications. This is a makeshift
 293 # solution before a sane type-mapping library is available, thus
 294 # the 'our' for easy overrides.
 295 our %TYPE_MAPPING  = (
 296     number    => 'numeric',
 297     money     => 'money',
 298     varchar   => 'varchar',
 299     varchar2  => 'varchar',
 300     timestamp => 'datetime',
 301     text      => 'varchar',
 302     real      => 'double precision',
 303     comment   => 'text',
 304     bit       => 'bit',
 305     tinyint   => 'smallint',
 306     float     => 'double precision',
 307     serial    => 'numeric',
 308     bigserial => 'numeric',
 309     boolean   => 'varchar',
 310     long      => 'varchar',
 311 );
 312
 313 sub _native_data_type {
 314   my ($self, $type) = @_;
 315
 316   $type = lc $type;
 317   $type =~ s/\s* identity//x;
 318
 319   return uc($TYPE_MAPPING{$type} || $type);
 320 }
 321
 322 sub _fetch_identity_sql {
 323   my ($self, $source, $col) = @_;
 324
 325   return sprintf ("SELECT MAX(%s) FROM %s",
 326     map { $self->sql_maker->_quote ($_) } ($col, $source->from)
 327   );
 328 }
 329
 330 sub _execute {
 331   my $self = shift;
 332   my ($op) = @_;
 333
 334   my ($rv, $sth, @bind) = $self->dbh_do($self->can('_dbh_execute'), @_);
 335
 336   if ($op eq 'insert') {
 337     $self->_identity($sth->fetchrow_array);
 338     $sth->finish;
 339   }
 340
 341   return wantarray ? ($rv, $sth, @bind) : $rv;
 342 }
 343
 344 sub last_insert_id { shift->_identity }
 345
 346 # handles TEXT/IMAGE and transaction for last_insert_id
 347 sub insert {
 348   my $self = shift;
 349   my ($source, $to_insert) = @_;
 350
 351   my $identity_col = (List::Util::first
 352     { $source->column_info($_)->{is_auto_increment} }
 353     $source->columns) || '';
 354
 355   # check for empty insert
 356   # INSERT INTO foo DEFAULT VALUES -- does not work with Sybase
 357   # try to insert explicit 'DEFAULT's instead (except for identity, timestamp
 358   # and computed columns)
 359   if (not %$to_insert) {
 360     for my $col ($source->columns) {
 361       next if $col eq $identity_col;
 362
 363       my $info = $source->column_info($col);
 364
 365       next if ref $info->{default_value} eq 'SCALAR'
 366         || (exists $info->{data_type} && (not defined $info->{data_type}));
 367
 368       next if $info->{data_type} && $info->{data_type} =~ /^timestamp\z/i;
 369
 370       $to_insert->{$col} = \'DEFAULT';
 371     }
 372   }
 373
 374   my $blob_cols = $self->_remove_blob_cols($source, $to_insert);
 375
 376   # do we need the horrific SELECT MAX(COL) hack?
 377   my $dumb_last_insert_id =
 378        $identity_col
 379     && (not exists $to_insert->{$identity_col})
 380     && ($self->_identity_method||'') ne '@@IDENTITY';
 381
 382   my $next = $self->next::can;
 383
 384   # we are already in a transaction, or there are no blobs
 385   # and we don't need the PK - just (try to) do it
 386   if ($self->{transaction_depth}
 387         || (!$blob_cols && !$dumb_last_insert_id)
 388   ) {
 389     return $self->_insert (
 390       $next, $source, $to_insert, $blob_cols, $identity_col
 391     );
 392   }
 393
 394   # otherwise use the _writer_storage to do the insert+transaction on another
 395   # connection
 396   my $guard = $self->_writer_storage->txn_scope_guard;
 397
 398   my $updated_cols = $self->_writer_storage->_insert (
 399     $next, $source, $to_insert, $blob_cols, $identity_col
 400   );
 401
 402   $self->_identity($self->_writer_storage->_identity);
 403
 404   $guard->commit;
 405
 406   return $updated_cols;
 407 }
 408
 409 sub _insert {
 410   my ($self, $next, $source, $to_insert, $blob_cols, $identity_col) = @_;
 411
 412   my $updated_cols = $self->$next ($source, $to_insert);
 413
 414   my $final_row = {
 415     ($identity_col ?
 416       ($identity_col => $self->last_insert_id($source, $identity_col)) : ()),
 417     %$to_insert,
 418     %$updated_cols,
 419   };
 420
 421   $self->_insert_blobs ($source, $blob_cols, $final_row) if $blob_cols;
 422
 423   return $updated_cols;
 424 }
 425
 426 sub update {
 427   my $self = shift;
 428   my ($source, $fields, $where, @rest) = @_;
 429
 430   my $wantarray = wantarray;
 431
 432   my $blob_cols = $self->_remove_blob_cols($source, $fields);
 433
 434   my $table = $source->name;
 435
 436   my $identity_col = List::Util::first
 437     { $source->column_info($_)->{is_auto_increment} }
 438     $source->columns;
 439
 440   my $is_identity_update = $identity_col && defined $fields->{$identity_col};
 441
 442   return $self->next::method(@_) unless $blob_cols;
 443
 444 # If there are any blobs in $where, Sybase will return a descriptive error
 445 # message.
 446 # XXX blobs can still be used with a LIKE query, and this should be handled.
 447
 448 # update+blob update(s) done atomically on separate connection
 449   $self = $self->_writer_storage;
 450
 451   my $guard = $self->txn_scope_guard;
 452
 453 # First update the blob columns to be updated to '' (taken from $fields, where
 454 # it is originally put by _remove_blob_cols .)
 455   my %blobs_to_empty = map { ($_ => delete $fields->{$_}) } keys %$blob_cols;
 456
 457 # We can't only update NULL blobs, because blobs cannot be in the WHERE clause.
 458
 459   $self->next::method($source, \%blobs_to_empty, $where, @rest);
 460
 461 # Now update the blobs before the other columns in case the update of other
 462 # columns makes the search condition invalid.
 463   $self->_update_blobs($source, $blob_cols, $where);
 464
 465   my @res;
 466   if (%$fields) {
 467     if ($wantarray) {
 468       @res    = $self->next::method(@_);
 469     }
 470     elsif (defined $wantarray) {
 471       $res[0] = $self->next::method(@_);
 472     }
 473     else {
 474       $self->next::method(@_);
 475     }
 476   }
 477
 478   $guard->commit;
 479
 480   return $wantarray ? @res : $res[0];
 481 }
 482
 483 sub insert_bulk {
 484   my $self = shift;
 485   my ($source, $cols, $data) = @_;
 486
 487   my $identity_col = List::Util::first
 488     { $source->column_info($_)->{is_auto_increment} }
 489     $source->columns;
 490
 491   my $is_identity_insert = (List::Util::first
 492     { $_ eq $identity_col }
 493     @{$cols}
 494   ) ? 1 : 0;
 495
 496   my @source_columns = $source->columns;
 497
 498   my $use_bulk_api =
 499     $self->_bulk_storage &&
 500     $self->_get_dbh->{syb_has_blk};
 501
 502   if ((not $use_bulk_api)
 503         &&
 504       (ref($self->_dbi_connect_info->[0]) eq 'CODE')
 505         &&
 506       (not $self->_bulk_disabled_due_to_coderef_connect_info_warned)) {
 507     carp <<'EOF';
 508 Bulk API support disabled due to use of a CODEREF connect_info. Reverting to
 509 regular array inserts.
 510 EOF
 511     $self->_bulk_disabled_due_to_coderef_connect_info_warned(1);
 512   }
 513
 514   if (not $use_bulk_api) {
 515     my $blob_cols = $self->_remove_blob_cols_array($source, $cols, $data);
 516
 517 # _execute_array uses a txn anyway, but it ends too early in case we need to
 518 # select max(col) to get the identity for inserting blobs.
 519     ($self, my $guard) = $self->{transaction_depth} == 0 ?
 520       ($self->_writer_storage, $self->_writer_storage->txn_scope_guard)
 521       :
 522       ($self, undef);
 523
 524     local $self->{insert_bulk} = 1;
 525
 526     $self->next::method(@_);
 527
 528     if ($blob_cols) {
 529       if ($is_identity_insert) {
 530         $self->_insert_blobs_array ($source, $blob_cols, $cols, $data);
 531       }
 532       else {
 533         my @cols_with_identities = (@$cols, $identity_col);
 534
 535         ## calculate identities
 536         # XXX This assumes identities always increase by 1, which may or may not
 537         # be true.
 538         my ($last_identity) =
 539           $self->_dbh->selectrow_array (
 540             $self->_fetch_identity_sql($source, $identity_col)
 541           );
 542         my @identities = (($last_identity - @$data + 1) .. $last_identity);
 543
 544         my @data_with_identities = map [@$_, shift @identities], @$data;
 545
 546         $self->_insert_blobs_array (
 547           $source, $blob_cols, \@cols_with_identities, \@data_with_identities
 548         );
 549       }
 550     }
 551
 552     $guard->commit if $guard;
 553
 554     return;
 555   }
 556
 557 # otherwise, use the bulk API
 558
 559 # rearrange @$data so that columns are in database order
 560   my %orig_idx;
 561   @orig_idx{@$cols} = 0..$#$cols;
 562
 563   my %new_idx;
 564   @new_idx{@source_columns} = 0..$#source_columns;
 565
 566   my @new_data;
 567   for my $datum (@$data) {
 568     my $new_datum = [];
 569     for my $col (@source_columns) {
 570 # identity data will be 'undef' if not $is_identity_insert
 571 # columns with defaults will also be 'undef'
 572       $new_datum->[ $new_idx{$col} ] =
 573         exists $orig_idx{$col} ? $datum->[ $orig_idx{$col} ] : undef;
 574     }
 575     push @new_data, $new_datum;
 576   }
 577
 578 # bcp identity index is 1-based
 579   my $identity_idx = exists $new_idx{$identity_col} ?
 580     $new_idx{$identity_col} + 1 : 0;
 581
 582 ## Set a client-side conversion error handler, straight from DBD::Sybase docs.
 583 # This ignores any data conversion errors detected by the client side libs, as
 584 # they are usually harmless.
 585   my $orig_cslib_cb = DBD::Sybase::set_cslib_cb(
 586     Sub::Name::subname insert_bulk => sub {
 587       my ($layer, $origin, $severity, $errno, $errmsg, $osmsg, $blkmsg) = @_;
 588
 589       return 1 if $errno == 36;
 590
 591       carp
 592         "Layer: $layer, Origin: $origin, Severity: $severity, Error: $errno" .
 593         ($errmsg ? "\n$errmsg" : '') .
 594         ($osmsg  ? "\n$osmsg"  : '')  .
 595         ($blkmsg ? "\n$blkmsg" : '');
 596
 597       return 0;
 598   });
 599
 600   my $exception;
 601   try {
 602     my $bulk = $self->_bulk_storage;
 603
 604     my $guard = $bulk->txn_scope_guard;
 605
 606 ## XXX get this to work instead of our own $sth
 607 ## will require SQLA or *Hacks changes for ordered columns
 608 #    $bulk->next::method($source, \@source_columns, \@new_data, {
 609 #      syb_bcp_attribs => {
 610 #        identity_flag   => $is_identity_insert,
 611 #        identity_column => $identity_idx,
 612 #      }
 613 #    });
 614     my $sql = 'INSERT INTO ' .
 615       $bulk->sql_maker->_quote($source->name) . ' (' .
 616 # colname list is ignored for BCP, but does no harm
 617       (join ', ', map $bulk->sql_maker->_quote($_), @source_columns) . ') '.
 618       ' VALUES ('.  (join ', ', ('?') x @source_columns) . ')';
 619
 620 ## XXX there's a bug in the DBD::Sybase bulk support that makes $sth->finish for
 621 ## a prepare_cached statement ineffective. Replace with ->sth when fixed, or
 622 ## better yet the version above. Should be fixed in DBD::Sybase .
 623     my $sth = $bulk->_get_dbh->prepare($sql,
 624 #      'insert', # op
 625       {
 626         syb_bcp_attribs => {
 627           identity_flag   => $is_identity_insert,
 628           identity_column => $identity_idx,
 629         }
 630       }
 631     );
 632
 633     my @bind = do {
 634       my $idx = 0;
 635       map [ $_, $idx++ ], @source_columns;
 636     };
 637
 638     $self->_execute_array(
 639       $source, $sth, \@bind, \@source_columns, \@new_data, sub {
 640         $guard->commit
 641       }
 642     );
 643
 644     $bulk->_query_end($sql);
 645   } catch {
 646     $exception = shift;
 647   };
 648
 649   DBD::Sybase::set_cslib_cb($orig_cslib_cb);
 650
 651   if ($exception =~ /-Y option/) {
 652     carp <<"EOF";
 653
 654 Sybase bulk API operation failed due to character set incompatibility, reverting
 655 to regular array inserts:
 656
 657 *** Try unsetting the LANG environment variable.
 658
 659 $exception
 660 EOF
 661     $self->_bulk_storage(undef);
 662     unshift @_, $self;
 663     goto \&insert_bulk;
 664   }
 665   elsif ($exception) {
 666 # rollback makes the bulkLogin connection unusable
 667     $self->_bulk_storage->disconnect;
 668     $self->throw_exception($exception);
 669   }
 670 }
 671
 672 sub _dbh_execute_array {
 673   my ($self, $sth, $tuple_status, $cb) = @_;
 674
 675   my $rv = $self->next::method($sth, $tuple_status);
 676   $cb->() if $cb;
 677
 678   return $rv;
 679 }
 680
 681 # Make sure blobs are not bound as placeholders, and return any non-empty ones
 682 # as a hash.
 683 sub _remove_blob_cols {
 684   my ($self, $source, $fields) = @_;
 685
 686   my %blob_cols;
 687
 688   for my $col (keys %$fields) {
 689     if ($self->_is_lob_column($source, $col)) {
 690       my $blob_val = delete $fields->{$col};
 691       if (not defined $blob_val) {
 692         $fields->{$col} = \'NULL';
 693       }
 694       else {
 695         $fields->{$col} = \"''";
 696         $blob_cols{$col} = $blob_val unless $blob_val eq '';
 697       }
 698     }
 699   }
 700
 701   return %blob_cols ? \%blob_cols : undef;
 702 }
 703
 704 # same for insert_bulk
 705 sub _remove_blob_cols_array {
 706   my ($self, $source, $cols, $data) = @_;
 707
 708   my @blob_cols;
 709
 710   for my $i (0..$#$cols) {
 711     my $col = $cols->[$i];
 712
 713     if ($self->_is_lob_column($source, $col)) {
 714       for my $j (0..$#$data) {
 715         my $blob_val = delete $data->[$j][$i];
 716         if (not defined $blob_val) {
 717           $data->[$j][$i] = \'NULL';
 718         }
 719         else {
 720           $data->[$j][$i] = \"''";
 721           $blob_cols[$j][$i] = $blob_val
 722             unless $blob_val eq '';
 723         }
 724       }
 725     }
 726   }
 727
 728   return @blob_cols ? \@blob_cols : undef;
 729 }
 730
 731 sub _update_blobs {
 732   my ($self, $source, $blob_cols, $where) = @_;
 733
 734   my @primary_cols = try
 735     { $source->_pri_cols }
 736     catch {
 737       $self->throw_exception("Cannot update TEXT/IMAGE column(s): $_")
 738     };
 739
 740 # check if we're updating a single row by PK
 741   my $pk_cols_in_where = 0;
 742   for my $col (@primary_cols) {
 743     $pk_cols_in_where++ if defined $where->{$col};
 744   }
 745   my @rows;
 746
 747   if ($pk_cols_in_where == @primary_cols) {
 748     my %row_to_update;
 749     @row_to_update{@primary_cols} = @{$where}{@primary_cols};
 750     @rows = \%row_to_update;
 751   } else {
 752     my $cursor = $self->select ($source, \@primary_cols, $where, {});
 753     @rows = map {
 754       my %row; @row{@primary_cols} = @$_; \%row
 755     } $cursor->all;
 756   }
 757
 758   for my $row (@rows) {
 759     $self->_insert_blobs($source, $blob_cols, $row);
 760   }
 761 }
 762
 763 sub _insert_blobs {
 764   my ($self, $source, $blob_cols, $row) = @_;
 765   my $dbh = $self->_get_dbh;
 766
 767   my $table = $source->name;
 768
 769   my %row = %$row;
 770   my @primary_cols = try
 771     { $source->_pri_cols }
 772     catch {
 773       $self->throw_exception("Cannot update TEXT/IMAGE column(s): $_")
 774     };
 775
 776   $self->throw_exception('Cannot update TEXT/IMAGE column(s) without primary key values')
 777     if ((grep { defined $row{$_} } @primary_cols) != @primary_cols);
 778
 779   for my $col (keys %$blob_cols) {
 780     my $blob = $blob_cols->{$col};
 781
 782     my %where = map { ($_, $row{$_}) } @primary_cols;
 783
 784     my $cursor = $self->select ($source, [$col], \%where, {});
 785     $cursor->next;
 786     my $sth = $cursor->sth;
 787
 788     if (not $sth) {
 789       $self->throw_exception(
 790           "Could not find row in table '$table' for blob update:\n"
 791         . Data::Dumper::Concise::Dumper (\%where)
 792       );
 793     }
 794
 795     try {
 796       do {
 797         $sth->func('CS_GET', 1, 'ct_data_info') or die $sth->errstr;
 798       } while $sth->fetch;
 799
 800       $sth->func('ct_prepare_send') or die $sth->errstr;
 801
 802       my $log_on_update = $self->_blob_log_on_update;
 803       $log_on_update    = 1 if not defined $log_on_update;
 804
 805       $sth->func('CS_SET', 1, {
 806         total_txtlen => length($blob),
 807         log_on_update => $log_on_update
 808       }, 'ct_data_info') or die $sth->errstr;
 809
 810       $sth->func($blob, length($blob), 'ct_send_data') or die $sth->errstr;
 811
 812       $sth->func('ct_finish_send') or die $sth->errstr;
 813     }
 814     catch {
 815       if ($self->using_freetds) {
 816         $self->throw_exception (
 817           "TEXT/IMAGE operation failed, probably because you are using FreeTDS: $_"
 818         );
 819       }
 820       else {
 821         $self->throw_exception($_);
 822       }
 823     }
 824     finally {
 825       $sth->finish if $sth;
 826     };
 827   }
 828 }
 829
 830 sub _insert_blobs_array {
 831   my ($self, $source, $blob_cols, $cols, $data) = @_;
 832
 833   for my $i (0..$#$data) {
 834     my $datum = $data->[$i];
 835
 836     my %row;
 837     @row{ @$cols } = @$datum;
 838
 839     my %blob_vals;
 840     for my $j (0..$#$cols) {
 841       if (exists $blob_cols->[$i][$j]) {
 842         $blob_vals{ $cols->[$j] } = $blob_cols->[$i][$j];
 843       }
 844     }
 845
 846     $self->_insert_blobs ($source, \%blob_vals, \%row);
 847   }
 848 }
 849
 850 =head2 connect_call_datetime_setup
 851
 852 Used as:
 853
 854   on_connect_call => 'datetime_setup'
 855
 856 In L<connect_info|DBIx::Class::Storage::DBI/connect_info> to set:
 857
 858   $dbh->syb_date_fmt('ISO_strict'); # output fmt: 2004-08-21T14:36:48.080Z
 859   $dbh->do('set dateformat mdy');   # input fmt:  08/13/1979 18:08:55.080
 860
 861 On connection for use with L<DBIx::Class::InflateColumn::DateTime>, using
 862 L<DateTime::Format::Sybase>, which you will need to install.
 863
 864 This works for both C<DATETIME> and C<SMALLDATETIME> columns, although
 865 C<SMALLDATETIME> columns only have minute precision.
 866
 867 =cut
 868
 869 {
 870   my $old_dbd_warned = 0;
 871
 872   sub connect_call_datetime_setup {
 873     my $self = shift;
 874     my $dbh = $self->_get_dbh;
 875
 876     if ($dbh->can('syb_date_fmt')) {
 877       # amazingly, this works with FreeTDS
 878       $dbh->syb_date_fmt('ISO_strict');
 879     } elsif (not $old_dbd_warned) {
 880       carp "Your DBD::Sybase is too old to support ".
 881       "DBIx::Class::InflateColumn::DateTime, please upgrade!";
 882       $old_dbd_warned = 1;
 883     }
 884
 885     $dbh->do('SET DATEFORMAT mdy');
 886
 887     1;
 888   }
 889 }
 890
 891 sub datetime_parser_type { "DateTime::Format::Sybase" }
 892
 893 # ->begin_work and such have no effect with FreeTDS but we run them anyway to
 894 # let the DBD keep any state it needs to.
 895 #
 896 # If they ever do start working, the extra statements will do no harm (because
 897 # Sybase supports nested transactions.)
 898
 899 sub _dbh_begin_work {
 900   my $self = shift;
 901
 902 # bulkLogin=1 connections are always in a transaction, and can only call BEGIN
 903 # TRAN once. However, we need to make sure there's a $dbh.
 904   return if $self->_is_bulk_storage && $self->_dbh && $self->_began_bulk_work;
 905
 906   $self->next::method(@_);
 907
 908   if ($self->using_freetds) {
 909     $self->_get_dbh->do('BEGIN TRAN');
 910   }
 911
 912   $self->_began_bulk_work(1) if $self->_is_bulk_storage;
 913 }
 914
 915 sub _dbh_commit {
 916   my $self = shift;
 917   if ($self->using_freetds) {
 918     $self->_dbh->do('COMMIT');
 919   }
 920   return $self->next::method(@_);
 921 }
 922
 923 sub _dbh_rollback {
 924   my $self = shift;
 925   if ($self->using_freetds) {
 926     $self->_dbh->do('ROLLBACK');
 927   }
 928   return $self->next::method(@_);
 929 }
 930
 931 # savepoint support using ASE syntax
 932
 933 sub _svp_begin {
 934   my ($self, $name) = @_;
 935
 936   $self->_get_dbh->do("SAVE TRANSACTION $name");
 937 }
 938
 939 # A new SAVE TRANSACTION with the same name releases the previous one.
 940 sub _svp_release { 1 }
 941
 942 sub _svp_rollback {
 943   my ($self, $name) = @_;
 944
 945   $self->_get_dbh->do("ROLLBACK TRANSACTION $name");
 946 }
 947
 948 1;
 949
 950 =head1 Schema::Loader Support
 951
 952 As of version C<0.05000>, L<DBIx::Class::Schema::Loader> should work well with
 953 most (if not all) versions of Sybase ASE.
 954
 955 =head1 FreeTDS
 956
 957 This driver supports L<DBD::Sybase> compiled against FreeTDS
 958 (L<http://www.freetds.org/>) to the best of our ability, however it is
 959 recommended that you recompile L<DBD::Sybase> against the Sybase Open Client
 960 libraries. They are a part of the Sybase ASE distribution:
 961
 962 The Open Client FAQ is here:
 963 L<http://www.isug.com/Sybase_FAQ/ASE/section7.html>.
 964
 965 Sybase ASE for Linux (which comes with the Open Client libraries) may be
 966 downloaded here: L<http://response.sybase.com/forms/ASE_Linux_Download>.
 967
 968 To see if you're using FreeTDS check C<< $schema->storage->using_freetds >>, or run:
 969
 970   perl -MDBI -le 'my $dbh = DBI->connect($dsn, $user, $pass); print $dbh->{syb_oc_version}'
 971
 972 Some versions of the libraries involved will not support placeholders, in which
 973 case the storage will be reblessed to
 974 L<DBIx::Class::Storage::DBI::Sybase::ASE::NoBindVars>.
 975
 976 In some configurations, placeholders will work but will throw implicit type
 977 conversion errors for anything that's not expecting a string. In such a case,
 978 the C<auto_cast> option from L<DBIx::Class::Storage::DBI::AutoCast> is
 979 automatically set, which you may enable on connection with
 980 L<DBIx::Class::Storage::DBI::AutoCast/connect_call_set_auto_cast>. The type info
 981 for the C<CAST>s is taken from the L<DBIx::Class::ResultSource/data_type>
 982 definitions in your Result classes, and are mapped to a Sybase type (if it isn't
 983 already) using a mapping based on L<SQL::Translator>.
 984
 985 In other configurations, placeholders will work just as they do with the Sybase
 986 Open Client libraries.
 987
 988 Inserts or updates of TEXT/IMAGE columns will B<NOT> work with FreeTDS.
 989
 990 =head1 INSERTS WITH PLACEHOLDERS
 991
 992 With placeholders enabled, inserts are done in a transaction so that there are
 993 no concurrency issues with getting the inserted identity value using
 994 C<SELECT MAX(col)>, which is the only way to get the C<IDENTITY> value in this
 995 mode.
 996
 997 In addition, they are done on a separate connection so that it's possible to
 998 have active cursors when doing an insert.
 999
1000 When using C<DBIx::Class::Storage::DBI::Sybase::ASE::NoBindVars> transactions
1001 are disabled, as there are no concurrency issues with C<SELECT @@IDENTITY> as
1002 it's a session variable.
1003
1004 =head1 TRANSACTIONS
1005
1006 Due to limitations of the TDS protocol, L<DBD::Sybase>, or both, you cannot
1007 begin a transaction while there are active cursors, nor can you use multiple
1008 active cursors within a transaction. An active cursor is, for example, a
1009 L<ResultSet|DBIx::Class::ResultSet> that has been executed using C<next> or
1010 C<first> but has not been exhausted or L<reset|DBIx::Class::ResultSet/reset>.
1011
1012 For example, this will not work:
1013
1014   $schema->txn_do(sub {
1015     my $rs = $schema->resultset('Book');
1016     while (my $row = $rs->next) {
1017       $schema->resultset('MetaData')->create({
1018         book_id => $row->id,
1019         ...
1020       });
1021     }
1022   });
1023
1024 This won't either:
1025
1026   my $first_row = $large_rs->first;
1027   $schema->txn_do(sub { ... });
1028
1029 Transactions done for inserts in C<AutoCommit> mode when placeholders are in use
1030 are not affected, as they are done on an extra database handle.
1031
1032 Some workarounds:
1033
1034 =over 4
1035
1036 =item * use L<DBIx::Class::Storage::DBI::Replicated>
1037
1038 =item * L<connect|DBIx::Class::Schema/connect> another L<Schema|DBIx::Class::Schema>
1039
1040 =item * load the data from your cursor with L<DBIx::Class::ResultSet/all>
1041
1042 =back
1043
1044 =head1 MAXIMUM CONNECTIONS
1045
1046 The TDS protocol makes separate connections to the server for active statements
1047 in the background. By default the number of such connections is limited to 25,
1048 on both the client side and the server side.
1049
1050 This is a bit too low for a complex L<DBIx::Class> application, so on connection
1051 the client side setting is set to C<256> (see L<DBD::Sybase/maxConnect>.) You
1052 can override it to whatever setting you like in the DSN.
1053
1054 See
1055 L<http://infocenter.sybase.com/help/index.jsp?topic=/com.sybase.help.ase_15.0.sag1/html/sag1/sag1272.htm>
1056 for information on changing the setting on the server side.
1057
1058 =head1 DATES
1059
1060 See L</connect_call_datetime_setup> to setup date formats
1061 for L<DBIx::Class::InflateColumn::DateTime>.
1062
1063 =head1 TEXT/IMAGE COLUMNS
1064
1065 L<DBD::Sybase> compiled with FreeTDS will B<NOT> allow you to insert or update
1066 C<TEXT/IMAGE> columns.
1067
1068 Setting C<< $dbh->{LongReadLen} >> will also not work with FreeTDS use either:
1069
1070   $schema->storage->dbh->do("SET TEXTSIZE $bytes");
1071
1072 or
1073
1074   $schema->storage->set_textsize($bytes);
1075
1076 instead.
1077
1078 However, the C<LongReadLen> you pass in
1079 L<connect_info|DBIx::Class::Storage::DBI/connect_info> is used to execute the
1080 equivalent C<SET TEXTSIZE> command on connection.
1081
1082 See L</connect_call_blob_setup> for a
1083 L<connect_info|DBIx::Class::Storage::DBI/connect_info> setting you need to work
1084 with C<IMAGE> columns.
1085
1086 =head1 BULK API
1087
1088 The experimental L<DBD::Sybase> Bulk API support is used for
1089 L<populate|DBIx::Class::ResultSet/populate> in B<void> context, in a transaction
1090 on a separate connection.
1091
1092 To use this feature effectively, use a large number of rows for each
1093 L<populate|DBIx::Class::ResultSet/populate> call, eg.:
1094
1095   while (my $rows = $data_source->get_100_rows()) {
1096     $rs->populate($rows);
1097   }
1098
1099 B<NOTE:> the L<add_columns|DBIx::Class::ResultSource/add_columns>
1100 calls in your C<Result> classes B<must> list columns in database order for this
1101 to work. Also, you may have to unset the C<LANG> environment variable before
1102 loading your app, if it doesn't match the character set of your database.
1103
1104 When inserting IMAGE columns using this method, you'll need to use
1105 L</connect_call_blob_setup> as well.
1106
1107 =head1 COMPUTED COLUMNS
1108
1109 If you have columns such as:
1110
1111   created_dtm AS getdate()
1112
1113 represent them in your Result classes as:
1114
1115   created_dtm => {
1116     data_type => undef,
1117     default_value => \'getdate()',
1118     is_nullable => 0,
1119   }
1120
1121 The C<data_type> must exist and must be C<undef>. Then empty inserts will work
1122 on tables with such columns.
1123
1124 =head1 TIMESTAMP COLUMNS
1125
1126 C<timestamp> columns in Sybase ASE are not really timestamps, see:
1127 L<http://dba.fyicenter.com/Interview-Questions/SYBASE/The_timestamp_datatype_in_Sybase_.html>.
1128
1129 They should be defined in your Result classes as:
1130
1131   ts => {
1132     data_type => 'timestamp',
1133     is_nullable => 0,
1134     inflate_datetime => 0,
1135   }
1136
1137 The C<<inflate_datetime => 0>> is necessary if you use
1138 L<DBIx::Class::InflateColumn::DateTime>, and most people do, and still want to
1139 be able to read these values.
1140
1141 The values will come back as hexadecimal.
1142
1143 =head1 TODO
1144
1145 =over
1146
1147 =item *
1148
1149 Transitions to AutoCommit=0 (starting a transaction) mode by exhausting
1150 any active cursors, using eager cursors.
1151
1152 =item *
1153
1154 Real limits and limited counts using stored procedures deployed on startup.
1155
1156 =item *
1157
1158 Adaptive Server Anywhere (ASA) support, with possible SQLA::Limit support.
1159
1160 =item *
1161
1162 Blob update with a LIKE query on a blob, without invalidating the WHERE condition.
1163
1164 =item *
1165
1166 bulk_insert using prepare_cached (see comments.)
1167
1168 =back
1169
1170 =head1 AUTHOR
1171
1172 See L<DBIx::Class/CONTRIBUTORS>.
1173
1174 =head1 LICENSE
1175
1176 You may distribute this code under the same terms as Perl itself.
1177
1178 =cut
1179 # vim:sts=2 sw=2: