lib/DBIx/Class/Storage/DBI/Sybase.pm

   1 package DBIx::Class::Storage::DBI::Sybase;
   2
   3 use strict;
   4 use warnings;
   5
   6 use base qw/
   7     DBIx::Class::Storage::DBI::Sybase::Common
   8     DBIx::Class::Storage::DBI::AutoCast
   9 /;
  10 use mro 'c3';
  11 use Carp::Clan qw/^DBIx::Class/;
  12 use List::Util();
  13 use Sub::Name();
  14 use Data::Dumper::Concise();
  15
  16 __PACKAGE__->mk_group_accessors('simple' =>
  17     qw/_identity _blob_log_on_update _writer_storage _is_extra_storage
  18        _bulk_storage _is_bulk_storage _began_bulk_work
  19        _bulk_disabled_due_to_coderef_connect_info_warned
  20        _identity_method/
  21 );
  22
  23 my @also_proxy_to_extra_storages = qw/
  24   connect_call_set_auto_cast auto_cast connect_call_blob_setup
  25   connect_call_datetime_setup
  26
  27   disconnect _connect_info _sql_maker _sql_maker_opts disable_sth_caching
  28   auto_savepoint unsafe cursor_class debug debugobj schema
  29 /;
  30
  31 =head1 NAME
  32
  33 DBIx::Class::Storage::DBI::Sybase - Sybase support for DBIx::Class
  34
  35 =head1 SYNOPSIS
  36
  37 This subclass supports L<DBD::Sybase> for real Sybase databases.  If you are
  38 using an MSSQL database via L<DBD::Sybase>, your storage will be reblessed to
  39 L<DBIx::Class::Storage::DBI::Sybase::Microsoft_SQL_Server>.
  40
  41 =head1 DESCRIPTION
  42
  43 If your version of Sybase does not support placeholders, then your storage
  44 will be reblessed to L<DBIx::Class::Storage::DBI::Sybase::NoBindVars>. You can
  45 also enable that driver explicitly, see the documentation for more details.
  46
  47 With this driver there is unfortunately no way to get the C<last_insert_id>
  48 without doing a C<SELECT MAX(col)>. This is done safely in a transaction
  49 (locking the table.) See L</INSERTS WITH PLACEHOLDERS>.
  50
  51 A recommended L<DBIx::Class::Storage::DBI/connect_info> setting:
  52
  53   on_connect_call => [['datetime_setup'], ['blob_setup', log_on_update => 0]]
  54
  55 =head1 METHODS
  56
  57 =cut
  58
  59 sub _rebless {
  60   my $self = shift;
  61
  62   if (ref($self) eq 'DBIx::Class::Storage::DBI::Sybase') {
  63     my $dbtype = eval {
  64       @{$self->_get_dbh->selectrow_arrayref(qq{sp_server_info \@attribute_id=1})}[2]
  65     } || '';
  66     $self->throw_exception("Unable to estable connection to determine database type: $@")
  67       if $@;
  68
  69     $dbtype =~ s/\W/_/gi;
  70     my $subclass = "DBIx::Class::Storage::DBI::Sybase::${dbtype}";
  71
  72     if ($dbtype && $self->load_optional_class($subclass)) {
  73       bless $self, $subclass;
  74       $self->_rebless;
  75     } else { # real Sybase
  76       my $no_bind_vars = 'DBIx::Class::Storage::DBI::Sybase::NoBindVars';
  77
  78       if ($self->using_freetds) {
  79         carp <<'EOF' unless $ENV{DBIC_SYBASE_FREETDS_NOWARN};
  80
  81 You are using FreeTDS with Sybase.
  82
  83 We will do our best to support this configuration, but please consider this
  84 support experimental.
  85
  86 TEXT/IMAGE columns will definitely not work.
  87
  88 You are encouraged to recompile DBD::Sybase with the Sybase Open Client libraries
  89 instead.
  90
  91 See perldoc DBIx::Class::Storage::DBI::Sybase for more details.
  92
  93 To turn off this warning set the DBIC_SYBASE_FREETDS_NOWARN environment
  94 variable.
  95 EOF
  96         if (not $self->_typeless_placeholders_supported) {
  97           if ($self->_placeholders_supported) {
  98             $self->auto_cast(1);
  99           } else {
 100             $self->ensure_class_loaded($no_bind_vars);
 101             bless $self, $no_bind_vars;
 102             $self->_rebless;
 103           }
 104         }
 105       }
 106       elsif (not $self->_get_dbh->{syb_dynamic_supported}) {
 107         # not necessarily FreeTDS, but no placeholders nevertheless
 108         $self->ensure_class_loaded($no_bind_vars);
 109         bless $self, $no_bind_vars;
 110         $self->_rebless;
 111       } elsif (not $self->_typeless_placeholders_supported) {
 112         # this is highly unlikely, but we check just in case
 113         $self->auto_cast(1);
 114       }
 115     }
 116   }
 117 }
 118
 119 sub _init {
 120   my $self = shift;
 121   $self->_set_max_connect(256);
 122
 123   # based on LongReadLen in connect_info
 124   $self->set_textsize if $self->using_freetds;
 125
 126 # create storage for insert/(update blob) transactions,
 127 # unless this is that storage
 128   return if $self->_is_extra_storage;
 129
 130   my $writer_storage = (ref $self)->new;
 131
 132   $writer_storage->_is_extra_storage(1);
 133   $writer_storage->connect_info($self->connect_info);
 134   $writer_storage->auto_cast($self->auto_cast);
 135
 136   $self->_writer_storage($writer_storage);
 137
 138 # create a bulk storage unless connect_info is a coderef
 139   return
 140     if (Scalar::Util::reftype($self->_dbi_connect_info->[0])||'') eq 'CODE';
 141
 142   my $bulk_storage = (ref $self)->new;
 143
 144   $bulk_storage->_is_extra_storage(1);
 145   $bulk_storage->_is_bulk_storage(1); # for special ->disconnect acrobatics
 146   $bulk_storage->connect_info($self->connect_info);
 147
 148 # this is why
 149   $bulk_storage->_dbi_connect_info->[0] .= ';bulkLogin=1';
 150
 151   $self->_bulk_storage($bulk_storage);
 152 }
 153
 154 for my $method (@also_proxy_to_extra_storages) {
 155   no strict 'refs';
 156   no warnings 'redefine';
 157
 158   my $replaced = __PACKAGE__->can($method);
 159
 160   *{$method} = Sub::Name::subname $method => sub {
 161     my $self = shift;
 162     $self->_writer_storage->$replaced(@_) if $self->_writer_storage;
 163     $self->_bulk_storage->$replaced(@_)   if $self->_bulk_storage;
 164     return $self->$replaced(@_);
 165   };
 166 }
 167
 168 sub disconnect {
 169   my $self = shift;
 170
 171 # Even though we call $sth->finish for uses off the bulk API, there's still an
 172 # "active statement" warning on disconnect, which we throw away here.
 173 # This is due to the bug described in insert_bulk.
 174 # Currently a noop because 'prepare' is used instead of 'prepare_cached'.
 175   local $SIG{__WARN__} = sub {
 176     warn $_[0] unless $_[0] =~ /active statement/i;
 177   } if $self->_is_bulk_storage;
 178
 179 # so that next transaction gets a dbh
 180   $self->_began_bulk_work(0) if $self->_is_bulk_storage;
 181
 182   $self->next::method;
 183 }
 184
 185 # Make sure we have CHAINED mode turned on if AutoCommit is off in non-FreeTDS
 186 # DBD::Sybase (since we don't know how DBD::Sybase was compiled.) If however
 187 # we're using FreeTDS, CHAINED mode turns on an implicit transaction which we
 188 # only want when AutoCommit is off.
 189 sub _populate_dbh {
 190   my $self = shift;
 191
 192   $self->next::method(@_);
 193
 194   if ($self->_is_bulk_storage) {
 195 # this should be cleared on every reconnect
 196     $self->_began_bulk_work(0);
 197     return;
 198   }
 199
 200   if (not $self->using_freetds) {
 201     $self->_dbh->{syb_chained_txn} = 1;
 202   } else {
 203     if ($self->_dbh_autocommit) {
 204       $self->_dbh->do('SET CHAINED OFF');
 205     } else {
 206       $self->_dbh->do('SET CHAINED ON');
 207     }
 208   }
 209 }
 210
 211 =head2 connect_call_blob_setup
 212
 213 Used as:
 214
 215   on_connect_call => [ [ 'blob_setup', log_on_update => 0 ] ]
 216
 217 Does C<< $dbh->{syb_binary_images} = 1; >> to return C<IMAGE> data as raw binary
 218 instead of as a hex string.
 219
 220 Recommended.
 221
 222 Also sets the C<log_on_update> value for blob write operations. The default is
 223 C<1>, but C<0> is better if your database is configured for it.
 224
 225 See
 226 L<DBD::Sybase/Handling_IMAGE/TEXT_data_with_syb_ct_get_data()/syb_ct_send_data()>.
 227
 228 =cut
 229
 230 sub connect_call_blob_setup {
 231   my $self = shift;
 232   my %args = @_;
 233   my $dbh = $self->_dbh;
 234   $dbh->{syb_binary_images} = 1;
 235
 236   $self->_blob_log_on_update($args{log_on_update})
 237     if exists $args{log_on_update};
 238 }
 239
 240 sub _is_lob_type {
 241   my $self = shift;
 242   my $type = shift;
 243   $type && $type =~ /(?:text|image|lob|bytea|binary|memo)/i;
 244 }
 245
 246 sub _is_lob_column {
 247   my ($self, $source, $column) = @_;
 248
 249   return $self->_is_lob_type($source->column_info($column)->{data_type});
 250 }
 251
 252 sub _prep_for_execute {
 253   my $self = shift;
 254   my ($op, $extra_bind, $ident, $args) = @_;
 255
 256   my ($sql, $bind) = $self->next::method (@_);
 257
 258   my $table = Scalar::Util::blessed($ident) ? $ident->from : $ident;
 259
 260   my $bind_info = $self->_resolve_column_info(
 261     $ident, [map $_->[0], @{$bind}]
 262   );
 263   my $bound_identity_col = List::Util::first
 264     { $bind_info->{$_}{is_auto_increment} }
 265     (keys %$bind_info)
 266   ;
 267   my $identity_col = Scalar::Util::blessed($ident) &&
 268     List::Util::first
 269     { $ident->column_info($_)->{is_auto_increment} }
 270     $ident->columns
 271   ;
 272
 273   if (($op eq 'insert' && $bound_identity_col) ||
 274       ($op eq 'update' && exists $args->[0]{$identity_col})) {
 275     $sql = join ("\n",
 276       $self->_set_table_identity_sql($op => $table, 'on'),
 277       $sql,
 278       $self->_set_table_identity_sql($op => $table, 'off'),
 279     );
 280   }
 281
 282   if ($op eq 'insert' && (not $bound_identity_col) && $identity_col &&
 283       (not $self->{insert_bulk})) {
 284     $sql =
 285       "$sql\n" .
 286       $self->_fetch_identity_sql($ident, $identity_col);
 287   }
 288
 289   return ($sql, $bind);
 290 }
 291
 292 sub _set_table_identity_sql {
 293   my ($self, $op, $table, $on_off) = @_;
 294
 295   return sprintf 'SET IDENTITY_%s %s %s',
 296     uc($op), $self->sql_maker->_quote($table), uc($on_off);
 297 }
 298
 299 # Stolen from SQLT, with some modifications. This is a makeshift
 300 # solution before a sane type-mapping library is available, thus
 301 # the 'our' for easy overrides.
 302 our %TYPE_MAPPING  = (
 303     number    => 'numeric',
 304     money     => 'money',
 305     varchar   => 'varchar',
 306     varchar2  => 'varchar',
 307     timestamp => 'datetime',
 308     text      => 'varchar',
 309     real      => 'double precision',
 310     comment   => 'text',
 311     bit       => 'bit',
 312     tinyint   => 'smallint',
 313     float     => 'double precision',
 314     serial    => 'numeric',
 315     bigserial => 'numeric',
 316     boolean   => 'varchar',
 317     long      => 'varchar',
 318 );
 319
 320 sub _native_data_type {
 321   my ($self, $type) = @_;
 322
 323   $type = lc $type;
 324   $type =~ s/\s* identity//x;
 325
 326   return uc($TYPE_MAPPING{$type} || $type);
 327 }
 328
 329 sub _fetch_identity_sql {
 330   my ($self, $source, $col) = @_;
 331
 332   return sprintf ("SELECT MAX(%s) FROM %s",
 333     map { $self->sql_maker->_quote ($_) } ($col, $source->from)
 334   );
 335 }
 336
 337 sub _execute {
 338   my $self = shift;
 339   my ($op) = @_;
 340
 341   my ($rv, $sth, @bind) = $self->dbh_do($self->can('_dbh_execute'), @_);
 342
 343   if ($op eq 'insert') {
 344     $self->_identity($sth->fetchrow_array);
 345     $sth->finish;
 346   }
 347
 348   return wantarray ? ($rv, $sth, @bind) : $rv;
 349 }
 350
 351 sub last_insert_id { shift->_identity }
 352
 353 # handles TEXT/IMAGE and transaction for last_insert_id
 354 sub insert {
 355   my $self = shift;
 356   my ($source, $to_insert) = @_;
 357
 358   my $identity_col = (List::Util::first
 359     { $source->column_info($_)->{is_auto_increment} }
 360     $source->columns) || '';
 361
 362   # check for empty insert
 363   # INSERT INTO foo DEFAULT VALUES -- does not work with Sybase
 364   # try to insert explicit 'DEFAULT's instead (except for identity)
 365   if (not %$to_insert) {
 366     for my $col ($source->columns) {
 367       next if $col eq $identity_col;
 368       $to_insert->{$col} = \'DEFAULT';
 369     }
 370   }
 371
 372   my $blob_cols = $self->_remove_blob_cols($source, $to_insert);
 373
 374   # do we need the horrific SELECT MAX(COL) hack?
 375   my $dumb_last_insert_id =
 376        $identity_col
 377     && (not exists $to_insert->{$identity_col})
 378     && ($self->_identity_method||'') ne '@@IDENTITY';
 379
 380   my $next = $self->next::can;
 381
 382   # we are already in a transaction, or there are no blobs
 383   # and we don't need the PK - just (try to) do it
 384   if ($self->{transaction_depth}
 385         || (!$blob_cols && !$dumb_last_insert_id)
 386   ) {
 387     return $self->_insert (
 388       $next, $source, $to_insert, $blob_cols, $identity_col
 389     );
 390   }
 391
 392   # otherwise use the _writer_storage to do the insert+transaction on another
 393   # connection
 394   my $guard = $self->_writer_storage->txn_scope_guard;
 395
 396   my $updated_cols = $self->_writer_storage->_insert (
 397     $next, $source, $to_insert, $blob_cols, $identity_col
 398   );
 399
 400   $self->_identity($self->_writer_storage->_identity);
 401
 402   $guard->commit;
 403
 404   return $updated_cols;
 405 }
 406
 407 sub _insert {
 408   my ($self, $next, $source, $to_insert, $blob_cols, $identity_col) = @_;
 409
 410   my $updated_cols = $self->$next ($source, $to_insert);
 411
 412   my $final_row = {
 413     ($identity_col ?
 414       ($identity_col => $self->last_insert_id($source, $identity_col)) : ()),
 415     %$to_insert,
 416     %$updated_cols,
 417   };
 418
 419   $self->_insert_blobs ($source, $blob_cols, $final_row) if $blob_cols;
 420
 421   return $updated_cols;
 422 }
 423
 424 sub update {
 425   my $self = shift;
 426   my ($source, $fields, $where, @rest) = @_;
 427
 428   my $wantarray = wantarray;
 429
 430   my $blob_cols = $self->_remove_blob_cols($source, $fields);
 431
 432   my $table = $source->name;
 433
 434   my $identity_col = List::Util::first
 435     { $source->column_info($_)->{is_auto_increment} }
 436     $source->columns;
 437
 438   my $is_identity_update = $identity_col && defined $fields->{$identity_col};
 439
 440   return $self->next::method(@_) unless $blob_cols;
 441
 442 # If there are any blobs in $where, Sybase will return a descriptive error
 443 # message.
 444 # XXX blobs can still be used with a LIKE query, and this should be handled.
 445
 446 # update+blob update(s) done atomically on separate connection
 447   $self = $self->_writer_storage;
 448
 449   my $guard = $self->txn_scope_guard;
 450
 451 # First update the blob columns to be updated to '' (taken from $fields, where
 452 # it is originally put by _remove_blob_cols .)
 453   my %blobs_to_empty = map { ($_ => delete $fields->{$_}) } keys %$blob_cols;
 454
 455 # We can't only update NULL blobs, because blobs cannot be in the WHERE clause.
 456
 457   $self->next::method($source, \%blobs_to_empty, $where, @rest);
 458
 459 # Now update the blobs before the other columns in case the update of other
 460 # columns makes the search condition invalid.
 461   $self->_update_blobs($source, $blob_cols, $where);
 462
 463   my @res;
 464   if (%$fields) {
 465     if ($wantarray) {
 466       @res    = $self->next::method(@_);
 467     }
 468     elsif (defined $wantarray) {
 469       $res[0] = $self->next::method(@_);
 470     }
 471     else {
 472       $self->next::method(@_);
 473     }
 474   }
 475
 476   $guard->commit;
 477
 478   return $wantarray ? @res : $res[0];
 479 }
 480
 481 sub insert_bulk {
 482   my $self = shift;
 483   my ($source, $cols, $data) = @_;
 484
 485   my $identity_col = List::Util::first
 486     { $source->column_info($_)->{is_auto_increment} }
 487     $source->columns;
 488
 489   my $is_identity_insert = (List::Util::first
 490     { $_ eq $identity_col }
 491     @{$cols}
 492   ) ? 1 : 0;
 493
 494   my @source_columns = $source->columns;
 495
 496   my $use_bulk_api =
 497     $self->_bulk_storage &&
 498     $self->_get_dbh->{syb_has_blk};
 499
 500   if ((not $use_bulk_api) &&
 501       (Scalar::Util::reftype($self->_dbi_connect_info->[0])||'') eq 'CODE' &&
 502       (not $self->_bulk_disabled_due_to_coderef_connect_info_warned)) {
 503     carp <<'EOF';
 504 Bulk API support disabled due to use of a CODEREF connect_info. Reverting to
 505 regular array inserts.
 506 EOF
 507     $self->_bulk_disabled_due_to_coderef_connect_info_warned(1);
 508   }
 509
 510   if (not $use_bulk_api) {
 511     my $blob_cols = $self->_remove_blob_cols_array($source, $cols, $data);
 512
 513 # _execute_array uses a txn anyway, but it ends too early in case we need to
 514 # select max(col) to get the identity for inserting blobs.
 515     ($self, my $guard) = $self->{transaction_depth} == 0 ?
 516       ($self->_writer_storage, $self->_writer_storage->txn_scope_guard)
 517       :
 518       ($self, undef);
 519
 520     local $self->{insert_bulk} = 1;
 521
 522     $self->next::method(@_);
 523
 524     if ($blob_cols) {
 525       if ($is_identity_insert) {
 526         $self->_insert_blobs_array ($source, $blob_cols, $cols, $data);
 527       }
 528       else {
 529         my @cols_with_identities = (@$cols, $identity_col);
 530
 531         ## calculate identities
 532         # XXX This assumes identities always increase by 1, which may or may not
 533         # be true.
 534         my ($last_identity) =
 535           $self->_dbh->selectrow_array (
 536             $self->_fetch_identity_sql($source, $identity_col)
 537           );
 538         my @identities = (($last_identity - @$data + 1) .. $last_identity);
 539
 540         my @data_with_identities = map [@$_, shift @identities], @$data;
 541
 542         $self->_insert_blobs_array (
 543           $source, $blob_cols, \@cols_with_identities, \@data_with_identities
 544         );
 545       }
 546     }
 547
 548     $guard->commit if $guard;
 549
 550     return;
 551   }
 552
 553 # otherwise, use the bulk API
 554
 555 # rearrange @$data so that columns are in database order
 556   my %orig_idx;
 557   @orig_idx{@$cols} = 0..$#$cols;
 558
 559   my %new_idx;
 560   @new_idx{@source_columns} = 0..$#source_columns;
 561
 562   my @new_data;
 563   for my $datum (@$data) {
 564     my $new_datum = [];
 565     for my $col (@source_columns) {
 566 # identity data will be 'undef' if not $is_identity_insert
 567 # columns with defaults will also be 'undef'
 568       $new_datum->[ $new_idx{$col} ] =
 569         exists $orig_idx{$col} ? $datum->[ $orig_idx{$col} ] : undef;
 570     }
 571     push @new_data, $new_datum;
 572   }
 573
 574 # bcp identity index is 1-based
 575   my $identity_idx = exists $new_idx{$identity_col} ?
 576     $new_idx{$identity_col} + 1 : 0;
 577
 578 ## Set a client-side conversion error handler, straight from DBD::Sybase docs.
 579 # This ignores any data conversion errors detected by the client side libs, as
 580 # they are usually harmless.
 581   my $orig_cslib_cb = DBD::Sybase::set_cslib_cb(
 582     Sub::Name::subname insert_bulk => sub {
 583       my ($layer, $origin, $severity, $errno, $errmsg, $osmsg, $blkmsg) = @_;
 584
 585       return 1 if $errno == 36;
 586
 587       carp
 588         "Layer: $layer, Origin: $origin, Severity: $severity, Error: $errno" .
 589         ($errmsg ? "\n$errmsg" : '') .
 590         ($osmsg  ? "\n$osmsg"  : '')  .
 591         ($blkmsg ? "\n$blkmsg" : '');
 592
 593       return 0;
 594   });
 595
 596   eval {
 597     my $bulk = $self->_bulk_storage;
 598
 599     my $guard = $bulk->txn_scope_guard;
 600
 601 ## XXX get this to work instead of our own $sth
 602 ## will require SQLA or *Hacks changes for ordered columns
 603 #    $bulk->next::method($source, \@source_columns, \@new_data, {
 604 #      syb_bcp_attribs => {
 605 #        identity_flag   => $is_identity_insert,
 606 #        identity_column => $identity_idx,
 607 #      }
 608 #    });
 609     my $sql = 'INSERT INTO ' .
 610       $bulk->sql_maker->_quote($source->name) . ' (' .
 611 # colname list is ignored for BCP, but does no harm
 612       (join ', ', map $bulk->sql_maker->_quote($_), @source_columns) . ') '.
 613       ' VALUES ('.  (join ', ', ('?') x @source_columns) . ')';
 614
 615 ## XXX there's a bug in the DBD::Sybase bulk support that makes $sth->finish for
 616 ## a prepare_cached statement ineffective. Replace with ->sth when fixed, or
 617 ## better yet the version above. Should be fixed in DBD::Sybase .
 618     my $sth = $bulk->_get_dbh->prepare($sql,
 619 #      'insert', # op
 620       {
 621         syb_bcp_attribs => {
 622           identity_flag   => $is_identity_insert,
 623           identity_column => $identity_idx,
 624         }
 625       }
 626     );
 627
 628     my @bind = do {
 629       my $idx = 0;
 630       map [ $_, $idx++ ], @source_columns;
 631     };
 632
 633     $self->_execute_array(
 634       $source, $sth, \@bind, \@source_columns, \@new_data, sub {
 635         $guard->commit
 636       }
 637     );
 638
 639     $bulk->_query_end($sql);
 640   };
 641
 642   my $exception = $@;
 643   DBD::Sybase::set_cslib_cb($orig_cslib_cb);
 644
 645   if ($exception =~ /-Y option/) {
 646     carp <<"EOF";
 647
 648 Sybase bulk API operation failed due to character set incompatibility, reverting
 649 to regular array inserts:
 650
 651 *** Try unsetting the LANG environment variable.
 652
 653 $exception
 654 EOF
 655     $self->_bulk_storage(undef);
 656     unshift @_, $self;
 657     goto \&insert_bulk;
 658   }
 659   elsif ($exception) {
 660 # rollback makes the bulkLogin connection unusable
 661     $self->_bulk_storage->disconnect;
 662     $self->throw_exception($exception);
 663   }
 664 }
 665
 666 sub _dbh_execute_array {
 667   my ($self, $sth, $tuple_status, $cb) = @_;
 668
 669   my $rv = $self->next::method($sth, $tuple_status);
 670   $cb->() if $cb;
 671
 672   return $rv;
 673 }
 674
 675 # Make sure blobs are not bound as placeholders, and return any non-empty ones
 676 # as a hash.
 677 sub _remove_blob_cols {
 678   my ($self, $source, $fields) = @_;
 679
 680   my %blob_cols;
 681
 682   for my $col (keys %$fields) {
 683     if ($self->_is_lob_column($source, $col)) {
 684       my $blob_val = delete $fields->{$col};
 685       if (not defined $blob_val) {
 686         $fields->{$col} = \'NULL';
 687       }
 688       else {
 689         $fields->{$col} = \"''";
 690         $blob_cols{$col} = $blob_val unless $blob_val eq '';
 691       }
 692     }
 693   }
 694
 695   return %blob_cols ? \%blob_cols : undef;
 696 }
 697
 698 # same for insert_bulk
 699 sub _remove_blob_cols_array {
 700   my ($self, $source, $cols, $data) = @_;
 701
 702   my @blob_cols;
 703
 704   for my $i (0..$#$cols) {
 705     my $col = $cols->[$i];
 706
 707     if ($self->_is_lob_column($source, $col)) {
 708       for my $j (0..$#$data) {
 709         my $blob_val = delete $data->[$j][$i];
 710         if (not defined $blob_val) {
 711           $data->[$j][$i] = \'NULL';
 712         }
 713         else {
 714           $data->[$j][$i] = \"''";
 715           $blob_cols[$j][$i] = $blob_val
 716             unless $blob_val eq '';
 717         }
 718       }
 719     }
 720   }
 721
 722   return @blob_cols ? \@blob_cols : undef;
 723 }
 724
 725 sub _update_blobs {
 726   my ($self, $source, $blob_cols, $where) = @_;
 727
 728   my (@primary_cols) = $source->primary_columns;
 729
 730   $self->throw_exception('Cannot update TEXT/IMAGE column(s) without a primary key')
 731     unless @primary_cols;
 732
 733 # check if we're updating a single row by PK
 734   my $pk_cols_in_where = 0;
 735   for my $col (@primary_cols) {
 736     $pk_cols_in_where++ if defined $where->{$col};
 737   }
 738   my @rows;
 739
 740   if ($pk_cols_in_where == @primary_cols) {
 741     my %row_to_update;
 742     @row_to_update{@primary_cols} = @{$where}{@primary_cols};
 743     @rows = \%row_to_update;
 744   } else {
 745     my $cursor = $self->select ($source, \@primary_cols, $where, {});
 746     @rows = map {
 747       my %row; @row{@primary_cols} = @$_; \%row
 748     } $cursor->all;
 749   }
 750
 751   for my $row (@rows) {
 752     $self->_insert_blobs($source, $blob_cols, $row);
 753   }
 754 }
 755
 756 sub _insert_blobs {
 757   my ($self, $source, $blob_cols, $row) = @_;
 758   my $dbh = $self->_get_dbh;
 759
 760   my $table = $source->name;
 761
 762   my %row = %$row;
 763   my (@primary_cols) = $source->primary_columns;
 764
 765   $self->throw_exception('Cannot update TEXT/IMAGE column(s) without a primary key')
 766     unless @primary_cols;
 767
 768   $self->throw_exception('Cannot update TEXT/IMAGE column(s) without primary key values')
 769     if ((grep { defined $row{$_} } @primary_cols) != @primary_cols);
 770
 771   for my $col (keys %$blob_cols) {
 772     my $blob = $blob_cols->{$col};
 773
 774     my %where = map { ($_, $row{$_}) } @primary_cols;
 775
 776     my $cursor = $self->select ($source, [$col], \%where, {});
 777     $cursor->next;
 778     my $sth = $cursor->sth;
 779
 780     if (not $sth) {
 781
 782       $self->throw_exception(
 783           "Could not find row in table '$table' for blob update:\n"
 784         . Data::Dumper::Concise::Dumper (\%where)
 785       );
 786     }
 787
 788     eval {
 789       do {
 790         $sth->func('CS_GET', 1, 'ct_data_info') or die $sth->errstr;
 791       } while $sth->fetch;
 792
 793       $sth->func('ct_prepare_send') or die $sth->errstr;
 794
 795       my $log_on_update = $self->_blob_log_on_update;
 796       $log_on_update    = 1 if not defined $log_on_update;
 797
 798       $sth->func('CS_SET', 1, {
 799         total_txtlen => length($blob),
 800         log_on_update => $log_on_update
 801       }, 'ct_data_info') or die $sth->errstr;
 802
 803       $sth->func($blob, length($blob), 'ct_send_data') or die $sth->errstr;
 804
 805       $sth->func('ct_finish_send') or die $sth->errstr;
 806     };
 807     my $exception = $@;
 808     $sth->finish if $sth;
 809     if ($exception) {
 810       if ($self->using_freetds) {
 811         $self->throw_exception (
 812           'TEXT/IMAGE operation failed, probably because you are using FreeTDS: '
 813           . $exception
 814         );
 815       } else {
 816         $self->throw_exception($exception);
 817       }
 818     }
 819   }
 820 }
 821
 822 sub _insert_blobs_array {
 823   my ($self, $source, $blob_cols, $cols, $data) = @_;
 824
 825   for my $i (0..$#$data) {
 826     my $datum = $data->[$i];
 827
 828     my %row;
 829     @row{ @$cols } = @$datum;
 830
 831     my %blob_vals;
 832     for my $j (0..$#$cols) {
 833       if (exists $blob_cols->[$i][$j]) {
 834         $blob_vals{ $cols->[$j] } = $blob_cols->[$i][$j];
 835       }
 836     }
 837
 838     $self->_insert_blobs ($source, \%blob_vals, \%row);
 839   }
 840 }
 841
 842 =head2 connect_call_datetime_setup
 843
 844 Used as:
 845
 846   on_connect_call => 'datetime_setup'
 847
 848 In L<DBIx::Class::Storage::DBI/connect_info> to set:
 849
 850   $dbh->syb_date_fmt('ISO_strict'); # output fmt: 2004-08-21T14:36:48.080Z
 851   $dbh->do('set dateformat mdy');   # input fmt:  08/13/1979 18:08:55.080
 852
 853 On connection for use with L<DBIx::Class::InflateColumn::DateTime>, using
 854 L<DateTime::Format::Sybase>, which you will need to install.
 855
 856 This works for both C<DATETIME> and C<SMALLDATETIME> columns, although
 857 C<SMALLDATETIME> columns only have minute precision.
 858
 859 =cut
 860
 861 {
 862   my $old_dbd_warned = 0;
 863
 864   sub connect_call_datetime_setup {
 865     my $self = shift;
 866     my $dbh = $self->_get_dbh;
 867
 868     if ($dbh->can('syb_date_fmt')) {
 869       # amazingly, this works with FreeTDS
 870       $dbh->syb_date_fmt('ISO_strict');
 871     } elsif (not $old_dbd_warned) {
 872       carp "Your DBD::Sybase is too old to support ".
 873       "DBIx::Class::InflateColumn::DateTime, please upgrade!";
 874       $old_dbd_warned = 1;
 875     }
 876
 877     $dbh->do('SET DATEFORMAT mdy');
 878
 879     1;
 880   }
 881 }
 882
 883 sub datetime_parser_type { "DateTime::Format::Sybase" }
 884
 885 # ->begin_work and such have no effect with FreeTDS but we run them anyway to
 886 # let the DBD keep any state it needs to.
 887 #
 888 # If they ever do start working, the extra statements will do no harm (because
 889 # Sybase supports nested transactions.)
 890
 891 sub _dbh_begin_work {
 892   my $self = shift;
 893
 894 # bulkLogin=1 connections are always in a transaction, and can only call BEGIN
 895 # TRAN once. However, we need to make sure there's a $dbh.
 896   return if $self->_is_bulk_storage && $self->_dbh && $self->_began_bulk_work;
 897
 898   $self->next::method(@_);
 899
 900   if ($self->using_freetds) {
 901     $self->_get_dbh->do('BEGIN TRAN');
 902   }
 903
 904   $self->_began_bulk_work(1) if $self->_is_bulk_storage;
 905 }
 906
 907 sub _dbh_commit {
 908   my $self = shift;
 909   if ($self->using_freetds) {
 910     $self->_dbh->do('COMMIT');
 911   }
 912   return $self->next::method(@_);
 913 }
 914
 915 sub _dbh_rollback {
 916   my $self = shift;
 917   if ($self->using_freetds) {
 918     $self->_dbh->do('ROLLBACK');
 919   }
 920   return $self->next::method(@_);
 921 }
 922
 923 # savepoint support using ASE syntax
 924
 925 sub _svp_begin {
 926   my ($self, $name) = @_;
 927
 928   $self->_get_dbh->do("SAVE TRANSACTION $name");
 929 }
 930
 931 # A new SAVE TRANSACTION with the same name releases the previous one.
 932 sub _svp_release { 1 }
 933
 934 sub _svp_rollback {
 935   my ($self, $name) = @_;
 936
 937   $self->_get_dbh->do("ROLLBACK TRANSACTION $name");
 938 }
 939
 940 1;
 941
 942 =head1 Schema::Loader Support
 943
 944 There is an experimental branch of L<DBIx::Class::Schema::Loader> that will
 945 allow you to dump a schema from most (if not all) versions of Sybase.
 946
 947 It is available via subversion from:
 948
 949   http://dev.catalyst.perl.org/repos/bast/branches/DBIx-Class-Schema-Loader/current/
 950
 951 =head1 FreeTDS
 952
 953 This driver supports L<DBD::Sybase> compiled against FreeTDS
 954 (L<http://www.freetds.org/>) to the best of our ability, however it is
 955 recommended that you recompile L<DBD::Sybase> against the Sybase Open Client
 956 libraries. They are a part of the Sybase ASE distribution:
 957
 958 The Open Client FAQ is here:
 959 L<http://www.isug.com/Sybase_FAQ/ASE/section7.html>.
 960
 961 Sybase ASE for Linux (which comes with the Open Client libraries) may be
 962 downloaded here: L<http://response.sybase.com/forms/ASE_Linux_Download>.
 963
 964 To see if you're using FreeTDS check C<< $schema->storage->using_freetds >>, or run:
 965
 966   perl -MDBI -le 'my $dbh = DBI->connect($dsn, $user, $pass); print $dbh->{syb_oc_version}'
 967
 968 Some versions of the libraries involved will not support placeholders, in which
 969 case the storage will be reblessed to
 970 L<DBIx::Class::Storage::DBI::Sybase::NoBindVars>.
 971
 972 In some configurations, placeholders will work but will throw implicit type
 973 conversion errors for anything that's not expecting a string. In such a case,
 974 the C<auto_cast> option from L<DBIx::Class::Storage::DBI::AutoCast> is
 975 automatically set, which you may enable on connection with
 976 L<DBIx::Class::Storage::DBI::AutoCast/connect_call_set_auto_cast>. The type info
 977 for the C<CAST>s is taken from the L<DBIx::Class::ResultSource/data_type>
 978 definitions in your Result classes, and are mapped to a Sybase type (if it isn't
 979 already) using a mapping based on L<SQL::Translator>.
 980
 981 In other configurations, placeholers will work just as they do with the Sybase
 982 Open Client libraries.
 983
 984 Inserts or updates of TEXT/IMAGE columns will B<NOT> work with FreeTDS.
 985
 986 =head1 INSERTS WITH PLACEHOLDERS
 987
 988 With placeholders enabled, inserts are done in a transaction so that there are
 989 no concurrency issues with getting the inserted identity value using
 990 C<SELECT MAX(col)>, which is the only way to get the C<IDENTITY> value in this
 991 mode.
 992
 993 In addition, they are done on a separate connection so that it's possible to
 994 have active cursors when doing an insert.
 995
 996 When using C<DBIx::Class::Storage::DBI::Sybase::NoBindVars> transactions are
 997 disabled, as there are no concurrency issues with C<SELECT @@IDENTITY> as it's a
 998 session variable.
 999
1000 =head1 TRANSACTIONS
1001
1002 Due to limitations of the TDS protocol, L<DBD::Sybase>, or both; you cannot
1003 begin a transaction while there are active cursors; nor can you use multiple
1004 active cursors within a transaction. An active cursor is, for example, a
1005 L<ResultSet|DBIx::Class::ResultSet> that has been executed using C<next> or
1006 C<first> but has not been exhausted or L<reset|DBIx::Class::ResultSet/reset>.
1007
1008 For example, this will not work:
1009
1010   $schema->txn_do(sub {
1011     my $rs = $schema->resultset('Book');
1012     while (my $row = $rs->next) {
1013       $schema->resultset('MetaData')->create({
1014         book_id => $row->id,
1015         ...
1016       });
1017     }
1018   });
1019
1020 This won't either:
1021
1022   my $first_row = $large_rs->first;
1023   $schema->txn_do(sub { ... });
1024
1025 Transactions done for inserts in C<AutoCommit> mode when placeholders are in use
1026 are not affected, as they are done on an extra database handle.
1027
1028 Some workarounds:
1029
1030 =over 4
1031
1032 =item * use L<DBIx::Class::Storage::DBI::Replicated>
1033
1034 =item * L<connect|DBIx::Class::Schema/connect> another L<Schema|DBIx::Class::Schema>
1035
1036 =item * load the data from your cursor with L<DBIx::Class::ResultSet/all>
1037
1038 =back
1039
1040 =head1 MAXIMUM CONNECTIONS
1041
1042 The TDS protocol makes separate connections to the server for active statements
1043 in the background. By default the number of such connections is limited to 25,
1044 on both the client side and the server side.
1045
1046 This is a bit too low for a complex L<DBIx::Class> application, so on connection
1047 the client side setting is set to C<256> (see L<DBD::Sybase/maxConnect>.) You
1048 can override it to whatever setting you like in the DSN.
1049
1050 See
1051 L<http://infocenter.sybase.com/help/index.jsp?topic=/com.sybase.help.ase_15.0.sag1/html/sag1/sag1272.htm>
1052 for information on changing the setting on the server side.
1053
1054 =head1 DATES
1055
1056 See L</connect_call_datetime_setup> to setup date formats
1057 for L<DBIx::Class::InflateColumn::DateTime>.
1058
1059 =head1 TEXT/IMAGE COLUMNS
1060
1061 L<DBD::Sybase> compiled with FreeTDS will B<NOT> allow you to insert or update
1062 C<TEXT/IMAGE> columns.
1063
1064 Setting C<< $dbh->{LongReadLen} >> will also not work with FreeTDS use either:
1065
1066   $schema->storage->dbh->do("SET TEXTSIZE $bytes");
1067
1068 or
1069
1070   $schema->storage->set_textsize($bytes);
1071
1072 instead.
1073
1074 However, the C<LongReadLen> you pass in
1075 L<DBIx::Class::Storage::DBI/connect_info> is used to execute the equivalent
1076 C<SET TEXTSIZE> command on connection.
1077
1078 See L</connect_call_blob_setup> for a L<DBIx::Class::Storage::DBI/connect_info>
1079 setting you need to work with C<IMAGE> columns.
1080
1081 =head1 BULK API
1082
1083 The experimental L<DBD::Sybase> Bulk API support is used for
1084 L<populate|DBIx::Class::ResultSet/populate> in B<void> context, in a transaction
1085 on a separate connection.
1086
1087 To use this feature effectively, use a large number of rows for each
1088 L<populate|DBIx::Class::ResultSet/populate> call, eg.:
1089
1090   while (my $rows = $data_source->get_100_rows()) {
1091     $rs->populate($rows);
1092   }
1093
1094 B<NOTE:> the L<add_columns|DBIx::Class::ResultSource/add_columns>
1095 calls in your C<Result> classes B<must> list columns in database order for this
1096 to work. Also, you may have to unset the C<LANG> environment variable before
1097 loading your app, if it doesn't match the character set of your database.
1098
1099 When inserting IMAGE columns using this method, you'll need to use
1100 L</connect_call_blob_setup> as well.
1101
1102 =head1 TODO
1103
1104 =over
1105
1106 =item *
1107
1108 Transitions to AutoCommit=0 (starting a transaction) mode by exhausting
1109 any active cursors, using eager cursors.
1110
1111 =item *
1112
1113 Real limits and limited counts using stored procedures deployed on startup.
1114
1115 =item *
1116
1117 Adaptive Server Anywhere (ASA) support, with possible SQLA::Limit support.
1118
1119 =item *
1120
1121 Blob update with a LIKE query on a blob, without invalidating the WHERE condition.
1122
1123 =item *
1124
1125 bulk_insert using prepare_cached (see comments.)
1126
1127 =back
1128
1129 =head1 AUTHOR
1130
1131 See L<DBIx::Class/CONTRIBUTORS>.
1132
1133 =head1 LICENSE
1134
1135 You may distribute this code under the same terms as Perl itself.
1136
1137 =cut
1138 # vim:sts=2 sw=2: