lib/DBIx/Class/Storage/DBI/Sybase.pm

   1 package DBIx::Class::Storage::DBI::Sybase;
   2
   3 use strict;
   4 use warnings;
   5 use Try::Tiny;
   6
   7 use base qw/DBIx::Class::Storage::DBI/;
   8
   9 =head1 NAME
  10
  11 DBIx::Class::Storage::DBI::Sybase - Base class for drivers using
  12 L<DBD::Sybase>
  13
  14 =head1 DESCRIPTION
  15
  16 This is the base class/dispatcher for Storage's designed to work with
  17 L<DBD::Sybase>
  18
  19 =head1 METHODS
  20
  21 =cut
  22
  23 sub _rebless {
  24   my $self = shift;
  25
  26   my $dbtype;
  27   try {
  28     $dbtype = @{$self->_get_dbh->selectrow_arrayref(qq{sp_server_info \@attribute_id=1})}[2]
  29   } catch {
  30     $self->throw_exception("Unable to estable connection to determine database type: $_")
  31   };
  32
  33   if ($dbtype) {
  34     $dbtype =~ s/\W/_/gi;
  35
  36     # saner class name
  37     $dbtype = 'ASE' if $dbtype eq 'SQL_Server';
  38
  39     my $subclass = __PACKAGE__ . "::$dbtype";
  40     if ($self->load_optional_class($subclass)) {
  41       bless $self, $subclass;
  42       $self->_rebless;
  43     }
  44   }
  45 }
  46
  47 sub _ping {
  48   my $self = shift;
  49
  50   my $dbh = $self->_dbh or return 0;
  51
  52   local $dbh->{RaiseError} = 1;
  53   local $dbh->{PrintError} = 0;
  54
  55   if ($dbh->{syb_no_child_con}) {
  56 # if extra connections are not allowed, then ->ping is reliable
  57     return try { $dbh->ping } catch { 0; };
  58   }
  59
  60   return try {
  61 # XXX if the main connection goes stale, does opening another for this statement
  62 # really determine anything?
  63     $dbh->do('select 1');
  64     1;
  65   } catch {
  66     0;
  67   };
  68 }
  69
  70 sub _set_max_connect {
  71   my $self = shift;
  72   my $val  = shift || 256;
  73
  74   my $dsn = $self->_dbi_connect_info->[0];
  75
  76   return if ref($dsn) eq 'CODE';
  77
  78   if ($dsn !~ /maxConnect=/) {
  79     $self->_dbi_connect_info->[0] = "$dsn;maxConnect=$val";
  80     my $connected = defined $self->_dbh;
  81     $self->disconnect;
  82     $self->ensure_connected if $connected;
  83   }
  84 }
  85
  86 =head2 using_freetds
  87
  88 Whether or not L<DBD::Sybase> was compiled against FreeTDS. If false, it means
  89 the Sybase OpenClient libraries were used.
  90
  91 =cut
  92
  93 sub using_freetds {
  94   my $self = shift;
  95
  96   return $self->_get_dbh->{syb_oc_version} =~ /freetds/i;
  97 }
  98
  99 =head2 set_textsize
 100
 101 When using FreeTDS and/or MSSQL, C<< $dbh->{LongReadLen} >> is not available,
 102 use this function instead. It does:
 103
 104   $dbh->do("SET TEXTSIZE $bytes");
 105
 106 Takes the number of bytes, or uses the C<LongReadLen> value from your
 107 L<connect_info|DBIx::Class::Storage::DBI/connect_info> if omitted, lastly falls
 108 back to the C<32768> which is the L<DBD::Sybase> default.
 109
 110 =cut
 111
 112 sub set_textsize {
 113   my $self = shift;
 114   my $text_size =
 115     shift
 116       ||
 117     try { $self->_dbi_connect_info->[-1]->{LongReadLen} }
 118       ||
 119     32768; # the DBD::Sybase default
 120
 121   return unless defined $text_size;
 122
 123   $self->_dbh->do("SET TEXTSIZE $text_size");
 124 }
 125
 126 1;
 127
 128 =head1 AUTHORS
 129
 130 See L<DBIx::Class/CONTRIBUTORS>.
 131
 132 =head1 LICENSE
 133
 134 You may distribute this code under the same terms as Perl itself.
 135
 136 =cut