lib/DBIx/Class/Storage/DBI/Sybase.pm

   1 package DBIx::Class::Storage::DBI::Sybase;
   2
   3 use strict;
   4 use warnings;
   5 use Try::Tiny;
   6
   7 use base qw/DBIx::Class::Storage::DBI/;
   8
   9 =head1 NAME
  10
  11 DBIx::Class::Storage::DBI::Sybase - Base class for drivers using
  12 L<DBD::Sybase>
  13
  14 =head1 DESCRIPTION
  15
  16 This is the base class/dispatcher for Storage's designed to work with
  17 L<DBD::Sybase>
  18
  19 =head1 METHODS
  20
  21 =cut
  22
  23 sub _rebless {
  24   my $self = shift;
  25
  26   my $dbtype;
  27   try {
  28     $dbtype = @{$self->_get_dbh->selectrow_arrayref(qq{sp_server_info \@attribute_id=1})}[2]
  29   } catch {
  30     $self->throw_exception("Unable to estable connection to determine database type: $_")
  31   };
  32
  33   if ($dbtype) {
  34     $dbtype =~ s/\W/_/gi;
  35
  36     # saner class name
  37     $dbtype = 'ASE' if $dbtype eq 'SQL_Server';
  38
  39     my $subclass = __PACKAGE__ . "::$dbtype";
  40     if ($self->load_optional_class($subclass)) {
  41       bless $self, $subclass;
  42       $self->_rebless;
  43     }
  44   }
  45 }
  46
  47 sub _ping {
  48   my $self = shift;
  49
  50   my $dbh = $self->_dbh or return 0;
  51
  52   local $dbh->{RaiseError} = 1;
  53   local $dbh->{PrintError} = 0;
  54
  55   if ($dbh->{syb_no_child_con}) {
  56 # if extra connections are not allowed, then ->ping is reliable
  57     my $ping = eval { $dbh->ping };
  58     return $@ ? 0 : $ping;
  59   }
  60
  61   my $rc = 1;
  62   try {
  63 # XXX if the main connection goes stale, does opening another for this statement
  64 # really determine anything?
  65     $dbh->do('select 1');
  66   } catch {
  67     $rc = 0;
  68   };
  69
  70   return $rc;
  71 }
  72
  73 sub _set_max_connect {
  74   my $self = shift;
  75   my $val  = shift || 256;
  76
  77   my $dsn = $self->_dbi_connect_info->[0];
  78
  79   return if ref($dsn) eq 'CODE';
  80
  81   if ($dsn !~ /maxConnect=/) {
  82     $self->_dbi_connect_info->[0] = "$dsn;maxConnect=$val";
  83     my $connected = defined $self->_dbh;
  84     $self->disconnect;
  85     $self->ensure_connected if $connected;
  86   }
  87 }
  88
  89 =head2 using_freetds
  90
  91 Whether or not L<DBD::Sybase> was compiled against FreeTDS. If false, it means
  92 the Sybase OpenClient libraries were used.
  93
  94 =cut
  95
  96 sub using_freetds {
  97   my $self = shift;
  98
  99   return $self->_get_dbh->{syb_oc_version} =~ /freetds/i;
 100 }
 101
 102 =head2 set_textsize
 103
 104 When using FreeTDS and/or MSSQL, C<< $dbh->{LongReadLen} >> is not available,
 105 use this function instead. It does:
 106
 107   $dbh->do("SET TEXTSIZE $bytes");
 108
 109 Takes the number of bytes, or uses the C<LongReadLen> value from your
 110 L<connect_info|DBIx::Class::Storage::DBI/connect_info> if omitted, lastly falls
 111 back to the C<32768> which is the L<DBD::Sybase> default.
 112
 113 =cut
 114
 115 sub set_textsize {
 116   my $self = shift;
 117   my $text_size = shift ||
 118     eval { $self->_dbi_connect_info->[-1]->{LongReadLen} } ||
 119     32768; # the DBD::Sybase default
 120
 121   return unless defined $text_size;
 122
 123   $self->_dbh->do("SET TEXTSIZE $text_size");
 124 }
 125
 126 1;
 127
 128 =head1 AUTHORS
 129
 130 See L<DBIx::Class/CONTRIBUTORS>.
 131
 132 =head1 LICENSE
 133
 134 You may distribute this code under the same terms as Perl itself.
 135
 136 =cut