lib/DBIx/Class/Storage/DBI/Sybase/ASE.pm

   1 package DBIx::Class::Storage::DBI::Sybase::ASE;
   2
   3 use strict;
   4 use warnings;
   5
   6 use base qw/
   7     DBIx::Class::Storage::DBI::Sybase
   8     DBIx::Class::Storage::DBI::AutoCast
   9 /;
  10 use mro 'c3';
  11 use Carp::Clan qw/^DBIx::Class/;
  12 use Scalar::Util();
  13 use List::Util();
  14 use Sub::Name();
  15 use Data::Dumper::Concise();
  16 use Try::Tiny;
  17 use namespace::clean;
  18
  19 __PACKAGE__->mk_group_accessors('simple' =>
  20     qw/_identity _blob_log_on_update _writer_storage _is_extra_storage
  21        _bulk_storage _is_bulk_storage _began_bulk_work
  22        _bulk_disabled_due_to_coderef_connect_info_warned
  23        _identity_method/
  24 );
  25
  26 my @also_proxy_to_extra_storages = qw/
  27   connect_call_set_auto_cast auto_cast connect_call_blob_setup
  28   connect_call_datetime_setup
  29
  30   disconnect _connect_info _sql_maker _sql_maker_opts disable_sth_caching
  31   auto_savepoint unsafe cursor_class debug debugobj schema
  32 /;
  33
  34 =head1 NAME
  35
  36 DBIx::Class::Storage::DBI::Sybase::ASE - Sybase ASE SQL Server support for
  37 DBIx::Class
  38
  39 =head1 SYNOPSIS
  40
  41 This subclass supports L<DBD::Sybase> for real (non-Microsoft) Sybase databases.
  42
  43 =head1 DESCRIPTION
  44
  45 If your version of Sybase does not support placeholders, then your storage will
  46 be reblessed to L<DBIx::Class::Storage::DBI::Sybase::ASE::NoBindVars>.
  47 You can also enable that driver explicitly, see the documentation for more
  48 details.
  49
  50 With this driver there is unfortunately no way to get the C<last_insert_id>
  51 without doing a C<SELECT MAX(col)>. This is done safely in a transaction
  52 (locking the table.) See L</INSERTS WITH PLACEHOLDERS>.
  53
  54 A recommended L<connect_info|DBIx::Class::Storage::DBI/connect_info> setting:
  55
  56   on_connect_call => [['datetime_setup'], ['blob_setup', log_on_update => 0]]
  57
  58 =head1 METHODS
  59
  60 =cut
  61
  62 sub _rebless {
  63   my $self = shift;
  64
  65   my $no_bind_vars = __PACKAGE__ . '::NoBindVars';
  66
  67   if ($self->using_freetds) {
  68     carp <<'EOF' unless $ENV{DBIC_SYBASE_FREETDS_NOWARN};
  69
  70 You are using FreeTDS with Sybase.
  71
  72 We will do our best to support this configuration, but please consider this
  73 support experimental.
  74
  75 TEXT/IMAGE columns will definitely not work.
  76
  77 You are encouraged to recompile DBD::Sybase with the Sybase Open Client libraries
  78 instead.
  79
  80 See perldoc DBIx::Class::Storage::DBI::Sybase::ASE for more details.
  81
  82 To turn off this warning set the DBIC_SYBASE_FREETDS_NOWARN environment
  83 variable.
  84 EOF
  85
  86     if (not $self->_typeless_placeholders_supported) {
  87       if ($self->_placeholders_supported) {
  88         $self->auto_cast(1);
  89       }
  90       else {
  91         $self->ensure_class_loaded($no_bind_vars);
  92         bless $self, $no_bind_vars;
  93         $self->_rebless;
  94       }
  95     }
  96   }
  97
  98   elsif (not $self->_get_dbh->{syb_dynamic_supported}) {
  99     # not necessarily FreeTDS, but no placeholders nevertheless
 100     $self->ensure_class_loaded($no_bind_vars);
 101     bless $self, $no_bind_vars;
 102     $self->_rebless;
 103   }
 104   # this is highly unlikely, but we check just in case
 105   elsif (not $self->_typeless_placeholders_supported) {
 106     $self->auto_cast(1);
 107   }
 108 }
 109
 110 sub _init {
 111   my $self = shift;
 112   $self->_set_max_connect(256);
 113
 114 # create storage for insert/(update blob) transactions,
 115 # unless this is that storage
 116   return if $self->_is_extra_storage;
 117
 118   my $writer_storage = (ref $self)->new;
 119
 120   $writer_storage->_is_extra_storage(1);
 121   $writer_storage->connect_info($self->connect_info);
 122   $writer_storage->auto_cast($self->auto_cast);
 123
 124   $self->_writer_storage($writer_storage);
 125
 126 # create a bulk storage unless connect_info is a coderef
 127   return if ref($self->_dbi_connect_info->[0]) eq 'CODE';
 128
 129   my $bulk_storage = (ref $self)->new;
 130
 131   $bulk_storage->_is_extra_storage(1);
 132   $bulk_storage->_is_bulk_storage(1); # for special ->disconnect acrobatics
 133   $bulk_storage->connect_info($self->connect_info);
 134
 135 # this is why
 136   $bulk_storage->_dbi_connect_info->[0] .= ';bulkLogin=1';
 137
 138   $self->_bulk_storage($bulk_storage);
 139 }
 140
 141 for my $method (@also_proxy_to_extra_storages) {
 142   no strict 'refs';
 143   no warnings 'redefine';
 144
 145   my $replaced = __PACKAGE__->can($method);
 146
 147   *{$method} = Sub::Name::subname $method => sub {
 148     my $self = shift;
 149     $self->_writer_storage->$replaced(@_) if $self->_writer_storage;
 150     $self->_bulk_storage->$replaced(@_)   if $self->_bulk_storage;
 151     return $self->$replaced(@_);
 152   };
 153 }
 154
 155 sub disconnect {
 156   my $self = shift;
 157
 158 # Even though we call $sth->finish for uses off the bulk API, there's still an
 159 # "active statement" warning on disconnect, which we throw away here.
 160 # This is due to the bug described in insert_bulk.
 161 # Currently a noop because 'prepare' is used instead of 'prepare_cached'.
 162   local $SIG{__WARN__} = sub {
 163     warn $_[0] unless $_[0] =~ /active statement/i;
 164   } if $self->_is_bulk_storage;
 165
 166 # so that next transaction gets a dbh
 167   $self->_began_bulk_work(0) if $self->_is_bulk_storage;
 168
 169   $self->next::method;
 170 }
 171
 172 # Set up session settings for Sybase databases for the connection.
 173 #
 174 # Make sure we have CHAINED mode turned on if AutoCommit is off in non-FreeTDS
 175 # DBD::Sybase (since we don't know how DBD::Sybase was compiled.) If however
 176 # we're using FreeTDS, CHAINED mode turns on an implicit transaction which we
 177 # only want when AutoCommit is off.
 178 #
 179 # Also SET TEXTSIZE for FreeTDS because LongReadLen doesn't work.
 180 sub _run_connection_actions {
 181   my $self = shift;
 182
 183   if ($self->_is_bulk_storage) {
 184 # this should be cleared on every reconnect
 185     $self->_began_bulk_work(0);
 186     return;
 187   }
 188
 189   if (not $self->using_freetds) {
 190     $self->_dbh->{syb_chained_txn} = 1;
 191   } else {
 192     # based on LongReadLen in connect_info
 193     $self->set_textsize;
 194
 195     if ($self->_dbh_autocommit) {
 196       $self->_dbh->do('SET CHAINED OFF');
 197     } else {
 198       $self->_dbh->do('SET CHAINED ON');
 199     }
 200   }
 201
 202   $self->next::method(@_);
 203 }
 204
 205 =head2 connect_call_blob_setup
 206
 207 Used as:
 208
 209   on_connect_call => [ [ 'blob_setup', log_on_update => 0 ] ]
 210
 211 Does C<< $dbh->{syb_binary_images} = 1; >> to return C<IMAGE> data as raw binary
 212 instead of as a hex string.
 213
 214 Recommended.
 215
 216 Also sets the C<log_on_update> value for blob write operations. The default is
 217 C<1>, but C<0> is better if your database is configured for it.
 218
 219 See
 220 L<DBD::Sybase/Handling_IMAGE/TEXT_data_with_syb_ct_get_data()/syb_ct_send_data()>.
 221
 222 =cut
 223
 224 sub connect_call_blob_setup {
 225   my $self = shift;
 226   my %args = @_;
 227   my $dbh = $self->_dbh;
 228   $dbh->{syb_binary_images} = 1;
 229
 230   $self->_blob_log_on_update($args{log_on_update})
 231     if exists $args{log_on_update};
 232 }
 233
 234 sub _is_lob_type {
 235   my $self = shift;
 236   my $type = shift;
 237   $type && $type =~ /(?:text|image|lob|bytea|binary|memo)/i;
 238 }
 239
 240 sub _is_lob_column {
 241   my ($self, $source, $column) = @_;
 242
 243   return $self->_is_lob_type($source->column_info($column)->{data_type});
 244 }
 245
 246 sub _prep_for_execute {
 247   my $self = shift;
 248   my ($op, $extra_bind, $ident, $args) = @_;
 249
 250   my ($sql, $bind) = $self->next::method (@_);
 251
 252   my $table = Scalar::Util::blessed($ident) ? $ident->from : $ident;
 253
 254   my $bind_info = $self->_resolve_column_info(
 255     $ident, [map $_->[0], @{$bind}]
 256   );
 257   my $bound_identity_col = List::Util::first
 258     { $bind_info->{$_}{is_auto_increment} }
 259     (keys %$bind_info)
 260   ;
 261   my $identity_col = Scalar::Util::blessed($ident) &&
 262     List::Util::first
 263     { $ident->column_info($_)->{is_auto_increment} }
 264     $ident->columns
 265   ;
 266
 267   if (($op eq 'insert' && $bound_identity_col) ||
 268       ($op eq 'update' && exists $args->[0]{$identity_col})) {
 269     $sql = join ("\n",
 270       $self->_set_table_identity_sql($op => $table, 'on'),
 271       $sql,
 272       $self->_set_table_identity_sql($op => $table, 'off'),
 273     );
 274   }
 275
 276   if ($op eq 'insert' && (not $bound_identity_col) && $identity_col &&
 277       (not $self->{insert_bulk})) {
 278     $sql =
 279       "$sql\n" .
 280       $self->_fetch_identity_sql($ident, $identity_col);
 281   }
 282
 283   return ($sql, $bind);
 284 }
 285
 286 sub _set_table_identity_sql {
 287   my ($self, $op, $table, $on_off) = @_;
 288
 289   return sprintf 'SET IDENTITY_%s %s %s',
 290     uc($op), $self->sql_maker->_quote($table), uc($on_off);
 291 }
 292
 293 # Stolen from SQLT, with some modifications. This is a makeshift
 294 # solution before a sane type-mapping library is available, thus
 295 # the 'our' for easy overrides.
 296 our %TYPE_MAPPING  = (
 297     number    => 'numeric',
 298     money     => 'money',
 299     varchar   => 'varchar',
 300     varchar2  => 'varchar',
 301     timestamp => 'datetime',
 302     text      => 'varchar',
 303     real      => 'double precision',
 304     comment   => 'text',
 305     bit       => 'bit',
 306     tinyint   => 'smallint',
 307     float     => 'double precision',
 308     serial    => 'numeric',
 309     bigserial => 'numeric',
 310     boolean   => 'varchar',
 311     long      => 'varchar',
 312 );
 313
 314 sub _native_data_type {
 315   my ($self, $type) = @_;
 316
 317   $type = lc $type;
 318   $type =~ s/\s* identity//x;
 319
 320   return uc($TYPE_MAPPING{$type} || $type);
 321 }
 322
 323 sub _fetch_identity_sql {
 324   my ($self, $source, $col) = @_;
 325
 326   return sprintf ("SELECT MAX(%s) FROM %s",
 327     map { $self->sql_maker->_quote ($_) } ($col, $source->from)
 328   );
 329 }
 330
 331 sub _execute {
 332   my $self = shift;
 333   my ($op) = @_;
 334
 335   my ($rv, $sth, @bind) = $self->dbh_do($self->can('_dbh_execute'), @_);
 336
 337   if ($op eq 'insert') {
 338     $self->_identity($sth->fetchrow_array);
 339     $sth->finish;
 340   }
 341
 342   return wantarray ? ($rv, $sth, @bind) : $rv;
 343 }
 344
 345 sub last_insert_id { shift->_identity }
 346
 347 # handles TEXT/IMAGE and transaction for last_insert_id
 348 sub insert {
 349   my $self = shift;
 350   my ($source, $to_insert) = @_;
 351
 352   my $identity_col = (List::Util::first
 353     { $source->column_info($_)->{is_auto_increment} }
 354     $source->columns) || '';
 355
 356   # check for empty insert
 357   # INSERT INTO foo DEFAULT VALUES -- does not work with Sybase
 358   # try to insert explicit 'DEFAULT's instead (except for identity, timestamp
 359   # and computed columns)
 360   if (not %$to_insert) {
 361     for my $col ($source->columns) {
 362       next if $col eq $identity_col;
 363
 364       my $info = $source->column_info($col);
 365
 366       next if ref $info->{default_value} eq 'SCALAR'
 367         || (exists $info->{data_type} && (not defined $info->{data_type}));
 368
 369       next if $info->{data_type} && $info->{data_type} =~ /^timestamp\z/i;
 370
 371       $to_insert->{$col} = \'DEFAULT';
 372     }
 373   }
 374
 375   my $blob_cols = $self->_remove_blob_cols($source, $to_insert);
 376
 377   # do we need the horrific SELECT MAX(COL) hack?
 378   my $dumb_last_insert_id =
 379        $identity_col
 380     && (not exists $to_insert->{$identity_col})
 381     && ($self->_identity_method||'') ne '@@IDENTITY';
 382
 383   my $next = $self->next::can;
 384
 385   # we are already in a transaction, or there are no blobs
 386   # and we don't need the PK - just (try to) do it
 387   if ($self->{transaction_depth}
 388         || (!$blob_cols && !$dumb_last_insert_id)
 389   ) {
 390     return $self->_insert (
 391       $next, $source, $to_insert, $blob_cols, $identity_col
 392     );
 393   }
 394
 395   # otherwise use the _writer_storage to do the insert+transaction on another
 396   # connection
 397   my $guard = $self->_writer_storage->txn_scope_guard;
 398
 399   my $updated_cols = $self->_writer_storage->_insert (
 400     $next, $source, $to_insert, $blob_cols, $identity_col
 401   );
 402
 403   $self->_identity($self->_writer_storage->_identity);
 404
 405   $guard->commit;
 406
 407   return $updated_cols;
 408 }
 409
 410 sub _insert {
 411   my ($self, $next, $source, $to_insert, $blob_cols, $identity_col) = @_;
 412
 413   my $updated_cols = $self->$next ($source, $to_insert);
 414
 415   my $final_row = {
 416     ($identity_col ?
 417       ($identity_col => $self->last_insert_id($source, $identity_col)) : ()),
 418     %$to_insert,
 419     %$updated_cols,
 420   };
 421
 422   $self->_insert_blobs ($source, $blob_cols, $final_row) if $blob_cols;
 423
 424   return $updated_cols;
 425 }
 426
 427 sub update {
 428   my $self = shift;
 429   my ($source, $fields, $where, @rest) = @_;
 430
 431   my $wantarray = wantarray;
 432
 433   my $blob_cols = $self->_remove_blob_cols($source, $fields);
 434
 435   my $table = $source->name;
 436
 437   my $identity_col = List::Util::first
 438     { $source->column_info($_)->{is_auto_increment} }
 439     $source->columns;
 440
 441   my $is_identity_update = $identity_col && defined $fields->{$identity_col};
 442
 443   return $self->next::method(@_) unless $blob_cols;
 444
 445 # If there are any blobs in $where, Sybase will return a descriptive error
 446 # message.
 447 # XXX blobs can still be used with a LIKE query, and this should be handled.
 448
 449 # update+blob update(s) done atomically on separate connection
 450   $self = $self->_writer_storage;
 451
 452   my $guard = $self->txn_scope_guard;
 453
 454 # First update the blob columns to be updated to '' (taken from $fields, where
 455 # it is originally put by _remove_blob_cols .)
 456   my %blobs_to_empty = map { ($_ => delete $fields->{$_}) } keys %$blob_cols;
 457
 458 # We can't only update NULL blobs, because blobs cannot be in the WHERE clause.
 459
 460   $self->next::method($source, \%blobs_to_empty, $where, @rest);
 461
 462 # Now update the blobs before the other columns in case the update of other
 463 # columns makes the search condition invalid.
 464   $self->_update_blobs($source, $blob_cols, $where);
 465
 466   my @res;
 467   if (%$fields) {
 468     if ($wantarray) {
 469       @res    = $self->next::method(@_);
 470     }
 471     elsif (defined $wantarray) {
 472       $res[0] = $self->next::method(@_);
 473     }
 474     else {
 475       $self->next::method(@_);
 476     }
 477   }
 478
 479   $guard->commit;
 480
 481   return $wantarray ? @res : $res[0];
 482 }
 483
 484 sub insert_bulk {
 485   my $self = shift;
 486   my ($source, $cols, $data) = @_;
 487
 488   my $identity_col = List::Util::first
 489     { $source->column_info($_)->{is_auto_increment} }
 490     $source->columns;
 491
 492   my $is_identity_insert = (List::Util::first
 493     { $_ eq $identity_col }
 494     @{$cols}
 495   ) ? 1 : 0;
 496
 497   my @source_columns = $source->columns;
 498
 499   my $use_bulk_api =
 500     $self->_bulk_storage &&
 501     $self->_get_dbh->{syb_has_blk};
 502
 503   if ((not $use_bulk_api)
 504         &&
 505       (ref($self->_dbi_connect_info->[0]) eq 'CODE')
 506         &&
 507       (not $self->_bulk_disabled_due_to_coderef_connect_info_warned)) {
 508     carp <<'EOF';
 509 Bulk API support disabled due to use of a CODEREF connect_info. Reverting to
 510 regular array inserts.
 511 EOF
 512     $self->_bulk_disabled_due_to_coderef_connect_info_warned(1);
 513   }
 514
 515   if (not $use_bulk_api) {
 516     my $blob_cols = $self->_remove_blob_cols_array($source, $cols, $data);
 517
 518 # _execute_array uses a txn anyway, but it ends too early in case we need to
 519 # select max(col) to get the identity for inserting blobs.
 520     ($self, my $guard) = $self->{transaction_depth} == 0 ?
 521       ($self->_writer_storage, $self->_writer_storage->txn_scope_guard)
 522       :
 523       ($self, undef);
 524
 525     local $self->{insert_bulk} = 1;
 526
 527     $self->next::method(@_);
 528
 529     if ($blob_cols) {
 530       if ($is_identity_insert) {
 531         $self->_insert_blobs_array ($source, $blob_cols, $cols, $data);
 532       }
 533       else {
 534         my @cols_with_identities = (@$cols, $identity_col);
 535
 536         ## calculate identities
 537         # XXX This assumes identities always increase by 1, which may or may not
 538         # be true.
 539         my ($last_identity) =
 540           $self->_dbh->selectrow_array (
 541             $self->_fetch_identity_sql($source, $identity_col)
 542           );
 543         my @identities = (($last_identity - @$data + 1) .. $last_identity);
 544
 545         my @data_with_identities = map [@$_, shift @identities], @$data;
 546
 547         $self->_insert_blobs_array (
 548           $source, $blob_cols, \@cols_with_identities, \@data_with_identities
 549         );
 550       }
 551     }
 552
 553     $guard->commit if $guard;
 554
 555     return;
 556   }
 557
 558 # otherwise, use the bulk API
 559
 560 # rearrange @$data so that columns are in database order
 561   my %orig_idx;
 562   @orig_idx{@$cols} = 0..$#$cols;
 563
 564   my %new_idx;
 565   @new_idx{@source_columns} = 0..$#source_columns;
 566
 567   my @new_data;
 568   for my $datum (@$data) {
 569     my $new_datum = [];
 570     for my $col (@source_columns) {
 571 # identity data will be 'undef' if not $is_identity_insert
 572 # columns with defaults will also be 'undef'
 573       $new_datum->[ $new_idx{$col} ] =
 574         exists $orig_idx{$col} ? $datum->[ $orig_idx{$col} ] : undef;
 575     }
 576     push @new_data, $new_datum;
 577   }
 578
 579 # bcp identity index is 1-based
 580   my $identity_idx = exists $new_idx{$identity_col} ?
 581     $new_idx{$identity_col} + 1 : 0;
 582
 583 ## Set a client-side conversion error handler, straight from DBD::Sybase docs.
 584 # This ignores any data conversion errors detected by the client side libs, as
 585 # they are usually harmless.
 586   my $orig_cslib_cb = DBD::Sybase::set_cslib_cb(
 587     Sub::Name::subname insert_bulk => sub {
 588       my ($layer, $origin, $severity, $errno, $errmsg, $osmsg, $blkmsg) = @_;
 589
 590       return 1 if $errno == 36;
 591
 592       carp
 593         "Layer: $layer, Origin: $origin, Severity: $severity, Error: $errno" .
 594         ($errmsg ? "\n$errmsg" : '') .
 595         ($osmsg  ? "\n$osmsg"  : '')  .
 596         ($blkmsg ? "\n$blkmsg" : '');
 597
 598       return 0;
 599   });
 600
 601   my $exception;
 602   try {
 603     my $bulk = $self->_bulk_storage;
 604
 605     my $guard = $bulk->txn_scope_guard;
 606
 607 ## XXX get this to work instead of our own $sth
 608 ## will require SQLA or *Hacks changes for ordered columns
 609 #    $bulk->next::method($source, \@source_columns, \@new_data, {
 610 #      syb_bcp_attribs => {
 611 #        identity_flag   => $is_identity_insert,
 612 #        identity_column => $identity_idx,
 613 #      }
 614 #    });
 615     my $sql = 'INSERT INTO ' .
 616       $bulk->sql_maker->_quote($source->name) . ' (' .
 617 # colname list is ignored for BCP, but does no harm
 618       (join ', ', map $bulk->sql_maker->_quote($_), @source_columns) . ') '.
 619       ' VALUES ('.  (join ', ', ('?') x @source_columns) . ')';
 620
 621 ## XXX there's a bug in the DBD::Sybase bulk support that makes $sth->finish for
 622 ## a prepare_cached statement ineffective. Replace with ->sth when fixed, or
 623 ## better yet the version above. Should be fixed in DBD::Sybase .
 624     my $sth = $bulk->_get_dbh->prepare($sql,
 625 #      'insert', # op
 626       {
 627         syb_bcp_attribs => {
 628           identity_flag   => $is_identity_insert,
 629           identity_column => $identity_idx,
 630         }
 631       }
 632     );
 633
 634     my @bind = do {
 635       my $idx = 0;
 636       map [ $_, $idx++ ], @source_columns;
 637     };
 638
 639     $self->_execute_array(
 640       $source, $sth, \@bind, \@source_columns, \@new_data, sub {
 641         $guard->commit
 642       }
 643     );
 644
 645     $bulk->_query_end($sql);
 646   } catch {
 647     $exception = shift;
 648   };
 649
 650   DBD::Sybase::set_cslib_cb($orig_cslib_cb);
 651
 652   if ($exception =~ /-Y option/) {
 653     carp <<"EOF";
 654
 655 Sybase bulk API operation failed due to character set incompatibility, reverting
 656 to regular array inserts:
 657
 658 *** Try unsetting the LANG environment variable.
 659
 660 $exception
 661 EOF
 662     $self->_bulk_storage(undef);
 663     unshift @_, $self;
 664     goto \&insert_bulk;
 665   }
 666   elsif ($exception) {
 667 # rollback makes the bulkLogin connection unusable
 668     $self->_bulk_storage->disconnect;
 669     $self->throw_exception($exception);
 670   }
 671 }
 672
 673 sub _dbh_execute_array {
 674   my ($self, $sth, $tuple_status, $cb) = @_;
 675
 676   my $rv = $self->next::method($sth, $tuple_status);
 677   $cb->() if $cb;
 678
 679   return $rv;
 680 }
 681
 682 # Make sure blobs are not bound as placeholders, and return any non-empty ones
 683 # as a hash.
 684 sub _remove_blob_cols {
 685   my ($self, $source, $fields) = @_;
 686
 687   my %blob_cols;
 688
 689   for my $col (keys %$fields) {
 690     if ($self->_is_lob_column($source, $col)) {
 691       my $blob_val = delete $fields->{$col};
 692       if (not defined $blob_val) {
 693         $fields->{$col} = \'NULL';
 694       }
 695       else {
 696         $fields->{$col} = \"''";
 697         $blob_cols{$col} = $blob_val unless $blob_val eq '';
 698       }
 699     }
 700   }
 701
 702   return %blob_cols ? \%blob_cols : undef;
 703 }
 704
 705 # same for insert_bulk
 706 sub _remove_blob_cols_array {
 707   my ($self, $source, $cols, $data) = @_;
 708
 709   my @blob_cols;
 710
 711   for my $i (0..$#$cols) {
 712     my $col = $cols->[$i];
 713
 714     if ($self->_is_lob_column($source, $col)) {
 715       for my $j (0..$#$data) {
 716         my $blob_val = delete $data->[$j][$i];
 717         if (not defined $blob_val) {
 718           $data->[$j][$i] = \'NULL';
 719         }
 720         else {
 721           $data->[$j][$i] = \"''";
 722           $blob_cols[$j][$i] = $blob_val
 723             unless $blob_val eq '';
 724         }
 725       }
 726     }
 727   }
 728
 729   return @blob_cols ? \@blob_cols : undef;
 730 }
 731
 732 sub _update_blobs {
 733   my ($self, $source, $blob_cols, $where) = @_;
 734
 735   my @primary_cols = try
 736     { $source->_pri_cols }
 737     catch {
 738       $self->throw_exception("Cannot update TEXT/IMAGE column(s): $_")
 739     };
 740
 741 # check if we're updating a single row by PK
 742   my $pk_cols_in_where = 0;
 743   for my $col (@primary_cols) {
 744     $pk_cols_in_where++ if defined $where->{$col};
 745   }
 746   my @rows;
 747
 748   if ($pk_cols_in_where == @primary_cols) {
 749     my %row_to_update;
 750     @row_to_update{@primary_cols} = @{$where}{@primary_cols};
 751     @rows = \%row_to_update;
 752   } else {
 753     my $cursor = $self->select ($source, \@primary_cols, $where, {});
 754     @rows = map {
 755       my %row; @row{@primary_cols} = @$_; \%row
 756     } $cursor->all;
 757   }
 758
 759   for my $row (@rows) {
 760     $self->_insert_blobs($source, $blob_cols, $row);
 761   }
 762 }
 763
 764 sub _insert_blobs {
 765   my ($self, $source, $blob_cols, $row) = @_;
 766   my $dbh = $self->_get_dbh;
 767
 768   my $table = $source->name;
 769
 770   my %row = %$row;
 771   my @primary_cols = try
 772     { $source->_pri_cols }
 773     catch {
 774       $self->throw_exception("Cannot update TEXT/IMAGE column(s): $_")
 775     };
 776
 777   $self->throw_exception('Cannot update TEXT/IMAGE column(s) without primary key values')
 778     if ((grep { defined $row{$_} } @primary_cols) != @primary_cols);
 779
 780   for my $col (keys %$blob_cols) {
 781     my $blob = $blob_cols->{$col};
 782
 783     my %where = map { ($_, $row{$_}) } @primary_cols;
 784
 785     my $cursor = $self->select ($source, [$col], \%where, {});
 786     $cursor->next;
 787     my $sth = $cursor->sth;
 788
 789     if (not $sth) {
 790       $self->throw_exception(
 791           "Could not find row in table '$table' for blob update:\n"
 792         . Data::Dumper::Concise::Dumper (\%where)
 793       );
 794     }
 795
 796     try {
 797       do {
 798         $sth->func('CS_GET', 1, 'ct_data_info') or die $sth->errstr;
 799       } while $sth->fetch;
 800
 801       $sth->func('ct_prepare_send') or die $sth->errstr;
 802
 803       my $log_on_update = $self->_blob_log_on_update;
 804       $log_on_update    = 1 if not defined $log_on_update;
 805
 806       $sth->func('CS_SET', 1, {
 807         total_txtlen => length($blob),
 808         log_on_update => $log_on_update
 809       }, 'ct_data_info') or die $sth->errstr;
 810
 811       $sth->func($blob, length($blob), 'ct_send_data') or die $sth->errstr;
 812
 813       $sth->func('ct_finish_send') or die $sth->errstr;
 814     }
 815     catch {
 816       if ($self->using_freetds) {
 817         $self->throw_exception (
 818           "TEXT/IMAGE operation failed, probably because you are using FreeTDS: $_"
 819         );
 820       }
 821       else {
 822         $self->throw_exception($_);
 823       }
 824     }
 825     finally {
 826       $sth->finish if $sth;
 827     };
 828   }
 829 }
 830
 831 sub _insert_blobs_array {
 832   my ($self, $source, $blob_cols, $cols, $data) = @_;
 833
 834   for my $i (0..$#$data) {
 835     my $datum = $data->[$i];
 836
 837     my %row;
 838     @row{ @$cols } = @$datum;
 839
 840     my %blob_vals;
 841     for my $j (0..$#$cols) {
 842       if (exists $blob_cols->[$i][$j]) {
 843         $blob_vals{ $cols->[$j] } = $blob_cols->[$i][$j];
 844       }
 845     }
 846
 847     $self->_insert_blobs ($source, \%blob_vals, \%row);
 848   }
 849 }
 850
 851 =head2 connect_call_datetime_setup
 852
 853 Used as:
 854
 855   on_connect_call => 'datetime_setup'
 856
 857 In L<connect_info|DBIx::Class::Storage::DBI/connect_info> to set:
 858
 859   $dbh->syb_date_fmt('ISO_strict'); # output fmt: 2004-08-21T14:36:48.080Z
 860   $dbh->do('set dateformat mdy');   # input fmt:  08/13/1979 18:08:55.080
 861
 862 On connection for use with L<DBIx::Class::InflateColumn::DateTime>, using
 863 L<DateTime::Format::Sybase>, which you will need to install.
 864
 865 This works for both C<DATETIME> and C<SMALLDATETIME> columns, although
 866 C<SMALLDATETIME> columns only have minute precision.
 867
 868 =cut
 869
 870 {
 871   my $old_dbd_warned = 0;
 872
 873   sub connect_call_datetime_setup {
 874     my $self = shift;
 875     my $dbh = $self->_get_dbh;
 876
 877     if ($dbh->can('syb_date_fmt')) {
 878       # amazingly, this works with FreeTDS
 879       $dbh->syb_date_fmt('ISO_strict');
 880     } elsif (not $old_dbd_warned) {
 881       carp "Your DBD::Sybase is too old to support ".
 882       "DBIx::Class::InflateColumn::DateTime, please upgrade!";
 883       $old_dbd_warned = 1;
 884     }
 885
 886     $dbh->do('SET DATEFORMAT mdy');
 887
 888     1;
 889   }
 890 }
 891
 892 sub datetime_parser_type { "DateTime::Format::Sybase" }
 893
 894 # ->begin_work and such have no effect with FreeTDS but we run them anyway to
 895 # let the DBD keep any state it needs to.
 896 #
 897 # If they ever do start working, the extra statements will do no harm (because
 898 # Sybase supports nested transactions.)
 899
 900 sub _dbh_begin_work {
 901   my $self = shift;
 902
 903 # bulkLogin=1 connections are always in a transaction, and can only call BEGIN
 904 # TRAN once. However, we need to make sure there's a $dbh.
 905   return if $self->_is_bulk_storage && $self->_dbh && $self->_began_bulk_work;
 906
 907   $self->next::method(@_);
 908
 909   if ($self->using_freetds) {
 910     $self->_get_dbh->do('BEGIN TRAN');
 911   }
 912
 913   $self->_began_bulk_work(1) if $self->_is_bulk_storage;
 914 }
 915
 916 sub _dbh_commit {
 917   my $self = shift;
 918   if ($self->using_freetds) {
 919     $self->_dbh->do('COMMIT');
 920   }
 921   return $self->next::method(@_);
 922 }
 923
 924 sub _dbh_rollback {
 925   my $self = shift;
 926   if ($self->using_freetds) {
 927     $self->_dbh->do('ROLLBACK');
 928   }
 929   return $self->next::method(@_);
 930 }
 931
 932 # savepoint support using ASE syntax
 933
 934 sub _svp_begin {
 935   my ($self, $name) = @_;
 936
 937   $self->_get_dbh->do("SAVE TRANSACTION $name");
 938 }
 939
 940 # A new SAVE TRANSACTION with the same name releases the previous one.
 941 sub _svp_release { 1 }
 942
 943 sub _svp_rollback {
 944   my ($self, $name) = @_;
 945
 946   $self->_get_dbh->do("ROLLBACK TRANSACTION $name");
 947 }
 948
 949 1;
 950
 951 =head1 Schema::Loader Support
 952
 953 As of version C<0.05000>, L<DBIx::Class::Schema::Loader> should work well with
 954 most (if not all) versions of Sybase ASE.
 955
 956 =head1 FreeTDS
 957
 958 This driver supports L<DBD::Sybase> compiled against FreeTDS
 959 (L<http://www.freetds.org/>) to the best of our ability, however it is
 960 recommended that you recompile L<DBD::Sybase> against the Sybase Open Client
 961 libraries. They are a part of the Sybase ASE distribution:
 962
 963 The Open Client FAQ is here:
 964 L<http://www.isug.com/Sybase_FAQ/ASE/section7.html>.
 965
 966 Sybase ASE for Linux (which comes with the Open Client libraries) may be
 967 downloaded here: L<http://response.sybase.com/forms/ASE_Linux_Download>.
 968
 969 To see if you're using FreeTDS check C<< $schema->storage->using_freetds >>, or run:
 970
 971   perl -MDBI -le 'my $dbh = DBI->connect($dsn, $user, $pass); print $dbh->{syb_oc_version}'
 972
 973 Some versions of the libraries involved will not support placeholders, in which
 974 case the storage will be reblessed to
 975 L<DBIx::Class::Storage::DBI::Sybase::ASE::NoBindVars>.
 976
 977 In some configurations, placeholders will work but will throw implicit type
 978 conversion errors for anything that's not expecting a string. In such a case,
 979 the C<auto_cast> option from L<DBIx::Class::Storage::DBI::AutoCast> is
 980 automatically set, which you may enable on connection with
 981 L<DBIx::Class::Storage::DBI::AutoCast/connect_call_set_auto_cast>. The type info
 982 for the C<CAST>s is taken from the L<DBIx::Class::ResultSource/data_type>
 983 definitions in your Result classes, and are mapped to a Sybase type (if it isn't
 984 already) using a mapping based on L<SQL::Translator>.
 985
 986 In other configurations, placeholders will work just as they do with the Sybase
 987 Open Client libraries.
 988
 989 Inserts or updates of TEXT/IMAGE columns will B<NOT> work with FreeTDS.
 990
 991 =head1 INSERTS WITH PLACEHOLDERS
 992
 993 With placeholders enabled, inserts are done in a transaction so that there are
 994 no concurrency issues with getting the inserted identity value using
 995 C<SELECT MAX(col)>, which is the only way to get the C<IDENTITY> value in this
 996 mode.
 997
 998 In addition, they are done on a separate connection so that it's possible to
 999 have active cursors when doing an insert.
1000
1001 When using C<DBIx::Class::Storage::DBI::Sybase::ASE::NoBindVars> transactions
1002 are disabled, as there are no concurrency issues with C<SELECT @@IDENTITY> as
1003 it's a session variable.
1004
1005 =head1 TRANSACTIONS
1006
1007 Due to limitations of the TDS protocol, L<DBD::Sybase>, or both, you cannot
1008 begin a transaction while there are active cursors, nor can you use multiple
1009 active cursors within a transaction. An active cursor is, for example, a
1010 L<ResultSet|DBIx::Class::ResultSet> that has been executed using C<next> or
1011 C<first> but has not been exhausted or L<reset|DBIx::Class::ResultSet/reset>.
1012
1013 For example, this will not work:
1014
1015   $schema->txn_do(sub {
1016     my $rs = $schema->resultset('Book');
1017     while (my $row = $rs->next) {
1018       $schema->resultset('MetaData')->create({
1019         book_id => $row->id,
1020         ...
1021       });
1022     }
1023   });
1024
1025 This won't either:
1026
1027   my $first_row = $large_rs->first;
1028   $schema->txn_do(sub { ... });
1029
1030 Transactions done for inserts in C<AutoCommit> mode when placeholders are in use
1031 are not affected, as they are done on an extra database handle.
1032
1033 Some workarounds:
1034
1035 =over 4
1036
1037 =item * use L<DBIx::Class::Storage::DBI::Replicated>
1038
1039 =item * L<connect|DBIx::Class::Schema/connect> another L<Schema|DBIx::Class::Schema>
1040
1041 =item * load the data from your cursor with L<DBIx::Class::ResultSet/all>
1042
1043 =back
1044
1045 =head1 MAXIMUM CONNECTIONS
1046
1047 The TDS protocol makes separate connections to the server for active statements
1048 in the background. By default the number of such connections is limited to 25,
1049 on both the client side and the server side.
1050
1051 This is a bit too low for a complex L<DBIx::Class> application, so on connection
1052 the client side setting is set to C<256> (see L<DBD::Sybase/maxConnect>.) You
1053 can override it to whatever setting you like in the DSN.
1054
1055 See
1056 L<http://infocenter.sybase.com/help/index.jsp?topic=/com.sybase.help.ase_15.0.sag1/html/sag1/sag1272.htm>
1057 for information on changing the setting on the server side.
1058
1059 =head1 DATES
1060
1061 See L</connect_call_datetime_setup> to setup date formats
1062 for L<DBIx::Class::InflateColumn::DateTime>.
1063
1064 =head1 TEXT/IMAGE COLUMNS
1065
1066 L<DBD::Sybase> compiled with FreeTDS will B<NOT> allow you to insert or update
1067 C<TEXT/IMAGE> columns.
1068
1069 Setting C<< $dbh->{LongReadLen} >> will also not work with FreeTDS use either:
1070
1071   $schema->storage->dbh->do("SET TEXTSIZE $bytes");
1072
1073 or
1074
1075   $schema->storage->set_textsize($bytes);
1076
1077 instead.
1078
1079 However, the C<LongReadLen> you pass in
1080 L<connect_info|DBIx::Class::Storage::DBI/connect_info> is used to execute the
1081 equivalent C<SET TEXTSIZE> command on connection.
1082
1083 See L</connect_call_blob_setup> for a
1084 L<connect_info|DBIx::Class::Storage::DBI/connect_info> setting you need to work
1085 with C<IMAGE> columns.
1086
1087 =head1 BULK API
1088
1089 The experimental L<DBD::Sybase> Bulk API support is used for
1090 L<populate|DBIx::Class::ResultSet/populate> in B<void> context, in a transaction
1091 on a separate connection.
1092
1093 To use this feature effectively, use a large number of rows for each
1094 L<populate|DBIx::Class::ResultSet/populate> call, eg.:
1095
1096   while (my $rows = $data_source->get_100_rows()) {
1097     $rs->populate($rows);
1098   }
1099
1100 B<NOTE:> the L<add_columns|DBIx::Class::ResultSource/add_columns>
1101 calls in your C<Result> classes B<must> list columns in database order for this
1102 to work. Also, you may have to unset the C<LANG> environment variable before
1103 loading your app, if it doesn't match the character set of your database.
1104
1105 When inserting IMAGE columns using this method, you'll need to use
1106 L</connect_call_blob_setup> as well.
1107
1108 =head1 COMPUTED COLUMNS
1109
1110 If you have columns such as:
1111
1112   created_dtm AS getdate()
1113
1114 represent them in your Result classes as:
1115
1116   created_dtm => {
1117     data_type => undef,
1118     default_value => \'getdate()',
1119     is_nullable => 0,
1120   }
1121
1122 The C<data_type> must exist and must be C<undef>. Then empty inserts will work
1123 on tables with such columns.
1124
1125 =head1 TIMESTAMP COLUMNS
1126
1127 C<timestamp> columns in Sybase ASE are not really timestamps, see:
1128 L<http://dba.fyicenter.com/Interview-Questions/SYBASE/The_timestamp_datatype_in_Sybase_.html>.
1129
1130 They should be defined in your Result classes as:
1131
1132   ts => {
1133     data_type => 'timestamp',
1134     is_nullable => 0,
1135     inflate_datetime => 0,
1136   }
1137
1138 The C<<inflate_datetime => 0>> is necessary if you use
1139 L<DBIx::Class::InflateColumn::DateTime>, and most people do, and still want to
1140 be able to read these values.
1141
1142 The values will come back as hexadecimal.
1143
1144 =head1 TODO
1145
1146 =over
1147
1148 =item *
1149
1150 Transitions to AutoCommit=0 (starting a transaction) mode by exhausting
1151 any active cursors, using eager cursors.
1152
1153 =item *
1154
1155 Real limits and limited counts using stored procedures deployed on startup.
1156
1157 =item *
1158
1159 Adaptive Server Anywhere (ASA) support, with possible SQLA::Limit support.
1160
1161 =item *
1162
1163 Blob update with a LIKE query on a blob, without invalidating the WHERE condition.
1164
1165 =item *
1166
1167 bulk_insert using prepare_cached (see comments.)
1168
1169 =back
1170
1171 =head1 AUTHOR
1172
1173 See L<DBIx::Class/CONTRIBUTORS>.
1174
1175 =head1 LICENSE
1176
1177 You may distribute this code under the same terms as Perl itself.
1178
1179 =cut
1180 # vim:sts=2 sw=2: