lib/DBIx/Class/Storage/DBI/Sybase.pm

   1 package DBIx::Class::Storage::DBI::Sybase;
   2
   3 use strict;
   4 use warnings;
   5
   6 use Class::C3;
   7 use base qw/DBIx::Class::Storage::DBI/;
   8
   9 use Carp::Clan qw/^DBIx::Class/;
  10
  11 sub _rebless {
  12   my $self = shift;
  13
  14   if (ref($self) eq 'DBIx::Class::Storage::DBI::Sybase') {
  15     my $dbtype = eval {
  16       @{$self->dbh->selectrow_arrayref(qq{sp_server_info \@attribute_id=1})}[2]
  17     } || '';
  18
  19     my $exception = $@;
  20     $dbtype =~ s/\W/_/gi;
  21     my $subclass = "DBIx::Class::Storage::DBI::Sybase::${dbtype}";
  22
  23     if (!$exception && $dbtype && $self->load_optional_class($subclass)) {
  24       bless $self, $subclass;
  25       $self->_rebless;
  26     } elsif (not $self->dbh->{syb_dynamic_supported}) {
  27       bless $self, 'DBIx::Class::Storage:DBI::Sybase::NoBindVars';
  28       $self->_rebless;
  29     }
  30   }
  31 }
  32
  33 {
  34   my $old_dbd_warned = 0;
  35
  36   sub _populate_dbh {
  37     my $self = shift;
  38     $self->next::method(@_);
  39     my $dbh = $self->_dbh;
  40
  41     if ($dbh->can('syb_date_fmt')) {
  42       $dbh->syb_date_fmt('ISO_strict');
  43     } elsif (not $old_dbd_warned) {
  44       carp "Your DBD::Sybase is too old to support ".
  45       "DBIx::Class::InflateColumn::DateTime, please upgrade!";
  46       $old_dbd_warned = 1;
  47     }
  48
  49     $dbh->do('set dateformat mdy');
  50
  51     1;
  52   }
  53 }
  54
  55 sub _dbh_last_insert_id {
  56   my ($self, $dbh, $source, $col) = @_;
  57
  58   # sorry, there's no other way!
  59   my $sth = $dbh->prepare_cached("select max($col) from ".$source->from);
  60   return ($dbh->selectrow_array($sth))[0];
  61 }
  62
  63 sub count {
  64   my ($self, $source, $attrs) = @_;
  65
  66   if (not exists $attrs->{rows}) {
  67     return $self->next::method(@_);
  68   }
  69
  70   my $offset = $attrs->{offset} || 0;
  71   my $total  = $attrs->{rows} + $offset;
  72
  73   my $new_attrs = $self->_trim_attributes_for_count($source, $attrs);
  74   $new_attrs->{select} = '1';
  75   $new_attrs->{as}     = ['dummy'];
  76
  77   my $tmp_rs = $source->resultset_class->new($source, $new_attrs);
  78
  79   $self->dbh->{syb_rowcount} = $total;
  80
  81   my $count = 0;
  82   $count++ while $tmp_rs->cursor->next;
  83
  84   $self->dbh->{syb_rowcount} = 0;
  85
  86   return $count - $offset;
  87 }
  88
  89 sub datetime_parser_type { "DBIx::Class::Storage::DBI::Sybase::DateTime" }
  90
  91 1;
  92
  93 =head1 NAME
  94
  95 DBIx::Class::Storage::DBI::Sybase - Storage::DBI subclass for Sybase
  96
  97 =head1 SYNOPSIS
  98
  99 This subclass supports L<DBD::Sybase> for real Sybase databases.  If you are
 100 using an MSSQL database via L<DBD::Sybase>, your storage will be reblessed to
 101 L<DBIx::Class::Storage::DBI::Sybase::Microsoft_SQL_Server>.
 102
 103 =head1 DESCRIPTION
 104
 105 If your version of Sybase does not support placeholders, then your storage
 106 will be reblessed to L<DBIx::Class::Storage::DBI::Sybase::NoBindVars>. You can
 107 also enable that driver explicitly, see the documentation for more details.
 108
 109 With this driver there is unfortunately no way to get the C<last_insert_id>
 110 without doing a C<select max(col)>.
 111
 112 But your queries will be cached.
 113
 114 =head1 DATES
 115
 116 On connection C<syb_date_fmt> is set to C<ISO_strict>, e.g.:
 117 C<2004-08-21T14:36:48.080Z> and C<dateformat> is set to C<mdy>, e.g.:
 118 C<08/13/1979 18:08:55.080>.
 119
 120 This works for both C<DATETIME> and C<SMALLDATETIME> columns, although
 121 C<SMALLDATETIME> columns only have minute precision.
 122
 123 You will need the L<DateTime::Format::Strptime> module if you are going to use
 124 L<DBIx::Class::InflateColumn::DateTime>.
 125
 126 =head1 AUTHORS
 127
 128 See L<DBIx::Class/CONTRIBUTORS>.
 129
 130 =head1 LICENSE
 131
 132 You may distribute this code under the same terms as Perl itself.
 133
 134 =cut
 135 # vim:sts=2 sw=2: