lib/DBIx/Class/Storage/DBI/Sybase.pm

   1 package DBIx::Class::Storage::DBI::Sybase;
   2
   3 use strict;
   4 use warnings;
   5
   6 use Class::C3;
   7 use base qw/DBIx::Class::Storage::DBI/;
   8
   9 use Carp::Clan qw/^DBIx::Class/;
  10
  11 sub _rebless {
  12   my $self = shift;
  13
  14   if (ref($self) eq 'DBIx::Class::Storage::DBI::Sybase') {
  15     my $dbtype = eval {
  16       @{$self->dbh->selectrow_arrayref(qq{sp_server_info \@attribute_id=1})}[2]
  17     } || '';
  18
  19     my $exception = $@;
  20     $dbtype =~ s/\W/_/gi;
  21     my $subclass = "DBIx::Class::Storage::DBI::Sybase::${dbtype}";
  22
  23     if (!$exception && $dbtype && $self->load_optional_class($subclass)) {
  24       bless $self, $subclass;
  25       $self->_rebless;
  26     } else {
  27       # real Sybase
  28       if (not $self->dbh->{syb_dynamic_supported}) {
  29         bless $self, 'DBIx::Class::Storage:DBI::Sybase::NoBindVars';
  30         $self->_rebless;
  31       }
  32       $self->connect_call_datetime_setup;
  33       $self->connect_call_blob_setup;
  34     }
  35   }
  36 }
  37
  38 sub _populate_dbh {
  39   my $self = shift;
  40   $self->next::method(@_);
  41   $self->connect_call_datetime_setup;
  42   $self->connect_call_blob_setup;
  43   1;
  44 }
  45
  46 =head2 connect_call_blob_setup
  47
  48 Used as:
  49
  50   on_connect_call => 'blob_setup'
  51
  52 Does C<< $dbh->{syb_binary_images} = 1; >> to return C<IMAGE> data as raw binary
  53 instead of as a hex string.
  54
  55 =cut
  56
  57 sub connect_call_blob_setup {
  58   my $self = shift;
  59   my $dbh = $self->_dbh;
  60   $dbh->{syb_binary_images} = 1;
  61 }
  62
  63 {
  64   my $old_dbd_warned = 0;
  65
  66 =head2 connect_call_datetime_setup
  67
  68 Used as:
  69
  70   on_connect_call => 'datetime_setup'
  71
  72 In L<DBIx::Class::Storage::DBI/connect_info> to set:
  73
  74   $dbh->syb_date_fmt('ISO_strict'); # output fmt: 2004-08-21T14:36:48.080Z
  75   $dbh->do('set dateformat mdy');   # input fmt:  08/13/1979 18:08:55.080
  76
  77 On connection for use with L<DBIx::Class::InflateColumn::DateTime>, using
  78 L<DateTime::Format::Sybase>, which you will need to install.
  79
  80 This works for both C<DATETIME> and C<SMALLDATETIME> columns, although
  81 C<SMALLDATETIME> columns only have minute precision.
  82
  83 =cut
  84
  85   sub connect_call_datetime_setup {
  86     my $self = shift;
  87     my $dbh = $self->_dbh;
  88
  89     if ($dbh->can('syb_date_fmt')) {
  90       $dbh->syb_date_fmt('ISO_strict');
  91     } elsif (not $old_dbd_warned) {
  92       carp "Your DBD::Sybase is too old to support ".
  93       "DBIx::Class::InflateColumn::DateTime, please upgrade!";
  94       $old_dbd_warned = 1;
  95     }
  96
  97     $dbh->do('set dateformat mdy');
  98
  99     1;
 100   }
 101 }
 102
 103 sub _dbh_last_insert_id {
 104   my ($self, $dbh, $source, $col) = @_;
 105
 106   # sorry, there's no other way!
 107   my $sth = $dbh->prepare_cached("select max($col) from ".$source->from);
 108   return ($dbh->selectrow_array($sth))[0];
 109 }
 110
 111 sub count {
 112   my $self = shift;
 113   my ($source, $attrs) = @_;
 114
 115   if (not exists $attrs->{rows}) {
 116     return $self->next::method(@_);
 117   }
 118
 119   my $offset = $attrs->{offset} || 0;
 120   my $total  = $attrs->{rows} + $offset;
 121
 122   my $new_attrs = $self->_copy_attributes_for_count($source, $attrs);
 123
 124   my $first_pk = ($source->primary_columns)[0];
 125
 126   $new_attrs->{select} = $first_pk ? "me.$first_pk" : 1;
 127
 128   my $tmp_rs = $source->resultset_class->new($source, $new_attrs);
 129
 130   $self->dbh->{syb_rowcount} = $total;
 131
 132   my $count = 0;
 133   $count++ while $tmp_rs->cursor->next;
 134
 135   $self->dbh->{syb_rowcount} = 0;
 136
 137   return $count - $offset;
 138 }
 139
 140 sub datetime_parser_type { "DateTime::Format::Sybase" }
 141
 142 1;
 143
 144 =head1 NAME
 145
 146 DBIx::Class::Storage::DBI::Sybase - Storage::DBI subclass for Sybase
 147
 148 =head1 SYNOPSIS
 149
 150 This subclass supports L<DBD::Sybase> for real Sybase databases.  If you are
 151 using an MSSQL database via L<DBD::Sybase>, your storage will be reblessed to
 152 L<DBIx::Class::Storage::DBI::Sybase::Microsoft_SQL_Server>.
 153
 154 =head1 DESCRIPTION
 155
 156 If your version of Sybase does not support placeholders, then your storage
 157 will be reblessed to L<DBIx::Class::Storage::DBI::Sybase::NoBindVars>. You can
 158 also enable that driver explicitly, see the documentation for more details.
 159
 160 With this driver there is unfortunately no way to get the C<last_insert_id>
 161 without doing a C<select max(col)>.
 162
 163 But your queries will be cached.
 164
 165 =head1 DATES
 166
 167 See L</connect_call_datetime_setup> to setup date formats
 168 for L<DBIx::Class::InflateColumn::DateTime>.
 169
 170 =head1 IMAGE COLUMNS
 171
 172 See L</connect_call_blob_setup> for a L<DBIx::Class::Storage::DBI/connect_info>
 173 setting you need to work with C<IMAGE> columns.
 174
 175 =head1 AUTHORS
 176
 177 See L<DBIx::Class/CONTRIBUTORS>.
 178
 179 =head1 LICENSE
 180
 181 You may distribute this code under the same terms as Perl itself.
 182
 183 =cut
 184 # vim:sts=2 sw=2: