lib/DBIx/Class/Storage/DBI/Sybase.pm

   1 package DBIx::Class::Storage::DBI::Sybase;
   2
   3 use strict;
   4 use warnings;
   5 use DBIx::Class::_Util 'dbic_internal_try';
   6 use Try::Tiny;
   7 use namespace::clean;
   8
   9 use base qw/DBIx::Class::Storage::DBI/;
  10
  11 =head1 NAME
  12
  13 DBIx::Class::Storage::DBI::Sybase - Base class for drivers using
  14 L<DBD::Sybase>
  15
  16 =head1 DESCRIPTION
  17
  18 This is the base class/dispatcher for Storage's designed to work with
  19 L<DBD::Sybase>
  20
  21 =head1 METHODS
  22
  23 =cut
  24
  25 sub _rebless { shift->_determine_connector_driver('Sybase') }
  26
  27 sub _get_rdbms_name {
  28   my $self = shift;
  29
  30   dbic_internal_try {
  31     my $name = $self->_get_dbh->selectrow_arrayref('sp_server_info @attribute_id=1')->[2];
  32
  33     if ($name) {
  34       $name =~ s/\W/_/gi;
  35
  36       # saner class name
  37       $name = 'ASE' if $name eq 'SQL_Server';
  38     }
  39
  40     $name;  # RV
  41   } catch {
  42     $self->throw_exception("Unable to establish connection to determine database type: $_")
  43   };
  44 }
  45
  46 sub _init {
  47   # once the driver is determined see if we need to insert the DBD::Sybase w/ FreeTDS fixups
  48   # this is a dirty version of "instance role application", \o/ DO WANT Moo \o/
  49   my $self = shift;
  50   if (! $self->isa('DBIx::Class::Storage::DBI::Sybase::FreeTDS') and $self->_using_freetds) {
  51     require DBIx::Class::Storage::DBI::Sybase::FreeTDS;
  52
  53     my @isa = @{mro::get_linear_isa(ref $self)};
  54     my $class = shift @isa; # this is our current ref
  55
  56     my $trait_class = $class . '::FreeTDS';
  57     mro::set_mro ($trait_class, 'c3');
  58     no strict 'refs';
  59     @{"${trait_class}::ISA"} = ($class, 'DBIx::Class::Storage::DBI::Sybase::FreeTDS', @isa);
  60
  61     bless ($self, $trait_class);
  62
  63     Class::C3->reinitialize() if DBIx::Class::_ENV_::OLD_MRO;
  64
  65     $self->_init(@_);
  66   }
  67
  68   $self->next::method(@_);
  69 }
  70
  71 sub _ping {
  72   my $self = shift;
  73
  74   my $dbh = $self->_dbh or return 0;
  75
  76   local $dbh->{RaiseError} = 1;
  77   local $dbh->{PrintError} = 0;
  78
  79 # FIXME if the main connection goes stale, does opening another for this statement
  80 # really determine anything?
  81 # FIXME (2) THIS MAKES 0 SENSE!!! Need to test later
  82   if ($dbh->{syb_no_child_con}) {
  83     return dbic_internal_try {
  84       $self->_connect->do('select 1');
  85       1;
  86     }
  87     catch {
  88       0;
  89     };
  90   }
  91
  92   return (
  93     (dbic_internal_try {
  94       $dbh->do('select 1');
  95       1;
  96     })
  97       ? 1
  98       : 0
  99   );
 100 }
 101
 102 sub _set_max_connect {
 103   my $self = shift;
 104   my $val  = shift || 256;
 105
 106   my $dsn = $self->_dbi_connect_info->[0];
 107
 108   return if ref($dsn) eq 'CODE';
 109
 110   if ($dsn !~ /maxConnect=/) {
 111     $self->_dbi_connect_info->[0] = "$dsn;maxConnect=$val";
 112     my $connected = defined $self->_dbh;
 113     $self->disconnect;
 114     $self->ensure_connected if $connected;
 115   }
 116 }
 117
 118 # Whether or not DBD::Sybase was compiled against FreeTDS. If false, it means
 119 # the Sybase OpenClient libraries were used.
 120 sub _using_freetds {
 121   my $self = shift;
 122   return ($self->_get_dbh->{syb_oc_version}||'') =~ /freetds/i;
 123 }
 124
 125 # Either returns the FreeTDS version against which DBD::Sybase was compiled,
 126 # 0 if can't be determined, or undef otherwise
 127 sub _using_freetds_version {
 128   my $inf = shift->_get_dbh->{syb_oc_version};
 129   return undef unless ($inf||'') =~ /freetds/i;
 130   return $inf =~ /v([0-9\.]+)/ ? $1 : 0;
 131 }
 132
 133 =head1 FURTHER QUESTIONS?
 134
 135 Check the list of L<additional DBIC resources|DBIx::Class/GETTING HELP/SUPPORT>.
 136
 137 =head1 COPYRIGHT AND LICENSE
 138
 139 This module is free software L<copyright|DBIx::Class/COPYRIGHT AND LICENSE>
 140 by the L<DBIx::Class (DBIC) authors|DBIx::Class/AUTHORS>. You can
 141 redistribute it and/or modify it under the same terms as the
 142 L<DBIx::Class library|DBIx::Class/COPYRIGHT AND LICENSE>.
 143
 144 =cut
 145
 146 1;
 147