lib/DBIx/Class/Storage/DBI/Sybase/ASE.pm

   1 package DBIx::Class::Storage::DBI::Sybase::ASE;
   2
   3 use strict;
   4 use warnings;
   5
   6 use base qw/
   7   DBIx::Class::Storage::DBI::Sybase
   8   DBIx::Class::Storage::DBI::AutoCast
   9   DBIx::Class::Storage::DBI::IdentityInsert
  10 /;
  11 use mro 'c3';
  12 use DBIx::Class::Carp;
  13 use Scalar::Util qw/blessed weaken/;
  14 use List::Util 'first';
  15 use Sub::Name();
  16 use Data::Dumper::Concise 'Dumper';
  17 use Try::Tiny;
  18 use Context::Preserve 'preserve_context';
  19 use namespace::clean;
  20
  21 __PACKAGE__->sql_limit_dialect ('RowCountOrGenericSubQ');
  22 __PACKAGE__->sql_quote_char ([qw/[ ]/]);
  23 __PACKAGE__->datetime_parser_type(
  24   'DBIx::Class::Storage::DBI::Sybase::ASE::DateTime::Format'
  25 );
  26
  27 __PACKAGE__->mk_group_accessors('simple' =>
  28     qw/_identity _identity_method _blob_log_on_update _parent_storage
  29        _writer_storage _is_writer_storage
  30        _bulk_storage _is_bulk_storage _began_bulk_work
  31     /
  32 );
  33
  34
  35 my @also_proxy_to_extra_storages = qw/
  36   connect_call_set_auto_cast auto_cast connect_call_blob_setup
  37   connect_call_datetime_setup
  38
  39   disconnect _connect_info _sql_maker _sql_maker_opts disable_sth_caching
  40   auto_savepoint unsafe cursor_class debug debugobj schema
  41 /;
  42
  43 =head1 NAME
  44
  45 DBIx::Class::Storage::DBI::Sybase::ASE - Sybase ASE SQL Server support for
  46 DBIx::Class
  47
  48 =head1 SYNOPSIS
  49
  50 This subclass supports L<DBD::Sybase> for real (non-Microsoft) Sybase databases.
  51
  52 =head1 DESCRIPTION
  53
  54 If your version of Sybase does not support placeholders, then your storage will
  55 be reblessed to L<DBIx::Class::Storage::DBI::Sybase::ASE::NoBindVars>.
  56 You can also enable that driver explicitly, see the documentation for more
  57 details.
  58
  59 With this driver there is unfortunately no way to get the C<last_insert_id>
  60 without doing a C<SELECT MAX(col)>. This is done safely in a transaction
  61 (locking the table.) See L</INSERTS WITH PLACEHOLDERS>.
  62
  63 A recommended L<connect_info|DBIx::Class::Storage::DBI/connect_info> setting:
  64
  65   on_connect_call => [['datetime_setup'], ['blob_setup', log_on_update => 0]]
  66
  67 =head1 METHODS
  68
  69 =cut
  70
  71 sub _rebless {
  72   my $self = shift;
  73
  74   my $no_bind_vars = __PACKAGE__ . '::NoBindVars';
  75
  76   if ($self->_using_freetds) {
  77     carp_once <<'EOF' unless $ENV{DBIC_SYBASE_FREETDS_NOWARN};
  78
  79 You are using FreeTDS with Sybase.
  80
  81 We will do our best to support this configuration, but please consider this
  82 support experimental.
  83
  84 TEXT/IMAGE columns will definitely not work.
  85
  86 You are encouraged to recompile DBD::Sybase with the Sybase Open Client libraries
  87 instead.
  88
  89 See perldoc DBIx::Class::Storage::DBI::Sybase::ASE for more details.
  90
  91 To turn off this warning set the DBIC_SYBASE_FREETDS_NOWARN environment
  92 variable.
  93 EOF
  94
  95     if (not $self->_use_typeless_placeholders) {
  96       if ($self->_use_placeholders) {
  97         $self->auto_cast(1);
  98       }
  99       else {
 100         $self->ensure_class_loaded($no_bind_vars);
 101         bless $self, $no_bind_vars;
 102         $self->_rebless;
 103       }
 104     }
 105   }
 106
 107   elsif (not $self->_get_dbh->{syb_dynamic_supported}) {
 108     # not necessarily FreeTDS, but no placeholders nevertheless
 109     $self->ensure_class_loaded($no_bind_vars);
 110     bless $self, $no_bind_vars;
 111     $self->_rebless;
 112   }
 113   # this is highly unlikely, but we check just in case
 114   elsif (not $self->_use_typeless_placeholders) {
 115     $self->auto_cast(1);
 116   }
 117 }
 118
 119 sub _init {
 120   my $self = shift;
 121
 122   $self->next::method(@_);
 123
 124   if ($self->_using_freetds && (my $ver = $self->_using_freetds_version||999) > 0.82) {
 125     carp_once(
 126       "Buggy FreeTDS version $ver detected, statement caching will not work and "
 127     . 'will be disabled.'
 128     );
 129     $self->disable_sth_caching(1);
 130   }
 131
 132   $self->_set_max_connect(256);
 133
 134 # create storage for insert/(update blob) transactions,
 135 # unless this is that storage
 136   return if $self->_parent_storage;
 137
 138   my $writer_storage = (ref $self)->new;
 139
 140   $writer_storage->_is_writer_storage(1); # just info
 141   $writer_storage->connect_info($self->connect_info);
 142   $writer_storage->auto_cast($self->auto_cast);
 143
 144   weaken ($writer_storage->{_parent_storage} = $self);
 145   $self->_writer_storage($writer_storage);
 146
 147 # create a bulk storage unless connect_info is a coderef
 148   return if ref($self->_dbi_connect_info->[0]) eq 'CODE';
 149
 150   my $bulk_storage = (ref $self)->new;
 151
 152   $bulk_storage->_is_bulk_storage(1); # for special ->disconnect acrobatics
 153   $bulk_storage->connect_info($self->connect_info);
 154
 155 # this is why
 156   $bulk_storage->_dbi_connect_info->[0] .= ';bulkLogin=1';
 157
 158   weaken ($bulk_storage->{_parent_storage} = $self);
 159   $self->_bulk_storage($bulk_storage);
 160 }
 161
 162 for my $method (@also_proxy_to_extra_storages) {
 163   no strict 'refs';
 164   no warnings 'redefine';
 165
 166   my $replaced = __PACKAGE__->can($method);
 167
 168   *{$method} = Sub::Name::subname $method => sub {
 169     my $self = shift;
 170     $self->_writer_storage->$replaced(@_) if $self->_writer_storage;
 171     $self->_bulk_storage->$replaced(@_)   if $self->_bulk_storage;
 172     return $self->$replaced(@_);
 173   };
 174 }
 175
 176 sub disconnect {
 177   my $self = shift;
 178
 179 # Even though we call $sth->finish for uses off the bulk API, there's still an
 180 # "active statement" warning on disconnect, which we throw away here.
 181 # This is due to the bug described in insert_bulk.
 182 # Currently a noop because 'prepare' is used instead of 'prepare_cached'.
 183   local $SIG{__WARN__} = sub {
 184     warn $_[0] unless $_[0] =~ /active statement/i;
 185   } if $self->_is_bulk_storage;
 186
 187 # so that next transaction gets a dbh
 188   $self->_began_bulk_work(0) if $self->_is_bulk_storage;
 189
 190   $self->next::method;
 191 }
 192
 193 # This is only invoked for FreeTDS drivers by ::Storage::DBI::Sybase::FreeTDS
 194 sub _set_autocommit_stmt {
 195   my ($self, $on) = @_;
 196
 197   return 'SET CHAINED ' . ($on ? 'OFF' : 'ON');
 198 }
 199
 200 # Set up session settings for Sybase databases for the connection.
 201 #
 202 # Make sure we have CHAINED mode turned on if AutoCommit is off in non-FreeTDS
 203 # DBD::Sybase (since we don't know how DBD::Sybase was compiled.) If however
 204 # we're using FreeTDS, CHAINED mode turns on an implicit transaction which we
 205 # only want when AutoCommit is off.
 206 sub _run_connection_actions {
 207   my $self = shift;
 208
 209   if ($self->_is_bulk_storage) {
 210     # this should be cleared on every reconnect
 211     $self->_began_bulk_work(0);
 212     return;
 213   }
 214
 215   $self->_dbh->{syb_chained_txn} = 1
 216     unless $self->_using_freetds;
 217
 218   $self->next::method(@_);
 219 }
 220
 221 =head2 connect_call_blob_setup
 222
 223 Used as:
 224
 225   on_connect_call => [ [ 'blob_setup', log_on_update => 0 ] ]
 226
 227 Does C<< $dbh->{syb_binary_images} = 1; >> to return C<IMAGE> data as raw binary
 228 instead of as a hex string.
 229
 230 Recommended.
 231
 232 Also sets the C<log_on_update> value for blob write operations. The default is
 233 C<1>, but C<0> is better if your database is configured for it.
 234
 235 See
 236 L<DBD::Sybase/Handling_IMAGE/TEXT_data_with_syb_ct_get_data()/syb_ct_send_data()>.
 237
 238 =cut
 239
 240 sub connect_call_blob_setup {
 241   my $self = shift;
 242   my %args = @_;
 243   my $dbh = $self->_dbh;
 244   $dbh->{syb_binary_images} = 1;
 245
 246   $self->_blob_log_on_update($args{log_on_update})
 247     if exists $args{log_on_update};
 248 }
 249
 250 sub _is_lob_column {
 251   my ($self, $source, $column) = @_;
 252
 253   return $self->_is_lob_type($source->column_info($column)->{data_type});
 254 }
 255
 256 sub _prep_for_execute {
 257   my $self = shift;
 258   my $ident = $_[1];
 259
 260   #
 261 ### This is commented out because all tests pass. However I am leaving it
 262 ### here as it may prove necessary (can't think through all combinations)
 263 ### BTW it doesn't currently work exactly - need better sensitivity to
 264   # currently set value
 265   #
 266   #my ($op, $ident) = @_;
 267   #
 268   # inherit these from the parent for the duration of _prep_for_execute
 269   # Don't know how to make a localizing loop with if's, otherwise I would
 270   #local $self->{_autoinc_supplied_for_op}
 271   #  = $self->_parent_storage->_autoinc_supplied_for_op
 272   #if ($op eq 'insert' or $op eq 'update') and $self->_parent_storage;
 273   #local $self->{_perform_autoinc_retrieval}
 274   #  = $self->_parent_storage->_perform_autoinc_retrieval
 275   #if ($op eq 'insert' or $op eq 'update') and $self->_parent_storage;
 276
 277   my ($sql, $bind) = $self->next::method (@_);
 278
 279   if (my $identity_col = $self->_perform_autoinc_retrieval) {
 280     $sql .= "\n" . $self->_fetch_identity_sql($ident, $identity_col)
 281   }
 282
 283   return ($sql, $bind);
 284 }
 285
 286 sub _fetch_identity_sql {
 287   my ($self, $source, $col) = @_;
 288
 289   return sprintf ("SELECT MAX(%s) FROM %s",
 290     map { $self->sql_maker->_quote ($_) } ($col, $source->from)
 291   );
 292 }
 293
 294 # Stolen from SQLT, with some modifications. This is a makeshift
 295 # solution before a sane type-mapping library is available, thus
 296 # the 'our' for easy overrides.
 297 our %TYPE_MAPPING  = (
 298     number    => 'numeric',
 299     money     => 'money',
 300     varchar   => 'varchar',
 301     varchar2  => 'varchar',
 302     timestamp => 'datetime',
 303     text      => 'varchar',
 304     real      => 'double precision',
 305     comment   => 'text',
 306     bit       => 'bit',
 307     tinyint   => 'smallint',
 308     float     => 'double precision',
 309     serial    => 'numeric',
 310     bigserial => 'numeric',
 311     boolean   => 'varchar',
 312     long      => 'varchar',
 313 );
 314
 315 sub _native_data_type {
 316   my ($self, $type) = @_;
 317
 318   $type = lc $type;
 319   $type =~ s/\s* identity//x;
 320
 321   return uc($TYPE_MAPPING{$type} || $type);
 322 }
 323
 324
 325 sub _execute {
 326   my $self = shift;
 327   my ($rv, $sth, @bind) = $self->next::method(@_);
 328
 329   $self->_identity( ($sth->fetchall_arrayref)->[0][0] )
 330     if $self->_perform_autoinc_retrieval;
 331
 332   return wantarray ? ($rv, $sth, @bind) : $rv;
 333 }
 334
 335 sub last_insert_id { shift->_identity }
 336
 337 # handles TEXT/IMAGE and transaction for last_insert_id
 338 sub insert {
 339   my $self = shift;
 340   my ($source, $to_insert) = @_;
 341
 342   my $columns_info = $source->columns_info;
 343
 344   my $identity_col =
 345     (first { $columns_info->{$_}{is_auto_increment} }
 346       keys %$columns_info )
 347     || '';
 348
 349   # FIXME - this is duplication from DBI.pm. When refactored towards
 350   # the LobWriter this can be folded back where it belongs.
 351   local $self->{_autoinc_supplied_for_op} = exists $to_insert->{$identity_col}
 352     ? 1
 353     : 0
 354   ;
 355   local $self->{_perform_autoinc_retrieval} =
 356     ($identity_col and ! exists $to_insert->{$identity_col})
 357       ? $identity_col
 358       : undef
 359   ;
 360
 361   # check for empty insert
 362   # INSERT INTO foo DEFAULT VALUES -- does not work with Sybase
 363   # try to insert explicit 'DEFAULT's instead (except for identity, timestamp
 364   # and computed columns)
 365   if (not %$to_insert) {
 366     for my $col ($source->columns) {
 367       next if $col eq $identity_col;
 368
 369       my $info = $source->column_info($col);
 370
 371       next if ref $info->{default_value} eq 'SCALAR'
 372         || (exists $info->{data_type} && (not defined $info->{data_type}));
 373
 374       next if $info->{data_type} && $info->{data_type} =~ /^timestamp\z/i;
 375
 376       $to_insert->{$col} = \'DEFAULT';
 377     }
 378   }
 379
 380   my $blob_cols = $self->_remove_blob_cols($source, $to_insert);
 381
 382   # do we need the horrific SELECT MAX(COL) hack?
 383   my $need_dumb_last_insert_id = (
 384     $self->_perform_autoinc_retrieval
 385       &&
 386     ($self->_identity_method||'') ne '@@IDENTITY'
 387   );
 388
 389   my $next = $self->next::can;
 390
 391   # we are already in a transaction, or there are no blobs
 392   # and we don't need the PK - just (try to) do it
 393   if ($self->{transaction_depth}
 394         || (!$blob_cols && !$need_dumb_last_insert_id)
 395   ) {
 396     return $self->_insert (
 397       $next, $source, $to_insert, $blob_cols, $identity_col
 398     );
 399   }
 400
 401   # otherwise use the _writer_storage to do the insert+transaction on another
 402   # connection
 403   my $guard = $self->_writer_storage->txn_scope_guard;
 404
 405   my $updated_cols = $self->_writer_storage->_insert (
 406     $next, $source, $to_insert, $blob_cols, $identity_col
 407   );
 408
 409   $self->_identity($self->_writer_storage->_identity);
 410
 411   $guard->commit;
 412
 413   return $updated_cols;
 414 }
 415
 416 sub _insert {
 417   my ($self, $next, $source, $to_insert, $blob_cols, $identity_col) = @_;
 418
 419   my $updated_cols = $self->$next ($source, $to_insert);
 420
 421   my $final_row = {
 422     ($identity_col ?
 423       ($identity_col => $self->last_insert_id($source, $identity_col)) : ()),
 424     %$to_insert,
 425     %$updated_cols,
 426   };
 427
 428   $self->_insert_blobs ($source, $blob_cols, $final_row) if $blob_cols;
 429
 430   return $updated_cols;
 431 }
 432
 433 sub update {
 434   my $self = shift;
 435   my ($source, $fields, $where, @rest) = @_;
 436
 437   #
 438   # When *updating* identities, ASE requires SET IDENTITY_UPDATE called
 439   #
 440   if (my $blob_cols = $self->_remove_blob_cols($source, $fields)) {
 441
 442     # If there are any blobs in $where, Sybase will return a descriptive error
 443     # message.
 444     # XXX blobs can still be used with a LIKE query, and this should be handled.
 445
 446     # update+blob update(s) done atomically on separate connection
 447     $self = $self->_writer_storage;
 448
 449     my $guard = $self->txn_scope_guard;
 450
 451     # First update the blob columns to be updated to '' (taken from $fields, where
 452     # it is originally put by _remove_blob_cols .)
 453     my %blobs_to_empty = map { ($_ => delete $fields->{$_}) } keys %$blob_cols;
 454
 455     # We can't only update NULL blobs, because blobs cannot be in the WHERE clause.
 456     $self->next::method($source, \%blobs_to_empty, $where, @rest);
 457
 458     # Now update the blobs before the other columns in case the update of other
 459     # columns makes the search condition invalid.
 460     my $rv = $self->_update_blobs($source, $blob_cols, $where);
 461
 462     if (keys %$fields) {
 463
 464       # Now set the identity update flags for the actual update
 465       local $self->{_autoinc_supplied_for_op} = (first
 466         { $_->{is_auto_increment} }
 467         values %{ $source->columns_info([ keys %$fields ]) }
 468       ) ? 1 : 0;
 469
 470       my $next = $self->next::can;
 471       my $args = \@_;
 472       return preserve_context {
 473         $self->$next(@$args);
 474       } after => sub { $guard->commit };
 475     }
 476     else {
 477       $guard->commit;
 478       return $rv;
 479     }
 480   }
 481   else {
 482     # Set the identity update flags for the actual update
 483     local $self->{_autoinc_supplied_for_op} = (first
 484       { $_->{is_auto_increment} }
 485       values %{ $source->columns_info([ keys %$fields ]) }
 486     ) ? 1 : 0;
 487
 488     return $self->next::method(@_);
 489   }
 490 }
 491
 492 sub insert_bulk {
 493   my $self = shift;
 494   my ($source, $cols, $data) = @_;
 495
 496   my $columns_info = $source->columns_info;
 497
 498   my $identity_col =
 499     first { $columns_info->{$_}{is_auto_increment} }
 500       keys %$columns_info;
 501
 502   # FIXME - this is duplication from DBI.pm. When refactored towards
 503   # the LobWriter this can be folded back where it belongs.
 504   local $self->{_autoinc_supplied_for_op} =
 505     (first { $_ eq $identity_col } @$cols)
 506       ? 1
 507       : 0
 508   ;
 509
 510   my $use_bulk_api =
 511     $self->_bulk_storage &&
 512     $self->_get_dbh->{syb_has_blk};
 513
 514   if (! $use_bulk_api and ref($self->_dbi_connect_info->[0]) eq 'CODE') {
 515     carp_unique( join ' ',
 516       'Bulk API support disabled due to use of a CODEREF connect_info.',
 517       'Reverting to regular array inserts.',
 518     );
 519   }
 520
 521   if (not $use_bulk_api) {
 522     my $blob_cols = $self->_remove_blob_cols_array($source, $cols, $data);
 523
 524 # next::method uses a txn anyway, but it ends too early in case we need to
 525 # select max(col) to get the identity for inserting blobs.
 526     ($self, my $guard) = $self->{transaction_depth} == 0 ?
 527       ($self->_writer_storage, $self->_writer_storage->txn_scope_guard)
 528       :
 529       ($self, undef);
 530
 531     $self->next::method(@_);
 532
 533     if ($blob_cols) {
 534       if ($self->_autoinc_supplied_for_op) {
 535         $self->_insert_blobs_array ($source, $blob_cols, $cols, $data);
 536       }
 537       else {
 538         my @cols_with_identities = (@$cols, $identity_col);
 539
 540         ## calculate identities
 541         # XXX This assumes identities always increase by 1, which may or may not
 542         # be true.
 543         my ($last_identity) =
 544           $self->_dbh->selectrow_array (
 545             $self->_fetch_identity_sql($source, $identity_col)
 546           );
 547         my @identities = (($last_identity - @$data + 1) .. $last_identity);
 548
 549         my @data_with_identities = map [@$_, shift @identities], @$data;
 550
 551         $self->_insert_blobs_array (
 552           $source, $blob_cols, \@cols_with_identities, \@data_with_identities
 553         );
 554       }
 555     }
 556
 557     $guard->commit if $guard;
 558
 559     return;
 560   }
 561
 562 # otherwise, use the bulk API
 563
 564 # rearrange @$data so that columns are in database order
 565 # and so we submit a full column list
 566   my %orig_order = map { $cols->[$_] => $_ } 0..$#$cols;
 567
 568   my @source_columns = $source->columns;
 569
 570   # bcp identity index is 1-based
 571   my $identity_idx = first { $source_columns[$_] eq $identity_col } (0..$#source_columns);
 572   $identity_idx = defined $identity_idx ? $identity_idx + 1 : 0;
 573
 574   my @new_data;
 575   for my $slice_idx (0..$#$data) {
 576     push @new_data, [map {
 577       # identity data will be 'undef' if not _autoinc_supplied_for_op()
 578       # columns with defaults will also be 'undef'
 579       exists $orig_order{$_}
 580         ? $data->[$slice_idx][$orig_order{$_}]
 581         : undef
 582     } @source_columns];
 583   }
 584
 585   my $proto_bind = $self->_resolve_bindattrs(
 586     $source,
 587     [map {
 588       [ { dbic_colname => $source_columns[$_], _bind_data_slice_idx => $_ }
 589         => $new_data[0][$_] ]
 590     } (0 ..$#source_columns) ],
 591     $columns_info
 592   );
 593
 594 ## Set a client-side conversion error handler, straight from DBD::Sybase docs.
 595 # This ignores any data conversion errors detected by the client side libs, as
 596 # they are usually harmless.
 597   my $orig_cslib_cb = DBD::Sybase::set_cslib_cb(
 598     Sub::Name::subname insert_bulk => sub {
 599       my ($layer, $origin, $severity, $errno, $errmsg, $osmsg, $blkmsg) = @_;
 600
 601       return 1 if $errno == 36;
 602
 603       carp
 604         "Layer: $layer, Origin: $origin, Severity: $severity, Error: $errno" .
 605         ($errmsg ? "\n$errmsg" : '') .
 606         ($osmsg  ? "\n$osmsg"  : '')  .
 607         ($blkmsg ? "\n$blkmsg" : '');
 608
 609       return 0;
 610   });
 611
 612   my $exception = '';
 613   try {
 614     my $bulk = $self->_bulk_storage;
 615
 616     my $guard = $bulk->txn_scope_guard;
 617
 618 ## FIXME - once this is done - address the FIXME on finish() below
 619 ## XXX get this to work instead of our own $sth
 620 ## will require SQLA or *Hacks changes for ordered columns
 621 #    $bulk->next::method($source, \@source_columns, \@new_data, {
 622 #      syb_bcp_attribs => {
 623 #        identity_flag   => $self->_autoinc_supplied_for_op ? 1 : 0,
 624 #        identity_column => $identity_idx,
 625 #      }
 626 #    });
 627     my $sql = 'INSERT INTO ' .
 628       $bulk->sql_maker->_quote($source->name) . ' (' .
 629 # colname list is ignored for BCP, but does no harm
 630       (join ', ', map $bulk->sql_maker->_quote($_), @source_columns) . ') '.
 631       ' VALUES ('.  (join ', ', ('?') x @source_columns) . ')';
 632
 633 ## XXX there's a bug in the DBD::Sybase bulk support that makes $sth->finish for
 634 ## a prepare_cached statement ineffective. Replace with ->sth when fixed, or
 635 ## better yet the version above. Should be fixed in DBD::Sybase .
 636     my $sth = $bulk->_get_dbh->prepare($sql,
 637 #      'insert', # op
 638       {
 639         syb_bcp_attribs => {
 640           identity_flag   => $self->_autoinc_supplied_for_op ? 1 : 0,
 641           identity_column => $identity_idx,
 642         }
 643       }
 644     );
 645
 646     {
 647       # FIXME the $sth->finish in _execute_array does a rollback for some
 648       # reason. Disable it temporarily until we fix the SQLMaker thing above
 649       no warnings 'redefine';
 650       no strict 'refs';
 651       local *{ref($sth).'::finish'} = sub {};
 652
 653       $self->_dbh_execute_for_fetch(
 654         $source, $sth, $proto_bind, \@source_columns, \@new_data
 655       );
 656     }
 657
 658     $guard->commit;
 659
 660     $bulk->_query_end($sql);
 661   } catch {
 662     $exception = shift;
 663   };
 664
 665   DBD::Sybase::set_cslib_cb($orig_cslib_cb);
 666
 667   if ($exception =~ /-Y option/) {
 668     my $w = 'Sybase bulk API operation failed due to character set incompatibility, '
 669           . 'reverting to regular array inserts. Try unsetting the LANG environment variable'
 670     ;
 671     $w .= "\n$exception" if $self->debug;
 672     carp $w;
 673
 674     $self->_bulk_storage(undef);
 675     unshift @_, $self;
 676     goto \&insert_bulk;
 677   }
 678   elsif ($exception) {
 679 # rollback makes the bulkLogin connection unusable
 680     $self->_bulk_storage->disconnect;
 681     $self->throw_exception($exception);
 682   }
 683 }
 684
 685 # Make sure blobs are not bound as placeholders, and return any non-empty ones
 686 # as a hash.
 687 sub _remove_blob_cols {
 688   my ($self, $source, $fields) = @_;
 689
 690   my %blob_cols;
 691
 692   for my $col (keys %$fields) {
 693     if ($self->_is_lob_column($source, $col)) {
 694       my $blob_val = delete $fields->{$col};
 695       if (not defined $blob_val) {
 696         $fields->{$col} = \'NULL';
 697       }
 698       else {
 699         $fields->{$col} = \"''";
 700         $blob_cols{$col} = $blob_val unless $blob_val eq '';
 701       }
 702     }
 703   }
 704
 705   return %blob_cols ? \%blob_cols : undef;
 706 }
 707
 708 # same for insert_bulk
 709 sub _remove_blob_cols_array {
 710   my ($self, $source, $cols, $data) = @_;
 711
 712   my @blob_cols;
 713
 714   for my $i (0..$#$cols) {
 715     my $col = $cols->[$i];
 716
 717     if ($self->_is_lob_column($source, $col)) {
 718       for my $j (0..$#$data) {
 719         my $blob_val = delete $data->[$j][$i];
 720         if (not defined $blob_val) {
 721           $data->[$j][$i] = \'NULL';
 722         }
 723         else {
 724           $data->[$j][$i] = \"''";
 725           $blob_cols[$j][$i] = $blob_val
 726             unless $blob_val eq '';
 727         }
 728       }
 729     }
 730   }
 731
 732   return @blob_cols ? \@blob_cols : undef;
 733 }
 734
 735 sub _update_blobs {
 736   my ($self, $source, $blob_cols, $where) = @_;
 737
 738   my @primary_cols = try
 739     { $source->_pri_cols }
 740     catch {
 741       $self->throw_exception("Cannot update TEXT/IMAGE column(s): $_")
 742     };
 743
 744   my @pks_to_update;
 745   if (
 746     ref $where eq 'HASH'
 747       and
 748     @primary_cols == grep { defined $where->{$_} } @primary_cols
 749   ) {
 750     my %row_to_update;
 751     @row_to_update{@primary_cols} = @{$where}{@primary_cols};
 752     @pks_to_update = \%row_to_update;
 753   }
 754   else {
 755     my $cursor = $self->select ($source, \@primary_cols, $where, {});
 756     @pks_to_update = map {
 757       my %row; @row{@primary_cols} = @$_; \%row
 758     } $cursor->all;
 759   }
 760
 761   for my $ident (@pks_to_update) {
 762     $self->_insert_blobs($source, $blob_cols, $ident);
 763   }
 764 }
 765
 766 sub _insert_blobs {
 767   my ($self, $source, $blob_cols, $row) = @_;
 768   my $dbh = $self->_get_dbh;
 769
 770   my $table = $source->name;
 771
 772   my %row = %$row;
 773   my @primary_cols = try
 774     { $source->_pri_cols }
 775     catch {
 776       $self->throw_exception("Cannot update TEXT/IMAGE column(s): $_")
 777     };
 778
 779   $self->throw_exception('Cannot update TEXT/IMAGE column(s) without primary key values')
 780     if ((grep { defined $row{$_} } @primary_cols) != @primary_cols);
 781
 782   for my $col (keys %$blob_cols) {
 783     my $blob = $blob_cols->{$col};
 784
 785     my %where = map { ($_, $row{$_}) } @primary_cols;
 786
 787     my $cursor = $self->select ($source, [$col], \%where, {});
 788     $cursor->next;
 789     my $sth = $cursor->sth;
 790
 791     if (not $sth) {
 792       $self->throw_exception(
 793           "Could not find row in table '$table' for blob update:\n"
 794         . (Dumper \%where)
 795       );
 796     }
 797
 798     try {
 799       do {
 800         $sth->func('CS_GET', 1, 'ct_data_info') or die $sth->errstr;
 801       } while $sth->fetch;
 802
 803       $sth->func('ct_prepare_send') or die $sth->errstr;
 804
 805       my $log_on_update = $self->_blob_log_on_update;
 806       $log_on_update    = 1 if not defined $log_on_update;
 807
 808       $sth->func('CS_SET', 1, {
 809         total_txtlen => length($blob),
 810         log_on_update => $log_on_update
 811       }, 'ct_data_info') or die $sth->errstr;
 812
 813       $sth->func($blob, length($blob), 'ct_send_data') or die $sth->errstr;
 814
 815       $sth->func('ct_finish_send') or die $sth->errstr;
 816     }
 817     catch {
 818       if ($self->_using_freetds) {
 819         $self->throw_exception (
 820           "TEXT/IMAGE operation failed, probably because you are using FreeTDS: $_"
 821         );
 822       }
 823       else {
 824         $self->throw_exception($_);
 825       }
 826     }
 827     finally {
 828       $sth->finish if $sth;
 829     };
 830   }
 831 }
 832
 833 sub _insert_blobs_array {
 834   my ($self, $source, $blob_cols, $cols, $data) = @_;
 835
 836   for my $i (0..$#$data) {
 837     my $datum = $data->[$i];
 838
 839     my %row;
 840     @row{ @$cols } = @$datum;
 841
 842     my %blob_vals;
 843     for my $j (0..$#$cols) {
 844       if (exists $blob_cols->[$i][$j]) {
 845         $blob_vals{ $cols->[$j] } = $blob_cols->[$i][$j];
 846       }
 847     }
 848
 849     $self->_insert_blobs ($source, \%blob_vals, \%row);
 850   }
 851 }
 852
 853 =head2 connect_call_datetime_setup
 854
 855 Used as:
 856
 857   on_connect_call => 'datetime_setup'
 858
 859 In L<connect_info|DBIx::Class::Storage::DBI/connect_info> to set:
 860
 861   $dbh->syb_date_fmt('ISO_strict'); # output fmt: 2004-08-21T14:36:48.080Z
 862   $dbh->do('set dateformat mdy');   # input fmt:  08/13/1979 18:08:55.080
 863
 864 This works for both C<DATETIME> and C<SMALLDATETIME> columns, note that
 865 C<SMALLDATETIME> columns only have minute precision.
 866
 867 =cut
 868
 869 sub connect_call_datetime_setup {
 870   my $self = shift;
 871   my $dbh = $self->_get_dbh;
 872
 873   if ($dbh->can('syb_date_fmt')) {
 874     # amazingly, this works with FreeTDS
 875     $dbh->syb_date_fmt('ISO_strict');
 876   }
 877   else {
 878     carp_once
 879       'Your DBD::Sybase is too old to support '
 880      .'DBIx::Class::InflateColumn::DateTime, please upgrade!';
 881
 882     # FIXME - in retrospect this is a rather bad US-centric choice
 883     # of format. Not changing as a bugwards compat, though in reality
 884     # the only piece that sees the results of $dt object formatting
 885     # (as opposed to parsing) is the database itself, so theoretically
 886     # changing both this SET command and the formatter definition of
 887     # ::S::D::Sybase::ASE::DateTime::Format below should be safe and
 888     # transparent
 889
 890     $dbh->do('SET DATEFORMAT mdy');
 891   }
 892 }
 893
 894
 895 sub _exec_txn_begin {
 896   my $self = shift;
 897
 898 # bulkLogin=1 connections are always in a transaction, and can only call BEGIN
 899 # TRAN once. However, we need to make sure there's a $dbh.
 900   return if $self->_is_bulk_storage && $self->_dbh && $self->_began_bulk_work;
 901
 902   $self->next::method(@_);
 903
 904   $self->_began_bulk_work(1) if $self->_is_bulk_storage;
 905 }
 906
 907 # savepoint support using ASE syntax
 908
 909 sub _exec_svp_begin {
 910   my ($self, $name) = @_;
 911
 912   $self->_dbh->do("SAVE TRANSACTION $name");
 913 }
 914
 915 # A new SAVE TRANSACTION with the same name releases the previous one.
 916 sub _exec_svp_release { 1 }
 917
 918 sub _exec_svp_rollback {
 919   my ($self, $name) = @_;
 920
 921   $self->_dbh->do("ROLLBACK TRANSACTION $name");
 922 }
 923
 924 package # hide from PAUSE
 925   DBIx::Class::Storage::DBI::Sybase::ASE::DateTime::Format;
 926
 927 my $datetime_parse_format  = '%Y-%m-%dT%H:%M:%S.%3NZ';
 928 my $datetime_format_format = '%m/%d/%Y %H:%M:%S.%3N';
 929
 930 my ($datetime_parser, $datetime_formatter);
 931
 932 sub parse_datetime {
 933   shift;
 934   require DateTime::Format::Strptime;
 935   $datetime_parser ||= DateTime::Format::Strptime->new(
 936     pattern  => $datetime_parse_format,
 937     on_error => 'croak',
 938   );
 939   return $datetime_parser->parse_datetime(shift);
 940 }
 941
 942 sub format_datetime {
 943   shift;
 944   require DateTime::Format::Strptime;
 945   $datetime_formatter ||= DateTime::Format::Strptime->new(
 946     pattern  => $datetime_format_format,
 947     on_error => 'croak',
 948   );
 949   return $datetime_formatter->format_datetime(shift);
 950 }
 951
 952 1;
 953
 954 =head1 Schema::Loader Support
 955
 956 As of version C<0.05000>, L<DBIx::Class::Schema::Loader> should work well with
 957 most versions of Sybase ASE.
 958
 959 =head1 FreeTDS
 960
 961 This driver supports L<DBD::Sybase> compiled against FreeTDS
 962 (L<http://www.freetds.org/>) to the best of our ability, however it is
 963 recommended that you recompile L<DBD::Sybase> against the Sybase Open Client
 964 libraries. They are a part of the Sybase ASE distribution:
 965
 966 The Open Client FAQ is here:
 967 L<http://www.isug.com/Sybase_FAQ/ASE/section7.html>.
 968
 969 Sybase ASE for Linux (which comes with the Open Client libraries) may be
 970 downloaded here: L<http://response.sybase.com/forms/ASE_Linux_Download>.
 971
 972 To see if you're using FreeTDS run:
 973
 974   perl -MDBI -le 'my $dbh = DBI->connect($dsn, $user, $pass); print $dbh->{syb_oc_version}'
 975
 976 It is recommended to set C<tds version> for your ASE server to C<5.0> in
 977 C</etc/freetds/freetds.conf>.
 978
 979 Some versions or configurations of the libraries involved will not support
 980 placeholders, in which case the storage will be reblessed to
 981 L<DBIx::Class::Storage::DBI::Sybase::ASE::NoBindVars>.
 982
 983 In some configurations, placeholders will work but will throw implicit type
 984 conversion errors for anything that's not expecting a string. In such a case,
 985 the C<auto_cast> option from L<DBIx::Class::Storage::DBI::AutoCast> is
 986 automatically set, which you may enable on connection with
 987 L<connect_call_set_auto_cast|DBIx::Class::Storage::DBI::AutoCast/connect_call_set_auto_cast>.
 988 The type info for the C<CAST>s is taken from the
 989 L<DBIx::Class::ResultSource/data_type> definitions in your Result classes, and
 990 are mapped to a Sybase type (if it isn't already) using a mapping based on
 991 L<SQL::Translator>.
 992
 993 In other configurations, placeholders will work just as they do with the Sybase
 994 Open Client libraries.
 995
 996 Inserts or updates of TEXT/IMAGE columns will B<NOT> work with FreeTDS.
 997
 998 =head1 INSERTS WITH PLACEHOLDERS
 999
1000 With placeholders enabled, inserts are done in a transaction so that there are
1001 no concurrency issues with getting the inserted identity value using
1002 C<SELECT MAX(col)>, which is the only way to get the C<IDENTITY> value in this
1003 mode.
1004
1005 In addition, they are done on a separate connection so that it's possible to
1006 have active cursors when doing an insert.
1007
1008 When using C<DBIx::Class::Storage::DBI::Sybase::ASE::NoBindVars> transactions
1009 are unnecessary and not used, as there are no concurrency issues with C<SELECT
1010 @@IDENTITY> which is a session variable.
1011
1012 =head1 TRANSACTIONS
1013
1014 Due to limitations of the TDS protocol and L<DBD::Sybase>, you cannot begin a
1015 transaction while there are active cursors, nor can you use multiple active
1016 cursors within a transaction. An active cursor is, for example, a
1017 L<ResultSet|DBIx::Class::ResultSet> that has been executed using C<next> or
1018 C<first> but has not been exhausted or L<reset|DBIx::Class::ResultSet/reset>.
1019
1020 For example, this will not work:
1021
1022   $schema->txn_do(sub {
1023     my $rs = $schema->resultset('Book');
1024     while (my $row = $rs->next) {
1025       $schema->resultset('MetaData')->create({
1026         book_id => $row->id,
1027         ...
1028       });
1029     }
1030   });
1031
1032 This won't either:
1033
1034   my $first_row = $large_rs->first;
1035   $schema->txn_do(sub { ... });
1036
1037 Transactions done for inserts in C<AutoCommit> mode when placeholders are in use
1038 are not affected, as they are done on an extra database handle.
1039
1040 Some workarounds:
1041
1042 =over 4
1043
1044 =item * use L<DBIx::Class::Storage::DBI::Replicated>
1045
1046 =item * L<connect|DBIx::Class::Schema/connect> another L<Schema|DBIx::Class::Schema>
1047
1048 =item * load the data from your cursor with L<DBIx::Class::ResultSet/all>
1049
1050 =back
1051
1052 =head1 MAXIMUM CONNECTIONS
1053
1054 The TDS protocol makes separate connections to the server for active statements
1055 in the background. By default the number of such connections is limited to 25,
1056 on both the client side and the server side.
1057
1058 This is a bit too low for a complex L<DBIx::Class> application, so on connection
1059 the client side setting is set to C<256> (see L<DBD::Sybase/maxConnect>.) You
1060 can override it to whatever setting you like in the DSN.
1061
1062 See
1063 L<http://infocenter.sybase.com/help/index.jsp?topic=/com.sybase.help.ase_15.0.sag1/html/sag1/sag1272.htm>
1064 for information on changing the setting on the server side.
1065
1066 =head1 DATES
1067
1068 See L</connect_call_datetime_setup> to setup date formats
1069 for L<DBIx::Class::InflateColumn::DateTime>.
1070
1071 =head1 LIMITED QUERIES
1072
1073 Because ASE does not have a good way to limit results in SQL that works for all
1074 types of queries, the limit dialect is set to
1075 L<GenericSubQ|SQL::Abstract::Limit/GenericSubQ>.
1076
1077 Fortunately, ASE and L<DBD::Sybase> support cursors properly, so when
1078 L<GenericSubQ|SQL::Abstract::Limit/GenericSubQ> is too slow you can use
1079 the L<software_limit|DBIx::Class::ResultSet/software_limit>
1080 L<DBIx::Class::ResultSet> attribute to simulate limited queries by skipping over
1081 records.
1082
1083 =head1 TEXT/IMAGE COLUMNS
1084
1085 L<DBD::Sybase> compiled with FreeTDS will B<NOT> allow you to insert or update
1086 C<TEXT/IMAGE> columns.
1087
1088 Setting C<< $dbh->{LongReadLen} >> will also not work with FreeTDS use either:
1089
1090   $schema->storage->dbh->do("SET TEXTSIZE $bytes");
1091
1092 or
1093
1094   $schema->storage->set_textsize($bytes);
1095
1096 instead.
1097
1098 However, the C<LongReadLen> you pass in
1099 L<connect_info|DBIx::Class::Storage::DBI/connect_info> is used to execute the
1100 equivalent C<SET TEXTSIZE> command on connection.
1101
1102 See L</connect_call_blob_setup> for a
1103 L<connect_info|DBIx::Class::Storage::DBI/connect_info> setting you need to work
1104 with C<IMAGE> columns.
1105
1106 =head1 BULK API
1107
1108 The experimental L<DBD::Sybase> Bulk API support is used for
1109 L<populate|DBIx::Class::ResultSet/populate> in B<void> context, in a transaction
1110 on a separate connection.
1111
1112 To use this feature effectively, use a large number of rows for each
1113 L<populate|DBIx::Class::ResultSet/populate> call, eg.:
1114
1115   while (my $rows = $data_source->get_100_rows()) {
1116     $rs->populate($rows);
1117   }
1118
1119 B<NOTE:> the L<add_columns|DBIx::Class::ResultSource/add_columns>
1120 calls in your C<Result> classes B<must> list columns in database order for this
1121 to work. Also, you may have to unset the C<LANG> environment variable before
1122 loading your app, as C<BCP -Y> is not yet supported in DBD::Sybase .
1123
1124 When inserting IMAGE columns using this method, you'll need to use
1125 L</connect_call_blob_setup> as well.
1126
1127 =head1 COMPUTED COLUMNS
1128
1129 If you have columns such as:
1130
1131   created_dtm AS getdate()
1132
1133 represent them in your Result classes as:
1134
1135   created_dtm => {
1136     data_type => undef,
1137     default_value => \'getdate()',
1138     is_nullable => 0,
1139     inflate_datetime => 1,
1140   }
1141
1142 The C<data_type> must exist and must be C<undef>. Then empty inserts will work
1143 on tables with such columns.
1144
1145 =head1 TIMESTAMP COLUMNS
1146
1147 C<timestamp> columns in Sybase ASE are not really timestamps, see:
1148 L<http://dba.fyicenter.com/Interview-Questions/SYBASE/The_timestamp_datatype_in_Sybase_.html>.
1149
1150 They should be defined in your Result classes as:
1151
1152   ts => {
1153     data_type => 'timestamp',
1154     is_nullable => 0,
1155     inflate_datetime => 0,
1156   }
1157
1158 The C<<inflate_datetime => 0>> is necessary if you use
1159 L<DBIx::Class::InflateColumn::DateTime>, and most people do, and still want to
1160 be able to read these values.
1161
1162 The values will come back as hexadecimal.
1163
1164 =head1 TODO
1165
1166 =over
1167
1168 =item *
1169
1170 Transitions to AutoCommit=0 (starting a transaction) mode by exhausting
1171 any active cursors, using eager cursors.
1172
1173 =item *
1174
1175 Real limits and limited counts using stored procedures deployed on startup.
1176
1177 =item *
1178
1179 Blob update with a LIKE query on a blob, without invalidating the WHERE condition.
1180
1181 =item *
1182
1183 bulk_insert using prepare_cached (see comments.)
1184
1185 =back
1186
1187 =head1 AUTHOR
1188
1189 See L<DBIx::Class/AUTHOR> and L<DBIx::Class/CONTRIBUTORS>.
1190
1191 =head1 LICENSE
1192
1193 You may distribute this code under the same terms as Perl itself.
1194
1195 =cut
1196 # vim:sts=2 sw=2: