lib/DBIx/Class/Storage/DBI/Sybase.pm

   1 package DBIx::Class::Storage::DBI::Sybase;
   2
   3 use strict;
   4 use warnings;
   5
   6 use Class::C3;
   7 use base qw/DBIx::Class::Storage::DBI/;
   8
   9 use Carp::Clan qw/^DBIx::Class/;
  10
  11 sub _rebless {
  12   my $self = shift;
  13
  14   if (ref($self) eq 'DBIx::Class::Storage::DBI::Sybase') {
  15     my $dbtype = eval {
  16       @{$self->dbh->selectrow_arrayref(qq{sp_server_info \@attribute_id=1})}[2]
  17     } || '';
  18
  19     my $exception = $@;
  20     $dbtype =~ s/\W/_/gi;
  21     my $subclass = "DBIx::Class::Storage::DBI::Sybase::${dbtype}";
  22
  23     if (!$exception && $dbtype && $self->load_optional_class($subclass)) {
  24       bless $self, $subclass;
  25       $self->_rebless;
  26     } else {
  27       # real Sybase
  28       if (not $self->dbh->{syb_dynamic_supported}) {
  29         bless $self, 'DBIx::Class::Storage:DBI::Sybase::NoBindVars';
  30         $self->_rebless;
  31       }
  32       $self->_init_date_fmt;
  33     }
  34   }
  35 }
  36
  37 sub _populate_dbh {
  38   my $self = shift;
  39   $self->next::method(@_);
  40   $self->_init_date_fmt;
  41   1;
  42 }
  43
  44 {
  45   my $old_dbd_warned = 0;
  46
  47   sub _init_date_fmt {
  48     my $self = shift;
  49     my $dbh = $self->_dbh;
  50
  51     if ($dbh->can('syb_date_fmt')) {
  52       $dbh->syb_date_fmt('ISO_strict');
  53     } elsif (not $old_dbd_warned) {
  54       carp "Your DBD::Sybase is too old to support ".
  55       "DBIx::Class::InflateColumn::DateTime, please upgrade!";
  56       $old_dbd_warned = 1;
  57     }
  58
  59     $dbh->do('set dateformat mdy');
  60
  61     1;
  62   }
  63 }
  64
  65 sub _dbh_last_insert_id {
  66   my ($self, $dbh, $source, $col) = @_;
  67
  68   # sorry, there's no other way!
  69   my $sth = $dbh->prepare_cached("select max($col) from ".$source->from);
  70   return ($dbh->selectrow_array($sth))[0];
  71 }
  72
  73 sub count {
  74   my $self = shift;
  75   my ($source, $attrs) = @_;
  76
  77   if (not exists $attrs->{rows}) {
  78     return $self->next::method(@_);
  79   }
  80
  81   my $offset = $attrs->{offset} || 0;
  82   my $total  = $attrs->{rows} + $offset;
  83
  84   my $new_attrs = $self->_copy_attributes_for_count($source, $attrs);
  85
  86   my $first_pk = ($source->primary_columns)[0];
  87
  88   $new_attrs->{select} = $first_pk ? "me.$first_pk" : 1;
  89
  90   my $tmp_rs = $source->resultset_class->new($source, $new_attrs);
  91
  92   $self->dbh->{syb_rowcount} = $total;
  93
  94   my $count = 0;
  95   $count++ while $tmp_rs->cursor->next;
  96
  97   $self->dbh->{syb_rowcount} = 0;
  98
  99   return $count - $offset;
 100 }
 101
 102 sub datetime_parser_type { "DateTime::Format::Sybase" }
 103
 104 1;
 105
 106 =head1 NAME
 107
 108 DBIx::Class::Storage::DBI::Sybase - Storage::DBI subclass for Sybase
 109
 110 =head1 SYNOPSIS
 111
 112 This subclass supports L<DBD::Sybase> for real Sybase databases.  If you are
 113 using an MSSQL database via L<DBD::Sybase>, your storage will be reblessed to
 114 L<DBIx::Class::Storage::DBI::Sybase::Microsoft_SQL_Server>.
 115
 116 =head1 DESCRIPTION
 117
 118 If your version of Sybase does not support placeholders, then your storage
 119 will be reblessed to L<DBIx::Class::Storage::DBI::Sybase::NoBindVars>. You can
 120 also enable that driver explicitly, see the documentation for more details.
 121
 122 With this driver there is unfortunately no way to get the C<last_insert_id>
 123 without doing a C<select max(col)>.
 124
 125 But your queries will be cached.
 126
 127 =head1 DATES
 128
 129 On connection C<syb_date_fmt> is set to C<ISO_strict>, e.g.:
 130 C<2004-08-21T14:36:48.080Z> and C<dateformat> is set to C<mdy>, e.g.:
 131 C<08/13/1979 18:08:55.080>.
 132
 133 This works for both C<DATETIME> and C<SMALLDATETIME> columns, although
 134 C<SMALLDATETIME> columns only have minute precision.
 135
 136 You will need the L<DateTime::Format::Sybase> module if you are going to use
 137 L<DBIx::Class::InflateColumn::DateTime>.
 138
 139 =head1 AUTHORS
 140
 141 See L<DBIx::Class/CONTRIBUTORS>.
 142
 143 =head1 LICENSE
 144
 145 You may distribute this code under the same terms as Perl itself.
 146
 147 =cut
 148 # vim:sts=2 sw=2: