lib/DBIx/Class/Storage/DBI/SQLite.pm

   1 package DBIx::Class::Storage::DBI::SQLite;
   2
   3 use strict;
   4 use warnings;
   5
   6 use base qw/DBIx::Class::Storage::DBI/;
   7 use mro 'c3';
   8
   9 use SQL::Abstract 'is_plain_value';
  10 use DBIx::Class::_Util qw(modver_gt_or_eq sigwarn_silencer);
  11 use DBIx::Class::Carp;
  12 use Try::Tiny;
  13 use namespace::clean;
  14
  15 __PACKAGE__->sql_maker_class('DBIx::Class::SQLMaker::SQLite');
  16 __PACKAGE__->sql_limit_dialect ('LimitOffset');
  17 __PACKAGE__->sql_quote_char ('"');
  18 __PACKAGE__->datetime_parser_type ('DateTime::Format::SQLite');
  19
  20 =head1 NAME
  21
  22 DBIx::Class::Storage::DBI::SQLite - Automatic primary key class for SQLite
  23
  24 =head1 SYNOPSIS
  25
  26   # In your table classes
  27   use base 'DBIx::Class::Core';
  28   __PACKAGE__->set_primary_key('id');
  29
  30 =head1 DESCRIPTION
  31
  32 This class implements autoincrements for SQLite.
  33
  34 =head2 Known Issues
  35
  36 =over
  37
  38 =item RT79576
  39
  40  NOTE - This section applies to you only if ALL of these are true:
  41
  42   * You are or were using DBD::SQLite with a version lesser than 1.38_01
  43
  44   * You are or were using DBIx::Class versions between 0.08191 and 0.08209
  45     (inclusive) or between 0.08240-TRIAL and 0.08242-TRIAL (also inclusive)
  46
  47   * You use objects with overloaded stringification and are feeding them
  48     to DBIC CRUD methods directly
  49
  50 An unfortunate chain of events led to DBIx::Class silently hitting the problem
  51 described in L<RT#79576|https://rt.cpan.org/Public/Bug/Display.html?id=79576>.
  52
  53 In order to trigger the bug condition one needs to supply B<more than one>
  54 bind value that is an object with overloaded stringification (numification
  55 is not relevant, only stringification is). When this is the case the internal
  56 DBIx::Class call to C<< $sth->bind_param >> would be executed in a way that
  57 triggers the above-mentioned DBD::SQLite bug. As a result all the logs and
  58 tracers will contain the expected values, however SQLite will receive B<all>
  59 these bind positions being set to the value of the B<last> supplied
  60 stringifiable object.
  61
  62 Even if you upgrade DBIx::Class (which works around the bug starting from
  63 version 0.08210) you may still have corrupted/incorrect data in your database.
  64 DBIx::Class warned about this condition for several years, hoping to give
  65 anyone affected sufficient notice of the potential issues. The warning was
  66 removed in version 0.082900.
  67
  68 =back
  69
  70 =head1 METHODS
  71
  72 =cut
  73
  74 sub backup {
  75
  76   require File::Spec;
  77   require File::Copy;
  78   require POSIX;
  79
  80   my ($self, $dir) = @_;
  81   $dir ||= './';
  82
  83   ## Where is the db file?
  84   my $dsn = $self->_dbi_connect_info()->[0];
  85
  86   my $dbname = $1 if($dsn =~ /dbname=([^;]+)/);
  87   if(!$dbname)
  88   {
  89     $dbname = $1 if($dsn =~ /^dbi:SQLite:(.+)$/i);
  90   }
  91   $self->throw_exception("Cannot determine name of SQLite db file")
  92     if(!$dbname || !-f $dbname);
  93
  94 #  print "Found database: $dbname\n";
  95 #  my $dbfile = file($dbname);
  96   my ($vol, $dbdir, $file) = File::Spec->splitpath($dbname);
  97 #  my $file = $dbfile->basename();
  98   $file = POSIX::strftime("%Y-%m-%d-%H_%M_%S", localtime()) . $file;
  99   $file = "B$file" while(-f $file);
 100
 101   mkdir($dir) unless -f $dir;
 102   my $backupfile = File::Spec->catfile($dir, $file);
 103
 104   my $res = File::Copy::copy($dbname, $backupfile);
 105   $self->throw_exception("Backup failed! ($!)") if(!$res);
 106
 107   return $backupfile;
 108 }
 109
 110 sub _exec_svp_begin {
 111   my ($self, $name) = @_;
 112
 113   $self->_dbh->do("SAVEPOINT $name");
 114 }
 115
 116 sub _exec_svp_release {
 117   my ($self, $name) = @_;
 118
 119   $self->_dbh->do("RELEASE SAVEPOINT $name");
 120 }
 121
 122 sub _exec_svp_rollback {
 123   my ($self, $name) = @_;
 124
 125   $self->_dbh->do("ROLLBACK TO SAVEPOINT $name");
 126 }
 127
 128 # older SQLite has issues here too - both of these are in fact
 129 # completely benign warnings (or at least so say the tests)
 130 sub _exec_txn_rollback {
 131   local $SIG{__WARN__} = sigwarn_silencer( qr/rollback ineffective/ )
 132     unless $DBD::SQLite::__DBIC_TXN_SYNC_SANE__;
 133
 134   shift->next::method(@_);
 135 }
 136
 137 sub _exec_txn_commit {
 138   local $SIG{__WARN__} = sigwarn_silencer( qr/commit ineffective/ )
 139     unless $DBD::SQLite::__DBIC_TXN_SYNC_SANE__;
 140
 141   shift->next::method(@_);
 142 }
 143
 144 sub _ping {
 145   my $self = shift;
 146
 147   # Be extremely careful what we do here. SQLite is notoriously bad at
 148   # synchronizing its internal transaction state with {AutoCommit}
 149   # https://metacpan.org/source/ADAMK/DBD-SQLite-1.37/lib/DBD/SQLite.pm#L921
 150   # There is a function http://www.sqlite.org/c3ref/get_autocommit.html
 151   # but DBD::SQLite does not expose it (nor does it seem to properly use it)
 152
 153   # Therefore only execute a "ping" when we have no other choice *AND*
 154   # scrutinize the thrown exceptions to make sure we are where we think we are
 155   my $dbh = $self->_dbh or return undef;
 156   return undef unless $dbh->FETCH('Active');
 157   return undef unless $dbh->ping;
 158
 159   my $ping_fail;
 160
 161   # older DBD::SQLite does not properly synchronize commit state between
 162   # the libsqlite and the $dbh
 163   unless (defined $DBD::SQLite::__DBIC_TXN_SYNC_SANE__) {
 164     $DBD::SQLite::__DBIC_TXN_SYNC_SANE__ = modver_gt_or_eq('DBD::SQLite', '1.38_02');
 165   }
 166
 167   # fallback to travesty
 168   unless ($DBD::SQLite::__DBIC_TXN_SYNC_SANE__) {
 169     # since we do not have access to sqlite3_get_autocommit(), do a trick
 170     # to attempt to *safely* determine what state are we *actually* in.
 171     # FIXME
 172     # also using T::T here leads to bizarre leaks - will figure it out later
 173     my $really_not_in_txn = do {
 174       local $@;
 175
 176       # older versions of DBD::SQLite do not properly detect multiline BEGIN/COMMIT
 177       # statements to adjust their {AutoCommit} state. Hence use such a statement
 178       # pair here as well, in order to escape from poking {AutoCommit} needlessly
 179       # https://rt.cpan.org/Public/Bug/Display.html?id=80087
 180       eval {
 181         # will fail instantly if already in a txn
 182         $dbh->do("-- multiline\nBEGIN");
 183         $dbh->do("-- multiline\nCOMMIT");
 184         1;
 185       } or do {
 186         ($@ =~ /transaction within a transaction/)
 187           ? 0
 188           : undef
 189         ;
 190       };
 191     };
 192
 193     # if we were unable to determine this - we may very well be dead
 194     if (not defined $really_not_in_txn) {
 195       $ping_fail = 1;
 196     }
 197     # check the AC sync-state
 198     elsif ($really_not_in_txn xor $dbh->{AutoCommit}) {
 199       carp_unique (sprintf
 200         'Internal transaction state of handle %s (apparently %s a transaction) does not seem to '
 201       . 'match its AutoCommit attribute setting of %s - this is an indication of a '
 202       . 'potentially serious bug in your transaction handling logic',
 203         $dbh,
 204         $really_not_in_txn ? 'NOT in' : 'in',
 205         $dbh->{AutoCommit} ? 'TRUE' : 'FALSE',
 206       );
 207
 208       # it is too dangerous to execute anything else in this state
 209       # assume everything works (safer - worst case scenario next statement throws)
 210       return 1;
 211     }
 212   }
 213
 214   # do the actual test and return on no failure
 215   ( $ping_fail ||= ! try { $dbh->do('SELECT * FROM sqlite_master LIMIT 1'); 1 } )
 216     or return 1; # the actual RV of _ping()
 217
 218   # ping failed (or so it seems) - need to do some cleanup
 219   # it is possible to have a proper "connection", and have "ping" return
 220   # false anyway (e.g. corrupted file). In such cases DBD::SQLite still
 221   # keeps the actual file handle open. We don't really want this to happen,
 222   # so force-close the handle via DBI itself
 223   #
 224   local $@; # so that we do not clobber the real error as set above
 225   eval { $dbh->disconnect }; # if it fails - it fails
 226   undef; # the actual RV of _ping()
 227 }
 228
 229 sub deployment_statements {
 230   my $self = shift;
 231   my ($schema, $type, $version, $dir, $sqltargs, @rest) = @_;
 232
 233   $sqltargs ||= {};
 234
 235   if (
 236     ! exists $sqltargs->{producer_args}{sqlite_version}
 237       and
 238     my $dver = $self->_server_info->{normalized_dbms_version}
 239   ) {
 240     $sqltargs->{producer_args}{sqlite_version} = $dver;
 241   }
 242
 243   $self->next::method($schema, $type, $version, $dir, $sqltargs, @rest);
 244 }
 245
 246 sub bind_attribute_by_data_type {
 247
 248   # According to http://www.sqlite.org/datatype3.html#storageclasses
 249   # all numeric types are dynamically allocated up to 8 bytes per
 250   # individual value
 251   # Thus it should be safe and non-wasteful to bind everything as
 252   # SQL_BIGINT and have SQLite deal with storage/comparisons however
 253   # it deems correct
 254   $_[1] =~ /^ (?: int(?:[1248]|eger)? | (?:tiny|small|medium|big)int ) $/ix
 255     ? DBI::SQL_BIGINT()
 256     : undef
 257   ;
 258 }
 259
 260 # FIXME - what the flying fuck... work around RT#76395
 261 # DBD::SQLite warns on binding >32 bit values with 32 bit IVs
 262 sub _dbh_execute {
 263   if (
 264     (
 265       DBIx::Class::_ENV_::IV_SIZE < 8
 266         or
 267       DBIx::Class::_ENV_::OS_NAME eq 'MSWin32'
 268     )
 269       and
 270     ! defined $DBD::SQLite::__DBIC_CHECK_dbd_mishandles_bound_BIGINT
 271   ) {
 272     $DBD::SQLite::__DBIC_CHECK_dbd_mishandles_bound_BIGINT = (
 273       modver_gt_or_eq('DBD::SQLite', '1.37')
 274     ) ? 1 : 0;
 275   }
 276
 277   local $SIG{__WARN__} = sigwarn_silencer( qr/
 278     \Qdatatype mismatch: bind\E \s (?:
 279       param \s+ \( \d+ \) \s+ [-+]? \d+ (?: \. 0*)? \Q as integer\E
 280         |
 281       \d+ \s type \s @{[ DBI::SQL_BIGINT() ]} \s as \s [-+]? \d+ (?: \. 0*)?
 282     )
 283   /x ) if (
 284     (
 285       DBIx::Class::_ENV_::IV_SIZE < 8
 286         or
 287       DBIx::Class::_ENV_::OS_NAME eq 'MSWin32'
 288     )
 289       and
 290     $DBD::SQLite::__DBIC_CHECK_dbd_mishandles_bound_BIGINT
 291   );
 292
 293   shift->next::method(@_);
 294 }
 295
 296 # DBD::SQLite (at least up to version 1.31 has a bug where it will
 297 # non-fatally numify a string value bound as an integer, resulting
 298 # in insertions of '0' into supposed-to-be-numeric fields
 299 # Since this can result in severe data inconsistency, remove the
 300 # bind attr if such a situation is detected
 301 #
 302 # FIXME - when a DBD::SQLite version is released that eventually fixes
 303 # this situation (somehow) - no-op this override once a proper DBD
 304 # version is detected
 305 sub _dbi_attrs_for_bind {
 306   my ($self, $ident, $bind) = @_;
 307
 308   my $bindattrs = $self->next::method($ident, $bind);
 309
 310   if (! defined $DBD::SQLite::__DBIC_CHECK_dbd_can_bind_bigint_values) {
 311     $DBD::SQLite::__DBIC_CHECK_dbd_can_bind_bigint_values
 312       = modver_gt_or_eq('DBD::SQLite', '1.37') ? 1 : 0;
 313   }
 314
 315   for my $i (0.. $#$bindattrs) {
 316     if (
 317       defined $bindattrs->[$i]
 318         and
 319       defined $bind->[$i][1]
 320         and
 321       grep { $bindattrs->[$i] eq $_ } (
 322         DBI::SQL_INTEGER(), DBI::SQL_TINYINT(), DBI::SQL_SMALLINT(), DBI::SQL_BIGINT()
 323       )
 324     ) {
 325       if ( $bind->[$i][1] !~ /^ [\+\-]? [0-9]+ (?: \. 0* )? $/x ) {
 326         carp_unique( sprintf (
 327           "Non-integer value supplied for column '%s' despite the integer datatype",
 328           $bind->[$i][0]{dbic_colname} || "# $i"
 329         ) );
 330         undef $bindattrs->[$i];
 331       }
 332       elsif (
 333         ! $DBD::SQLite::__DBIC_CHECK_dbd_can_bind_bigint_values
 334       ) {
 335         # unsigned 32 bit ints have a range of −2,147,483,648 to 2,147,483,647
 336         # alternatively expressed as the hexadecimal numbers below
 337         # the comparison math will come out right regardless of ivsize, since
 338         # we are operating within 31 bits
 339         # P.S. 31 because one bit is lost for the sign
 340         if ($bind->[$i][1] > 0x7fff_ffff or $bind->[$i][1] < -0x8000_0000) {
 341           carp_unique( sprintf (
 342             "An integer value occupying more than 32 bits was supplied for column '%s' "
 343           . 'which your version of DBD::SQLite (%s) can not bind properly so DBIC '
 344           . 'will treat it as a string instead, consider upgrading to at least '
 345           . 'DBD::SQLite version 1.37',
 346             $bind->[$i][0]{dbic_colname} || "# $i",
 347             DBD::SQLite->VERSION,
 348           ) );
 349           undef $bindattrs->[$i];
 350         }
 351         else {
 352           $bindattrs->[$i] = DBI::SQL_INTEGER()
 353         }
 354       }
 355     }
 356   }
 357
 358   return $bindattrs;
 359 }
 360
 361 =head2 connect_call_use_foreign_keys
 362
 363 Used as:
 364
 365     on_connect_call => 'use_foreign_keys'
 366
 367 In L<connect_info|DBIx::Class::Storage::DBI/connect_info> to turn on foreign key
 368 (including cascading) support for recent versions of SQLite and L<DBD::SQLite>.
 369
 370 Executes:
 371
 372   PRAGMA foreign_keys = ON
 373
 374 See L<http://www.sqlite.org/foreignkeys.html> for more information.
 375
 376 =cut
 377
 378 sub connect_call_use_foreign_keys {
 379   my $self = shift;
 380
 381   $self->_do_query(
 382     'PRAGMA foreign_keys = ON'
 383   );
 384 }
 385
 386 =head1 FURTHER QUESTIONS?
 387
 388 Check the list of L<additional DBIC resources|DBIx::Class/GETTING HELP/SUPPORT>.
 389
 390 =head1 COPYRIGHT AND LICENSE
 391
 392 This module is free software L<copyright|DBIx::Class/COPYRIGHT AND LICENSE>
 393 by the L<DBIx::Class (DBIC) authors|DBIx::Class/AUTHORS>. You can
 394 redistribute it and/or modify it under the same terms as the
 395 L<DBIx::Class library|DBIx::Class/COPYRIGHT AND LICENSE>.
 396
 397 =cut
 398
 399 1;