lib/DBIx/Class/Storage/DBI/Sybase.pm

   1 package DBIx::Class::Storage::DBI::Sybase;
   2
   3 use strict;
   4 use warnings;
   5
   6 use base qw/
   7     DBIx::Class::Storage::DBI::Sybase::Common
   8     DBIx::Class::Storage::DBI::AutoCast
   9 /;
  10 use mro 'c3';
  11 use Carp::Clan qw/^DBIx::Class/;
  12 use List::Util ();
  13 use Sub::Name ();
  14
  15 __PACKAGE__->mk_group_accessors('simple' =>
  16     qw/_identity _blob_log_on_update _writer_storage _is_extra_storage
  17        _bulk_storage _is_bulk_storage _began_bulk_work
  18        _bulk_disabled_due_to_coderef_connect_info_warned
  19        _identity_method/
  20 );
  21
  22 my @also_proxy_to_extra_storages = qw/
  23   connect_call_set_auto_cast auto_cast connect_call_blob_setup
  24   connect_call_datetime_setup
  25
  26   disconnect _connect_info _sql_maker _sql_maker_opts disable_sth_caching
  27   auto_savepoint unsafe cursor_class debug debugobj schema
  28 /;
  29
  30 =head1 NAME
  31
  32 DBIx::Class::Storage::DBI::Sybase - Sybase support for DBIx::Class
  33
  34 =head1 SYNOPSIS
  35
  36 This subclass supports L<DBD::Sybase> for real Sybase databases.  If you are
  37 using an MSSQL database via L<DBD::Sybase>, your storage will be reblessed to
  38 L<DBIx::Class::Storage::DBI::Sybase::Microsoft_SQL_Server>.
  39
  40 =head1 DESCRIPTION
  41
  42 If your version of Sybase does not support placeholders, then your storage
  43 will be reblessed to L<DBIx::Class::Storage::DBI::Sybase::NoBindVars>. You can
  44 also enable that driver explicitly, see the documentation for more details.
  45
  46 With this driver there is unfortunately no way to get the C<last_insert_id>
  47 without doing a C<SELECT MAX(col)>. This is done safely in a transaction
  48 (locking the table.) See L</INSERTS WITH PLACEHOLDERS>.
  49
  50 A recommended L<DBIx::Class::Storage::DBI/connect_info> setting:
  51
  52   on_connect_call => [['datetime_setup'], ['blob_setup', log_on_update => 0]]
  53
  54 =head1 METHODS
  55
  56 =cut
  57
  58 sub _rebless {
  59   my $self = shift;
  60
  61   if (ref($self) eq 'DBIx::Class::Storage::DBI::Sybase') {
  62     my $dbtype = eval {
  63       @{$self->_get_dbh->selectrow_arrayref(qq{sp_server_info \@attribute_id=1})}[2]
  64     } || '';
  65
  66     my $exception = $@;
  67     $dbtype =~ s/\W/_/gi;
  68     my $subclass = "DBIx::Class::Storage::DBI::Sybase::${dbtype}";
  69
  70     if (!$exception && $dbtype && $self->load_optional_class($subclass)) {
  71       bless $self, $subclass;
  72       $self->_rebless;
  73     } else { # real Sybase
  74       my $no_bind_vars = 'DBIx::Class::Storage::DBI::Sybase::NoBindVars';
  75
  76       if ($self->using_freetds) {
  77         carp <<'EOF' unless $ENV{DBIC_SYBASE_FREETDS_NOWARN};
  78
  79 You are using FreeTDS with Sybase.
  80
  81 We will do our best to support this configuration, but please consider this
  82 support experimental.
  83
  84 TEXT/IMAGE columns will definitely not work.
  85
  86 You are encouraged to recompile DBD::Sybase with the Sybase Open Client libraries
  87 instead.
  88
  89 See perldoc DBIx::Class::Storage::DBI::Sybase for more details.
  90
  91 To turn off this warning set the DBIC_SYBASE_FREETDS_NOWARN environment
  92 variable.
  93 EOF
  94         if (not $self->_typeless_placeholders_supported) {
  95           if ($self->_placeholders_supported) {
  96             $self->auto_cast(1);
  97           } else {
  98             $self->ensure_class_loaded($no_bind_vars);
  99             bless $self, $no_bind_vars;
 100             $self->_rebless;
 101           }
 102         }
 103       }
 104       elsif (not $self->_get_dbh->{syb_dynamic_supported}) {
 105         # not necessarily FreeTDS, but no placeholders nevertheless
 106         $self->ensure_class_loaded($no_bind_vars);
 107         bless $self, $no_bind_vars;
 108         $self->_rebless;
 109       } elsif (not $self->_typeless_placeholders_supported) {
 110         # this is highly unlikely, but we check just in case
 111         $self->auto_cast(1);
 112       }
 113     }
 114   }
 115 }
 116
 117 sub _init {
 118   my $self = shift;
 119   $self->_set_max_connect(256);
 120
 121   # based on LongReadLen in connect_info
 122   $self->set_textsize if $self->using_freetds;
 123
 124 # create storage for insert/(update blob) transactions,
 125 # unless this is that storage
 126   return if $self->_is_extra_storage;
 127
 128   my $writer_storage = (ref $self)->new;
 129
 130   $writer_storage->_is_extra_storage(1);
 131   $writer_storage->connect_info($self->connect_info);
 132   $writer_storage->auto_cast($self->auto_cast);
 133
 134   $self->_writer_storage($writer_storage);
 135
 136 # create a bulk storage unless connect_info is a coderef
 137   return
 138     if (Scalar::Util::reftype($self->_dbi_connect_info->[0])||'') eq 'CODE';
 139
 140   my $bulk_storage = (ref $self)->new;
 141
 142   $bulk_storage->_is_extra_storage(1);
 143   $bulk_storage->_is_bulk_storage(1); # for special ->disconnect acrobatics
 144   $bulk_storage->connect_info($self->connect_info);
 145
 146 # this is why
 147   $bulk_storage->_dbi_connect_info->[0] .= ';bulkLogin=1';
 148
 149   $self->_bulk_storage($bulk_storage);
 150 }
 151
 152 for my $method (@also_proxy_to_extra_storages) {
 153   no strict 'refs';
 154   no warnings 'redefine';
 155
 156   my $replaced = __PACKAGE__->can($method);
 157
 158   *{$method} = Sub::Name::subname $method => sub {
 159     my $self = shift;
 160     $self->_writer_storage->$replaced(@_) if $self->_writer_storage;
 161     $self->_bulk_storage->$replaced(@_)   if $self->_bulk_storage;
 162     return $self->$replaced(@_);
 163   };
 164 }
 165
 166 sub disconnect {
 167   my $self = shift;
 168
 169 # Even though we call $sth->finish for uses off the bulk API, there's still an
 170 # "active statement" warning on disconnect, which we throw away here.
 171 # This is due to the bug described in insert_bulk.
 172 # Currently a noop because 'prepare' is used instead of 'prepare_cached'.
 173   local $SIG{__WARN__} = sub {
 174     warn $_[0] unless $_[0] =~ /active statement/i;
 175   } if $self->_is_bulk_storage;
 176
 177 # so that next transaction gets a dbh
 178   $self->_began_bulk_work(0) if $self->_is_bulk_storage;
 179
 180   $self->next::method;
 181 }
 182
 183 # Make sure we have CHAINED mode turned on if AutoCommit is off in non-FreeTDS
 184 # DBD::Sybase (since we don't know how DBD::Sybase was compiled.) If however
 185 # we're using FreeTDS, CHAINED mode turns on an implicit transaction which we
 186 # only want when AutoCommit is off.
 187 sub _populate_dbh {
 188   my $self = shift;
 189
 190   $self->next::method(@_);
 191
 192   if ($self->_is_bulk_storage) {
 193 # this should be cleared on every reconnect
 194     $self->_began_bulk_work(0);
 195     return;
 196   }
 197
 198   if (not $self->using_freetds) {
 199     $self->_dbh->{syb_chained_txn} = 1;
 200   } else {
 201     if ($self->_dbh_autocommit) {
 202       $self->_dbh->do('SET CHAINED OFF');
 203     } else {
 204       $self->_dbh->do('SET CHAINED ON');
 205     }
 206   }
 207 }
 208
 209 =head2 connect_call_blob_setup
 210
 211 Used as:
 212
 213   on_connect_call => [ [ 'blob_setup', log_on_update => 0 ] ]
 214
 215 Does C<< $dbh->{syb_binary_images} = 1; >> to return C<IMAGE> data as raw binary
 216 instead of as a hex string.
 217
 218 Recommended.
 219
 220 Also sets the C<log_on_update> value for blob write operations. The default is
 221 C<1>, but C<0> is better if your database is configured for it.
 222
 223 See
 224 L<DBD::Sybase/Handling_IMAGE/TEXT_data_with_syb_ct_get_data()/syb_ct_send_data()>.
 225
 226 =cut
 227
 228 sub connect_call_blob_setup {
 229   my $self = shift;
 230   my %args = @_;
 231   my $dbh = $self->_dbh;
 232   $dbh->{syb_binary_images} = 1;
 233
 234   $self->_blob_log_on_update($args{log_on_update})
 235     if exists $args{log_on_update};
 236 }
 237
 238 sub _is_lob_type {
 239   my $self = shift;
 240   my $type = shift;
 241   $type && $type =~ /(?:text|image|lob|bytea|binary|memo)/i;
 242 }
 243
 244 sub _is_lob_column {
 245   my ($self, $source, $column) = @_;
 246
 247   return $self->_is_lob_type($source->column_info($column)->{data_type});
 248 }
 249
 250 sub _prep_for_execute {
 251   my $self = shift;
 252   my ($op, $extra_bind, $ident, $args) = @_;
 253
 254   my ($sql, $bind) = $self->next::method (@_);
 255
 256   my $table = Scalar::Util::blessed($ident) ? $ident->from : $ident;
 257
 258   my $bind_info = $self->_resolve_column_info(
 259     $ident, [map $_->[0], @{$bind}]
 260   );
 261   my $bound_identity_col = List::Util::first
 262     { $bind_info->{$_}{is_auto_increment} }
 263     (keys %$bind_info)
 264   ;
 265   my $identity_col = Scalar::Util::blessed($ident) &&
 266     List::Util::first
 267     { $ident->column_info($_)->{is_auto_increment} }
 268     $ident->columns
 269   ;
 270
 271   if (($op eq 'insert' && $bound_identity_col) ||
 272       ($op eq 'update' && exists $args->[0]{$identity_col})) {
 273     $sql = join ("\n",
 274       $self->_set_table_identity_sql($op => $table, 'on'),
 275       $sql,
 276       $self->_set_table_identity_sql($op => $table, 'off'),
 277     );
 278   }
 279
 280   if ($op eq 'insert' && (not $bound_identity_col) && $identity_col) {
 281     $sql =
 282       "$sql\n" .
 283       $self->_fetch_identity_sql($ident, $identity_col);
 284   }
 285
 286   return ($sql, $bind);
 287 }
 288
 289 sub _set_table_identity_sql {
 290   my ($self, $op, $table, $on_off) = @_;
 291
 292   return sprintf 'SET IDENTITY_%s %s %s',
 293     uc($op), $self->sql_maker->_quote($table), uc($on_off);
 294 }
 295
 296 # Stolen from SQLT, with some modifications. This is a makeshift
 297 # solution before a sane type-mapping library is available, thus
 298 # the 'our' for easy overrides.
 299 our %TYPE_MAPPING  = (
 300     number    => 'numeric',
 301     money     => 'money',
 302     varchar   => 'varchar',
 303     varchar2  => 'varchar',
 304     timestamp => 'datetime',
 305     text      => 'varchar',
 306     real      => 'double precision',
 307     comment   => 'text',
 308     bit       => 'bit',
 309     tinyint   => 'smallint',
 310     float     => 'double precision',
 311     serial    => 'numeric',
 312     bigserial => 'numeric',
 313     boolean   => 'varchar',
 314     long      => 'varchar',
 315 );
 316
 317 sub _native_data_type {
 318   my ($self, $type) = @_;
 319
 320   $type = lc $type;
 321   $type =~ s/\s* identity//x;
 322
 323   return uc($TYPE_MAPPING{$type} || $type);
 324 }
 325
 326 sub _fetch_identity_sql {
 327   my ($self, $source, $col) = @_;
 328
 329   return sprintf ("SELECT MAX(%s) FROM %s",
 330     map { $self->sql_maker->_quote ($_) } ($col, $source->from)
 331   );
 332 }
 333
 334 sub _execute {
 335   my $self = shift;
 336   my ($op) = @_;
 337
 338   my ($rv, $sth, @bind) = $self->dbh_do($self->can('_dbh_execute'), @_);
 339
 340   if ($op eq 'insert') {
 341     $self->_identity($sth->fetchrow_array);
 342     $sth->finish;
 343   }
 344
 345   return wantarray ? ($rv, $sth, @bind) : $rv;
 346 }
 347
 348 sub last_insert_id { shift->_identity }
 349
 350 # handles TEXT/IMAGE and transaction for last_insert_id
 351 sub insert {
 352   my $self = shift;
 353   my ($source, $to_insert) = @_;
 354
 355   my $identity_col = (List::Util::first
 356     { $source->column_info($_)->{is_auto_increment} }
 357     $source->columns) || '';
 358
 359   # check for empty insert
 360   # INSERT INTO foo DEFAULT VALUES -- does not work with Sybase
 361   # try to insert explicit 'DEFAULT's instead (except for identity)
 362   if (not %$to_insert) {
 363     for my $col ($source->columns) {
 364       next if $col eq $identity_col;
 365       $to_insert->{$col} = \'DEFAULT';
 366     }
 367   }
 368
 369   my $blob_cols = $self->_remove_blob_cols($source, $to_insert);
 370
 371   # do we need the horrific SELECT MAX(COL) hack?
 372   my $dumb_last_insert_id =
 373        $identity_col
 374     && (not exists $to_insert->{$identity_col})
 375     && ($self->_identity_method||'') ne '@@IDENTITY';
 376
 377   my $next = $self->next::can;
 378
 379   # we are already in a transaction, or there are no blobs
 380   # and we don't need the PK - just (try to) do it
 381   if ($self->{transaction_depth}
 382         || (!$blob_cols && !$dumb_last_insert_id)
 383   ) {
 384     return $self->_insert (
 385       $next, $source, $to_insert, $blob_cols, $identity_col
 386     );
 387   }
 388
 389   # otherwise use the _writer_storage to do the insert+transaction on another
 390   # connection
 391   my $guard = $self->_writer_storage->txn_scope_guard;
 392
 393   my $updated_cols = $self->_writer_storage->_insert (
 394     $next, $source, $to_insert, $blob_cols, $identity_col
 395   );
 396
 397   $self->_identity($self->_writer_storage->_identity);
 398
 399   $guard->commit;
 400
 401   return $updated_cols;
 402 }
 403
 404 sub _insert {
 405   my ($self, $next, $source, $to_insert, $blob_cols, $identity_col) = @_;
 406
 407   my $updated_cols = $self->$next ($source, $to_insert);
 408
 409   my $final_row = {
 410     ($identity_col ?
 411       ($identity_col => $self->last_insert_id($source, $identity_col)) : ()),
 412     %$to_insert,
 413     %$updated_cols,
 414   };
 415
 416   $self->_insert_blobs ($source, $blob_cols, $final_row) if $blob_cols;
 417
 418   return $updated_cols;
 419 }
 420
 421 sub update {
 422   my $self = shift;
 423   my ($source, $fields, $where, @rest) = @_;
 424
 425   my $wantarray = wantarray;
 426
 427   my $blob_cols = $self->_remove_blob_cols($source, $fields);
 428
 429   my $table = $source->name;
 430
 431   my $identity_col = List::Util::first
 432     { $source->column_info($_)->{is_auto_increment} }
 433     $source->columns;
 434
 435   my $is_identity_update = $identity_col && defined $fields->{$identity_col};
 436
 437   return $self->next::method(@_) unless $blob_cols;
 438
 439 # If there are any blobs in $where, Sybase will return a descriptive error
 440 # message.
 441 # XXX blobs can still be used with a LIKE query, and this should be handled.
 442
 443 # update+blob update(s) done atomically on separate connection
 444   $self = $self->_writer_storage;
 445
 446   my $guard = $self->txn_scope_guard;
 447
 448 # First update the blob columns to be updated to '' (taken from $fields, where
 449 # it is originally put by _remove_blob_cols .)
 450   my %blobs_to_empty = map { ($_ => delete $fields->{$_}) } keys %$blob_cols;
 451
 452 # We can't only update NULL blobs, because blobs cannot be in the WHERE clause.
 453
 454   $self->next::method($source, \%blobs_to_empty, $where, @rest);
 455
 456 # Now update the blobs before the other columns in case the update of other
 457 # columns makes the search condition invalid.
 458   $self->_update_blobs($source, $blob_cols, $where);
 459
 460   my @res;
 461   if (%$fields) {
 462     if ($wantarray) {
 463       @res    = $self->next::method(@_);
 464     }
 465     elsif (defined $wantarray) {
 466       $res[0] = $self->next::method(@_);
 467     }
 468     else {
 469       $self->next::method(@_);
 470     }
 471   }
 472
 473   $guard->commit;
 474
 475   return $wantarray ? @res : $res[0];
 476 }
 477
 478 sub insert_bulk {
 479   my $self = shift;
 480   my ($source, $cols, $data) = @_;
 481
 482   my $identity_col = List::Util::first
 483     { $source->column_info($_)->{is_auto_increment} }
 484     $source->columns;
 485
 486   my $is_identity_insert = (List::Util::first
 487     { $_ eq $identity_col }
 488     @{$cols}
 489   ) ? 1 : 0;
 490
 491   my @source_columns = $source->columns;
 492
 493   my $use_bulk_api =
 494     $self->_bulk_storage &&
 495     $self->_get_dbh->{syb_has_blk};
 496
 497   if ((not $use_bulk_api) &&
 498       (Scalar::Util::reftype($self->_dbi_connect_info->[0])||'') eq 'CODE' &&
 499       (not $self->_bulk_disabled_due_to_coderef_connect_info_warned)) {
 500     carp <<'EOF';
 501 Bulk API support disabled due to use of a CODEREF connect_info. Reverting to
 502 regular array inserts.
 503 EOF
 504     $self->_bulk_disabled_due_to_coderef_connect_info_warned(1);
 505   }
 506
 507   if (not $use_bulk_api) {
 508     my $blob_cols = $self->_remove_blob_cols_array($source, $cols, $data);
 509
 510     my $dumb_last_insert_id =
 511          $identity_col
 512       && (not $is_identity_insert)
 513       && ($self->_identity_method||'') ne '@@IDENTITY';
 514
 515     ($self, my ($guard)) = do {
 516       if ($self->{transaction_depth} == 0 && $blob_cols &&
 517           $dumb_last_insert_id) {
 518         ($self->_writer_storage, $self->_writer_storage->txn_scope_guard);
 519       }
 520       else {
 521         ($self, undef);
 522       }
 523     };
 524
 525     $self->next::method(@_);
 526
 527     if ($blob_cols) {
 528       if ($is_identity_insert) {
 529         $self->_insert_blobs_array ($source, $blob_cols, $cols, $data);
 530       }
 531       else {
 532         my @cols_with_identities = (@$cols, $identity_col);
 533
 534         ## calculate identities
 535         # XXX This assumes identities always increase by 1, which may or may not
 536         # be true.
 537         my ($last_identity) =
 538           $self->_dbh->selectrow_array (
 539             $self->_fetch_identity_sql($source, $identity_col)
 540           );
 541         my @identities = (($last_identity - @$data + 1) .. $last_identity);
 542
 543         my @data_with_identities = map [@$_, shift @identities], @$data;
 544
 545         $self->_insert_blobs_array (
 546           $source, $blob_cols, \@cols_with_identities, \@data_with_identities
 547         );
 548       }
 549     }
 550
 551     $guard->commit if $guard;
 552     return;
 553   }
 554
 555 # otherwise, use the bulk API
 556
 557 # rearrange @$data so that columns are in database order
 558   my %orig_idx;
 559   @orig_idx{@$cols} = 0..$#$cols;
 560
 561   my %new_idx;
 562   @new_idx{@source_columns} = 0..$#source_columns;
 563
 564   my @new_data;
 565   for my $datum (@$data) {
 566     my $new_datum = [];
 567     for my $col (@source_columns) {
 568 # identity data will be 'undef' if not $is_identity_insert
 569 # columns with defaults will also be 'undef'
 570       $new_datum->[ $new_idx{$col} ] =
 571         exists $orig_idx{$col} ? $datum->[ $orig_idx{$col} ] : undef;
 572     }
 573     push @new_data, $new_datum;
 574   }
 575
 576 # bcp identity index is 1-based
 577   my $identity_idx = exists $new_idx{$identity_col} ?
 578     $new_idx{$identity_col} + 1 : 0;
 579
 580 ## Set a client-side conversion error handler, straight from DBD::Sybase docs.
 581 # This ignores any data conversion errors detected by the client side libs, as
 582 # they are usually harmless.
 583   my $orig_cslib_cb = DBD::Sybase::set_cslib_cb(
 584     Sub::Name::subname insert_bulk => sub {
 585       my ($layer, $origin, $severity, $errno, $errmsg, $osmsg, $blkmsg) = @_;
 586
 587       return 1 if $errno == 36;
 588
 589       carp
 590         "Layer: $layer, Origin: $origin, Severity: $severity, Error: $errno" .
 591         ($errmsg ? "\n$errmsg" : '') .
 592         ($osmsg  ? "\n$osmsg"  : '')  .
 593         ($blkmsg ? "\n$blkmsg" : '');
 594
 595       return 0;
 596   });
 597
 598   eval {
 599     my $bulk = $self->_bulk_storage;
 600
 601     my $guard = $bulk->txn_scope_guard;
 602
 603 ## XXX get this to work instead of our own $sth
 604 ## will require SQLA or *Hacks changes for ordered columns
 605 #    $bulk->next::method($source, \@source_columns, \@new_data, {
 606 #      syb_bcp_attribs => {
 607 #        identity_flag   => $is_identity_insert,
 608 #        identity_column => $identity_idx,
 609 #      }
 610 #    });
 611     my $sql = 'INSERT INTO ' .
 612       $bulk->sql_maker->_quote($source->name) . ' (' .
 613 # colname list is ignored for BCP, but does no harm
 614       (join ', ', map $bulk->sql_maker->_quote($_), @source_columns) . ') '.
 615       ' VALUES ('.  (join ', ', ('?') x @source_columns) . ')';
 616
 617 ## XXX there's a bug in the DBD::Sybase bulk support that makes $sth->finish for
 618 ## a prepare_cached statement ineffective. Replace with ->sth when fixed, or
 619 ## better yet the version above. Should be fixed in DBD::Sybase .
 620     my $sth = $bulk->_get_dbh->prepare($sql,
 621 #      'insert', # op
 622       {
 623         syb_bcp_attribs => {
 624           identity_flag   => $is_identity_insert,
 625           identity_column => $identity_idx,
 626         }
 627       }
 628     );
 629
 630     my @bind = do {
 631       my $idx = 0;
 632       map [ $_, $idx++ ], @source_columns;
 633     };
 634
 635     $self->_execute_array(
 636       $source, $sth, \@bind, \@source_columns, \@new_data, $guard
 637     );
 638
 639     $bulk->_query_end($sql);
 640   };
 641
 642   my $exception = $@;
 643   DBD::Sybase::set_cslib_cb($orig_cslib_cb);
 644
 645   if ($exception =~ /-Y option/) {
 646     carp <<"EOF";
 647
 648 Sybase bulk API operation failed due to character set incompatibility, reverting
 649 to regular array inserts:
 650
 651 *** Try unsetting the LANG environment variable.
 652
 653 $exception
 654 EOF
 655     $self->_bulk_storage(undef);
 656     unshift @_, $self;
 657     goto \&insert_bulk;
 658   }
 659   elsif ($exception) {
 660 # rollback makes the bulkLogin connection unusable
 661     $self->_bulk_storage->disconnect;
 662     $self->throw_exception($exception);
 663   }
 664 }
 665
 666 # Make sure blobs are not bound as placeholders, and return any non-empty ones
 667 # as a hash.
 668 sub _remove_blob_cols {
 669   my ($self, $source, $fields) = @_;
 670
 671   my %blob_cols;
 672
 673   for my $col (keys %$fields) {
 674     if ($self->_is_lob_column($source, $col)) {
 675       my $blob_val = delete $fields->{$col};
 676       if (not defined $blob_val) {
 677         $fields->{$col} = \'NULL';
 678       }
 679       else {
 680         $fields->{$col} = \"''";
 681         $blob_cols{$col} = $blob_val unless $blob_val eq '';
 682       }
 683     }
 684   }
 685
 686   return %blob_cols ? \%blob_cols : undef;
 687 }
 688
 689 # same for insert_bulk
 690 sub _remove_blob_cols_array {
 691   my ($self, $source, $cols, $data) = @_;
 692
 693   my @blob_cols;
 694
 695   for my $i (0..$#$cols) {
 696     my $col = $cols->[$i];
 697
 698     if ($self->_is_lob_column($source, $col)) {
 699       for my $j (0..$#$data) {
 700         my $blob_val = delete $data->[$j][$i];
 701         if (not defined $blob_val) {
 702           $data->[$j][$i] = \'NULL';
 703         }
 704         else {
 705           $data->[$j][$i] = \"''";
 706           $blob_cols[$j][$i] = $blob_val
 707             unless $blob_val eq '';
 708         }
 709       }
 710     }
 711   }
 712
 713   return @blob_cols ? \@blob_cols : undef;
 714 }
 715
 716 sub _update_blobs {
 717   my ($self, $source, $blob_cols, $where) = @_;
 718
 719   my (@primary_cols) = $source->primary_columns;
 720
 721   $self->throw_exception('Cannot update TEXT/IMAGE column(s) without a primary key')
 722     unless @primary_cols;
 723
 724 # check if we're updating a single row by PK
 725   my $pk_cols_in_where = 0;
 726   for my $col (@primary_cols) {
 727     $pk_cols_in_where++ if defined $where->{$col};
 728   }
 729   my @rows;
 730
 731   if ($pk_cols_in_where == @primary_cols) {
 732     my %row_to_update;
 733     @row_to_update{@primary_cols} = @{$where}{@primary_cols};
 734     @rows = \%row_to_update;
 735   } else {
 736     my $cursor = $self->select ($source, \@primary_cols, $where, {});
 737     @rows = map {
 738       my %row; @row{@primary_cols} = @$_; \%row
 739     } $cursor->all;
 740   }
 741
 742   for my $row (@rows) {
 743     $self->_insert_blobs($source, $blob_cols, $row);
 744   }
 745 }
 746
 747 sub _insert_blobs {
 748   my ($self, $source, $blob_cols, $row) = @_;
 749   my $dbh = $self->_get_dbh;
 750
 751   my $table = $source->name;
 752
 753   my %row = %$row;
 754   my (@primary_cols) = $source->primary_columns;
 755
 756   $self->throw_exception('Cannot update TEXT/IMAGE column(s) without a primary key')
 757     unless @primary_cols;
 758
 759   $self->throw_exception('Cannot update TEXT/IMAGE column(s) without primary key values')
 760     if ((grep { defined $row{$_} } @primary_cols) != @primary_cols);
 761
 762   for my $col (keys %$blob_cols) {
 763     my $blob = $blob_cols->{$col};
 764
 765     my %where = map { ($_, $row{$_}) } @primary_cols;
 766
 767     my $cursor = $self->select ($source, [$col], \%where, {});
 768     $cursor->next;
 769     my $sth = $cursor->sth;
 770
 771     if (not $sth) {
 772
 773       $self->throw_exception(
 774           "Could not find row in table '$table' for blob update:\n"
 775         . $self->_pretty_print (\%where)
 776       );
 777     }
 778
 779     eval {
 780       do {
 781         $sth->func('CS_GET', 1, 'ct_data_info') or die $sth->errstr;
 782       } while $sth->fetch;
 783
 784       $sth->func('ct_prepare_send') or die $sth->errstr;
 785
 786       my $log_on_update = $self->_blob_log_on_update;
 787       $log_on_update    = 1 if not defined $log_on_update;
 788
 789       $sth->func('CS_SET', 1, {
 790         total_txtlen => length($blob),
 791         log_on_update => $log_on_update
 792       }, 'ct_data_info') or die $sth->errstr;
 793
 794       $sth->func($blob, length($blob), 'ct_send_data') or die $sth->errstr;
 795
 796       $sth->func('ct_finish_send') or die $sth->errstr;
 797     };
 798     my $exception = $@;
 799     $sth->finish if $sth;
 800     if ($exception) {
 801       if ($self->using_freetds) {
 802         $self->throw_exception (
 803           'TEXT/IMAGE operation failed, probably because you are using FreeTDS: '
 804           . $exception
 805         );
 806       } else {
 807         $self->throw_exception($exception);
 808       }
 809     }
 810   }
 811 }
 812
 813 sub _insert_blobs_array {
 814   my ($self, $source, $blob_cols, $cols, $data) = @_;
 815
 816   for my $i (0..$#$data) {
 817     my $datum = $data->[$i];
 818
 819     my %row;
 820     @row{ @$cols } = @$datum;
 821
 822     my %blob_vals;
 823     for my $j (0..$#$cols) {
 824       if (exists $blob_cols->[$i][$j]) {
 825         $blob_vals{ $cols->[$j] } = $blob_cols->[$i][$j];
 826       }
 827     }
 828
 829     $self->_insert_blobs ($source, \%blob_vals, \%row);
 830   }
 831 }
 832
 833 =head2 connect_call_datetime_setup
 834
 835 Used as:
 836
 837   on_connect_call => 'datetime_setup'
 838
 839 In L<DBIx::Class::Storage::DBI/connect_info> to set:
 840
 841   $dbh->syb_date_fmt('ISO_strict'); # output fmt: 2004-08-21T14:36:48.080Z
 842   $dbh->do('set dateformat mdy');   # input fmt:  08/13/1979 18:08:55.080
 843
 844 On connection for use with L<DBIx::Class::InflateColumn::DateTime>, using
 845 L<DateTime::Format::Sybase>, which you will need to install.
 846
 847 This works for both C<DATETIME> and C<SMALLDATETIME> columns, although
 848 C<SMALLDATETIME> columns only have minute precision.
 849
 850 =cut
 851
 852 {
 853   my $old_dbd_warned = 0;
 854
 855   sub connect_call_datetime_setup {
 856     my $self = shift;
 857     my $dbh = $self->_get_dbh;
 858
 859     if ($dbh->can('syb_date_fmt')) {
 860       # amazingly, this works with FreeTDS
 861       $dbh->syb_date_fmt('ISO_strict');
 862     } elsif (not $old_dbd_warned) {
 863       carp "Your DBD::Sybase is too old to support ".
 864       "DBIx::Class::InflateColumn::DateTime, please upgrade!";
 865       $old_dbd_warned = 1;
 866     }
 867
 868     $dbh->do('SET DATEFORMAT mdy');
 869
 870     1;
 871   }
 872 }
 873
 874 sub datetime_parser_type { "DateTime::Format::Sybase" }
 875
 876 # ->begin_work and such have no effect with FreeTDS but we run them anyway to
 877 # let the DBD keep any state it needs to.
 878 #
 879 # If they ever do start working, the extra statements will do no harm (because
 880 # Sybase supports nested transactions.)
 881
 882 sub _dbh_begin_work {
 883   my $self = shift;
 884
 885 # bulkLogin=1 connections are always in a transaction, and can only call BEGIN
 886 # TRAN once. However, we need to make sure there's a $dbh.
 887   return if $self->_is_bulk_storage && $self->_dbh && $self->_began_bulk_work;
 888
 889   $self->next::method(@_);
 890
 891   if ($self->using_freetds) {
 892     $self->_get_dbh->do('BEGIN TRAN');
 893   }
 894
 895   $self->_began_bulk_work(1) if $self->_is_bulk_storage;
 896 }
 897
 898 sub _dbh_commit {
 899   my $self = shift;
 900   if ($self->using_freetds) {
 901     $self->_dbh->do('COMMIT');
 902   }
 903   return $self->next::method(@_);
 904 }
 905
 906 sub _dbh_rollback {
 907   my $self = shift;
 908   if ($self->using_freetds) {
 909     $self->_dbh->do('ROLLBACK');
 910   }
 911   return $self->next::method(@_);
 912 }
 913
 914 # savepoint support using ASE syntax
 915
 916 sub _svp_begin {
 917   my ($self, $name) = @_;
 918
 919   $self->_get_dbh->do("SAVE TRANSACTION $name");
 920 }
 921
 922 # A new SAVE TRANSACTION with the same name releases the previous one.
 923 sub _svp_release { 1 }
 924
 925 sub _svp_rollback {
 926   my ($self, $name) = @_;
 927
 928   $self->_get_dbh->do("ROLLBACK TRANSACTION $name");
 929 }
 930
 931 1;
 932
 933 =head1 Schema::Loader Support
 934
 935 There is an experimental branch of L<DBIx::Class::Schema::Loader> that will
 936 allow you to dump a schema from most (if not all) versions of Sybase.
 937
 938 It is available via subversion from:
 939
 940   http://dev.catalyst.perl.org/repos/bast/branches/DBIx-Class-Schema-Loader/current/
 941
 942 =head1 FreeTDS
 943
 944 This driver supports L<DBD::Sybase> compiled against FreeTDS
 945 (L<http://www.freetds.org/>) to the best of our ability, however it is
 946 recommended that you recompile L<DBD::Sybase> against the Sybase Open Client
 947 libraries. They are a part of the Sybase ASE distribution:
 948
 949 The Open Client FAQ is here:
 950 L<http://www.isug.com/Sybase_FAQ/ASE/section7.html>.
 951
 952 Sybase ASE for Linux (which comes with the Open Client libraries) may be
 953 downloaded here: L<http://response.sybase.com/forms/ASE_Linux_Download>.
 954
 955 To see if you're using FreeTDS check C<< $schema->storage->using_freetds >>, or run:
 956
 957   perl -MDBI -le 'my $dbh = DBI->connect($dsn, $user, $pass); print $dbh->{syb_oc_version}'
 958
 959 Some versions of the libraries involved will not support placeholders, in which
 960 case the storage will be reblessed to
 961 L<DBIx::Class::Storage::DBI::Sybase::NoBindVars>.
 962
 963 In some configurations, placeholders will work but will throw implicit type
 964 conversion errors for anything that's not expecting a string. In such a case,
 965 the C<auto_cast> option from L<DBIx::Class::Storage::DBI::AutoCast> is
 966 automatically set, which you may enable on connection with
 967 L<DBIx::Class::Storage::DBI::AutoCast/connect_call_set_auto_cast>. The type info
 968 for the C<CAST>s is taken from the L<DBIx::Class::ResultSource/data_type>
 969 definitions in your Result classes, and are mapped to a Sybase type (if it isn't
 970 already) using a mapping based on L<SQL::Translator>.
 971
 972 In other configurations, placeholers will work just as they do with the Sybase
 973 Open Client libraries.
 974
 975 Inserts or updates of TEXT/IMAGE columns will B<NOT> work with FreeTDS.
 976
 977 =head1 INSERTS WITH PLACEHOLDERS
 978
 979 With placeholders enabled, inserts are done in a transaction so that there are
 980 no concurrency issues with getting the inserted identity value using
 981 C<SELECT MAX(col)>, which is the only way to get the C<IDENTITY> value in this
 982 mode.
 983
 984 In addition, they are done on a separate connection so that it's possible to
 985 have active cursors when doing an insert.
 986
 987 When using C<DBIx::Class::Storage::DBI::Sybase::NoBindVars> transactions are
 988 disabled, as there are no concurrency issues with C<SELECT @@IDENTITY> as it's a
 989 session variable.
 990
 991 =head1 TRANSACTIONS
 992
 993 Due to limitations of the TDS protocol, L<DBD::Sybase>, or both; you cannot
 994 begin a transaction while there are active cursors; nor can you use multiple
 995 active cursors within a transaction. An active cursor is, for example, a
 996 L<ResultSet|DBIx::Class::ResultSet> that has been executed using C<next> or
 997 C<first> but has not been exhausted or L<reset|DBIx::Class::ResultSet/reset>.
 998
 999 For example, this will not work:
1000
1001   $schema->txn_do(sub {
1002     my $rs = $schema->resultset('Book');
1003     while (my $row = $rs->next) {
1004       $schema->resultset('MetaData')->create({
1005         book_id => $row->id,
1006         ...
1007       });
1008     }
1009   });
1010
1011 This won't either:
1012
1013   my $first_row = $large_rs->first;
1014   $schema->txn_do(sub { ... });
1015
1016 Transactions done for inserts in C<AutoCommit> mode when placeholders are in use
1017 are not affected, as they are done on an extra database handle.
1018
1019 Some workarounds:
1020
1021 =over 4
1022
1023 =item * use L<DBIx::Class::Storage::DBI::Replicated>
1024
1025 =item * L<connect|DBIx::Class::Schema/connect> another L<Schema|DBIx::Class::Schema>
1026
1027 =item * load the data from your cursor with L<DBIx::Class::ResultSet/all>
1028
1029 =back
1030
1031 =head1 MAXIMUM CONNECTIONS
1032
1033 The TDS protocol makes separate connections to the server for active statements
1034 in the background. By default the number of such connections is limited to 25,
1035 on both the client side and the server side.
1036
1037 This is a bit too low for a complex L<DBIx::Class> application, so on connection
1038 the client side setting is set to C<256> (see L<DBD::Sybase/maxConnect>.) You
1039 can override it to whatever setting you like in the DSN.
1040
1041 See
1042 L<http://infocenter.sybase.com/help/index.jsp?topic=/com.sybase.help.ase_15.0.sag1/html/sag1/sag1272.htm>
1043 for information on changing the setting on the server side.
1044
1045 =head1 DATES
1046
1047 See L</connect_call_datetime_setup> to setup date formats
1048 for L<DBIx::Class::InflateColumn::DateTime>.
1049
1050 =head1 TEXT/IMAGE COLUMNS
1051
1052 L<DBD::Sybase> compiled with FreeTDS will B<NOT> allow you to insert or update
1053 C<TEXT/IMAGE> columns.
1054
1055 Setting C<< $dbh->{LongReadLen} >> will also not work with FreeTDS use either:
1056
1057   $schema->storage->dbh->do("SET TEXTSIZE $bytes");
1058
1059 or
1060
1061   $schema->storage->set_textsize($bytes);
1062
1063 instead.
1064
1065 However, the C<LongReadLen> you pass in
1066 L<DBIx::Class::Storage::DBI/connect_info> is used to execute the equivalent
1067 C<SET TEXTSIZE> command on connection.
1068
1069 See L</connect_call_blob_setup> for a L<DBIx::Class::Storage::DBI/connect_info>
1070 setting you need to work with C<IMAGE> columns.
1071
1072 =head1 BULK API
1073
1074 The experimental L<DBD::Sybase> Bulk API support is used for
1075 L<populate|DBIx::Class::ResultSet/populate> in B<void> context, in a transaction
1076 on a separate connection.
1077
1078 To use this feature effectively, use a large number of rows for each
1079 L<populate|DBIx::Class::ResultSet/populate> call, eg.:
1080
1081   while (my $rows = $data_source->get_100_rows()) {
1082     $rs->populate($rows);
1083   }
1084
1085 B<NOTE:> the L<add_columns|DBIx::Class::ResultSource/add_columns>
1086 calls in your C<Result> classes B<must> list columns in database order for this
1087 to work. Also, you may have to unset the C<LANG> environment variable before
1088 loading your app, if it doesn't match the character set of your database.
1089
1090 When inserting IMAGE columns using this method, you'll need to use
1091 L</connect_call_blob_setup> as well.
1092
1093 =head1 TODO
1094
1095 =over
1096
1097 =item *
1098
1099 Transitions to AutoCommit=0 (starting a transaction) mode by exhausting
1100 any active cursors, using eager cursors.
1101
1102 =item *
1103
1104 Real limits and limited counts using stored procedures deployed on startup.
1105
1106 =item *
1107
1108 Adaptive Server Anywhere (ASA) support, with possible SQLA::Limit support.
1109
1110 =item *
1111
1112 Blob update with a LIKE query on a blob, without invalidating the WHERE condition.
1113
1114 =item *
1115
1116 bulk_insert using prepare_cached (see comments.)
1117
1118 =back
1119
1120 =head1 AUTHOR
1121
1122 See L<DBIx::Class/CONTRIBUTORS>.
1123
1124 =head1 LICENSE
1125
1126 You may distribute this code under the same terms as Perl itself.
1127
1128 =cut
1129 # vim:sts=2 sw=2: