lib/DBIx/Class/Storage/DBI/SQLAnywhere.pm

   1 package DBIx::Class::Storage::DBI::SQLAnywhere;
   2
   3 use strict;
   4 use warnings;
   5 use base qw/DBIx::Class::Storage::DBI::UniqueIdentifier/;
   6 use mro 'c3';
   7 use List::Util 'first';
   8 use Try::Tiny;
   9 use namespace::clean;
  10
  11 __PACKAGE__->mk_group_accessors(simple => qw/_identity/);
  12 __PACKAGE__->sql_limit_dialect ('RowNumberOver');
  13
  14 =head1 NAME
  15
  16 DBIx::Class::Storage::DBI::SQLAnywhere - Driver for Sybase SQL Anywhere
  17
  18 =head1 DESCRIPTION
  19
  20 This class implements autoincrements for Sybase SQL Anywhere, selects the
  21 RowNumberOver limit implementation and provides
  22 L<DBIx::Class::InflateColumn::DateTime> support.
  23
  24 You need the C<DBD::SQLAnywhere> driver that comes with the SQL Anywhere
  25 distribution, B<NOT> the one on CPAN. It is usually under a path such as:
  26
  27   /opt/sqlanywhere11/sdk/perl
  28
  29 Recommended L<connect_info|DBIx::Class::Storage::DBI/connect_info> settings:
  30
  31   on_connect_call => 'datetime_setup'
  32
  33 =head1 METHODS
  34
  35 =cut
  36
  37 sub last_insert_id { shift->_identity }
  38
  39 sub _new_uuid { 'UUIDTOSTR(NEWID())' }
  40
  41 sub insert {
  42   my $self = shift;
  43   my ($source, $to_insert) = @_;
  44
  45   my $identity_col =
  46     first { $source->column_info($_)->{is_auto_increment} } $source->columns;
  47
  48 # user might have an identity PK without is_auto_increment
  49   if (not $identity_col) {
  50     foreach my $pk_col ($source->primary_columns) {
  51       if (not exists $to_insert->{$pk_col} &&
  52           $source->column_info($pk_col)->{data_type} !~ /^uniqueidentifier/i)
  53       {
  54         $identity_col = $pk_col;
  55         last;
  56       }
  57     }
  58   }
  59
  60   if ($identity_col && (not exists $to_insert->{$identity_col})) {
  61     my $dbh = $self->_get_dbh;
  62     my $table_name = $source->from;
  63     $table_name    = $$table_name if ref $table_name;
  64
  65     my ($identity) = try {
  66       $dbh->selectrow_array("SELECT GET_IDENTITY('$table_name')")
  67     };
  68
  69     if (defined $identity) {
  70       $to_insert->{$identity_col} = $identity;
  71       $self->_identity($identity);
  72     }
  73   }
  74
  75   return $self->next::method(@_);
  76 }
  77
  78 # convert UUIDs to strings in selects
  79 sub _select_args {
  80   my $self = shift;
  81   my ($ident, $select) = @_;
  82
  83   my $col_info = $self->_resolve_column_info($ident);
  84
  85   for my $select_idx (0..$#$select) {
  86     my $selected = $select->[$select_idx];
  87
  88     next if ref $selected;
  89
  90     my $data_type = $col_info->{$selected}{data_type};
  91
  92     if ($data_type && lc($data_type) eq 'uniqueidentifier') {
  93       $select->[$select_idx] = { UUIDTOSTR => $selected };
  94     }
  95   }
  96
  97   return $self->next::method(@_);
  98 }
  99
 100 # this sub stolen from MSSQL
 101
 102 sub build_datetime_parser {
 103   my $self = shift;
 104   my $type = "DateTime::Format::Strptime";
 105   try {
 106     eval "require ${type}"
 107   }
 108   catch {
 109     $self->throw_exception("Couldn't load ${type}: $_");
 110   };
 111
 112   return $type->new( pattern => '%Y-%m-%d %H:%M:%S.%6N' );
 113 }
 114
 115 =head2 connect_call_datetime_setup
 116
 117 Used as:
 118
 119     on_connect_call => 'datetime_setup'
 120
 121 In L<connect_info|DBIx::Class::Storage::DBI/connect_info> to set the date and
 122 timestamp formats (as temporary options for the session) for use with
 123 L<DBIx::Class::InflateColumn::DateTime>.
 124
 125 The C<TIMESTAMP> data type supports up to 6 digits after the decimal point for
 126 second precision. The full precision is used.
 127
 128 The C<DATE> data type supposedly stores hours and minutes too, according to the
 129 documentation, but I could not get that to work. It seems to only store the
 130 date.
 131
 132 You will need the L<DateTime::Format::Strptime> module for inflation to work.
 133
 134 =cut
 135
 136 sub connect_call_datetime_setup {
 137   my $self = shift;
 138
 139   $self->_do_query(
 140     "set temporary option timestamp_format = 'yyyy-mm-dd hh:mm:ss.ssssss'"
 141   );
 142   $self->_do_query(
 143     "set temporary option date_format      = 'yyyy-mm-dd hh:mm:ss.ssssss'"
 144   );
 145 }
 146
 147 sub _svp_begin {
 148     my ($self, $name) = @_;
 149
 150     $self->_get_dbh->do("SAVEPOINT $name");
 151 }
 152
 153 # can't release savepoints that have been rolled back
 154 sub _svp_release { 1 }
 155
 156 sub _svp_rollback {
 157     my ($self, $name) = @_;
 158
 159     $self->_get_dbh->do("ROLLBACK TO SAVEPOINT $name")
 160 }
 161
 162 1;
 163
 164 =head1 MAXIMUM CURSORS
 165
 166 A L<DBIx::Class> application can use a lot of cursors, due to the usage of
 167 L<prepare_cached|DBI/prepare_cached>.
 168
 169 The default cursor maximum is C<50>, which can be a bit too low. This limit can
 170 be turned off (or increased) by the DBA by executing:
 171
 172   set option max_statement_count = 0
 173   set option max_cursor_count    = 0
 174
 175 Highly recommended.
 176
 177 =head1 AUTHOR
 178
 179 See L<DBIx::Class/AUTHOR> and L<DBIx::Class/CONTRIBUTORS>.
 180
 181 =head1 LICENSE
 182
 183 You may distribute this code under the same terms as Perl itself.
 184
 185 =cut