lib/DBIx/Class/Storage/DBI/Sybase.pm

   1 package DBIx::Class::Storage::DBI::Sybase;
   2
   3 use strict;
   4 use warnings;
   5
   6 use base qw/
   7     DBIx::Class::Storage::DBI::Sybase::Common
   8     DBIx::Class::Storage::DBI::AutoCast
   9 /;
  10 use mro 'c3';
  11 use Carp::Clan qw/^DBIx::Class/;
  12 use List::Util ();
  13 use Sub::Name ();
  14
  15 __PACKAGE__->mk_group_accessors('simple' =>
  16     qw/_identity _blob_log_on_update _writer_storage _is_extra_storage
  17        _bulk_storage _is_bulk_storage _began_bulk_work
  18        _bulk_disabled_due_to_coderef_connect_info_warned
  19        _identity_method/
  20 );
  21
  22 my @also_proxy_to_extra_storages = qw/
  23   connect_call_set_auto_cast auto_cast connect_call_blob_setup
  24   connect_call_datetime_setup
  25
  26   disconnect _connect_info _sql_maker _sql_maker_opts disable_sth_caching
  27   auto_savepoint unsafe cursor_class debug debugobj schema
  28 /;
  29
  30 =head1 NAME
  31
  32 DBIx::Class::Storage::DBI::Sybase - Sybase support for DBIx::Class
  33
  34 =head1 SYNOPSIS
  35
  36 This subclass supports L<DBD::Sybase> for real Sybase databases.  If you are
  37 using an MSSQL database via L<DBD::Sybase>, your storage will be reblessed to
  38 L<DBIx::Class::Storage::DBI::Sybase::Microsoft_SQL_Server>.
  39
  40 =head1 DESCRIPTION
  41
  42 If your version of Sybase does not support placeholders, then your storage
  43 will be reblessed to L<DBIx::Class::Storage::DBI::Sybase::NoBindVars>. You can
  44 also enable that driver explicitly, see the documentation for more details.
  45
  46 With this driver there is unfortunately no way to get the C<last_insert_id>
  47 without doing a C<SELECT MAX(col)>. This is done safely in a transaction
  48 (locking the table.) See L</INSERTS WITH PLACEHOLDERS>.
  49
  50 A recommended L<DBIx::Class::Storage::DBI/connect_info> setting:
  51
  52   on_connect_call => [['datetime_setup'], ['blob_setup', log_on_update => 0]]
  53
  54 =head1 METHODS
  55
  56 =cut
  57
  58 sub _rebless {
  59   my $self = shift;
  60
  61   if (ref($self) eq 'DBIx::Class::Storage::DBI::Sybase') {
  62     my $dbtype = eval {
  63       @{$self->_get_dbh->selectrow_arrayref(qq{sp_server_info \@attribute_id=1})}[2]
  64     } || '';
  65
  66     my $exception = $@;
  67     $dbtype =~ s/\W/_/gi;
  68     my $subclass = "DBIx::Class::Storage::DBI::Sybase::${dbtype}";
  69
  70     if (!$exception && $dbtype && $self->load_optional_class($subclass)) {
  71       bless $self, $subclass;
  72       $self->_rebless;
  73     } else { # real Sybase
  74       my $no_bind_vars = 'DBIx::Class::Storage::DBI::Sybase::NoBindVars';
  75
  76       if ($self->using_freetds) {
  77         carp <<'EOF' unless $ENV{DBIC_SYBASE_FREETDS_NOWARN};
  78
  79 You are using FreeTDS with Sybase.
  80
  81 We will do our best to support this configuration, but please consider this
  82 support experimental.
  83
  84 TEXT/IMAGE columns will definitely not work.
  85
  86 You are encouraged to recompile DBD::Sybase with the Sybase Open Client libraries
  87 instead.
  88
  89 See perldoc DBIx::Class::Storage::DBI::Sybase for more details.
  90
  91 To turn off this warning set the DBIC_SYBASE_FREETDS_NOWARN environment
  92 variable.
  93 EOF
  94         if (not $self->_typeless_placeholders_supported) {
  95           if ($self->_placeholders_supported) {
  96             $self->auto_cast(1);
  97           } else {
  98             $self->ensure_class_loaded($no_bind_vars);
  99             bless $self, $no_bind_vars;
 100             $self->_rebless;
 101           }
 102         }
 103       }
 104       elsif (not $self->_get_dbh->{syb_dynamic_supported}) {
 105         # not necessarily FreeTDS, but no placeholders nevertheless
 106         $self->ensure_class_loaded($no_bind_vars);
 107         bless $self, $no_bind_vars;
 108         $self->_rebless;
 109       } elsif (not $self->_typeless_placeholders_supported) {
 110         # this is highly unlikely, but we check just in case
 111         $self->auto_cast(1);
 112       }
 113     }
 114   }
 115 }
 116
 117 sub _init {
 118   my $self = shift;
 119   $self->_set_max_connect(256);
 120
 121   # based on LongReadLen in connect_info
 122   $self->set_textsize if $self->using_freetds;
 123
 124 # create storage for insert/(update blob) transactions,
 125 # unless this is that storage
 126   return if $self->_is_extra_storage;
 127
 128   my $writer_storage = (ref $self)->new;
 129
 130   $writer_storage->_is_extra_storage(1);
 131   $writer_storage->connect_info($self->connect_info);
 132   $writer_storage->auto_cast($self->auto_cast);
 133
 134   $self->_writer_storage($writer_storage);
 135
 136 # create a bulk storage unless connect_info is a coderef
 137   return
 138     if (Scalar::Util::reftype($self->_dbi_connect_info->[0])||'') eq 'CODE';
 139
 140   my $bulk_storage = (ref $self)->new;
 141
 142   $bulk_storage->_is_extra_storage(1);
 143   $bulk_storage->_is_bulk_storage(1); # for special ->disconnect acrobatics
 144   $bulk_storage->connect_info($self->connect_info);
 145
 146 # this is why
 147   $bulk_storage->_dbi_connect_info->[0] .= ';bulkLogin=1';
 148
 149   $self->_bulk_storage($bulk_storage);
 150 }
 151
 152 for my $method (@also_proxy_to_extra_storages) {
 153   no strict 'refs';
 154   no warnings 'redefine';
 155
 156   my $replaced = __PACKAGE__->can($method);
 157
 158   *{$method} = Sub::Name::subname $method => sub {
 159     my $self = shift;
 160     $self->_writer_storage->$replaced(@_) if $self->_writer_storage;
 161     $self->_bulk_storage->$replaced(@_)   if $self->_bulk_storage;
 162     return $self->$replaced(@_);
 163   };
 164 }
 165
 166 sub disconnect {
 167   my $self = shift;
 168
 169 # Even though we call $sth->finish for uses off the bulk API, there's still an
 170 # "active statement" warning on disconnect, which we throw away here.
 171 # This is due to the bug described in insert_bulk.
 172 # Currently a noop because 'prepare' is used instead of 'prepare_cached'.
 173   local $SIG{__WARN__} = sub {
 174     warn $_[0] unless $_[0] =~ /active statement/i;
 175   } if $self->_is_bulk_storage;
 176
 177 # so that next transaction gets a dbh
 178   $self->_began_bulk_work(0) if $self->_is_bulk_storage;
 179
 180   $self->next::method;
 181 }
 182
 183 # Make sure we have CHAINED mode turned on if AutoCommit is off in non-FreeTDS
 184 # DBD::Sybase (since we don't know how DBD::Sybase was compiled.) If however
 185 # we're using FreeTDS, CHAINED mode turns on an implicit transaction which we
 186 # only want when AutoCommit is off.
 187 sub _populate_dbh {
 188   my $self = shift;
 189
 190   $self->next::method(@_);
 191
 192   if ($self->_is_bulk_storage) {
 193 # this should be cleared on every reconnect
 194     $self->_began_bulk_work(0);
 195     return;
 196   }
 197
 198   if (not $self->using_freetds) {
 199     $self->_dbh->{syb_chained_txn} = 1;
 200   } else {
 201     if ($self->_dbh_autocommit) {
 202       $self->_dbh->do('SET CHAINED OFF');
 203     } else {
 204       $self->_dbh->do('SET CHAINED ON');
 205     }
 206   }
 207 }
 208
 209 =head2 connect_call_blob_setup
 210
 211 Used as:
 212
 213   on_connect_call => [ [ 'blob_setup', log_on_update => 0 ] ]
 214
 215 Does C<< $dbh->{syb_binary_images} = 1; >> to return C<IMAGE> data as raw binary
 216 instead of as a hex string.
 217
 218 Recommended.
 219
 220 Also sets the C<log_on_update> value for blob write operations. The default is
 221 C<1>, but C<0> is better if your database is configured for it.
 222
 223 See
 224 L<DBD::Sybase/Handling_IMAGE/TEXT_data_with_syb_ct_get_data()/syb_ct_send_data()>.
 225
 226 =cut
 227
 228 sub connect_call_blob_setup {
 229   my $self = shift;
 230   my %args = @_;
 231   my $dbh = $self->_dbh;
 232   $dbh->{syb_binary_images} = 1;
 233
 234   $self->_blob_log_on_update($args{log_on_update})
 235     if exists $args{log_on_update};
 236 }
 237
 238 sub _is_lob_type {
 239   my $self = shift;
 240   my $type = shift;
 241   $type && $type =~ /(?:text|image|lob|bytea|binary|memo)/i;
 242 }
 243
 244 sub _is_lob_column {
 245   my ($self, $source, $column) = @_;
 246
 247   return $self->_is_lob_type($source->column_info($column)->{data_type});
 248 }
 249
 250 sub _prep_for_execute {
 251   my $self = shift;
 252   my ($op, $extra_bind, $ident, $args) = @_;
 253
 254   my ($sql, $bind) = $self->next::method (@_);
 255
 256   if ($op eq 'insert') {
 257     my $table = $ident->from;
 258
 259     my $bind_info = $self->_resolve_column_info(
 260       $ident, [map $_->[0], @{$bind}]
 261     );
 262     my $identity_col = List::Util::first
 263       { $bind_info->{$_}{is_auto_increment} }
 264       (keys %$bind_info)
 265     ;
 266
 267     if ($identity_col) {
 268       $sql = join ("\n",
 269         "SET IDENTITY_INSERT $table ON",
 270         $sql,
 271         "SET IDENTITY_INSERT $table OFF",
 272       );
 273     }
 274     else {
 275       $identity_col = List::Util::first
 276         { $ident->column_info($_)->{is_auto_increment} }
 277         $ident->columns
 278       ;
 279     }
 280
 281     if ($identity_col) {
 282       $sql =
 283         "$sql\n" .
 284         $self->_fetch_identity_sql($ident, $identity_col);
 285     }
 286   }
 287
 288   return ($sql, $bind);
 289 }
 290
 291 # Stolen from SQLT, with some modifications. This is a makeshift
 292 # solution before a sane type-mapping library is available, thus
 293 # the 'our' for easy overrides.
 294 our %TYPE_MAPPING  = (
 295     number    => 'numeric',
 296     money     => 'money',
 297     varchar   => 'varchar',
 298     varchar2  => 'varchar',
 299     timestamp => 'datetime',
 300     text      => 'varchar',
 301     real      => 'double precision',
 302     comment   => 'text',
 303     bit       => 'bit',
 304     tinyint   => 'smallint',
 305     float     => 'double precision',
 306     serial    => 'numeric',
 307     bigserial => 'numeric',
 308     boolean   => 'varchar',
 309     long      => 'varchar',
 310 );
 311
 312 sub _native_data_type {
 313   my ($self, $type) = @_;
 314
 315   $type = lc $type;
 316   $type =~ s/\s* identity//x;
 317
 318   return uc($TYPE_MAPPING{$type} || $type);
 319 }
 320
 321 sub _fetch_identity_sql {
 322   my ($self, $source, $col) = @_;
 323
 324   return sprintf ("SELECT MAX(%s) FROM %s",
 325     map { $self->sql_maker->_quote ($_) } ($col, $source->from)
 326   );
 327 }
 328
 329 sub _execute {
 330   my $self = shift;
 331   my ($op) = @_;
 332
 333   my ($rv, $sth, @bind) = $self->dbh_do($self->can('_dbh_execute'), @_);
 334
 335   if ($op eq 'insert') {
 336     $self->_identity($sth->fetchrow_array);
 337     $sth->finish;
 338   }
 339
 340   return wantarray ? ($rv, $sth, @bind) : $rv;
 341 }
 342
 343 sub last_insert_id { shift->_identity }
 344
 345 # handles TEXT/IMAGE and transaction for last_insert_id
 346 sub insert {
 347   my $self = shift;
 348   my ($source, $to_insert) = @_;
 349
 350   my $blob_cols = $self->_remove_blob_cols($source, $to_insert);
 351
 352   my $identity_col = List::Util::first
 353     { $source->column_info($_)->{is_auto_increment} }
 354     $source->columns;
 355
 356   # do we need the horrific SELECT MAX(COL) hack?
 357   my $dumb_last_insert_id =
 358        $identity_col
 359     && (not exists $to_insert->{$identity_col})
 360     && ($self->_identity_method||'') ne '@@IDENTITY';
 361
 362   my $next = $self->next::can;
 363
 364   # we are already in a transaction, or there are no blobs
 365   # and we don't need the PK - just (try to) do it
 366   if ($self->{transaction_depth}
 367         || (!$blob_cols && !$dumb_last_insert_id)
 368   ) {
 369     return $self->_insert (
 370       $next, $source, $to_insert, $blob_cols, $identity_col
 371     );
 372   }
 373
 374   # otherwise use the _writer_storage to do the insert+transaction on another
 375   # connection
 376   my $guard = $self->_writer_storage->txn_scope_guard;
 377
 378   my $updated_cols = $self->_writer_storage->_insert (
 379     $next, $source, $to_insert, $blob_cols, $identity_col
 380   );
 381
 382   $self->_identity($self->_writer_storage->_identity);
 383
 384   $guard->commit;
 385
 386   return $updated_cols;
 387 }
 388
 389 sub _insert {
 390   my ($self, $next, $source, $to_insert, $blob_cols, $identity_col) = @_;
 391
 392   my $updated_cols = $self->$next ($source, $to_insert);
 393
 394   my $final_row = {
 395     $identity_col => $self->last_insert_id($source, $identity_col),
 396     %$to_insert,
 397     %$updated_cols,
 398   };
 399
 400   $self->_insert_blobs ($source, $blob_cols, $final_row) if $blob_cols;
 401
 402   return $updated_cols;
 403 }
 404
 405 sub update {
 406   my $self = shift;
 407   my ($source, $fields, $where, @rest) = @_;
 408
 409   my $wantarray = wantarray;
 410
 411   my $blob_cols = $self->_remove_blob_cols($source, $fields);
 412
 413   my $table = $source->name;
 414
 415   my $identity_col = List::Util::first
 416     { $source->column_info($_)->{is_auto_increment} }
 417     $source->columns;
 418
 419   my $is_identity_update = $identity_col && defined $fields->{$identity_col};
 420
 421   if (not $blob_cols) {
 422     $self->_set_identity_insert($table, 'update')   if $is_identity_update;
 423     return $self->next::method(@_);
 424     $self->_unset_identity_insert($table, 'update') if $is_identity_update;
 425   }
 426
 427 # check that we're not updating a blob column that's also in $where
 428   for my $blob (grep $self->_is_lob_column($source, $_), $source->columns) {
 429     if (exists $where->{$blob} && exists $fields->{$blob}) {
 430       croak
 431 'Update of TEXT/IMAGE column that is also in search condition impossible';
 432     }
 433   }
 434
 435 # update+blob update(s) done atomically on separate connection
 436   $self = $self->_writer_storage;
 437
 438   my $guard = $self->txn_scope_guard;
 439
 440 # First update the blob columns to be updated to '' (taken from $fields, where
 441 # it is originally put by _remove_blob_cols .)
 442   my %blobs_to_empty = map { ($_ => delete $fields->{$_}) } keys %$blob_cols;
 443
 444   $self->next::method($source, \%blobs_to_empty, $where, @rest);
 445
 446 # Now update the blobs before the other columns in case the update of other
 447 # columns makes the search condition invalid.
 448   $self->_update_blobs($source, $blob_cols, $where);
 449
 450   my @res;
 451   if (%$fields) {
 452     $self->_set_identity_insert($table, 'update')   if $is_identity_update;
 453
 454     if ($wantarray) {
 455       @res    = $self->next::method(@_);
 456     }
 457     elsif (defined $wantarray) {
 458       $res[0] = $self->next::method(@_);
 459     }
 460     else {
 461       $self->next::method(@_);
 462     }
 463
 464     $self->_unset_identity_insert($table, 'update') if $is_identity_update;
 465   }
 466
 467   $guard->commit;
 468
 469   return $wantarray ? @res : $res[0];
 470 }
 471
 472 ### the insert_bulk partially stolen from DBI/MSSQL.pm
 473
 474 sub _set_identity_insert {
 475   my ($self, $table, $op) = @_;
 476
 477   my $sql = sprintf (
 478     'SET IDENTITY_%s %s ON',
 479     (uc($op) || 'INSERT'),
 480     $self->sql_maker->_quote ($table),
 481   );
 482
 483   $self->_query_start($sql);
 484
 485   my $dbh = $self->_get_dbh;
 486   eval { $dbh->do ($sql) };
 487   my $exception = $@;
 488
 489   $self->_query_end($sql);
 490
 491   if ($exception) {
 492     $self->throw_exception (sprintf "Error executing '%s': %s",
 493       $sql,
 494       $dbh->errstr,
 495     );
 496   }
 497 }
 498
 499 sub _unset_identity_insert {
 500   my ($self, $table, $op) = @_;
 501
 502   my $sql = sprintf (
 503     'SET IDENTITY_%s %s OFF',
 504     (uc($op) || 'INSERT'),
 505     $self->sql_maker->_quote ($table),
 506   );
 507
 508   $self->_query_start($sql);
 509
 510   my $dbh = $self->_get_dbh;
 511   $dbh->do ($sql);
 512
 513   $self->_query_end($sql);
 514 }
 515
 516 # for tests
 517 sub _can_insert_bulk { 1 }
 518
 519 sub insert_bulk {
 520   my $self = shift;
 521   my ($source, $cols, $data) = @_;
 522
 523   my $is_identity_insert = (List::Util::first
 524     { $source->column_info ($_)->{is_auto_increment} } @{$cols}
 525   ) ? 1 : 0;
 526
 527   my @source_columns = $source->columns;
 528
 529   my $use_bulk_api =
 530     $self->_bulk_storage &&
 531     $self->_get_dbh->{syb_has_blk};
 532
 533   if ((not $use_bulk_api) &&
 534       (Scalar::Util::reftype($self->_dbi_connect_info->[0])||'') eq 'CODE' &&
 535       (not $self->_bulk_disabled_due_to_coderef_connect_info_warned)) {
 536     carp <<'EOF';
 537 Bulk API support disabled due to use of a CODEREF connect_info. Reverting to
 538 array inserts.
 539 EOF
 540     $self->_bulk_disabled_due_to_coderef_connect_info_warned(1);
 541   }
 542
 543   if (not $use_bulk_api) {
 544     if ($is_identity_insert) {
 545        $self->_set_identity_insert ($source->name);
 546     }
 547
 548     $self->next::method(@_);
 549
 550     if ($is_identity_insert) {
 551        $self->_unset_identity_insert ($source->name);
 552     }
 553
 554     return;
 555   }
 556
 557 # otherwise, use the bulk API
 558
 559 # rearrange @$data so that columns are in database order
 560   my %orig_idx;
 561   @orig_idx{@$cols} = 0..$#$cols;
 562
 563   my %new_idx;
 564   @new_idx{@source_columns} = 0..$#source_columns;
 565
 566   my @new_data;
 567   for my $datum (@$data) {
 568     my $new_datum = [];
 569     for my $col (@source_columns) {
 570 # identity data will be 'undef' if not $is_identity_insert
 571 # columns with defaults will also be 'undef'
 572       $new_datum->[ $new_idx{$col} ] =
 573         exists $orig_idx{$col} ? $datum->[ $orig_idx{$col} ] : undef;
 574     }
 575     push @new_data, $new_datum;
 576   }
 577
 578   my $identity_col = List::Util::first
 579     { $source->column_info($_)->{is_auto_increment} } @source_columns;
 580
 581 # bcp identity index is 1-based
 582   my $identity_idx = exists $new_idx{$identity_col} ?
 583     $new_idx{$identity_col} + 1 : 0;
 584
 585 ## Set a client-side conversion error handler, straight from DBD::Sybase docs.
 586 # This ignores any data conversion errors detected by the client side libs, as
 587 # they are usually harmless.
 588   my $orig_cslib_cb = DBD::Sybase::set_cslib_cb(
 589     Sub::Name::subname insert_bulk => sub {
 590       my ($layer, $origin, $severity, $errno, $errmsg, $osmsg, $blkmsg) = @_;
 591
 592       return 1 if $errno == 36;
 593
 594       carp
 595         "Layer: $layer, Origin: $origin, Severity: $severity, Error: $errno" .
 596         ($errmsg ? "\n$errmsg" : '') .
 597         ($osmsg  ? "\n$osmsg"  : '')  .
 598         ($blkmsg ? "\n$blkmsg" : '');
 599
 600       return 0;
 601   });
 602
 603   eval {
 604     my $bulk = $self->_bulk_storage;
 605
 606     my $guard = $bulk->txn_scope_guard;
 607
 608 ## XXX get this to work instead of our own $sth
 609 ## will require SQLA or *Hacks changes for ordered columns
 610 #    $bulk->next::method($source, \@source_columns, \@new_data, {
 611 #      syb_bcp_attribs => {
 612 #        identity_flag   => $is_identity_insert,
 613 #        identity_column => $identity_idx,
 614 #      }
 615 #    });
 616     my $sql = 'INSERT INTO ' .
 617       $bulk->sql_maker->_quote($source->name) . ' (' .
 618 # colname list is ignored for BCP, but does no harm
 619       (join ', ', map $bulk->sql_maker->_quote($_), @source_columns) . ') '.
 620       ' VALUES ('.  (join ', ', ('?') x @source_columns) . ')';
 621
 622 ## XXX there's a bug in the DBD::Sybase bulk support that makes $sth->finish for
 623 ## a prepare_cached statement ineffective. Replace with ->sth when fixed, or
 624 ## better yet the version above. Should be fixed in DBD::Sybase .
 625     my $sth = $bulk->_get_dbh->prepare($sql,
 626 #      'insert', # op
 627       {
 628         syb_bcp_attribs => {
 629           identity_flag   => $is_identity_insert,
 630           identity_column => $identity_idx,
 631         }
 632       }
 633     );
 634
 635     my $bind_attributes = $self->source_bind_attributes($source);
 636
 637     foreach my $slice_idx (0..$#source_columns) {
 638       my $col = $source_columns[$slice_idx];
 639
 640       my $attributes = $bind_attributes->{$col}
 641         if $bind_attributes && defined $bind_attributes->{$col};
 642
 643       my @slice = map $_->[$slice_idx], @new_data;
 644
 645       $sth->bind_param_array(($slice_idx + 1), \@slice, $attributes);
 646     }
 647
 648     $bulk->_query_start($sql);
 649
 650 # this is stolen from DBI::insert_bulk
 651     my $tuple_status = [];
 652     my $rv = eval { $sth->execute_array({ArrayTupleStatus => $tuple_status}) };
 653
 654     if (my $err = $@ || $sth->errstr) {
 655       my $i = 0;
 656       ++$i while $i <= $#$tuple_status && !ref $tuple_status->[$i];
 657
 658       $self->throw_exception("Unexpected populate error: $err")
 659         if ($i > $#$tuple_status);
 660
 661       require Data::Dumper;
 662       local $Data::Dumper::Terse = 1;
 663       local $Data::Dumper::Indent = 1;
 664       local $Data::Dumper::Useqq = 1;
 665       local $Data::Dumper::Quotekeys = 0;
 666       local $Data::Dumper::Sortkeys = 1;
 667
 668       $self->throw_exception(sprintf "%s for populate slice:\n%s",
 669         ($tuple_status->[$i][1] || $err),
 670         Data::Dumper::Dumper(
 671           { map { $source_columns[$_] => $new_data[$i][$_] } (0 .. $#$cols) }
 672         ),
 673       );
 674     }
 675
 676     $guard->commit;
 677     $sth->finish;
 678
 679     $bulk->_query_end($sql);
 680   };
 681   my $exception = $@;
 682   if ($exception =~ /-Y option/) {
 683     carp <<"EOF";
 684
 685 Sybase bulk API operation failed due to character set incompatibility, reverting
 686 to regular array inserts:
 687
 688 *** Try unsetting the LANG environment variable.
 689
 690 $@
 691 EOF
 692     $self->_bulk_storage(undef);
 693     DBD::Sybase::set_cslib_cb($orig_cslib_cb);
 694     unshift @_, $self;
 695     goto \&insert_bulk;
 696   }
 697   elsif ($exception) {
 698     DBD::Sybase::set_cslib_cb($orig_cslib_cb);
 699 # rollback makes the bulkLogin connection unusable
 700     $self->_bulk_storage->disconnect;
 701     $self->throw_exception($exception);
 702   }
 703
 704   DBD::Sybase::set_cslib_cb($orig_cslib_cb);
 705 }
 706
 707 # Make sure blobs are not bound as placeholders, and return any non-empty ones
 708 # as a hash.
 709 sub _remove_blob_cols {
 710   my ($self, $source, $fields) = @_;
 711
 712   my %blob_cols;
 713
 714   for my $col (keys %$fields) {
 715     if ($self->_is_lob_type($source->column_info($col)->{data_type})) {
 716       my $blob_val = delete $fields->{$col};
 717       if (not defined $blob_val) {
 718         $fields->{$col} = \'NULL';
 719       }
 720       else {
 721         $fields->{$col} = \"''";
 722         $blob_cols{$col} = $blob_val unless $blob_val eq '';
 723       }
 724     }
 725   }
 726
 727   return keys %blob_cols ? \%blob_cols : undef;
 728 }
 729
 730 sub _update_blobs {
 731   my ($self, $source, $blob_cols, $where) = @_;
 732
 733   my (@primary_cols) = $source->primary_columns;
 734
 735   croak "Cannot update TEXT/IMAGE column(s) without a primary key"
 736     unless @primary_cols;
 737
 738 # check if we're updating a single row by PK
 739   my $pk_cols_in_where = 0;
 740   for my $col (@primary_cols) {
 741     $pk_cols_in_where++ if defined $where->{$col};
 742   }
 743   my @rows;
 744
 745   if ($pk_cols_in_where == @primary_cols) {
 746     my %row_to_update;
 747     @row_to_update{@primary_cols} = @{$where}{@primary_cols};
 748     @rows = \%row_to_update;
 749   } else {
 750     my $cursor = $self->select ($source, \@primary_cols, $where, {});
 751     @rows = map {
 752       my %row; @row{@primary_cols} = @$_; \%row
 753     } $cursor->all;
 754   }
 755
 756   for my $row (@rows) {
 757     $self->_insert_blobs($source, $blob_cols, $row);
 758   }
 759 }
 760
 761 sub _insert_blobs {
 762   my ($self, $source, $blob_cols, $row) = @_;
 763   my $dbh = $self->_get_dbh;
 764
 765   my $table = $source->name;
 766
 767   my %row = %$row;
 768   my (@primary_cols) = $source->primary_columns;
 769
 770   croak "Cannot update TEXT/IMAGE column(s) without a primary key"
 771     unless @primary_cols;
 772
 773   if ((grep { defined $row{$_} } @primary_cols) != @primary_cols) {
 774     croak "Cannot update TEXT/IMAGE column(s) without primary key values";
 775   }
 776
 777   for my $col (keys %$blob_cols) {
 778     my $blob = $blob_cols->{$col};
 779
 780     my %where = map { ($_, $row{$_}) } @primary_cols;
 781
 782     my $cursor = $self->select ($source, [$col], \%where, {});
 783     $cursor->next;
 784     my $sth = $cursor->sth;
 785
 786     if (not $sth) {
 787       require Data::Dumper;
 788       local $Data::Dumper::Terse = 1;
 789       local $Data::Dumper::Indent = 1;
 790       local $Data::Dumper::Useqq = 1;
 791       local $Data::Dumper::Quotekeys = 0;
 792       local $Data::Dumper::Sortkeys = 1;
 793
 794       croak "\nCould not find row in table '$table' for blob update:\n".
 795         Data::Dumper::Dumper(\%where)."\n";
 796     }
 797
 798     eval {
 799       do {
 800         $sth->func('CS_GET', 1, 'ct_data_info') or die $sth->errstr;
 801       } while $sth->fetch;
 802
 803       $sth->func('ct_prepare_send') or die $sth->errstr;
 804
 805       my $log_on_update = $self->_blob_log_on_update;
 806       $log_on_update    = 1 if not defined $log_on_update;
 807
 808       $sth->func('CS_SET', 1, {
 809         total_txtlen => length($blob),
 810         log_on_update => $log_on_update
 811       }, 'ct_data_info') or die $sth->errstr;
 812
 813       $sth->func($blob, length($blob), 'ct_send_data') or die $sth->errstr;
 814
 815       $sth->func('ct_finish_send') or die $sth->errstr;
 816     };
 817     my $exception = $@;
 818     $sth->finish if $sth;
 819     if ($exception) {
 820       if ($self->using_freetds) {
 821         croak (
 822           'TEXT/IMAGE operation failed, probably because you are using FreeTDS: '
 823           . $exception
 824         );
 825       } else {
 826         croak $exception;
 827       }
 828     }
 829   }
 830 }
 831
 832 =head2 connect_call_datetime_setup
 833
 834 Used as:
 835
 836   on_connect_call => 'datetime_setup'
 837
 838 In L<DBIx::Class::Storage::DBI/connect_info> to set:
 839
 840   $dbh->syb_date_fmt('ISO_strict'); # output fmt: 2004-08-21T14:36:48.080Z
 841   $dbh->do('set dateformat mdy');   # input fmt:  08/13/1979 18:08:55.080
 842
 843 On connection for use with L<DBIx::Class::InflateColumn::DateTime>, using
 844 L<DateTime::Format::Sybase>, which you will need to install.
 845
 846 This works for both C<DATETIME> and C<SMALLDATETIME> columns, although
 847 C<SMALLDATETIME> columns only have minute precision.
 848
 849 =cut
 850
 851 {
 852   my $old_dbd_warned = 0;
 853
 854   sub connect_call_datetime_setup {
 855     my $self = shift;
 856     my $dbh = $self->_dbh;
 857
 858     if ($dbh->can('syb_date_fmt')) {
 859       # amazingly, this works with FreeTDS
 860       $dbh->syb_date_fmt('ISO_strict');
 861     } elsif (not $old_dbd_warned) {
 862       carp "Your DBD::Sybase is too old to support ".
 863       "DBIx::Class::InflateColumn::DateTime, please upgrade!";
 864       $old_dbd_warned = 1;
 865     }
 866
 867     $dbh->do('SET DATEFORMAT mdy');
 868
 869     1;
 870   }
 871 }
 872
 873 sub datetime_parser_type { "DateTime::Format::Sybase" }
 874
 875 # ->begin_work and such have no effect with FreeTDS but we run them anyway to
 876 # let the DBD keep any state it needs to.
 877 #
 878 # If they ever do start working, the extra statements will do no harm (because
 879 # Sybase supports nested transactions.)
 880
 881 sub _dbh_begin_work {
 882   my $self = shift;
 883
 884 # bulkLogin=1 connections are always in a transaction, and can only call BEGIN
 885 # TRAN once. However, we need to make sure there's a $dbh.
 886   return if $self->_is_bulk_storage && $self->_dbh && $self->_began_bulk_work;
 887
 888   $self->next::method(@_);
 889
 890   if ($self->using_freetds) {
 891     $self->_get_dbh->do('BEGIN TRAN');
 892   }
 893
 894   $self->_began_bulk_work(1) if $self->_is_bulk_storage;
 895 }
 896
 897 sub _dbh_commit {
 898   my $self = shift;
 899   if ($self->using_freetds) {
 900     $self->_dbh->do('COMMIT');
 901   }
 902   return $self->next::method(@_);
 903 }
 904
 905 sub _dbh_rollback {
 906   my $self = shift;
 907   if ($self->using_freetds) {
 908     $self->_dbh->do('ROLLBACK');
 909   }
 910   return $self->next::method(@_);
 911 }
 912
 913 # savepoint support using ASE syntax
 914
 915 sub _svp_begin {
 916   my ($self, $name) = @_;
 917
 918   $self->_get_dbh->do("SAVE TRANSACTION $name");
 919 }
 920
 921 # A new SAVE TRANSACTION with the same name releases the previous one.
 922 sub _svp_release { 1 }
 923
 924 sub _svp_rollback {
 925   my ($self, $name) = @_;
 926
 927   $self->_get_dbh->do("ROLLBACK TRANSACTION $name");
 928 }
 929
 930 1;
 931
 932 =head1 Schema::Loader Support
 933
 934 There is an experimental branch of L<DBIx::Class::Schema::Loader> that will
 935 allow you to dump a schema from most (if not all) versions of Sybase.
 936
 937 It is available via subversion from:
 938
 939   http://dev.catalyst.perl.org/repos/bast/branches/DBIx-Class-Schema-Loader/current/
 940
 941 =head1 FreeTDS
 942
 943 This driver supports L<DBD::Sybase> compiled against FreeTDS
 944 (L<http://www.freetds.org/>) to the best of our ability, however it is
 945 recommended that you recompile L<DBD::Sybase> against the Sybase Open Client
 946 libraries. They are a part of the Sybase ASE distribution:
 947
 948 The Open Client FAQ is here:
 949 L<http://www.isug.com/Sybase_FAQ/ASE/section7.html>.
 950
 951 Sybase ASE for Linux (which comes with the Open Client libraries) may be
 952 downloaded here: L<http://response.sybase.com/forms/ASE_Linux_Download>.
 953
 954 To see if you're using FreeTDS check C<< $schema->storage->using_freetds >>, or run:
 955
 956   perl -MDBI -le 'my $dbh = DBI->connect($dsn, $user, $pass); print $dbh->{syb_oc_version}'
 957
 958 Some versions of the libraries involved will not support placeholders, in which
 959 case the storage will be reblessed to
 960 L<DBIx::Class::Storage::DBI::Sybase::NoBindVars>.
 961
 962 In some configurations, placeholders will work but will throw implicit type
 963 conversion errors for anything that's not expecting a string. In such a case,
 964 the C<auto_cast> option from L<DBIx::Class::Storage::DBI::AutoCast> is
 965 automatically set, which you may enable on connection with
 966 L<DBIx::Class::Storage::DBI::AutoCast/connect_call_set_auto_cast>. The type info
 967 for the C<CAST>s is taken from the L<DBIx::Class::ResultSource/data_type>
 968 definitions in your Result classes, and are mapped to a Sybase type (if it isn't
 969 already) using a mapping based on L<SQL::Translator>.
 970
 971 In other configurations, placeholers will work just as they do with the Sybase
 972 Open Client libraries.
 973
 974 Inserts or updates of TEXT/IMAGE columns will B<NOT> work with FreeTDS.
 975
 976 =head1 INSERTS WITH PLACEHOLDERS
 977
 978 With placeholders enabled, inserts are done in a transaction so that there are
 979 no concurrency issues with getting the inserted identity value using
 980 C<SELECT MAX(col)>, which is the only way to get the C<IDENTITY> value in this
 981 mode.
 982
 983 In addition, they are done on a separate connection so that it's possible to
 984 have active cursors when doing an insert.
 985
 986 When using C<DBIx::Class::Storage::DBI::Sybase::NoBindVars> transactions are
 987 disabled, as there are no concurrency issues with C<SELECT @@IDENTITY> as it's a
 988 session variable.
 989
 990 =head1 TRANSACTIONS
 991
 992 Due to limitations of the TDS protocol, L<DBD::Sybase>, or both; you cannot
 993 begin a transaction while there are active cursors. An active cursor is, for
 994 example, a L<ResultSet|DBIx::Class::ResultSet> that has been executed using
 995 C<next> or C<first> but has not been exhausted or
 996 L<reset|DBIx::Class::ResultSet/reset>.
 997
 998 For example, this will not work:
 999
1000   $schema->txn_do(sub {
1001     my $rs = $schema->resultset('Book');
1002     while (my $row = $rs->next) {
1003       $schema->resultset('MetaData')->create({
1004         book_id => $row->id,
1005         ...
1006       });
1007     }
1008   });
1009
1010 Transactions done for inserts in C<AutoCommit> mode when placeholders are in use
1011 are not affected, as they are done on an extra database handle.
1012
1013 Some workarounds:
1014
1015 =over 4
1016
1017 =item * use L<DBIx::Class::Storage::DBI::Replicated>
1018
1019 =item * L<connect|DBIx::Class::Schema/connect> another L<Schema|DBIx::Class::Schema>
1020
1021 =item * load the data from your cursor with L<DBIx::Class::ResultSet/all>
1022
1023 =back
1024
1025 =head1 MAXIMUM CONNECTIONS
1026
1027 The TDS protocol makes separate connections to the server for active statements
1028 in the background. By default the number of such connections is limited to 25,
1029 on both the client side and the server side.
1030
1031 This is a bit too low for a complex L<DBIx::Class> application, so on connection
1032 the client side setting is set to C<256> (see L<DBD::Sybase/maxConnect>.) You
1033 can override it to whatever setting you like in the DSN.
1034
1035 See
1036 L<http://infocenter.sybase.com/help/index.jsp?topic=/com.sybase.help.ase_15.0.sag1/html/sag1/sag1272.htm>
1037 for information on changing the setting on the server side.
1038
1039 =head1 DATES
1040
1041 See L</connect_call_datetime_setup> to setup date formats
1042 for L<DBIx::Class::InflateColumn::DateTime>.
1043
1044 =head1 TEXT/IMAGE COLUMNS
1045
1046 L<DBD::Sybase> compiled with FreeTDS will B<NOT> allow you to insert or update
1047 C<TEXT/IMAGE> columns.
1048
1049 Setting C<< $dbh->{LongReadLen} >> will also not work with FreeTDS use either:
1050
1051   $schema->storage->dbh->do("SET TEXTSIZE $bytes");
1052
1053 or
1054
1055   $schema->storage->set_textsize($bytes);
1056
1057 instead.
1058
1059 However, the C<LongReadLen> you pass in
1060 L<DBIx::Class::Storage::DBI/connect_info> is used to execute the equivalent
1061 C<SET TEXTSIZE> command on connection.
1062
1063 See L</connect_call_blob_setup> for a L<DBIx::Class::Storage::DBI/connect_info>
1064 setting you need to work with C<IMAGE> columns.
1065
1066 =head1 BULK API
1067
1068 The experimental L<DBD::Sybase> Bulk API support is used for
1069 L<populate|DBIx::Class::ResultSet/populate> in B<void> context, in a transaction
1070 on a separate connection.
1071
1072 To use this feature effectively, use a large number of rows for each
1073 L<populate|DBIx::Class::ResultSet/populate> call, eg.:
1074
1075   while (my $rows = $data_source->get_100_rows()) {
1076     $rs->populate($rows);
1077   }
1078
1079 B<NOTE:> the L<add_columns|DBIx::Class::ResultSource/add_columns>
1080 calls in your C<Result> classes B<must> list columns in database order for this
1081 to work. Also, you may have to unset the C<LANG> environment variable before
1082 loading your app, if it doesn't match the character set of your database.
1083
1084 When inserting IMAGE columns using this method, you'll need to use
1085 L</connect_call_blob_setup> as well.
1086
1087 =head1 AUTHOR
1088
1089 See L<DBIx::Class/CONTRIBUTORS>.
1090
1091 =head1 LICENSE
1092
1093 You may distribute this code under the same terms as Perl itself.
1094
1095 =cut
1096 # vim:sts=2 sw=2: